configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [4])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [1])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [2])
  50 m4_define([pacman_version_micro], [2])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for buildscript filename
  92 AC_ARG_WITH(buildscript,
  93         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  94         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  95
  96 # Help line for libfetch
  97 AC_ARG_ENABLE(internal-download,
  98         AS_HELP_STRING([--disable-internal-download], [do not build with libfetch support]),
  99         [internaldownload=$enableval], [internaldownload=yes])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.6 python2.5 python], [false])
 130
 131 # find installed gettext
 132 AM_GNU_GETTEXT([external])
 133 AM_GNU_GETTEXT_VERSION(0.13.1)
 134
 135 # Check for libarchive
 136 AC_CHECK_LIB([archive], [archive_read_data], ,
 137         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 138
 139 # Enable or disable usage of libfetch
 140 AC_MSG_CHECKING(whether to link with libfetch)
 141 if test "x$internaldownload" = "xyes" ; then
 142         AC_MSG_RESULT(yes)
 143         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 144         # Check for a download library if it was actually requested
 145         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 146                 AC_MSG_ERROR([libfetch is needed to compile with internal download support]) )
 147 else
 148         AC_MSG_RESULT(no)
 149 fi
 150 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 151
 152 # Checks for header files.
 153 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 154
 155 # Checks for typedefs, structures, and compiler characteristics.
 156 AC_C_INLINE
 157 AC_TYPE_MODE_T
 158 AC_TYPE_OFF_T
 159 AC_TYPE_PID_T
 160 AC_TYPE_SIZE_T
 161 AC_STRUCT_TM
 162 AC_TYPE_UID_T
 163
 164 # Checks for library functions.
 165 AC_FUNC_FORK
 166 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 167 AC_FUNC_MKTIME
 168 AC_TYPE_SIGNAL
 169 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 170                 strndup strrchr strsep swprintf \
 171                 wcwidth uname])
 172
 173 # Enable large file support if available
 174 AC_SYS_LARGEFILE
 175
 176 # Check if we can use symbol visibility support in GCC
 177 GCC_VISIBILITY_CC
 178 # Check if we have -fgnu89-inline flag
 179 GCC_GNU89_INLINE_CC
 180
 181 # Host-dependant definitions
 182 SIZECMD="stat -c %s"
 183 SEDINPLACE="sed -i"
 184 case "${host_os}" in
 185         *bsd*)
 186                 SIZECMD="stat -f %z"
 187                 SEDINPLACE="sed -i ''"
 188                 ;;
 189         cygwin*)
 190                 host_os_cygwin=yes
 191                 CFLAGS="$CFLAGS -DCYGWIN"
 192                 ;;
 193         darwin*)
 194                 host_os_darwin=yes
 195                 SIZECMD="/usr/bin/stat -f %z"
 196                 SEDINPLACE="/usr/bin/sed -i ''"
 197                 ;;
 198 esac
 199
 200 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 201 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 202 AC_SUBST(SIZECMD)
 203 AC_SUBST(SEDINPLACE)
 204
 205 # Check for architecture, used in default makepkg.conf
 206 # (Note single space left after CARCHFLAGS)
 207 case "${host}" in
 208         i686-*)
 209                 CARCH="i686"
 210                 CARCHFLAGS="-march=i686 "
 211                 ;;
 212         x86_64-*)
 213                 CARCH="x86_64"
 214                 CARCHFLAGS="-march=x86-64 "
 215                 ;;
 216         ia64-*)
 217                 CARCH="ia64"
 218                 CARCHFLAGS="-march=ia64 "
 219                 ;;
 220         sparc-*)
 221                 CARCH="sparc"
 222                 CARCHFLAGS="-mcpu=v9 "
 223                 ;;
 224         ppc-* | powerpc-*)
 225                 CARCH="ppc"
 226                 CARCHFLAGS="-mcpu=750 "
 227                 ;;
 228         i386-*)
 229                 CARCH="i386"
 230                 CARCHFLAGS="-march=i386 "
 231                 ;;
 232         arm-*)
 233                 CARCH="arm"
 234                 CARCHFLAGS="-march=armv4 "
 235                 ;;
 236         *)
 237                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 238                 CARCH="unknown"
 239                 CARCHFLAGS=""
 240                 ;;
 241 esac
 242
 243 # Now do some things common to all architectures
 244 CHOST="${host}"
 245 AC_SUBST(CARCH)
 246 AC_SUBST(CARCHFLAGS)
 247 AC_SUBST(CHOST)
 248
 249 # Check for documentation support and status
 250 AC_MSG_CHECKING([for building documentation])
 251 if test "x$wantdoc" = "xyes" ; then
 252         AC_MSG_RESULT([yes])
 253         wantdoc=yes
 254 else
 255         AC_MSG_RESULT([no, disabled by configure])
 256         wantdoc=no
 257 fi
 258 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 259
 260 # Check for doxygen support and status
 261 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 262 AC_MSG_CHECKING([for doxygen])
 263 if test "x$wantdoxygen" = "xyes" ; then
 264         if test $DOXYGEN ; then
 265                 AC_MSG_RESULT([yes])
 266                 usedoxygen=yes
 267         else
 268                 AC_MSG_RESULT([no, doxygen missing])
 269                 usedoxygen=no
 270         fi
 271 else
 272         AC_MSG_RESULT([no, disabled by configure])
 273         usedoxygen=no
 274 fi
 275 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 276
 277 # Enable or disable debug code
 278 AC_MSG_CHECKING(for debug mode request)
 279 if test "x$debug" = "xyes" ; then
 280         AC_MSG_RESULT(yes)
 281         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 282         # Check for mcheck
 283         AC_CHECK_HEADERS([mcheck.h])
 284         # Check for -fstack-protector availability
 285         GCC_STACK_PROTECT_LIB
 286         GCC_STACK_PROTECT_CC
 287         CFLAGS="$CFLAGS -Wall -Werror"
 288 else
 289         AC_MSG_RESULT(no)
 290         CFLAGS="$CFLAGS -Wall"
 291 fi
 292
 293 # Enable or disable use of git version in pacman version string
 294 AC_CHECK_PROGS([GIT], [git])
 295 AC_CHECK_FILE([.git/], hasgitdir=yes)
 296 AC_MSG_CHECKING(whether to use git version if available)
 297 if test "x$wantgitver" = "xyes" ; then
 298         if test $GIT -a "x$hasgitdir" = "xyes"; then
 299                 AC_MSG_RESULT([yes])
 300                 usegitver=yes
 301                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 302         else
 303                 AC_MSG_RESULT([no, git or .git dir missing])
 304                 usegitver=no
 305         fi
 306 else
 307         AC_MSG_RESULT([no, disabled by configure])
 308         usegitver=no
 309 fi
 310 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 311
 312 # Set root directory
 313 AC_SUBST(ROOTDIR)
 314 # Set package file extension
 315 AC_SUBST(PKGEXT)
 316 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 317 # Set source package file extension
 318 AC_SUBST(SRCEXT)
 319 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 320 # Set database file extension
 321 AC_SUBST(DBEXT)
 322 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 323 # Set makepkg build script name
 324 AC_SUBST(BUILDSCRIPT)
 325 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 326
 327 # Configuration files
 328 AC_CONFIG_FILES([
 329 lib/libalpm/Makefile
 330 lib/libalpm/po/Makefile.in
 331 src/pacman/Makefile
 332 src/util/Makefile
 333 scripts/Makefile
 334 doc/Makefile
 335 etc/Makefile
 336 po/Makefile.in
 337 pactest/Makefile
 338 pactest/tests/Makefile
 339 contrib/Makefile
 340 Makefile
 341 ])
 342 AC_OUTPUT
 343
 344 echo "
 345 ${PACKAGE_NAME}:
 346
 347   Build information:
 348     source code location   : ${srcdir}
 349     prefix                 : ${prefix}
 350     sysconfdir             : $(eval echo ${sysconfdir})
 351        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 352     localstatedir          : $(eval echo ${localstatedir})
 353        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 354        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 355     compiler               : ${CC}
 356     compiler flags         : ${CFLAGS}
 357     defines                : ${DEFS}
 358
 359     Architecture           : ${CARCH}
 360     Architecture flags     : ${CARCHFLAGS}
 361     Host Type              : ${CHOST}
 362     Filesize command       : ${SIZECMD}
 363     In-place sed command   : ${SEDINPLACE}
 364
 365     libalpm version        : ${LIB_VERSION}
 366     libalpm version info   : ${LIB_VERSION_INFO}
 367     pacman version         : ${PACKAGE_VERSION}
 368     using git version      : ${usegitver}
 369
 370   Directory and file information:
 371     root working directory : ${ROOTDIR}
 372     package extension      : ${PKGEXT}
 373     source pkg extension   : ${SRCEXT}
 374     database extension     : ${DBEXT}
 375     build script name      : ${BUILDSCRIPT}
 376
 377   Compilation options:
 378     Run make in doc/ dir   : ${wantdoc}
 379     Use download library   : ${internaldownload}
 380     Doxygen support        : ${usedoxygen}
 381     debug support          : ${debug}
 382 "
 383
 384 # vim:set ts=2 sw=2 noet: