tools/sgf2gtp.pl

   1 #!/usr/bin/perl -l
   2 #
   3 # sgf2gtp - Convert SGF game record to GTP command stream
   4 #
   5 # Usage: sgf2gtp [-g] [-n MOVENUM] [FILENAME]
   6 #
   7 # This is a naive Perl script that will convert SGF files to GTP
   8 # format so that you can feed them to Pachi, insert genmove at
   9 # the right places etc. Might not work on obscure SGF files,
  10 # and of course there must be no variations.
  11 #
  12 # When called with a filename argument, it will create the output
  13 # file with .gtp extension instead of .sgf.
  14 #
  15 # -g: Automatically append genmove command for the other color.
  16 # -n MOVENUM: Output at most first MOVENUM moves.
  17
  18 use warnings;
  19
  20 my $genmove;
  21 if ($ARGV[0] and $ARGV[0] eq '-g') {
  22         shift @ARGV;
  23         $genmove = 1;
  24 }
  25
  26 my $maxmoves;
  27 if ($ARGV[0] and $ARGV[0] eq '-n') {
  28         shift @ARGV;
  29         $maxmoves = shift @ARGV;
  30 }
  31
  32 if ($ARGV[0]) {
  33         open STDIN, "$ARGV[0]" or die "$ARGV[0]: $!";
  34         my $ofile = $ARGV[0]; $ofile =~ s/sgf$//i; $ofile .= 'gtp';
  35         open STDOUT, ">$ofile" or die "$ofile: $!";
  36 }
  37
  38 local $/ = undef; my $sgf = <>;
  39 my $size = ($sgf =~ /SZ\[(\d+)\]/)[0];
  40 $size ||= 19;
  41 $sgf =~ s/\bC\[.*?\]//gs; # no comments
  42 #$sgf =~ s/\).*//gs; # cut at end of principal branch
  43
  44 print "boardsize " . $size;
  45 print "clear_board";
  46 if ($sgf =~ s/\bKM\[([\d.]+)\]//gs) {
  47         print "komi $1";
  48 }
  49 if ($sgf =~ s/\bHA\[(\d+)\]//gs and $1 > 0) {
  50         print "fixed_handicap $1";
  51 }
  52
  53 my $abcd = "abcdefghijklmnopqrstuvwxyz";
  54 my $movenum = 0;
  55 my $last_color = 'w';
  56
  57 my @m = split /;/, $sgf;
  58 foreach (@m) {
  59         $maxmoves and $movenum >= $maxmoves and last;
  60
  61         if (/^([BW])\[\]/) {
  62                 $last_color = $1;
  63                 $movenum++;
  64                 print "play $1 pass";
  65                 next;
  66         }
  67         unless (/^([BW])\[(\w\w)\]/) {
  68                 next;
  69         }
  70
  71         my ($color, $coord) = ($1, $2);
  72         my ($x, $y) = split //, $coord;
  73         ($x ge 'i') and $x++;
  74         $y = $size - index($abcd, $y);
  75
  76         $last_color = $color;
  77         $movenum++;
  78         print "play $color $x$y";
  79 }
  80
  81 if ($genmove) {
  82         print "genmove ".(uc $last_color eq 'W' ? 'B' : 'W');
  83 }