configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for buildscript filename
  92 AC_ARG_WITH(buildscript,
  93         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  94         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  95
  96 # Help line for libfetch
  97 AC_ARG_ENABLE(internal-download,
  98         AS_HELP_STRING([--disable-internal-download], [do not build with libfetch support]),
  99         [internaldownload=$enableval], [internaldownload=yes])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.6 python2.5 python], [false])
 130
 131 # find installed gettext
 132 AM_GNU_GETTEXT([external])
 133 AM_GNU_GETTEXT_VERSION(0.13.1)
 134
 135 # Check for libarchive
 136 AC_CHECK_LIB([archive], [archive_read_data], ,
 137         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 138
 139 # Enable or disable usage of libfetch
 140 AC_MSG_CHECKING(whether to link with libfetch)
 141 if test "x$internaldownload" = "xyes" ; then
 142         AC_MSG_RESULT(yes)
 143         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 144         # Check for a download library if it was actually requested
 145         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 146                 AC_MSG_ERROR([libfetch is needed to compile with internal download support]), [-lcrypto -ldl] )
 147         # Check if libfetch supports conditional GET
 148         # (version >=2.21, struct url has member last_modified)
 149         AC_CHECK_MEMBER(struct url.last_modified, ,
 150                 AC_MSG_ERROR([libfetch must be version 2.21 or greater]),
 151                 [#include <fetch.h>] )
 152 else
 153         AC_MSG_RESULT(no)
 154 fi
 155 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 156
 157 # Checks for header files.
 158 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 159
 160 # Checks for typedefs, structures, and compiler characteristics.
 161 AC_C_INLINE
 162 AC_TYPE_MODE_T
 163 AC_TYPE_OFF_T
 164 AC_TYPE_PID_T
 165 AC_TYPE_SIZE_T
 166 AC_STRUCT_TM
 167 AC_TYPE_UID_T
 168
 169 # Checks for library functions.
 170 AC_FUNC_FORK
 171 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 172 AC_FUNC_MKTIME
 173 AC_TYPE_SIGNAL
 174 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 175                 strndup strrchr strsep swprintf \
 176                 wcwidth uname])
 177
 178 # Enable large file support if available
 179 AC_SYS_LARGEFILE
 180
 181 # Check if we can use symbol visibility support in GCC
 182 GCC_VISIBILITY_CC
 183 # Check if we have -fgnu89-inline flag
 184 GCC_GNU89_INLINE_CC
 185
 186 # Host-dependant definitions
 187 SIZECMD="stat -L -c %s"
 188 SEDINPLACE="sed -i"
 189 STRIP_BINARIES="--strip-all"
 190 STRIP_SHARED="--strip-unneeded"
 191 STRIP_STATIC="--strip-debug"
 192 case "${host_os}" in
 193         *bsd*)
 194                 SIZECMD="stat -L -f %z"
 195                 SEDINPLACE="sed -i ''"
 196                 ;;
 197         cygwin*)
 198                 host_os_cygwin=yes
 199                 CFLAGS="$CFLAGS -DCYGWIN"
 200                 ;;
 201         darwin*)
 202                 host_os_darwin=yes
 203                 SIZECMD="/usr/bin/stat -L -f %z"
 204                 SEDINPLACE="/usr/bin/sed -i ''"
 205                 STRIP_BINARIES=""
 206                 STRIP_SHARED="-S"
 207                 STRIP_STATIC="-S"
 208                 ;;
 209 esac
 210
 211 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 212 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 213 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 214 AC_SUBST(SIZECMD)
 215 AC_SUBST(SEDINPLACE)
 216 AC_SUBST(STRIP_BINARIES)
 217 AC_SUBST(STRIP_SHARED)
 218 AC_SUBST(STRIP_STATIC)
 219
 220 # Check for architecture, used in default makepkg.conf
 221 # (Note single space left after CARCHFLAGS)
 222 case "${host}" in
 223         i686-*)
 224                 CARCH="i686"
 225                 CARCHFLAGS="-march=i686 "
 226                 ;;
 227         x86_64-*)
 228                 CARCH="x86_64"
 229                 CARCHFLAGS="-march=x86-64 "
 230                 ;;
 231         ia64-*)
 232                 CARCH="ia64"
 233                 CARCHFLAGS="-march=ia64 "
 234                 ;;
 235         sparc-*)
 236                 CARCH="sparc"
 237                 CARCHFLAGS="-mcpu=v9 "
 238                 ;;
 239         ppc-* | powerpc-*)
 240                 CARCH="ppc"
 241                 CARCHFLAGS="-mcpu=750 "
 242                 ;;
 243         i386-*)
 244                 CARCH="i386"
 245                 CARCHFLAGS="-march=i386 "
 246                 ;;
 247         arm-*)
 248                 CARCH="arm"
 249                 CARCHFLAGS="-march=armv4 "
 250                 ;;
 251         *)
 252                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 253                 CARCH="unknown"
 254                 CARCHFLAGS=""
 255                 ;;
 256 esac
 257
 258 # Now do some things common to all architectures
 259 CHOST="${host}"
 260 AC_SUBST(CARCH)
 261 AC_SUBST(CARCHFLAGS)
 262 AC_SUBST(CHOST)
 263
 264 # Check for documentation support and status
 265 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 266 AC_MSG_CHECKING([for building documentation])
 267 if test "x$wantdoc" = "xyes" ; then
 268         if test $ASCIIDOC ; then
 269                 AC_MSG_RESULT([yes, enabled by configure])
 270         else
 271                 asciidoc="(warning : asciidoc not installed)"
 272                 AC_MSG_RESULT([yes $asciidoc])
 273         fi
 274         wantdoc=yes
 275 else
 276         AC_MSG_RESULT([no, disabled by configure])
 277         wantdoc=no
 278 fi
 279 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 280
 281 # Check for doxygen support and status
 282 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 283 AC_MSG_CHECKING([for doxygen])
 284 if test "x$wantdoxygen" = "xyes" ; then
 285         if test $DOXYGEN ; then
 286                 AC_MSG_RESULT([yes])
 287                 usedoxygen=yes
 288         else
 289                 AC_MSG_RESULT([no, doxygen missing])
 290                 usedoxygen=no
 291         fi
 292 else
 293         AC_MSG_RESULT([no, disabled by configure])
 294         usedoxygen=no
 295 fi
 296 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 297
 298 # Enable or disable debug code
 299 AC_MSG_CHECKING(for debug mode request)
 300 if test "x$debug" = "xyes" ; then
 301         AC_MSG_RESULT(yes)
 302         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 303         # Check for mcheck
 304         AC_CHECK_HEADERS([mcheck.h])
 305         # Check for -fstack-protector availability
 306         GCC_STACK_PROTECT_LIB
 307         GCC_STACK_PROTECT_CC
 308         CFLAGS="$CFLAGS -g -Wall -Werror"
 309 else
 310         AC_MSG_RESULT(no)
 311         CFLAGS="$CFLAGS -Wall"
 312 fi
 313
 314 # Enable or disable use of git version in pacman version string
 315 AC_MSG_CHECKING(whether to use git version if available)
 316 if test "x$wantgitver" = "xyes" ; then
 317         AC_CHECK_PROGS([GIT], [git])
 318         AC_CHECK_FILE([.git/], hasgitdir=yes)
 319         if test $GIT -a "x$hasgitdir" = "xyes"; then
 320                 AC_MSG_RESULT([yes])
 321                 usegitver=yes
 322                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 323         else
 324                 AC_MSG_RESULT([no, git or .git dir missing])
 325                 usegitver=no
 326         fi
 327 else
 328         AC_MSG_RESULT([no, disabled by configure])
 329         usegitver=no
 330 fi
 331 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 332
 333 # Set root directory
 334 AC_SUBST(ROOTDIR)
 335 # Set package file extension
 336 AC_SUBST(PKGEXT)
 337 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 338 # Set source package file extension
 339 AC_SUBST(SRCEXT)
 340 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 341 # Set database file extension
 342 AC_SUBST(DBEXT)
 343 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 344 # Set makepkg build script name
 345 AC_SUBST(BUILDSCRIPT)
 346 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 347
 348 # Configuration files
 349 AC_CONFIG_FILES([
 350 lib/libalpm/Makefile
 351 lib/libalpm/po/Makefile.in
 352 src/pacman/Makefile
 353 src/util/Makefile
 354 scripts/Makefile
 355 doc/Makefile
 356 etc/Makefile
 357 po/Makefile.in
 358 test/pacman/Makefile
 359 test/pacman/tests/Makefile
 360 test/util/Makefile
 361 contrib/Makefile
 362 Makefile
 363 ])
 364 AC_OUTPUT
 365
 366 echo "
 367 ${PACKAGE_NAME}:
 368
 369   Build information:
 370     source code location   : ${srcdir}
 371     prefix                 : ${prefix}
 372     sysconfdir             : $(eval echo ${sysconfdir})
 373        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 374     localstatedir          : $(eval echo ${localstatedir})
 375        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 376        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 377     compiler               : ${CC}
 378     compiler flags         : ${CFLAGS}
 379     defines                : ${DEFS}
 380
 381     Architecture           : ${CARCH}
 382     Architecture flags     : ${CARCHFLAGS}
 383     Host Type              : ${CHOST}
 384     Filesize command       : ${SIZECMD}
 385     In-place sed command   : ${SEDINPLACE}
 386
 387     libalpm version        : ${LIB_VERSION}
 388     libalpm version info   : ${LIB_VERSION_INFO}
 389     pacman version         : ${PACKAGE_VERSION}
 390     using git version      : ${usegitver}
 391
 392   Directory and file information:
 393     root working directory : ${ROOTDIR}
 394     package extension      : ${PKGEXT}
 395     source pkg extension   : ${SRCEXT}
 396     database extension     : ${DBEXT}
 397     build script name      : ${BUILDSCRIPT}
 398
 399   Compilation options:
 400     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 401     Use download library   : ${internaldownload}
 402     Doxygen support        : ${usedoxygen}
 403     debug support          : ${debug}
 404 "
 405
 406 # vim:set ts=2 sw=2 noet: