lisp/org-archive.el

   1 ;;; org-archive.el --- Archiving for Org             -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: https://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the face definitions for Org.
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-element-type "org-element" (element))
  34 (declare-function org-datetree-find-date-create "org-datetree" (date &optional keep-restriction))
  35 (declare-function org-inlinetask-remove-END-maybe "org-inlinetask" ())
  36
  37 (defcustom org-archive-default-command 'org-archive-subtree
  38   "The default archiving command."
  39   :group 'org-archive
  40   :type '(choice
  41           (const org-archive-subtree)
  42           (const org-archive-to-archive-sibling)
  43           (const org-archive-set-tag)))
  44
  45 (defcustom org-archive-reversed-order nil
  46   "Non-nil means make the tree first child under the archive heading, not last."
  47   :group 'org-archive
  48   :version "24.1"
  49   :type 'boolean)
  50
  51 (defcustom org-archive-sibling-heading "Archive"
  52   "Name of the local archive sibling that is used to archive entries locally.
  53 Locally means: in the tree, under a sibling.
  54 See `org-archive-to-archive-sibling' for more information."
  55   :group 'org-archive
  56   :type 'string)
  57
  58 (defcustom org-archive-mark-done nil
  59   "Non-nil means mark entries as DONE when they are moved to the archive file.
  60 This can be a string to set the keyword to use.  When non-nil, Org will
  61 use the first keyword in its list that means done."
  62   :group 'org-archive
  63   :type '(choice
  64           (const :tag "No" nil)
  65           (const :tag "Yes" t)
  66           (string :tag "Use this keyword")))
  67
  68 (defcustom org-archive-stamp-time t
  69   "Non-nil means add a time stamp to entries moved to an archive file.
  70 This variable is obsolete and has no effect anymore, instead add or remove
  71 `time' from the variable `org-archive-save-context-info'."
  72   :group 'org-archive
  73   :type 'boolean)
  74
  75 (defcustom org-archive-file-header-format "\nArchived entries from file %s\n\n"
  76   "The header format string for newly created archive files.
  77 When nil, no header will be inserted.
  78 When a string, a %s formatter will be replaced by the file name."
  79   :group 'org-archive
  80   :version "24.4"
  81   :package-version '(Org . "8.0")
  82   :type 'string)
  83
  84 (defcustom org-archive-subtree-add-inherited-tags 'infile
  85   "Non-nil means append inherited tags when archiving a subtree."
  86   :group 'org-archive
  87   :version "24.1"
  88   :type '(choice
  89           (const :tag "Never" nil)
  90           (const :tag "When archiving a subtree to the same file" infile)
  91           (const :tag "Always" t)))
  92
  93 (defcustom org-archive-save-context-info '(time file olpath category todo itags)
  94   "Parts of context info that should be stored as properties when archiving.
  95 When a subtree is moved to an archive file, it loses information given by
  96 context, like inherited tags, the category, and possibly also the TODO
  97 state (depending on the variable `org-archive-mark-done').
  98 This variable can be a list of any of the following symbols:
  99
 100 time       The time of archiving.
 101 file       The file where the entry originates.
 102 ltags      The local tags, in the headline of the subtree.
 103 itags      The tags the subtree inherits from further up the hierarchy.
 104 todo       The pre-archive TODO state.
 105 category   The category, taken from file name or #+CATEGORY lines.
 106 olpath     The outline path to the item.  These are all headlines above
 107            the current item, separated by /, like a file path.
 108
 109 For each symbol present in the list, a property will be created in
 110 the archived entry, with a prefix \"ARCHIVE_\", to remember this
 111 information."
 112   :group 'org-archive
 113   :type '(set :greedy t
 114               (const :tag "Time" time)
 115               (const :tag "File" file)
 116               (const :tag "Category" category)
 117               (const :tag "TODO state" todo)
 118               (const :tag "Priority" priority)
 119               (const :tag "Inherited tags" itags)
 120               (const :tag "Outline path" olpath)
 121               (const :tag "Local tags" ltags)))
 122
 123 (defvar org-archive-hook nil
 124   "Hook run after successfully archiving a subtree.
 125 Hook functions are called with point on the subtree in the
 126 original file.  At this stage, the subtree has been added to the
 127 archive location, but not yet deleted from the original file.")
 128
 129 (defun org-get-local-archive-location ()
 130   "Get the archive location applicable at point."
 131   (let ((re "^[ \t]*#\\+ARCHIVE:[ \t]+\\(\\S-.*\\S-\\)[ \t]*$")
 132         prop)
 133     (save-excursion
 134       (save-restriction
 135         (widen)
 136         (setq prop (org-entry-get nil "ARCHIVE" 'inherit))
 137         (cond
 138          ((and prop (string-match "\\S-" prop))
 139           prop)
 140          ((or (re-search-backward re nil t)
 141               (re-search-forward re nil t))
 142           (match-string 1))
 143          (t org-archive-location))))))
 144
 145 ;;;###autoload
 146 (defun org-add-archive-files (files)
 147   "Splice the archive files into the list of files.
 148 This implies visiting all these files and finding out what the
 149 archive file is."
 150   (org-uniquify
 151    (apply
 152     'append
 153     (mapcar
 154      (lambda (f)
 155        (if (not (file-exists-p f))
 156            nil
 157          (with-current-buffer (org-get-agenda-file-buffer f)
 158            (cons f (org-all-archive-files)))))
 159      files))))
 160
 161 (defun org-all-archive-files ()
 162   "Get a list of all archive files used in the current buffer."
 163   (let ((case-fold-search t)
 164         files)
 165     (org-with-wide-buffer
 166      (goto-char (point-min))
 167      (while (re-search-forward
 168              "^[ \t]*\\(#\\+\\|:\\)ARCHIVE:[ \t]+\\(.*\\)"
 169              nil t)
 170        (when (save-match-data
 171                (if (eq (match-string 1) ":") (org-at-property-p)
 172                  (eq (org-element-type (org-element-at-point)) 'keyword)))
 173          (let ((file (org-extract-archive-file
 174                       (match-string-no-properties 2))))
 175            (when (and (org-string-nw-p file) (file-exists-p file))
 176              (push file files))))))
 177     (setq files (nreverse files))
 178     (let ((file (org-extract-archive-file)))
 179       (when (and (org-string-nw-p file) (file-exists-p file))
 180         (push file files)))
 181     files))
 182
 183 (defun org-extract-archive-file (&optional location)
 184   "Extract and expand the file name from archive LOCATION.
 185 if LOCATION is not given, the value of `org-archive-location' is used."
 186   (setq location (or location org-archive-location))
 187   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 188       (if (= (match-beginning 1) (match-end 1))
 189           (buffer-file-name (buffer-base-buffer))
 190         (expand-file-name
 191          (format (match-string 1 location)
 192                  (file-name-nondirectory
 193                   (buffer-file-name (buffer-base-buffer))))))))
 194
 195 (defun org-extract-archive-heading (&optional location)
 196   "Extract the heading from archive LOCATION.
 197 if LOCATION is not given, the value of `org-archive-location' is used."
 198   (setq location (or location org-archive-location))
 199   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 200       (format (match-string 2 location)
 201               (file-name-nondirectory
 202                (buffer-file-name (buffer-base-buffer))))))
 203
 204 ;;;###autoload
 205 (defun org-archive-subtree (&optional find-done)
 206   "Move the current subtree to the archive.
 207 The archive can be a certain top-level heading in the current
 208 file, or in a different file.  The tree will be moved to that
 209 location, the subtree heading be marked DONE, and the current
 210 time will be added.
 211
 212 When called with a single prefix argument FIND-DONE, find whole
 213 trees without any open TODO items and archive them (after getting
 214 confirmation from the user).  When called with a double prefix
 215 argument, find whole trees with timestamps before today and
 216 archive them (after getting confirmation from the user).  If the
 217 cursor is not at a headline when these commands are called, try
 218 all level 1 trees.  If the cursor is on a headline, only try the
 219 direct children of this heading."
 220   (interactive "P")
 221   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 222       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 223                     'region-start-level 'region))
 224             org-loop-over-headlines-in-active-region)
 225         (org-map-entries
 226          `(progn (setq org-map-continue-from (progn (org-back-to-heading) (point)))
 227                  (org-archive-subtree ,find-done))
 228          org-loop-over-headlines-in-active-region
 229          cl (if (org-invisible-p) (org-end-of-subtree nil t))))
 230     (cond
 231      ((equal find-done '(4))  (org-archive-all-done))
 232      ((equal find-done '(16)) (org-archive-all-old))
 233      (t
 234       ;; Save all relevant TODO keyword-relatex variables
 235       (let* ((tr-org-todo-keywords-1 org-todo-keywords-1)
 236              (tr-org-todo-kwd-alist org-todo-kwd-alist)
 237              (tr-org-done-keywords org-done-keywords)
 238              (tr-org-todo-regexp org-todo-regexp)
 239              (tr-org-todo-line-regexp org-todo-line-regexp)
 240              (tr-org-odd-levels-only org-odd-levels-only)
 241              (this-buffer (current-buffer))
 242              (time (format-time-string
 243                     (substring (cdr org-time-stamp-formats) 1 -1)))
 244              (file (abbreviate-file-name
 245                     (or (buffer-file-name (buffer-base-buffer))
 246                         (error "No file associated to buffer"))))
 247              (location (org-get-local-archive-location))
 248              (afile (or (org-extract-archive-file location)
 249                         (error "Invalid `org-archive-location'")))
 250              (heading (org-extract-archive-heading location))
 251              (infile-p (equal file (abbreviate-file-name (or afile ""))))
 252              (newfile-p (and (org-string-nw-p afile)
 253                              (not (file-exists-p afile))))
 254              (buffer (cond ((not (org-string-nw-p afile)) this-buffer)
 255                            ((find-buffer-visiting afile))
 256                            ((find-file-noselect afile))
 257                            (t (error "Cannot access file \"%s\"" afile))))
 258              level datetree-date datetree-subheading-p)
 259         (when (string-match "\\`datetree/" heading)
 260           ;; Replace with ***, to represent the 3 levels of headings the
 261           ;; datetree has.
 262           (setq heading (replace-regexp-in-string "\\`datetree/" "***" heading))
 263           (setq datetree-subheading-p (> (length heading) 3))
 264           (setq datetree-date (org-date-to-gregorian
 265                                (or (org-entry-get nil "CLOSED" t) time))))
 266         (if (and (> (length heading) 0)
 267                  (string-match "^\\*+" heading))
 268             (setq level (match-end 0))
 269           (setq heading nil level 0))
 270         (save-excursion
 271           (org-back-to-heading t)
 272           ;; Get context information that will be lost by moving the
 273           ;; tree.  See `org-archive-save-context-info'.
 274           (let* ((all-tags (org-get-tags))
 275                  (local-tags
 276                   (cl-remove-if (lambda (tag)
 277                                   (get-text-property 0 'inherited tag))
 278                                 all-tags))
 279                  (inherited-tags
 280                   (cl-remove-if-not (lambda (tag)
 281                                       (get-text-property 0 'inherited tag))
 282                                     all-tags))
 283                  (context
 284                   `((category . ,(org-get-category nil 'force-refresh))
 285                     (file . ,file)
 286                     (itags . ,(mapconcat #'identity inherited-tags " "))
 287                     (ltags . ,(mapconcat #'identity local-tags " "))
 288                     (olpath . ,(mapconcat #'identity
 289                                           (org-get-outline-path)
 290                                           "/"))
 291                     (time . ,time)
 292                     (todo . ,(org-entry-get (point) "TODO")))))
 293             ;; We first only copy, in case something goes wrong
 294             ;; we need to protect `this-command', to avoid kill-region sets it,
 295             ;; which would lead to duplication of subtrees
 296             (let (this-command) (org-copy-subtree 1 nil t))
 297             (set-buffer buffer)
 298             ;; Enforce Org mode for the archive buffer
 299             (if (not (derived-mode-p 'org-mode))
 300                 ;; Force the mode for future visits.
 301                 (let ((org-insert-mode-line-in-empty-file t)
 302                       (org-inhibit-startup t))
 303                   (call-interactively 'org-mode)))
 304             (when (and newfile-p org-archive-file-header-format)
 305               (goto-char (point-max))
 306               (insert (format org-archive-file-header-format
 307                               (buffer-file-name this-buffer))))
 308             (when datetree-date
 309               (require 'org-datetree)
 310               (org-datetree-find-date-create datetree-date)
 311               (org-narrow-to-subtree))
 312             ;; Force the TODO keywords of the original buffer
 313             (let ((org-todo-line-regexp tr-org-todo-line-regexp)
 314                   (org-todo-keywords-1 tr-org-todo-keywords-1)
 315                   (org-todo-kwd-alist tr-org-todo-kwd-alist)
 316                   (org-done-keywords tr-org-done-keywords)
 317                   (org-todo-regexp tr-org-todo-regexp)
 318                   (org-todo-line-regexp tr-org-todo-line-regexp)
 319                   (org-odd-levels-only
 320                    (if (local-variable-p 'org-odd-levels-only (current-buffer))
 321                        org-odd-levels-only
 322                      tr-org-odd-levels-only)))
 323               (goto-char (point-min))
 324               (org-show-all '(headings blocks))
 325               (if (and heading (not (and datetree-date (not datetree-subheading-p))))
 326                   (progn
 327                     (if (re-search-forward
 328                          (concat "^" (regexp-quote heading)
 329                                  "\\([ \t]+:\\(" org-tag-re ":\\)+\\)?[ \t]*$")
 330                          nil t)
 331                         (goto-char (match-end 0))
 332                       ;; Heading not found, just insert it at the end
 333                       (goto-char (point-max))
 334                       (or (bolp) (insert "\n"))
 335                       ;; datetrees don't need too much spacing
 336                       (insert (if datetree-date "" "\n") heading "\n")
 337                       (end-of-line 0))
 338                     ;; Make the subtree visible
 339                     (outline-show-subtree)
 340                     (if org-archive-reversed-order
 341                         (progn
 342                           (org-back-to-heading t)
 343                           (outline-next-heading))
 344                       (org-end-of-subtree t))
 345                     (skip-chars-backward " \t\r\n")
 346                     (and (looking-at "[ \t\r\n]*")
 347                          ;; datetree archives don't need so much spacing.
 348                          (replace-match (if datetree-date "\n" "\n\n"))))
 349                 ;; No specific heading, just go to end of file, or to the
 350                 ;; beginning, depending on `org-archive-reversed-order'.
 351                 (if org-archive-reversed-order
 352                     (progn
 353                       (goto-char (point-min))
 354                       (unless (org-at-heading-p) (outline-next-heading)))
 355                   (goto-char (point-max))
 356                   ;; Subtree narrowing can let the buffer end on
 357                   ;; a headline.  `org-paste-subtree' then deletes it.
 358                   ;; To prevent this, make sure visible part of buffer
 359                   ;; always terminates on a new line, while limiting
 360                   ;; number of blank lines in a date tree.
 361                   (unless (and datetree-date (bolp)) (insert "\n"))))
 362               ;; Paste
 363               (org-paste-subtree (org-get-valid-level level (and heading 1)))
 364               ;; Shall we append inherited tags?
 365               (and inherited-tags
 366                    (or (and (eq org-archive-subtree-add-inherited-tags 'infile)
 367                             infile-p)
 368                        (eq org-archive-subtree-add-inherited-tags t))
 369                    (org-set-tags all-tags))
 370               ;; Mark the entry as done
 371               (when (and org-archive-mark-done
 372                          (let ((case-fold-search nil))
 373                            (looking-at org-todo-line-regexp))
 374                          (or (not (match-end 2))
 375                              (not (member (match-string 2) org-done-keywords))))
 376                 (let (org-log-done org-todo-log-states)
 377                   (org-todo
 378                    (car (or (member org-archive-mark-done org-done-keywords)
 379                             org-done-keywords)))))
 380
 381               ;; Add the context info.
 382               (dolist (item org-archive-save-context-info)
 383                 (let ((value (cdr (assq item context))))
 384                   (when (org-string-nw-p value)
 385                     (org-entry-put
 386                      (point)
 387                      (concat "ARCHIVE_" (upcase (symbol-name item)))
 388                      value))))
 389               (widen))))
 390         ;; Here we are back in the original buffer.  Everything seems
 391         ;; to have worked.  So now run hooks, cut the tree and finish
 392         ;; up.
 393         (run-hooks 'org-archive-hook)
 394         (let (this-command) (org-cut-subtree))
 395         (when (featurep 'org-inlinetask)
 396           (org-inlinetask-remove-END-maybe))
 397         (setq org-markers-to-move nil)
 398         (when org-provide-todo-statistics
 399           (save-excursion
 400             ;; Go to parent, even if no children exist.
 401             (org-up-heading-safe)
 402             ;; Update cookie of parent.
 403             (org-update-statistics-cookies nil)))
 404         (message "Subtree archived %s"
 405                  (if (eq this-buffer buffer)
 406                      (concat "under heading: " heading)
 407                    (concat "in file: " (abbreviate-file-name afile)))))))
 408     (org-reveal)
 409     (if (looking-at "^[ \t]*$")
 410         (outline-next-visible-heading 1))))
 411
 412 ;;;###autoload
 413 (defun org-archive-to-archive-sibling ()
 414   "Archive the current heading by moving it under the archive sibling.
 415
 416 The archive sibling is a sibling of the heading with the heading name
 417 `org-archive-sibling-heading' and an `org-archive-tag' tag.  If this
 418 sibling does not exist, it will be created at the end of the subtree.
 419
 420 Archiving time is retained in the ARCHIVE_TIME node property."
 421   (interactive)
 422   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 423       (let ((cl (when (eq org-loop-over-headlines-in-active-region 'start-level)
 424                   'region-start-level 'region))
 425             org-loop-over-headlines-in-active-region)
 426         (org-map-entries
 427          '(progn (setq org-map-continue-from
 428                        (progn (org-back-to-heading)
 429                               (if (looking-at (concat "^.*:" org-archive-tag ":.*$"))
 430                                   (org-end-of-subtree t)
 431                                 (point))))
 432                  (when (org-at-heading-p)
 433                    (org-archive-to-archive-sibling)))
 434          org-loop-over-headlines-in-active-region
 435          cl (if (org-invisible-p) (org-end-of-subtree nil t))))
 436     (save-restriction
 437       (widen)
 438       (let (b e pos leader level)
 439         (org-back-to-heading t)
 440         (looking-at org-outline-regexp)
 441         (setq leader (match-string 0)
 442               level (funcall outline-level))
 443         (setq pos (point-marker))
 444         (condition-case nil
 445             (outline-up-heading 1 t)
 446           (error (setq e (point-max)) (goto-char (point-min))))
 447         (setq b (point))
 448         (unless e
 449           (condition-case nil
 450               (org-end-of-subtree t t)
 451             (error (goto-char (point-max))))
 452           (setq e (point)))
 453         (goto-char b)
 454         (unless (re-search-forward
 455                  (concat "^" (regexp-quote leader)
 456                          "[ \t]*"
 457                          org-archive-sibling-heading
 458                          "[ \t]*:"
 459                          org-archive-tag ":") e t)
 460           (goto-char e)
 461           (or (bolp) (newline))
 462           (insert leader org-archive-sibling-heading "\n")
 463           (beginning-of-line 0)
 464           (org-toggle-tag org-archive-tag 'on))
 465         (beginning-of-line 1)
 466         (if org-archive-reversed-order
 467             (outline-next-heading)
 468           (org-end-of-subtree t t))
 469         (save-excursion
 470           (goto-char pos)
 471           (let ((this-command this-command)) (org-cut-subtree)))
 472         (org-paste-subtree (org-get-valid-level level 1))
 473         (org-set-property
 474          "ARCHIVE_TIME"
 475          (format-time-string
 476           (substring (cdr org-time-stamp-formats) 1 -1)))
 477         (outline-up-heading 1 t)
 478         (outline-hide-subtree)
 479         (org-cycle-show-empty-lines 'folded)
 480         (when org-provide-todo-statistics
 481           ;; Update TODO statistics of parent.
 482           (org-update-parent-todo-statistics))
 483         (goto-char pos)))
 484     (org-reveal)
 485     (if (looking-at "^[ \t]*$")
 486         (outline-next-visible-heading 1))))
 487
 488 (defun org-archive-all-done (&optional tag)
 489   "Archive sublevels of the current tree without open TODO items.
 490 If the cursor is not on a headline, try all level 1 trees.  If
 491 it is on a headline, try all direct children.
 492 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 493   (org-archive-all-matches
 494    (lambda (_beg end)
 495      (let ((case-fold-search nil))
 496        (unless (re-search-forward org-not-done-heading-regexp end t)
 497          "no open TODO items")))
 498    tag))
 499
 500 (defun org-archive-all-old (&optional tag)
 501   "Archive sublevels of the current tree with timestamps prior to today.
 502 If the cursor is not on a headline, try all level 1 trees.  If
 503 it is on a headline, try all direct children.
 504 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 505   (org-archive-all-matches
 506    (lambda (_beg end)
 507      (let (ts)
 508        (and (re-search-forward org-ts-regexp end t)
 509             (setq ts (match-string 0))
 510             (< (org-time-stamp-to-now ts) 0)
 511             (if (not (looking-at
 512                       (concat "--\\(" org-ts-regexp "\\)")))
 513                 (concat "old timestamp " ts)
 514               (setq ts (concat "old timestamp " ts (match-string 0)))
 515               (and (< (org-time-stamp-to-now (match-string 1)) 0)
 516                    ts)))))
 517    tag))
 518
 519 (defun org-archive-all-matches (predicate &optional tag)
 520   "Archive sublevels of the current tree that match PREDICATE.
 521
 522 PREDICATE is a function of two arguments, BEG and END, which
 523 specify the beginning and end of the headline being considered.
 524 It is called with point positioned at BEG.  The headline will be
 525 archived if PREDICATE returns non-nil.  If the return value of
 526 PREDICATE is a string, it should describe the reason for
 527 archiving the heading.
 528
 529 If the cursor is not on a headline, try all level 1 trees.  If it
 530 is on a headline, try all direct children.  When TAG is non-nil,
 531 don't move trees, but mark them with the ARCHIVE tag."
 532   (let ((rea (concat ".*:" org-archive-tag ":")) re1
 533         (begm (make-marker))
 534         (endm (make-marker))
 535         (question (if tag "Set ARCHIVE tag? "
 536                     "Move subtree to archive? "))
 537         reason beg end (cntarch 0))
 538     (if (org-at-heading-p)
 539         (progn
 540           (setq re1 (concat "^" (regexp-quote
 541                                  (make-string
 542                                   (+ (- (match-end 0) (match-beginning 0) 1)
 543                                      (if org-odd-levels-only 2 1))
 544                                   ?*))
 545                             " "))
 546           (move-marker begm (point))
 547           (move-marker endm (org-end-of-subtree t)))
 548       (setq re1 "^* ")
 549       (move-marker begm (point-min))
 550       (move-marker endm (point-max)))
 551     (save-excursion
 552       (goto-char begm)
 553       (while (re-search-forward re1 endm t)
 554         (setq beg (match-beginning 0)
 555               end (save-excursion (org-end-of-subtree t) (point)))
 556         (goto-char beg)
 557         (if (not (setq reason (funcall predicate beg end)))
 558             (goto-char end)
 559           (goto-char beg)
 560           (if (and (or (not tag) (not (looking-at rea)))
 561                    (y-or-n-p
 562                     (if (stringp reason)
 563                         (concat question "(" reason ")")
 564                       question)))
 565               (progn
 566                 (if tag
 567                     (org-toggle-tag org-archive-tag 'on)
 568                   (org-archive-subtree))
 569                 (setq cntarch (1+ cntarch)))
 570             (goto-char end)))))
 571     (message "%d trees archived" cntarch)))
 572
 573 ;;;###autoload
 574 (defun org-toggle-archive-tag (&optional find-done)
 575   "Toggle the archive tag for the current headline.
 576 With prefix ARG, check all children of current headline and offer tagging
 577 the children that do not contain any open TODO items."
 578   (interactive "P")
 579   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 580       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 581                     'region-start-level 'region))
 582             org-loop-over-headlines-in-active-region)
 583         (org-map-entries
 584          `(org-toggle-archive-tag ,find-done)
 585          org-loop-over-headlines-in-active-region
 586          cl (if (org-invisible-p) (org-end-of-subtree nil t))))
 587     (if find-done
 588         (org-archive-all-done 'tag)
 589       (let (set)
 590         (save-excursion
 591           (org-back-to-heading t)
 592           (setq set (org-toggle-tag org-archive-tag))
 593           (when set (org-flag-subtree t)))
 594         (and set (beginning-of-line 1))
 595         (message "Subtree %s" (if set "archived" "unarchived"))))))
 596
 597 (defun org-archive-set-tag ()
 598   "Set the ARCHIVE tag."
 599   (interactive)
 600   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 601       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 602                     'region-start-level 'region))
 603             org-loop-over-headlines-in-active-region)
 604         (org-map-entries
 605          'org-archive-set-tag
 606          org-loop-over-headlines-in-active-region
 607          cl (if (org-invisible-p) (org-end-of-subtree nil t))))
 608     (org-toggle-tag org-archive-tag 'on)))
 609
 610 ;;;###autoload
 611 (defun org-archive-subtree-default ()
 612   "Archive the current subtree with the default command.
 613 This command is set with the variable `org-archive-default-command'."
 614   (interactive)
 615   (call-interactively org-archive-default-command))
 616
 617 ;;;###autoload
 618 (defun org-archive-subtree-default-with-confirmation ()
 619   "Archive the current subtree with the default command.
 620 This command is set with the variable `org-archive-default-command'."
 621   (interactive)
 622   (if (y-or-n-p "Archive this subtree or entry? ")
 623       (call-interactively org-archive-default-command)
 624     (error "Abort")))
 625
 626 (provide 'org-archive)
 627
 628 ;; Local variables:
 629 ;; generated-autoload-file: "org-loaddefs.el"
 630 ;; End:
 631
 632 ;;; org-archive.el ends here