configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_CHECK_PROGS([BASH], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libfetch
 153 AC_MSG_CHECKING(whether to link with libfetch)
 154 AS_IF([test "x$with_fetch" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157         [if test "x$with_fetch" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 159         fi],
 160         [-lcrypto -ldl])
 161         # Check if libfetch supports connnection caching which we use
 162         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 163         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 164                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 165                 [#include <fetch.h>])
 166         ])
 167         ],
 168         AC_MSG_RESULT(no))
 169 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 170
 171 # Checks for header files.
 172 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 173
 174 # Checks for typedefs, structures, and compiler characteristics.
 175 AC_C_INLINE
 176 AC_TYPE_MODE_T
 177 AC_TYPE_OFF_T
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_STRUCT_TM
 181 AC_TYPE_UID_T
 182
 183 # Checks for library functions.
 184 AC_FUNC_FORK
 185 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 186 AC_FUNC_MKTIME
 187 AC_TYPE_SIGNAL
 188 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 189                 strndup strrchr strsep swprintf \
 190                 wcwidth uname])
 191
 192 # Enable large file support if available
 193 AC_SYS_LARGEFILE
 194
 195 # Check if we can use symbol visibility support in GCC
 196 GCC_VISIBILITY_CC
 197 # Check if we have -fgnu89-inline flag
 198 GCC_GNU89_INLINE_CC
 199
 200 # Host-dependant definitions
 201 SIZECMD="stat -L -c %s"
 202 SEDINPLACE="sed -i"
 203 STRIP_BINARIES="--strip-all"
 204 STRIP_SHARED="--strip-unneeded"
 205 STRIP_STATIC="--strip-debug"
 206 case "${host_os}" in
 207         *bsd*)
 208                 SIZECMD="stat -L -f %z"
 209                 SEDINPLACE="sed -i ''"
 210                 ;;
 211         cygwin*)
 212                 host_os_cygwin=yes
 213                 CFLAGS="$CFLAGS -DCYGWIN"
 214                 ;;
 215         darwin*)
 216                 host_os_darwin=yes
 217                 SIZECMD="/usr/bin/stat -L -f %z"
 218                 SEDINPLACE="/usr/bin/sed -i ''"
 219                 STRIP_BINARIES=""
 220                 STRIP_SHARED="-S"
 221                 STRIP_STATIC="-S"
 222                 ;;
 223 esac
 224
 225 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 226 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 227 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 228 AC_SUBST(SIZECMD)
 229 AC_SUBST(SEDINPLACE)
 230 AC_SUBST(STRIP_BINARIES)
 231 AC_SUBST(STRIP_SHARED)
 232 AC_SUBST(STRIP_STATIC)
 233
 234 # Check for architecture, used in default makepkg.conf
 235 # (Note single space left after CARCHFLAGS)
 236 case "${host}" in
 237         i686-*)
 238                 CARCH="i686"
 239                 CARCHFLAGS="-march=i686 "
 240                 ;;
 241         x86_64-*)
 242                 CARCH="x86_64"
 243                 CARCHFLAGS="-march=x86-64 "
 244                 ;;
 245         ia64-*)
 246                 CARCH="ia64"
 247                 CARCHFLAGS="-march=ia64 "
 248                 ;;
 249         sparc-*)
 250                 CARCH="sparc"
 251                 CARCHFLAGS="-mcpu=v9 "
 252                 ;;
 253         ppc-* | powerpc-*)
 254                 CARCH="ppc"
 255                 CARCHFLAGS="-mcpu=750 "
 256                 ;;
 257         i386-*)
 258                 CARCH="i386"
 259                 CARCHFLAGS="-march=i386 "
 260                 ;;
 261         arm-*)
 262                 CARCH="arm"
 263                 CARCHFLAGS="-march=armv4 "
 264                 ;;
 265         *)
 266                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 267                 CARCH="unknown"
 268                 CARCHFLAGS=""
 269                 ;;
 270 esac
 271
 272 # Now do some things common to all architectures
 273 CHOST="${host}"
 274 AC_SUBST(CARCH)
 275 AC_SUBST(CARCHFLAGS)
 276 AC_SUBST(CHOST)
 277
 278 # Check for documentation support and status
 279 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 280 AC_MSG_CHECKING([for building documentation])
 281 if test "x$wantdoc" = "xyes" ; then
 282         if test $ASCIIDOC ; then
 283                 AC_MSG_RESULT([yes, enabled by configure])
 284         else
 285                 asciidoc="(warning : asciidoc not installed)"
 286                 AC_MSG_RESULT([yes $asciidoc])
 287         fi
 288         wantdoc=yes
 289 else
 290         AC_MSG_RESULT([no, disabled by configure])
 291         wantdoc=no
 292 fi
 293 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 294
 295 # Check for doxygen support and status
 296 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 297 AC_MSG_CHECKING([for doxygen])
 298 if test "x$wantdoxygen" = "xyes" ; then
 299         if test $DOXYGEN ; then
 300                 AC_MSG_RESULT([yes])
 301                 usedoxygen=yes
 302         else
 303                 AC_MSG_RESULT([no, doxygen missing])
 304                 usedoxygen=no
 305         fi
 306 else
 307         AC_MSG_RESULT([no, disabled by configure])
 308         usedoxygen=no
 309 fi
 310 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 311
 312 # Enable or disable debug code
 313 AC_MSG_CHECKING(for debug mode request)
 314 if test "x$debug" = "xyes" ; then
 315         AC_MSG_RESULT(yes)
 316         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 317         # Check for mcheck
 318         AC_CHECK_HEADERS([mcheck.h])
 319         # Check for -fstack-protector availability
 320         GCC_STACK_PROTECT_LIB
 321         GCC_STACK_PROTECT_CC
 322         GCC_FORTIFY_SOURCE_CC
 323         CFLAGS="$CFLAGS -g -Wall -Werror"
 324 else
 325         AC_MSG_RESULT(no)
 326         CFLAGS="$CFLAGS -Wall"
 327 fi
 328
 329 # Enable or disable use of git version in pacman version string
 330 AC_MSG_CHECKING(whether to use git version if available)
 331 if test "x$wantgitver" = "xyes" ; then
 332         AC_CHECK_PROGS([GIT], [git])
 333         AC_CHECK_FILE([.git/], hasgitdir=yes)
 334         if test $GIT -a "x$hasgitdir" = "xyes"; then
 335                 AC_MSG_RESULT([yes])
 336                 usegitver=yes
 337                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 338         else
 339                 AC_MSG_RESULT([no, git or .git dir missing])
 340                 usegitver=no
 341         fi
 342 else
 343         AC_MSG_RESULT([no, disabled by configure])
 344         usegitver=no
 345 fi
 346 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 347
 348 # Set root directory
 349 AC_SUBST(ROOTDIR)
 350 # Set package file extension
 351 AC_SUBST(PKGEXT)
 352 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 353 # Set source package file extension
 354 AC_SUBST(SRCEXT)
 355 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 356 # Set makepkg build script name
 357 AC_SUBST(BUILDSCRIPT)
 358 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 359
 360 # Configuration files
 361 AC_CONFIG_FILES([
 362 lib/libalpm/Makefile
 363 lib/libalpm/po/Makefile.in
 364 src/pacman/Makefile
 365 src/util/Makefile
 366 scripts/Makefile
 367 doc/Makefile
 368 etc/Makefile
 369 po/Makefile.in
 370 test/pacman/Makefile
 371 test/pacman/tests/Makefile
 372 test/util/Makefile
 373 contrib/Makefile
 374 Makefile
 375 ])
 376 AC_OUTPUT
 377
 378 echo "
 379 ${PACKAGE_NAME}:
 380
 381   Build information:
 382     source code location   : ${srcdir}
 383     prefix                 : ${prefix}
 384     sysconfdir             : $(eval echo ${sysconfdir})
 385        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 386     localstatedir          : $(eval echo ${localstatedir})
 387        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 388        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 389     compiler               : ${CC}
 390     compiler flags         : ${CFLAGS}
 391     defines                : ${DEFS}
 392
 393     Architecture           : ${CARCH}
 394     Architecture flags     : ${CARCHFLAGS}
 395     Host Type              : ${CHOST}
 396     Filesize command       : ${SIZECMD}
 397     In-place sed command   : ${SEDINPLACE}
 398
 399     libalpm version        : ${LIB_VERSION}
 400     libalpm version info   : ${LIB_VERSION_INFO}
 401     pacman version         : ${PACKAGE_VERSION}
 402     using git version      : ${usegitver}
 403
 404   Directory and file information:
 405     root working directory : ${ROOTDIR}
 406     package extension      : ${PKGEXT}
 407     source pkg extension   : ${SRCEXT}
 408     build script name      : ${BUILDSCRIPT}
 409
 410   Compilation options:
 411     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 412     Doxygen support        : ${usedoxygen}
 413     debug support          : ${debug}
 414 "
 415
 416 # vim:set ts=2 sw=2 noet: