lisp/org-latex.el

   1 ;;; org-latex.el --- LaTeX exporter for org-mode
   2 ;;
   3 ;; Copyright (C) 2007, 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-latex.el
   7 ;; Version: 6.28trans
   8 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   9 ;; Maintainer: Carsten Dominik <carsten.dominik AT gmail DOT com>
  10 ;; Keywords: org, wp, tex
  11 ;; Description: Converts an org-mode buffer into LaTeX
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29 ;;
  30 ;; This library implements a LaTeX exporter for org-mode.
  31 ;;
  32 ;; It is part of Org and will be autoloaded
  33 ;;
  34 ;; The interactive functions are similar to those of the HTML exporter:
  35 ;;
  36 ;; M-x `org-export-as-latex'
  37 ;; M-x `org-export-as-pdf'
  38 ;; M-x `org-export-as-pdf-and-open'
  39 ;; M-x `org-export-as-latex-batch'
  40 ;; M-x `org-export-as-latex-to-buffer'
  41 ;; M-x `org-export-region-as-latex'
  42 ;; M-x `org-replace-region-by-latex'
  43 ;;
  44 ;;; Code:
  45
  46 (eval-when-compile
  47   (require 'cl))
  48
  49 (require 'footnote)
  50 (require 'org)
  51 (require 'org-exp)
  52
  53 ;;; Variables:
  54 (defvar org-export-latex-class nil)
  55 (defvar org-export-latex-header nil)
  56 (defvar org-export-latex-append-header nil)
  57 (defvar org-export-latex-options-plist nil)
  58 (defvar org-export-latex-todo-keywords-1 nil)
  59 (defvar org-export-latex-complex-heading-re nil)
  60 (defvar org-export-latex-not-done-keywords nil)
  61 (defvar org-export-latex-done-keywords nil)
  62 (defvar org-export-latex-display-custom-times nil)
  63 (defvar org-export-latex-all-targets-re nil)
  64 (defvar org-export-latex-add-level 0)
  65 (defvar org-export-latex-sectioning "")
  66 (defvar org-export-latex-sectioning-depth 0)
  67 (defvar org-export-latex-special-keyword-regexp
  68   (concat "\\<\\(" org-scheduled-string "\\|"
  69           org-deadline-string "\\|"
  70           org-closed-string"\\)")
  71   "Regexp matching special time planning keywords plus the time after it.")
  72
  73 (defvar latexp)    ; dynamically scoped from org.el
  74 (defvar re-quote)  ; dynamically scoped from org.el
  75 (defvar commentsp) ; dynamically scoped from org.el
  76
  77 ;;; User variables:
  78
  79 (defgroup org-export-latex nil
  80   "Options for exporting Org-mode files to LaTeX."
  81   :tag "Org Export LaTeX"
  82   :group 'org-export)
  83
  84 (defcustom org-export-latex-default-class "article"
  85   "The default LaTeX class."
  86   :group 'org-export-latex
  87   :type '(string :tag "LaTeX class"))
  88
  89 (defcustom org-export-latex-classes
  90   '(("article"
  91      "\\documentclass[11pt]{article}
  92 \\usepackage[utf8]{inputenc}
  93 \\usepackage[T1]{fontenc}
  94 \\usepackage{graphicx}
  95 \\usepackage{longtable}
  96 \\usepackage{hyperref}"
  97      ("\\section{%s}" . "\\section*{%s}")
  98      ("\\subsection{%s}" . "\\subsection*{%s}")
  99      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 100      ("\\paragraph{%s}" . "\\paragraph*{%s}")
 101      ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 102     ("report"
 103      "\\documentclass[11pt]{report}
 104 \\usepackage[utf8]{inputenc}
 105 \\usepackage[T1]{fontenc}
 106 \\usepackage{graphicx}
 107 \\usepackage{longtable}
 108 \\usepackage{hyperref}"
 109      ("\\part{%s}" . "\\part*{%s}")
 110      ("\\chapter{%s}" . "\\chapter*{%s}")
 111      ("\\section{%s}" . "\\section*{%s}")
 112      ("\\subsection{%s}" . "\\subsection*{%s}")
 113      ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))
 114     ("book"
 115      "\\documentclass[11pt]{book}
 116 \\usepackage[utf8]{inputenc}
 117 \\usepackage[T1]{fontenc}
 118 \\usepackage{graphicx}
 119 \\usepackage{longtable}
 120 \\usepackage{hyperref}"
 121      ("\\part{%s}" . "\\part*{%s}")
 122      ("\\chapter{%s}" . "\\chapter*{%s}")
 123      ("\\section{%s}" . "\\section*{%s}")
 124      ("\\subsection{%s}" . "\\subsection*{%s}")
 125      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")))
 126   "Alist of LaTeX classes and associated header and structure.
 127 If #+LaTeX_CLASS is set in the buffer, use its value and the
 128 associated information.  Here is the structure of each cell:
 129
 130   \(class-name
 131     header-string
 132     (numbered-section . unnumbered-section\)
 133     ...\)
 134
 135 A %s formatter is mandatory in each section string and will be
 136 replaced by the title of the section.
 137
 138 Instead of a cons cell (numbered . unnumbered), you can also provide a list
 139 of 2-4 elements,
 140
 141   (numbered-open numbered-close)
 142
 143 or
 144
 145   (numbered-open numbered-close unnumbered-open unnumbered-close)
 146
 147 providing opening and closing strings for an environment that should
 148 represent the document section.  The opening clause should have a %s
 149 to represent the section title."
 150   :group 'org-export-latex
 151   :type '(repeat
 152           (list (string :tag "LaTeX class")
 153                 (string :tag "LaTeX header")
 154                 (repeat :tag "Levels" :inline t
 155                         (choice
 156                          (cons :tag "Heading"
 157                                (string :tag "numbered")
 158                                (string :tag "unnumbered)"))
 159                          (list :tag "Environment"
 160                                (string :tag "Opening (numbered)  ")
 161                                (string :tag "Closing (numbered)  ")
 162                                (string :tag "Opening (unnumbered)")
 163                                (string :tag "Closing (unnumbered)")))))))
 164
 165 (defcustom org-export-latex-emphasis-alist
 166   '(("*" "\\textbf{%s}" nil)
 167     ("/" "\\emph{%s}" nil)
 168     ("_" "\\underline{%s}" nil)
 169     ("+" "\\texttt{%s}" nil)
 170     ("=" "\\verb" t)
 171     ("~" "\\verb" t))
 172   "Alist of LaTeX expressions to convert emphasis fontifiers.
 173 Each element of the list is a list of three elements.
 174 The first element is the character used as a marker for fontification.
 175 The second element is a formatting string to wrap fontified text with.
 176 If it is \"\\verb\", Org will automatically select a deimiter
 177 character that is not in the string.
 178 The third element decides whether to protect converted text from other
 179 conversions."
 180   :group 'org-export-latex
 181   :type 'alist)
 182
 183 (defcustom org-export-latex-title-command "\\maketitle"
 184   "The command used to insert the title just after \\begin{document}.
 185 If this string contains the formatting specification \"%s\" then
 186 it will be used as a formatting string, passing the title as an
 187 argument."
 188   :group 'org-export-latex
 189   :type 'string)
 190
 191 (defcustom org-export-latex-import-inbuffer-stuff nil
 192   "Non-nil means define TeX macros for Org's inbuffer definitions.
 193 For example \orgTITLE for #+TITLE."
 194   :group 'org-export-latex
 195   :type 'boolean)
 196
 197 (defcustom org-export-latex-date-format
 198   "%d %B %Y"
 199   "Format string for \\date{...}."
 200   :group 'org-export-latex
 201   :type 'string)
 202
 203 (defcustom org-export-latex-todo-keyword-markup "\\textbf{%s}"
 204   "Markup for TODO keywords, as a printf format.
 205 This can be a single format for all keywords, a cons cell with separate
 206 formats for not-done and done states, or an association list with setup
 207 for individual keywords.  If a keyword shows up for which there is no
 208 markup defined, the first one in the association list will be used."
 209   :group 'org-export-latex
 210   :type '(choice
 211           (string :tag "Default")
 212           (cons :tag "Distinguish undone and done"
 213                 (string :tag "Not-DONE states")
 214                 (string :tag "DONE states"))
 215           (repeat :tag "Per keyword markup"
 216                   (cons
 217                    (string :tag "Keyword")
 218                    (string :tag "Markup")))))
 219
 220 (defcustom org-export-latex-timestamp-markup "\\textit{%s}"
 221   "A printf format string to be applied to time stamps."
 222   :group 'org-export-latex
 223   :type 'string)
 224
 225 (defcustom org-export-latex-timestamp-keyword-markup "\\texttt{%s}"
 226   "A printf format string to be applied to time stamps."
 227   :group 'org-export-latex
 228   :type 'string)
 229
 230 (defcustom org-export-latex-tables-verbatim nil
 231   "When non-nil, tables are exported verbatim."
 232   :group 'org-export-latex
 233   :type 'boolean)
 234
 235 (defcustom org-export-latex-tables-centered t
 236   "When non-nil, tables are exported in a center environment."
 237   :group 'org-export-latex
 238   :type 'boolean)
 239
 240 (defcustom org-export-latex-tables-column-borders nil
 241   "When non-nil, grouping columns can cause outer vertical lines in tables.
 242 When nil, grouping causes only separation lines between groups."
 243   :group 'org-export-latex
 244   :type 'boolean)
 245
 246 (defcustom org-export-latex-packages-alist nil
 247   "Alist of packages to be inserted in the header.
 248 Each cell is of the forma \( \"option\" . \"package\" \)."
 249   :group 'org-export-latex
 250   :type 'alist)
 251
 252 (defcustom org-export-latex-low-levels 'itemize
 253   "How to convert sections below the current level of sectioning.
 254 This is specified by the `org-export-headline-levels' option or the
 255 value of \"H:\" in Org's #+OPTION line.
 256
 257 This can be either nil (skip the sections), `description', `itemize',
 258 or `enumerate' (convert the sections as the corresponding list type), or
 259 a string to be used instead of \\section{%s}.  In this latter case,
 260 the %s stands here for the inserted headline and is mandatory.
 261
 262 It may also be a list of three string to define a user-defined environment
 263 that should be used.  The first string should be the like
 264 \"\\begin{itemize}\", the second should be like \"\\item %s %s\" with up
 265 to two occurrences of %s for the title and a lable, respectively.  The third
 266 string should be like \"\\end{itemize\"."
 267   :group 'org-export-latex
 268   :type '(choice (const :tag "Ignore" nil)
 269                  (const :tag "Convert as descriptive list" description)
 270                  (const :tag "Convert as itemized list" itemize)
 271                  (const :tag "Convert as enumerated list" enumerate)
 272                  (list  :tag "User-defined environment"
 273                         :value ("\\begin{itemize}" "\\end{itemize}" "\\item %s")
 274                         (string :tag "Start")
 275                         (string :tag "End")
 276                         (string :tag "item"))
 277                  (string :tag "Use a section string" :value "\\subparagraph{%s}")))
 278
 279 (defcustom org-export-latex-list-parameters
 280   '(:cbon "\\texttt{[X]}" :cboff "\\texttt{[ ]}")
 281   "Parameters for the LaTeX list exporter.
 282 These parameters will be passed on to `org-list-to-latex', which in turn
 283 will pass them (combined with the LaTeX default list parameters) to
 284 `org-list-to-generic'."
 285   :group 'org-export-latex
 286   :type 'plist)
 287
 288 (defcustom org-export-latex-verbatim-wrap
 289   '("\\begin{verbatim}\n" . "\\end{verbatim}\n")
 290   "Environment to be wrapped around a fixed-width section in LaTeX export.
 291 This is a cons with two strings, to be added before and after the
 292 fixed-with text.
 293
 294 Defaults to \\begin{verbatim} and \\end{verbatim}."
 295   :group 'org-export_translation
 296   :group 'org-export-latex
 297   :type '(cons (string :tag "Open")
 298                (string :tag "Close")))
 299
 300 (defcustom org-export-latex-remove-from-headlines
 301   '(:todo nil :priority nil :tags nil)
 302   "A plist of keywords to remove from headlines. OBSOLETE.
 303 Non-nil means remove this keyword type from the headline.
 304
 305 Don't remove the keys, just change their values.
 306
 307 Obsolete, this variable is no longer used.  Use the separate
 308 variables `org-export-with-todo-keywords', `org-export-with-priority',
 309 and `org-export-with-tags' instead."
 310   :type 'plist
 311   :group 'org-export-latex)
 312
 313 (defcustom org-export-latex-image-default-option "width=10em"
 314   "Default option for images."
 315   :group 'org-export-latex
 316   :type 'string)
 317
 318 (defcustom org-export-latex-inline-image-extensions
 319   '("pdf" "jpeg" "jpg" "png" "ps" "eps")
 320   "Extensions of image files that can be inlined into LaTeX.
 321 Note that the image extension *actually* allowed depend on the way the
 322 LaTeX file is processed.  When used with pdflatex, pdf, jpg and png images
 323 are OK.  When processing through dvi to Postscript, only ps and eps are
 324 allowed.  The default we use here encompasses both."
 325   :group 'org-export-latex
 326   :type '(repeat (string :tag "Extension")))
 327
 328 (defcustom org-export-latex-coding-system nil
 329   "Coding system for the exported LaTex file."
 330   :group 'org-export-latex
 331   :type 'coding-system)
 332
 333 (defgroup org-export-pdf nil
 334   "Options for exporting Org-mode files to PDF, via LaTeX."
 335   :tag "Org Export LaTeX"
 336   :group 'org-export-latex
 337   :group 'org-export)
 338
 339 (defcustom org-latex-to-pdf-process
 340   '("pdflatex -interaction nonstopmode %s"
 341     "pdflatex -interaction nonstopmode %s")
 342   "Commands to process a LaTeX file to a PDF file.
 343 This is a list of strings, each of them will be given to the shell
 344 as a command.  %s in the command will be replaced by the full file name, %b
 345 by the file base name (i.e. without extension).
 346 The reason why this is a list is that it usually takes several runs of
 347 pdflatex, maybe mixed with a call to bibtex.  Org does not have a clever
 348 mechanism to detect whihc of these commands have to be run to get to a stable
 349 result, and it also does not do any error checking.
 350
 351 Alternatively, this may be a Lisp function that does the processing, so you
 352 could use this to apply the machinery of AUCTeX or the Emacs LaTeX mode.
 353 THis function should accept the file name as its single argument."
 354   :group 'org-export-latex
 355   :type '(choice (repeat :tag "Shell command sequence"
 356                   (string :tag "Shell command"))
 357                  (function)))
 358
 359 (defcustom org-export-pdf-remove-logfiles t
 360   "Non-nil means, remove the logfiles produced by PDF production.
 361 These are the .aux, .log, .out, and .toc files."
 362   :group 'org-export-pdf
 363   :type 'boolean)
 364
 365 ;;; Hooks
 366
 367 (defvar org-export-latex-after-blockquotes-hook nil
 368   "Hook run during LaTeX export, after blockquote, verse, center are done.")
 369
 370 ;;; Autoload functions:
 371
 372 ;;;###autoload
 373 (defun org-export-as-latex-batch ()
 374   "Call `org-export-as-latex', may be used in batch processing.
 375 For example:
 376
 377 emacs   --batch
 378         --load=$HOME/lib/emacs/org.el
 379         --eval \"(setq org-export-headline-levels 2)\"
 380         --visit=MyFile --funcall org-export-as-latex-batch"
 381   (org-export-as-latex org-export-headline-levels 'hidden))
 382
 383 ;;;###autoload
 384 (defun org-export-as-latex-to-buffer (arg)
 385   "Call `org-export-as-latex` with output to a temporary buffer.
 386 No file is created.  The prefix ARG is passed through to `org-export-as-latex'."
 387   (interactive "P")
 388   (org-export-as-latex arg nil nil "*Org LaTeX Export*")
 389   (when org-export-show-temporary-export-buffer
 390     (switch-to-buffer-other-window "*Org LaTeX Export*")))
 391
 392 ;;;###autoload
 393 (defun org-replace-region-by-latex (beg end)
 394   "Replace the region from BEG to END with its LaTeX export.
 395 It assumes the region has `org-mode' syntax, and then convert it to
 396 LaTeX.  This can be used in any buffer.  For example, you could
 397 write an itemized list in `org-mode' syntax in an LaTeX buffer and
 398 then use this command to convert it."
 399   (interactive "r")
 400   (let (reg latex buf)
 401     (save-window-excursion
 402       (if (org-mode-p)
 403           (setq latex (org-export-region-as-latex
 404                        beg end t 'string))
 405         (setq reg (buffer-substring beg end)
 406               buf (get-buffer-create "*Org tmp*"))
 407         (save-excursion
 408           (set-buffer buf)
 409           (erase-buffer)
 410           (insert reg)
 411           (org-mode)
 412           (setq latex (org-export-region-as-latex
 413                        (point-min) (point-max) t 'string)))
 414         (kill-buffer buf)))
 415     (delete-region beg end)
 416     (insert latex)))
 417
 418 ;;;###autoload
 419 (defun org-export-region-as-latex (beg end &optional body-only buffer)
 420   "Convert region from BEG to END in `org-mode' buffer to LaTeX.
 421 If prefix arg BODY-ONLY is set, omit file header, footer, and table of
 422 contents, and only produce the region of converted text, useful for
 423 cut-and-paste operations.
 424 If BUFFER is a buffer or a string, use/create that buffer as a target
 425 of the converted LaTeX.  If BUFFER is the symbol `string', return the
 426 produced LaTeX as a string and leave no buffer behind.  For example,
 427 a Lisp program could call this function in the following way:
 428
 429   (setq latex (org-export-region-as-latex beg end t 'string))
 430
 431 When called interactively, the output buffer is selected, and shown
 432 in a window.  A non-interactive call will only return the buffer."
 433   (interactive "r\nP")
 434   (when (interactive-p)
 435     (setq buffer "*Org LaTeX Export*"))
 436   (let ((transient-mark-mode t) (zmacs-regions t)
 437         ext-plist rtn)
 438     (setq ext-plist (plist-put ext-plist :ignore-subree-p t))
 439     (goto-char end)
 440     (set-mark (point)) ;; to activate the region
 441     (goto-char beg)
 442     (setq rtn (org-export-as-latex
 443                nil nil ext-plist
 444                buffer body-only))
 445     (if (fboundp 'deactivate-mark) (deactivate-mark))
 446     (if (and (interactive-p) (bufferp rtn))
 447         (switch-to-buffer-other-window rtn)
 448       rtn)))
 449
 450 ;;;###autoload
 451 (defun org-export-as-latex (arg &optional hidden ext-plist
 452                                 to-buffer body-only pub-dir)
 453   "Export current buffer to a LaTeX file.
 454 If there is an active region, export only the region.  The prefix
 455 ARG specifies how many levels of the outline should become
 456 headlines.  The default is 3.  Lower levels will be exported
 457 depending on `org-export-latex-low-levels'.  The default is to
 458 convert them as description lists.
 459 HIDDEN is obsolete and does nothing.
 460 EXT-PLIST is a property list with
 461 external parameters overriding org-mode's default settings, but
 462 still inferior to file-local settings.  When TO-BUFFER is
 463 non-nil, create a buffer with that name and export to that
 464 buffer.  If TO-BUFFER is the symbol `string', don't leave any
 465 buffer behind but just return the resulting LaTeX as a string.
 466 When BODY-ONLY is set, don't produce the file header and footer,
 467 simply return the content of \begin{document}...\end{document},
 468 without even the \begin{document} and \end{document} commands.
 469 when PUB-DIR is set, use this as the publishing directory."
 470   (interactive "P")
 471   ;; Make sure we have a file name when we need it.
 472   (when (and (not (or to-buffer body-only))
 473              (not buffer-file-name))
 474     (if (buffer-base-buffer)
 475         (org-set-local 'buffer-file-name
 476                        (with-current-buffer (buffer-base-buffer)
 477                          buffer-file-name))
 478       (error "Need a file name to be able to export")))
 479
 480   (message "Exporting to LaTeX...")
 481   (org-unmodified
 482    (remove-text-properties (point-min) (point-max)
 483                            '(:org-license-to-kill nil)))
 484   (org-update-radio-target-regexp)
 485   (org-export-latex-set-initial-vars ext-plist arg)
 486   (let* ((wcf (current-window-configuration))
 487          (opt-plist org-export-latex-options-plist)
 488          (region-p (org-region-active-p))
 489          (rbeg (and region-p (region-beginning)))
 490          (rend (and region-p (region-end)))
 491          (subtree-p
 492           (if (plist-get opt-plist :ignore-subree-p)
 493               nil
 494             (when region-p
 495               (save-excursion
 496                 (goto-char rbeg)
 497                 (and (org-at-heading-p)
 498                      (>= (org-end-of-subtree t t) rend))))))
 499          (opt-plist (setq org-export-opt-plist
 500                           (if subtree-p
 501                               (org-export-add-subtree-options opt-plist rbeg)
 502                             opt-plist)))
 503          ;; Make sure the variable contains the updated values.
 504          (org-export-latex-options-plist opt-plist)
 505          (title (or (and subtree-p (org-export-get-title-from-subtree))
 506                     (plist-get opt-plist :title)
 507                     (and (not
 508                           (plist-get opt-plist :skip-before-1st-heading))
 509                          (org-export-grab-title-from-buffer))
 510                     (file-name-sans-extension
 511                      (file-name-nondirectory buffer-file-name))))
 512          (filename (concat (file-name-as-directory
 513                             (or pub-dir
 514                                 (org-export-directory :LaTeX ext-plist)))
 515                            (file-name-sans-extension
 516                             (or (and subtree-p
 517                                      (org-entry-get rbeg "EXPORT_FILE_NAME" t))
 518                                 (file-name-nondirectory ;sans-extension
 519                                  buffer-file-name)))
 520                            ".tex"))
 521          (filename (if (equal (file-truename filename)
 522                               (file-truename buffer-file-name))
 523                        (concat filename ".tex")
 524                      filename))
 525          (buffer (if to-buffer
 526                      (cond
 527                       ((eq to-buffer 'string) (get-buffer-create
 528                                                "*Org LaTeX Export*"))
 529                       (t (get-buffer-create to-buffer)))
 530                    (find-file-noselect filename)))
 531          (odd org-odd-levels-only)
 532          (header (org-export-latex-make-header title opt-plist))
 533          (skip (cond (subtree-p nil)
 534                      (region-p nil)
 535                      (t (plist-get opt-plist :skip-before-1st-heading))))
 536          (text (plist-get opt-plist :text))
 537          (org-export-preprocess-hook
 538           (cons
 539            `(lambda () (org-set-local 'org-complex-heading-regexp
 540                                       ,org-export-latex-complex-heading-re))
 541            org-export-preprocess-hook))
 542          (first-lines (if skip "" (org-export-latex-first-lines
 543                                    opt-plist
 544                                    (if subtree-p
 545                                        (save-excursion
 546                                          (goto-char rbeg)
 547                                          (point-at-bol 2))
 548                                      rbeg)
 549                                    (if region-p rend))))
 550          (coding-system (and (boundp 'buffer-file-coding-system)
 551                              buffer-file-coding-system))
 552          (coding-system-for-write (or org-export-latex-coding-system
 553                                       coding-system))
 554          (save-buffer-coding-system (or org-export-latex-coding-system
 555                                         coding-system))
 556          (region (buffer-substring
 557                   (if region-p (region-beginning) (point-min))
 558                   (if region-p (region-end) (point-max))))
 559          (string-for-export
 560           (org-export-preprocess-string
 561            region
 562            :emph-multiline t
 563            :for-LaTeX t
 564            :comments nil
 565            :tags (plist-get opt-plist :tags)
 566            :priority (plist-get opt-plist :priority)
 567            :footnotes (plist-get opt-plist :footnotes)
 568            :timestamps (plist-get opt-plist :timestamps)
 569            :todo-keywords (plist-get opt-plist :todo-keywords)
 570            :add-text (if (eq to-buffer 'string) nil text)
 571            :skip-before-1st-heading skip
 572            :select-tags (plist-get opt-plist :select-tags)
 573            :exclude-tags (plist-get opt-plist :exclude-tags)
 574            :LaTeX-fragments nil)))
 575
 576     (set-buffer buffer)
 577     (erase-buffer)
 578
 579     (and (fboundp 'set-buffer-file-coding-system)
 580          (set-buffer-file-coding-system coding-system-for-write))
 581
 582     ;; insert the header and initial document commands
 583     (unless (or (eq to-buffer 'string) body-only)
 584       (insert header))
 585
 586     ;; insert text found in #+TEXT
 587     (when (and text (not (eq to-buffer 'string)))
 588       (insert (org-export-latex-content
 589                text '(lists tables fixed-width keywords))
 590                "\n\n"))
 591
 592     ;; insert lines before the first headline
 593     (unless skip
 594       (insert first-lines))
 595
 596     ;; export the content of headlines
 597     (org-export-latex-global
 598      (with-temp-buffer
 599        (insert string-for-export)
 600        (goto-char (point-min))
 601        (when (re-search-forward "^\\(\\*+\\) " nil t)
 602          (let* ((asters (length (match-string 1)))
 603                 (level (if odd (- asters 2) (- asters 1))))
 604            (setq org-export-latex-add-level
 605                  (if odd (1- (/ (1+ asters) 2)) (1- asters)))
 606            (org-export-latex-parse-global level odd)))))
 607
 608     ;; finalization
 609     (unless body-only (insert "\n\\end{document}"))
 610
 611     ;; Relocate the table of contents
 612     (goto-char (point-min))
 613     (when (re-search-forward "\\[TABLE-OF-CONTENTS\\]" nil t)
 614       (goto-char (point-min))
 615       (while (re-search-forward "\\\\tableofcontents\\>[ \t]*\n?" nil t)
 616         (replace-match ""))
 617       (goto-char (point-min))
 618       (and (re-search-forward "\\[TABLE-OF-CONTENTS\\]" nil t)
 619            (replace-match "\\tableofcontents" t t)))
 620
 621     (or to-buffer (save-buffer))
 622     (goto-char (point-min))
 623     (or (org-export-push-to-kill-ring "LaTeX")
 624         (message "Exporting to LaTeX...done"))
 625     (prog1
 626         (if (eq to-buffer 'string)
 627             (prog1 (buffer-substring (point-min) (point-max))
 628               (kill-buffer (current-buffer)))
 629           (current-buffer))
 630       (set-window-configuration wcf))))
 631
 632 ;;;###autoload
 633 (defun org-export-as-pdf (arg &optional hidden ext-plist
 634                               to-buffer body-only pub-dir)
 635   "Export as LaTeX, then process through to PDF."
 636   (interactive "P")
 637   (message "Exporting to PDF...")
 638   (let* ((wconfig (current-window-configuration))
 639          (lbuf (org-export-as-latex arg hidden ext-plist
 640                                     to-buffer body-only pub-dir))
 641          (file (buffer-file-name lbuf))
 642          (base (file-name-sans-extension (buffer-file-name lbuf)))
 643          (pdffile (concat base ".pdf"))
 644          (cmds org-latex-to-pdf-process)
 645          (outbuf (get-buffer-create "*Org PDF LaTeX Output*"))
 646          (bibtex-p (with-current-buffer lbuf
 647                      (save-excursion
 648                        (goto-char (point-min))
 649                        (re-search-forward "\\\\bibliography{" nil t))))
 650          cmd)
 651     (with-current-buffer outbuf (erase-buffer))
 652     (and (file-exists-p pdffile) (delete-file pdffile))
 653     (message "Processing LaTeX file...")
 654     (if (and cmds (symbolp cmds))
 655         (funcall cmds file)
 656       (while cmds
 657         (setq cmd (pop cmds))
 658         (while (string-match "%b" cmd)
 659           (setq cmd (replace-match
 660                      (save-match-data
 661                        (shell-quote-argument base))
 662                      t t cmd)))
 663         (while (string-match "%s" cmd)
 664           (setq cmd (replace-match
 665                      (save-match-data
 666                        (shell-quote-argument file))
 667                      t t cmd)))
 668         (shell-command cmd outbuf outbuf)))
 669     (message "Processing LaTeX file...done")
 670     (if (not (file-exists-p pdffile))
 671         (error "PDF file was not produced")
 672       (set-window-configuration wconfig)
 673       (when org-export-pdf-remove-logfiles
 674         (dolist (ext '("aux" "log" "out" "toc"))
 675           (setq file (concat base "." ext))
 676           (and (file-exists-p file) (delete-file file))))
 677       (message "Exporting to PDF...done")
 678       pdffile)))
 679
 680 ;;;###autoload
 681 (defun org-export-as-pdf-and-open (arg)
 682   "Export as LaTeX, then process through to PDF, and open."
 683   (interactive "P")
 684   (let ((pdffile (org-export-as-pdf arg)))
 685     (if pdffile
 686         (org-open-file pdffile)
 687       (error "PDF file was not produced"))))
 688
 689 ;;; Parsing functions:
 690
 691 (defun org-export-latex-parse-global (level odd)
 692   "Parse the current buffer recursively, starting at LEVEL.
 693 If ODD is non-nil, assume the buffer only contains odd sections.
 694 Return a list reflecting the document structure."
 695   (save-excursion
 696     (goto-char (point-min))
 697     (let* ((cnt 0) output
 698            (depth org-export-latex-sectioning-depth))
 699       (while (re-search-forward
 700               (concat "^\\(\\(?:\\*\\)\\{"
 701                       (number-to-string (+ (if odd 2 1) level))
 702                       "\\}\\) \\(.*\\)$")
 703               ;; make sure that there is no upper heading
 704               (when (> level 0)
 705                 (save-excursion
 706                   (save-match-data
 707                     (re-search-forward
 708                      (concat "^\\(\\(?:\\*\\)\\{"
 709                              (number-to-string level)
 710                              "\\}\\) \\(.*\\)$") nil t)))) t)
 711         (setq cnt (1+ cnt))
 712         (let* ((pos (match-beginning 0))
 713                (heading (match-string 2))
 714                (nlevel (if odd (/ (+ 3 level) 2) (1+ level))))
 715           (save-excursion
 716             (narrow-to-region
 717              (point)
 718              (save-match-data
 719                (if (re-search-forward
 720                     (concat "^\\(\\(?:\\*\\)\\{"
 721                             (number-to-string (+ (if odd 2 1) level))
 722                             "\\}\\) \\(.*\\)$") nil t)
 723                    (match-beginning 0)
 724                  (point-max))))
 725             (goto-char (point-min))
 726             (setq output
 727                   (append output
 728                           (list
 729                            (list
 730                             `(pos . ,pos)
 731                             `(level . ,nlevel)
 732                             `(occur . ,cnt)
 733                             `(heading . ,heading)
 734                             `(content . ,(org-export-latex-parse-content))
 735                             `(subcontent . ,(org-export-latex-parse-subcontent
 736                                              level odd)))))))
 737           (widen)))
 738       (list output))))
 739
 740 (defun org-export-latex-parse-content ()
 741   "Extract the content of a section."
 742   (let ((beg (point))
 743         (end (if (re-search-forward "^\\(\\*\\)+ .*$" nil t)
 744                  (progn (beginning-of-line) (point))
 745                (point-max))))
 746     (buffer-substring beg end)))
 747
 748 (defun org-export-latex-parse-subcontent (level odd)
 749   "Extract the subcontent of a section at LEVEL.
 750 If ODD Is non-nil, assume subcontent only contains odd sections."
 751   (if (not (re-search-forward
 752             (concat "^\\(\\(?:\\*\\)\\{"
 753                     (number-to-string (+ (if odd 4 2) level))
 754                     "\\}\\) \\(.*\\)$")
 755             nil t))
 756       nil ; subcontent is nil
 757     (org-export-latex-parse-global (+ (if odd 2 1) level) odd)))
 758
 759 ;;; Rendering functions:
 760 (defun org-export-latex-global (content)
 761   "Export CONTENT to LaTeX.
 762 CONTENT is an element of the list produced by
 763 `org-export-latex-parse-global'."
 764   (if (eq (car content) 'subcontent)
 765       (mapc 'org-export-latex-sub (cdr content))
 766     (org-export-latex-sub (car content))))
 767
 768 (defun org-export-latex-sub (subcontent)
 769   "Export the list SUBCONTENT to LaTeX.
 770 SUBCONTENT is an alist containing information about the headline
 771 and its content."
 772   (let ((num (plist-get org-export-latex-options-plist :section-numbers)))
 773     (mapc (lambda(x) (org-export-latex-subcontent x num)) subcontent)))
 774
 775 (defun org-export-latex-subcontent (subcontent num)
 776   "Export each cell of SUBCONTENT to LaTeX.
 777 If NUM, export sections as numerical sections."
 778   (let* ((heading (org-export-latex-fontify-headline
 779                    (cdr (assoc 'heading subcontent))))
 780          (level (- (cdr (assoc 'level subcontent))
 781                    org-export-latex-add-level))
 782          (occur (number-to-string (cdr (assoc 'occur subcontent))))
 783          (content (cdr (assoc 'content subcontent)))
 784          (subcontent (cadr (assoc 'subcontent subcontent)))
 785          (label (org-get-text-property-any 0 'target heading))
 786          (label-list (cons label (cdr (assoc label
 787                                              org-export-target-aliases)))))
 788     (cond
 789      ;; Normal conversion
 790      ((<= level org-export-latex-sectioning-depth)
 791       (let* ((sec (nth (1- level) org-export-latex-sectioning))
 792              start end)
 793         (if (consp (cdr sec))
 794             (setq start (nth (if num 0 2) sec)
 795                   end (nth (if num 1 3) sec))
 796           (setq start (if num (car sec) (cdr sec))))
 797         (insert (format start heading) "\n")
 798         (when label
 799           (insert (mapconcat (lambda (l) (format "\\label{%s}" l))
 800                              label-list "\n") "\n"))
 801         (insert (org-export-latex-content content))
 802         (cond ((stringp subcontent) (insert subcontent))
 803               ((listp subcontent) (org-export-latex-sub subcontent)))
 804         (if end (insert end "\n"))))
 805      ;; At a level under the hl option: we can drop this subsection
 806      ((> level org-export-latex-sectioning-depth)
 807       (cond ((eq org-export-latex-low-levels 'description)
 808              (if (string-match "% ends low level$"
 809                                (buffer-substring (point-at-bol 0) (point)))
 810                  (delete-region (point-at-bol 0) (point))
 811                (insert "\\begin{description}\n"))
 812              (insert (format "\n\\item[%s]%s~\n\n"
 813                              heading
 814                              (if label (format "\\label{%s}" label) "")))
 815              (insert (org-export-latex-content content))
 816              (cond ((stringp subcontent) (insert subcontent))
 817                    ((listp subcontent) (org-export-latex-sub subcontent)))
 818              (insert "\\end{description} % ends low level\n"))
 819             ((memq org-export-latex-low-levels '(itemize enumerate))
 820              (if (string-match "% ends low level$"
 821                                (buffer-substring (point-at-bol 0) (point)))
 822                  (delete-region (point-at-bol 0) (point))
 823                (insert (format "\\begin{%s}\n"
 824                                (symbol-name org-export-latex-low-levels))))
 825              (insert (format "\n\\item %s\\\\\n%s\n"
 826                              heading
 827                              (if label (format "\\label{%s}" label) "")))
 828              (insert (org-export-latex-content content))
 829              (cond ((stringp subcontent) (insert subcontent))
 830                    ((listp subcontent) (org-export-latex-sub subcontent)))
 831              (insert (format "\\end{%s} %% ends low level\n"
 832                              (symbol-name org-export-latex-low-levels))))
 833
 834             ((listp org-export-latex-low-levels)
 835              (if (string-match "% ends low level$"
 836                                (buffer-substring (point-at-bol 0) (point)))
 837                  (delete-region (point-at-bol 0) (point))
 838                (insert (car org-export-latex-low-levels) "\n"))
 839              (insert (format (nth 2 org-export-latex-low-levels)
 840                              heading
 841                              (if label (format "\\label{%s}" label) "")))
 842              (insert (org-export-latex-content content))
 843              (cond ((stringp subcontent) (insert subcontent))
 844                    ((listp subcontent) (org-export-latex-sub subcontent)))
 845              (insert (nth 1 org-export-latex-low-levels)
 846                      " %% ends low level\n"))
 847
 848             ((stringp org-export-latex-low-levels)
 849              (insert (format org-export-latex-low-levels heading) "\n")
 850              (when label (insert (format "\\label{%s}\n" label)))
 851              (insert (org-export-latex-content content))
 852              (cond ((stringp subcontent) (insert subcontent))
 853                    ((listp subcontent) (org-export-latex-sub subcontent)))))))))
 854
 855 ;;; Exporting internals:
 856 (defun org-export-latex-set-initial-vars (ext-plist level)
 857   "Store org local variables required for LaTeX export.
 858 EXT-PLIST is an optional additional plist.
 859 LEVEL indicates the default depth for export."
 860   (setq org-export-latex-todo-keywords-1 org-todo-keywords-1
 861         org-export-latex-done-keywords org-done-keywords
 862         org-export-latex-not-done-keywords org-not-done-keywords
 863         org-export-latex-complex-heading-re org-complex-heading-regexp
 864         org-export-latex-display-custom-times org-display-custom-times
 865         org-export-latex-all-targets-re
 866         (org-make-target-link-regexp (org-all-targets))
 867         org-export-latex-options-plist
 868         (org-combine-plists (org-default-export-plist) ext-plist
 869                             (org-infile-export-plist))
 870         org-export-latex-class
 871         (or (and (org-region-active-p)
 872                  (save-excursion
 873                    (goto-char (region-beginning))
 874                    (and (looking-at org-complex-heading-regexp)
 875                         (org-entry-get nil "LaTeX_CLASS" 'selective))))
 876             (save-excursion
 877               (save-restriction
 878                 (widen)
 879                 (goto-char (point-min))
 880                 (and (re-search-forward "^#\\+LaTeX_CLASS:[ \t]*\\([a-zA-Z]+\\)" nil t)
 881                      (match-string 1))))
 882             org-export-latex-default-class)
 883         org-export-latex-class
 884         (or (car (assoc org-export-latex-class org-export-latex-classes))
 885             (error "No definition for class `%s' in `org-export-latex-classes'"
 886                    org-export-latex-class))
 887         org-export-latex-header
 888         (cadr (assoc org-export-latex-class org-export-latex-classes))
 889         org-export-latex-sectioning
 890         (cddr (assoc org-export-latex-class org-export-latex-classes))
 891         org-export-latex-sectioning-depth
 892         (or level
 893             (let ((hl-levels
 894                    (plist-get org-export-latex-options-plist :headline-levels))
 895                   (sec-depth (length org-export-latex-sectioning)))
 896               (if (> hl-levels sec-depth) sec-depth hl-levels)))))
 897
 898 (defun org-export-latex-make-header (title opt-plist)
 899   "Make the LaTeX header and return it as a string.
 900 TITLE is the current title from the buffer or region.
 901 OPT-PLIST is the options plist for current buffer."
 902   (let ((toc (plist-get opt-plist :table-of-contents))
 903         (author (plist-get opt-plist :author)))
 904     (concat
 905      (if (plist-get opt-plist :time-stamp-file)
 906          (format-time-string "%% Created %Y-%m-%d %a %H:%M\n"))
 907      ;; insert LaTeX custom header
 908      (org-export-apply-macros-in-string org-export-latex-header)
 909      "\n"
 910      ;; insert information on LaTeX packages
 911      (when org-export-latex-packages-alist
 912        (mapconcat (lambda(p)
 913                     (if (equal "" (car p))
 914                         (format "\\usepackage{%s}" (cadr p))
 915                       (format "\\usepackage[%s]{%s}"
 916                               (car p) (cadr p))))
 917                   org-export-latex-packages-alist "\n"))
 918      ;; insert additional commands in the header
 919      (org-export-apply-macros-in-string
 920       (plist-get opt-plist :latex-header-extra))
 921      (org-export-apply-macros-in-string org-export-latex-append-header)
 922      ;; insert the title
 923      (format
 924       "\n\n\\title{%s}\n"
 925       ;; convert the title
 926       (org-export-latex-content
 927        title '(lists tables fixed-width keywords)))
 928      ;; insert author info
 929      (if (plist-get opt-plist :author-info)
 930          (format "\\author{%s}\n"
 931                  (or author user-full-name))
 932        (format "%%\\author{%s}\n"
 933                (or author user-full-name)))
 934      ;; insert the date
 935      (format "\\date{%s}\n"
 936              (format-time-string
 937               (or (plist-get opt-plist :date)
 938                   org-export-latex-date-format)))
 939      ;; beginning of the document
 940      "\n\\begin{document}\n\n"
 941      ;; insert the title command
 942      (if (string-match "%s" org-export-latex-title-command)
 943          (format org-export-latex-title-command title)
 944        org-export-latex-title-command)
 945      "\n\n"
 946      ;; table of contents
 947      (when (and org-export-with-toc
 948                 (plist-get opt-plist :section-numbers))
 949        (cond ((numberp toc)
 950               (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\\vspace*{1cm}\n"
 951                       (min toc (plist-get opt-plist :headline-levels))))
 952              (toc (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\\vspace*{1cm}\n"
 953                           (plist-get opt-plist :headline-levels))))))))
 954
 955 (defun org-export-latex-first-lines (opt-plist &optional beg end)
 956   "Export the first lines before first headline.
 957 If BEG is non-nil, it is the beginning of the region.
 958 If END is non-nil, it is the end of the region."
 959   (save-excursion
 960     (goto-char (or beg (point-min)))
 961     (let* ((pt (point))
 962            (end (if (re-search-forward "^\\*+ " end t)
 963                     (goto-char (match-beginning 0))
 964                   (goto-char (point-max)))))
 965       (prog1
 966           (org-export-latex-content
 967            (org-export-preprocess-string
 968             (buffer-substring pt end)
 969             :for-LaTeX t
 970             :emph-multiline t
 971             :add-text nil
 972             :comments nil
 973             :skip-before-1st-heading nil
 974             :LaTeX-fragments nil
 975             :timestamps (plist-get opt-plist :timestamps)
 976             :footnotes (plist-get opt-plist :footnotes)))
 977         (org-unmodified
 978          (add-text-properties pt (max pt (1- end))
 979                               '(:org-license-to-kill t)))))))
 980
 981 (defvar org-export-latex-header-defs nil
 982   "The header definitions that might be used in the LaTeX body.")
 983 (defvar org-export-latex-header-defs-re nil
 984   "The header definitions that might be used in the LaTeX body.")
 985
 986 (defun org-export-latex-content (content &optional exclude-list)
 987   "Convert CONTENT string to LaTeX.
 988 Don't perform conversions that are in EXCLUDE-LIST.  Recognized
 989 conversion types are: quotation-marks, emphasis, sub-superscript,
 990 links, keywords, lists, tables, fixed-width"
 991   (with-temp-buffer
 992    (insert content)
 993    (unless (memq 'timestamps exclude-list)
 994      (org-export-latex-time-stamps))
 995    (unless (memq 'quotation-marks exclude-list)
 996      (org-export-latex-quotation-marks))
 997    (unless (memq 'emphasis exclude-list)
 998      (when (plist-get org-export-latex-options-plist :emphasize)
 999        (org-export-latex-fontify)))
1000    (unless (memq 'sub-superscript exclude-list)
1001      (org-export-latex-special-chars
1002       (plist-get org-export-latex-options-plist :sub-superscript)))
1003    (unless (memq 'links exclude-list)
1004      (org-export-latex-links))
1005    (unless (memq 'keywords exclude-list)
1006      (org-export-latex-keywords))
1007    (unless (memq 'lists exclude-list)
1008      (org-export-latex-lists))
1009    (unless (memq 'tables exclude-list)
1010      (org-export-latex-tables
1011       (plist-get org-export-latex-options-plist :tables)))
1012    (unless (memq 'fixed-width exclude-list)
1013      (org-export-latex-fixed-width
1014       (plist-get org-export-latex-options-plist :fixed-width)))
1015    ;; return string
1016    (buffer-substring (point-min) (point-max))))
1017
1018 (defun org-export-latex-protect-string (s)
1019   "Add the org-protected property to string S."
1020   (add-text-properties 0 (length s) '(org-protected t) s) s)
1021
1022 (defun org-export-latex-protect-char-in-string (char-list string)
1023   "Add org-protected text-property to char from CHAR-LIST in STRING."
1024   (with-temp-buffer
1025     (save-match-data
1026       (insert string)
1027       (goto-char (point-min))
1028       (while (re-search-forward (regexp-opt char-list) nil t)
1029         (add-text-properties (match-beginning 0)
1030                              (match-end 0) '(org-protected t)))
1031       (buffer-string))))
1032
1033 (defun org-export-latex-keywords-maybe (&optional remove-list)
1034   "Maybe remove keywords depending on rules in REMOVE-LIST."
1035   (goto-char (point-min))
1036   (let ((re-todo (mapconcat 'identity org-export-latex-todo-keywords-1 "\\|"))
1037         (case-fold-search nil)
1038         (todo-markup org-export-latex-todo-keyword-markup)
1039         fmt)
1040     ;; convert TODO keywords
1041     (when (re-search-forward (concat "^\\(" re-todo "\\)") nil t)
1042       (if (plist-get remove-list :todo)
1043           (replace-match "")
1044         (setq fmt (cond
1045                    ((stringp todo-markup) todo-markup)
1046                    ((and (consp todo-markup) (stringp (car todo-markup)))
1047                     (if (member (match-string 1) org-export-latex-done-keywords)
1048                         (cdr todo-markup) (car todo-markup)))
1049                    (t (cdr (or (assoc (match-string 1) todo-markup)
1050                                (car todo-markup))))))
1051         (replace-match (format fmt (match-string 1)) t t)))
1052     ;; convert priority string
1053     (when (re-search-forward "\\[\\\\#.\\]" nil t)
1054       (if (plist-get remove-list :priority)
1055           (replace-match "")
1056         (replace-match (format "\\textbf{%s}" (match-string 0)) t t)))
1057     ;; convert tags
1058     (when (re-search-forward "\\(:[a-zA-Z0-9_@]+\\)+:" nil t)
1059       (if (or (not org-export-with-tags)
1060               (plist-get remove-list :tags))
1061           (replace-match "")
1062         (replace-match
1063          (org-export-latex-protect-string
1064           (format "\\textbf{%s}"
1065                   (save-match-data
1066                     (replace-regexp-in-string
1067                      "_" "\\\\_" (match-string 0)))))
1068          t t)))))
1069
1070 (defun org-export-latex-fontify-headline (string)
1071   "Fontify special words in STRING."
1072   (with-temp-buffer
1073     ;; FIXME: org-inside-LaTeX-fragment-p doesn't work when the $...$ is at
1074     ;; the beginning of the buffer - inserting "\n" is safe here though.
1075     (insert "\n" string)
1076     (goto-char (point-min))
1077     (when (plist-get org-export-latex-options-plist :emphasize)
1078       (org-export-latex-fontify))
1079     (org-export-latex-keywords-maybe)
1080     (org-export-latex-special-chars
1081      (plist-get org-export-latex-options-plist :sub-superscript))
1082     (org-export-latex-links)
1083     (org-trim (buffer-string))))
1084
1085 (defun org-export-latex-time-stamps ()
1086   "Format time stamps."
1087   (goto-char (point-min))
1088   (let ((org-display-custom-times org-export-latex-display-custom-times))
1089     (while (re-search-forward org-ts-regexp-both nil t)
1090       (org-if-unprotected-at (1- (point))
1091        (replace-match
1092         (org-export-latex-protect-string
1093          (format org-export-latex-timestamp-markup
1094                  (substring (org-translate-time (match-string 0)) 1 -1)))
1095         t t)))))
1096
1097 (defun org-export-latex-quotation-marks ()
1098   "Export quotation marks depending on language conventions."
1099   (let* ((lang (plist-get org-export-latex-options-plist :language))
1100          (quote-rpl (if (equal lang "fr")
1101                         '(("\\(\\s-\\)\"" "«~")
1102                           ("\\(\\S-\\)\"" "~»")
1103                           ("\\(\\s-\\)'" "`"))
1104                       '(("\\(\\s-\\|(\\)\"" "``")
1105                         ("\\(\\S-\\)\"" "''")
1106                         ("\\(\\s-\\|(\\)'" "`")))))
1107     (mapc (lambda(l) (goto-char (point-min))
1108             (while (re-search-forward (car l) nil t)
1109               (let ((rpl (concat (match-string 1) (cadr l))))
1110                 (org-export-latex-protect-string rpl)
1111                 (org-if-unprotected-1
1112                  (replace-match rpl t t))))) quote-rpl)))
1113
1114 (defun org-export-latex-special-chars (sub-superscript)
1115   "Export special characters to LaTeX.
1116 If SUB-SUPERSCRIPT is non-nil, convert \\ and ^.
1117 See the `org-export-latex.el' code for a complete conversion table."
1118   (goto-char (point-min))
1119   (mapc (lambda(c)
1120           (goto-char (point-min))
1121           (while (re-search-forward c nil t)
1122             ;; Put the point where to check for org-protected
1123             (unless (get-text-property (match-beginning 2) 'org-protected)
1124               (cond ((member (match-string 2) '("\\$" "$"))
1125                      (if (equal (match-string 2) "\\$")
1126                          nil
1127                        (replace-match "\\$" t t)))
1128                     ((member (match-string 2) '("&" "%" "#"))
1129                      (if (equal (match-string 1) "\\")
1130                          (replace-match (match-string 2) t t)
1131                        (replace-match (concat (match-string 1) "\\"
1132                                               (match-string 2)) t t)))
1133                     ((equal (match-string 2) "...")
1134                      (replace-match
1135                       (concat (match-string 1)
1136                               (org-export-latex-protect-string "\\ldots{}")) t t))
1137                     ((equal (match-string 2) "~")
1138                      (cond ((equal (match-string 1) "\\") nil)
1139                            ((eq 'org-link (get-text-property 0 'face (match-string 2)))
1140                             (replace-match (concat (match-string 1) "\\~") t t))
1141                            (t (replace-match
1142                                (org-export-latex-protect-string
1143                                 (concat (match-string 1) "\\~{}")) t t))))
1144                     ((member (match-string 2) '("{" "}"))
1145                      (unless (save-match-data (org-inside-latex-math-p))
1146                        (if (equal (match-string 1) "\\")
1147                            (replace-match (match-string 2) t t)
1148                          (replace-match (concat (match-string 1) "\\"
1149                                                 (match-string 2)) t t)))))
1150               (unless (save-match-data (org-inside-latex-math-p))
1151                 (cond ((equal (match-string 2) "\\")
1152                        (replace-match (or (save-match-data
1153                                             (org-export-latex-treat-backslash-char
1154                                              (match-string 1)
1155                                              (or (match-string 3) "")))
1156                                           "") t t))
1157                       ((member (match-string 2) '("_" "^"))
1158                        (replace-match (or (save-match-data
1159                                             (org-export-latex-treat-sub-super-char
1160                                              sub-superscript
1161                                              (match-string 2)
1162                                              (match-string 1)
1163                                              (match-string 3))) "") t t)))))))
1164         '(;"^\\([^\n$]*?\\|^\\)\\(\\\\?\\$\\)\\([^\n$]*\\)$"
1165           "\\(\\(\\\\?\\$\\)\\)"
1166           "\\([a-za-z0-9]+\\|[ \t\n]\\|\\b\\|\\\\\\)\\(_\\|\\^\\)\\({[^{}]+}\\|[a-za-z0-9]+\\|[ \t\n]\\|[:punct:]\\|{[a-za-z0-9]+}\\|([a-za-z0-9]+)\\)"
1167           "\\(.\\|^\\)\\(\\\\\\)\\([ \t\n]\\|[a-zA-Z&#%{}\"]+\\)"
1168           "\\(.\\|^\\)\\(&\\)"
1169           "\\(.\\|^\\)\\(#\\)"
1170           "\\(.\\|^\\)\\(%\\)"
1171           "\\(.\\|^\\)\\({\\)"
1172           "\\(.\\|^\\)\\(}\\)"
1173           "\\(.\\|^\\)\\(~\\)"
1174           "\\(.\\|^\\)\\(\\.\\.\\.\\)"
1175           ;; (?\< . "\\textless{}")
1176           ;; (?\> . "\\textgreater{}")
1177           )))
1178
1179 (defun org-inside-latex-math-p ()
1180   (get-text-property (point) 'org-latex-math))
1181
1182 (defun org-export-latex-treat-sub-super-char
1183   (subsup char string-before string-after)
1184   "Convert the \"_\" and \"^\" characters to LaTeX.
1185 SUBSUP corresponds to the ^: option in the #+OPTIONS line.
1186 Convert CHAR depending on STRING-BEFORE and STRING-AFTER."
1187   (cond ((equal string-before "\\")
1188          (concat string-before char string-after))
1189         ;; this is part of a math formula
1190         ((and (string-match "\\S-+" string-before)
1191               (string-match "\\S-+" string-after))
1192          (cond ((eq 'org-link (get-text-property 0 'face char))
1193                 (concat string-before "\\" char string-after))
1194                ((save-match-data (org-inside-latex-math-p))
1195                 (if subsup
1196                     (cond ((eq 1 (length string-after))
1197                            (concat string-before char string-after))
1198                           ((string-match "[({]?\\([^)}]+\\)[)}]?" string-after)
1199                            (format "%s%s{%s}" string-before char
1200                                    (match-string 1 string-after))))))
1201                ((and (> (length string-after) 1)
1202                      (or (eq subsup t)
1203                          (and (equal subsup '{}) (eq (string-to-char string-after) ?\{)))
1204                      (string-match "[({]?\\([^)}]+\\)[)}]?" string-after))
1205                 (org-export-latex-protect-string
1206                  (format "%s$%s{%s}$" string-before char
1207                          (if (and (> (match-end 1) (1+ (match-beginning 1)))
1208                                   (not (equal (substring string-after 0 2) "{\\")))
1209                              (concat "\\mathrm{" (match-string 1 string-after) "}")
1210                            (match-string 1 string-after)))))
1211                ((eq subsup t) (concat string-before "$" char string-after "$"))
1212                (t (org-export-latex-protect-string
1213                    (concat string-before "\\" char "{}" string-after)))))
1214         (t (org-export-latex-protect-string
1215             (concat string-before "\\" char "{}" string-after)))))
1216
1217 (defun org-export-latex-treat-backslash-char (string-before string-after)
1218   "Convert the \"$\" special character to LaTeX.
1219 The conversion is made depending of STRING-BEFORE and STRING-AFTER."
1220   (cond ((member (list string-after) org-html-entities)
1221          ;; backslash is part of a special entity (like "\alpha")
1222          (concat string-before "$\\"
1223                  (or (cdar (member (list string-after) org-html-entities))
1224                      string-after) "$"))
1225         ((and (not (string-match "^[ \n\t]" string-after))
1226               (not (string-match "[ \t]\\'\\|^" string-before)))
1227          ;; backslash is inside a word
1228          (org-export-latex-protect-string
1229           (concat string-before "\\textbackslash{}" string-after)))
1230         ((not (or (equal string-after "")
1231                   (string-match "^[ \t\n]" string-after)))
1232          ;; backslash might escape a character (like \#) or a user TeX
1233          ;; macro (like \setcounter)
1234          (org-export-latex-protect-string
1235           (concat string-before "\\" string-after)))
1236         ((and (string-match "^[ \t\n]" string-after)
1237               (string-match "[ \t\n]\\'" string-before))
1238          ;; backslash is alone, convert it to $\backslash$
1239          (org-export-latex-protect-string
1240           (concat string-before "\\textbackslash{}" string-after)))
1241         (t (org-export-latex-protect-string
1242             (concat string-before "\\textbackslash{}" string-after)))))
1243
1244 (defun org-export-latex-keywords ()
1245   "Convert special keywords to LaTeX."
1246   (goto-char (point-min))
1247   (while (re-search-forward org-export-latex-special-keyword-regexp nil t)
1248     (replace-match (format org-export-latex-timestamp-keyword-markup
1249                            (match-string 0)) t t)
1250     (save-excursion
1251       (beginning-of-line 1)
1252       (unless (looking-at ".*\\\\newline[ \t]*$")
1253         (end-of-line 1)
1254         (insert "\\newline")))))
1255
1256 (defun org-export-latex-fixed-width (opt)
1257   "When OPT is non-nil convert fixed-width sections to LaTeX."
1258   (goto-char (point-min))
1259   (while (re-search-forward "^[ \t]*:\\([ \t]\\|$\\)" nil t)
1260     (if opt
1261         (progn (goto-char (match-beginning 0))
1262                (insert "\\begin{verbatim}\n")
1263                (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1264                  (replace-match (concat (match-string 1)
1265                                         (match-string 2)) t t)
1266                  (forward-line))
1267                (insert "\\end{verbatim}\n\n"))
1268       (progn (goto-char (match-beginning 0))
1269              (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1270                (replace-match (concat "%" (match-string 1)
1271                                       (match-string 2)) t t)
1272                (forward-line))))))
1273
1274
1275 (defvar org-table-last-alignment) ; defined in org-table.el
1276 (declare-function orgtbl-to-latex "org-table" (table params) t)
1277 (defun org-export-latex-tables (insert)
1278   "Convert tables to LaTeX and INSERT it."
1279   (goto-char (point-min))
1280   (while (re-search-forward "^\\([ \t]*\\)|" nil t)
1281     ;; FIXME really need to save-excursion?
1282     (save-excursion (org-table-align))
1283     (let* ((beg (org-table-begin))
1284            (end (org-table-end))
1285            (raw-table (buffer-substring beg end))
1286            fnum fields line lines olines gr colgropen line-fmt align
1287            caption label attr floatp longtblp)
1288       (if org-export-latex-tables-verbatim
1289           (let* ((tbl (concat "\\begin{verbatim}\n" raw-table
1290                               "\\end{verbatim}\n")))
1291             (apply 'delete-region (list beg end))
1292             (insert (org-export-latex-protect-string tbl)))
1293         (progn
1294           (setq caption (org-find-text-property-in-string
1295                          'org-caption raw-table)
1296                 attr (org-find-text-property-in-string
1297                       'org-attributes raw-table)
1298                 label (org-find-text-property-in-string
1299                        'org-label raw-table)
1300                 longtblp (and attr (stringp attr)
1301                               (string-match "\\<longtable\\>" attr))
1302                 align (and attr (stringp attr)
1303                            (string-match "\\<align=\\([^ \t\n\r,]+\\)" attr)
1304                            (match-string 1 attr))
1305                 floatp (or caption label))
1306           (setq lines (org-split-string raw-table "\n"))
1307           (apply 'delete-region (list beg end))
1308           (when org-export-table-remove-special-lines
1309             (setq lines (org-table-clean-before-export lines 'maybe-quoted)))
1310           ;; make a formatting string to reflect aligment
1311           (setq olines lines)
1312           (while (and (not line-fmt) (setq line (pop olines)))
1313             (unless (string-match "^[ \t]*|-" line)
1314               (setq fields (org-split-string line "[ \t]*|[ \t]*"))
1315               (setq fnum (make-vector (length fields) 0))
1316               (setq line-fmt
1317                     (mapconcat
1318                      (lambda (x)
1319                        (setq gr (pop org-table-colgroup-info))
1320                        (format "%s%%s%s"
1321                                (cond ((eq gr :start)
1322                                       (prog1 (if colgropen "|" "|")
1323                                         (setq colgropen t)))
1324                                      ((eq gr :startend)
1325                                       (prog1 (if colgropen "|" "|")
1326                                         (setq colgropen nil)))
1327                                      (t ""))
1328                                (if (memq gr '(:end :startend))
1329                                    (progn (setq colgropen nil) "|")
1330                                  "")))
1331                      fnum ""))))
1332           ;; fix double || in line-fmt
1333           (setq line-fmt (replace-regexp-in-string "||" "|" line-fmt))
1334           ;; maybe remove the first and last "|"
1335           (when (and (not org-export-latex-tables-column-borders)
1336                      (string-match "^\\(|\\)?\\(.+\\)|$" line-fmt))
1337             (setq line-fmt (match-string 2 line-fmt)))
1338           ;; format alignment
1339           (unless align
1340             (setq align (apply 'format
1341                                (cons line-fmt
1342                                      (mapcar (lambda (x) (if x "r" "l"))
1343                                              org-table-last-alignment)))))
1344           ;; prepare the table to send to orgtbl-to-latex
1345           (setq lines
1346                 (mapcar
1347                  (lambda(elem)
1348                    (or (and (string-match "[ \t]*|-+" elem) 'hline)
1349                        (org-split-string (org-trim elem) "|")))
1350                  lines))
1351           (when insert
1352             (insert (org-export-latex-protect-string
1353                      (concat
1354                       (if longtblp
1355                           (concat "\\begin{longtable}{" align "}\n")
1356                         (if floatp "\\begin{table}[htb]\n"))
1357                       (if (or floatp longtblp)
1358                           (format
1359                            "\\caption{%s%s}"
1360                            (if label (concat "\\\label{" label "}") "")
1361                            (or caption "")))
1362                       (if longtblp "\\\\\n" "\n")
1363                       (if (and org-export-latex-tables-centered (not longtblp))
1364                           "\\begin{center}\n")
1365                       (if (not longtblp) (concat "\\begin{tabular}{" align "}\n"))
1366                       (orgtbl-to-latex
1367                        lines
1368                        `(:tstart nil :tend nil
1369                                  :hlend ,(if longtblp
1370                                              (format "\\\\
1371 \\hline
1372 \\endhead
1373 \\hline\\multicolumn{%d}{r}{Continued on next page}\\
1374 \\endfoot
1375 \\endlastfoot" (length org-table-last-alignment))
1376                                            nil)))
1377                       (if (not longtblp) (concat "\n\\end{tabular}"))
1378                       (if longtblp "\n" (if org-export-latex-tables-centered
1379                                             "\n\\end{center}\n" "\n"))
1380                       (if longtblp
1381                           "\\end{longtable}"
1382                         (if floatp "\\end{table}"))))
1383                     "\n\n")))))))
1384
1385 (defun org-export-latex-fontify ()
1386   "Convert fontification to LaTeX."
1387   (goto-char (point-min))
1388   (while (re-search-forward org-emph-re nil t)
1389     ;; The match goes one char after the *string*
1390     (let ((emph (assoc (match-string 3)
1391                        org-export-latex-emphasis-alist))
1392           (beg (match-beginning 0))
1393           (end (match-end 0))
1394           rpl)
1395       (unless emph
1396         (message "`org-export-latex-emphasis-alist' has no entry for formatting triggered by \"%s\""
1397                  (match-string 3)))
1398       (unless (or (get-text-property (1- (point)) 'org-protected)
1399                   (save-excursion
1400                     (goto-char (match-beginning 1))
1401                     (save-match-data
1402                       (and (org-at-table-p)
1403                            (string-match
1404                             "[|\n]" (buffer-substring beg end))))))
1405         (setq rpl (concat (match-string 1)
1406                           (org-export-latex-emph-format (cadr emph)
1407                                                         (match-string 4))
1408                           (match-string 5)))
1409         (if (caddr emph)
1410             (setq rpl (org-export-latex-protect-string rpl)))
1411         (replace-match rpl t t)))
1412     (backward-char)))
1413
1414 (defvar org-export-latex-use-verb nil)
1415 (defun org-export-latex-emph-format (format string)
1416   "Format an emphasis string and handle the \\verb special case."
1417   (when (equal format "\\verb")
1418     (save-match-data
1419       (if org-export-latex-use-verb
1420           (let ((ll "~,./?;':\"|!@#%^&-_=+abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ<>()[]{}"))
1421             (catch 'exit
1422               (loop for i from 0 to (1- (length ll)) do
1423                     (if (not (string-match (regexp-quote (substring ll i (1+ i)))
1424                                            string))
1425                         (progn
1426                           (setq format (concat "\\verb" (substring ll i (1+ i))
1427                                                "%s" (substring ll i (1+ i))))
1428                           (throw 'exit nil))))))
1429         (let ((start 0)
1430               (trans '(("\\" . "\\backslash")
1431                        ("~" . "\\ensuremath{\\sim}")
1432                        ("^" . "\\ensuremath{\\wedge}")))
1433               (rtn "") char)
1434           (while (string-match "[\\{}$%&_#~^]" string)
1435             (setq char (match-string 0 string))
1436             (if (> (match-beginning 0) 0)
1437                 (setq rtn (concat rtn (substring string
1438                                                  0 (match-beginning 0)))))
1439             (setq string (substring string (1+ (match-beginning 0))))
1440             (setq char (or (cdr (assoc char trans)) (concat "\\" char))
1441                   rtn (concat rtn char)))
1442           (setq string (concat rtn string) format "\\texttt{%s}")))))
1443   (setq string (org-export-latex-protect-string
1444                 (format format string))))
1445
1446 (defun org-export-latex-links ()
1447   ;; Make sure to use the LaTeX hyperref and graphicx package
1448   ;; or send some warnings.
1449   "Convert links to LaTeX."
1450   (goto-char (point-min))
1451   (while (re-search-forward org-bracket-link-analytic-regexp++ nil t)
1452     (org-if-unprotected
1453      (goto-char (match-beginning 0))
1454      (let* ((re-radio org-export-latex-all-targets-re)
1455             (remove (list (match-beginning 0) (match-end 0)))
1456             (raw-path (org-extract-attributes (match-string 3)))
1457             (full-raw-path (concat (match-string 1) raw-path))
1458             (desc (match-string 5))
1459             (type (or (match-string 2)
1460                       (if (or (file-name-absolute-p raw-path)
1461                               (string-match "^\\.\\.?/" raw-path))
1462                           "file")))
1463             (coderefp (equal type "coderef"))
1464             (caption (org-find-text-property-in-string 'org-caption raw-path))
1465             (attr (or (org-find-text-property-in-string 'org-attributes raw-path)
1466                       (plist-get org-export-latex-options-plist :latex-image-options)))
1467             (label (org-find-text-property-in-string 'org-label raw-path))
1468             (floatp (or label caption))
1469             imgp radiop
1470             ;; define the path of the link
1471             (path (cond
1472                    ((member type '("coderef"))
1473                     raw-path)
1474                    ((member type '("http" "https" "ftp"))
1475                     (concat type ":" raw-path))
1476                    ((and re-radio (string-match re-radio raw-path))
1477                     (setq radiop t))
1478                    ((equal type "mailto")
1479                     (concat type ":" raw-path))
1480                    ((equal type "file")
1481                     (if (and (org-file-image-p
1482                               (expand-file-name
1483                                raw-path)
1484                               org-export-latex-inline-image-extensions)
1485                              (or (get-text-property 0 'org-no-description
1486                                                     raw-path)
1487                                  (equal desc full-raw-path)))
1488                         (setq imgp t)
1489                       (progn (when (string-match "\\(.+\\)::.+" raw-path)
1490                                (setq raw-path (match-string 1 raw-path)))
1491                              (if (file-exists-p raw-path)
1492                                  (concat type "://" (expand-file-name raw-path))
1493                                (concat type "://" (org-export-directory
1494                                                    :LaTeX org-export-latex-options-plist)
1495                                        raw-path))))))))
1496        ;; process with link inserting
1497        (apply 'delete-region remove)
1498        (cond ((and imgp (plist-get org-export-latex-options-plist :inline-images))
1499               (insert
1500                (concat
1501                 (if floatp "\\begin{figure}[htb]\n")
1502                 (format "\\centerline{\\includegraphics[%s]{%s}}\n"
1503                         attr
1504                         (if (file-name-absolute-p raw-path)
1505                             (expand-file-name raw-path)
1506                           raw-path))
1507                 (if floatp
1508                     (format "\\caption{%s%s}\n"
1509                             (if label (concat "\\label{" label "}") "")
1510                             (or caption "")))
1511                 (if floatp "\\end{figure}\n"))))
1512              (coderefp
1513               (insert (format
1514                        (org-export-get-coderef-format path desc)
1515                        (cdr (assoc path org-export-code-refs)))))
1516              (radiop (insert (format "\\hyperref[%s]{%s}"
1517                                      (org-solidify-link-text raw-path) desc)))
1518              ((not type)
1519               (insert (format "\\hyperref[%s]{%s}"
1520                               (org-remove-initial-hash
1521                                (org-solidify-link-text raw-path)) desc)))
1522              (path (insert (format "\\href{%s}{%s}" path desc)))
1523              (t (insert "\\texttt{" desc "}")))))))
1524
1525 (defun org-remove-initial-hash (s)
1526   (if (string-match "\\`#" s)
1527       (substring s 1)
1528     s))
1529 (defvar org-latex-entities)   ; defined below
1530 (defvar org-latex-entities-regexp)   ; defined below
1531 (defvar org-latex-entities-exceptions)   ; defined below
1532
1533 (defun org-export-latex-preprocess (parameters)
1534   "Clean stuff in the LaTeX export."
1535   ;; Preserve line breaks
1536   (goto-char (point-min))
1537   (while (re-search-forward "\\\\\\\\" nil t)
1538     (add-text-properties (match-beginning 0) (match-end 0)
1539                          '(org-protected t)))
1540
1541   ;; Preserve latex environments
1542   (goto-char (point-min))
1543   (while (re-search-forward "^[ \t]*\\\\begin{\\([a-zA-Z]+\\*?\\)}" nil t)
1544     (let* ((start (progn (beginning-of-line) (point)))
1545            (end (or (and (re-search-forward
1546                           (concat "^[ \t]*\\\\end{"
1547                                   (regexp-quote (match-string 1))
1548                                   "}") nil t)
1549                          (point-at-eol))
1550                     (point-max))))
1551       (add-text-properties start end '(org-protected t))))
1552
1553   ;; Preserve math snippets
1554
1555   (let* ((matchers (plist-get org-format-latex-options :matchers))
1556          (re-list org-latex-regexps)
1557          beg end re e m n block off)
1558     ;; Check the different regular expressions
1559     (while (setq e (pop re-list))
1560       (setq m (car e) re (nth 1 e) n (nth 2 e)
1561             block (if (nth 3 e) "\n\n" ""))
1562       (setq off (if (member m '("$" "$1")) 1 0))
1563       (when (and (member m matchers) (not (equal m "begin")))
1564         (goto-char (point-min))
1565         (while (re-search-forward re nil t)
1566           (setq beg (+ (match-beginning 0) off) end (- (match-end 0) 0))
1567           (add-text-properties beg end '(org-protected t org-latex-math t))))))
1568
1569   ;; Convert LaTeX to \LaTeX{}
1570   (goto-char (point-min))
1571   (let ((case-fold-search nil))
1572     (while (re-search-forward "\\([^+_]\\)LaTeX" nil t)
1573       (org-if-unprotected
1574        (replace-match (org-export-latex-protect-string
1575                        (concat (match-string 1) "\\LaTeX{}")) t t))))
1576
1577   ;; Convert blockquotes
1578   (goto-char (point-min))
1579   (while (search-forward "ORG-BLOCKQUOTE-START" nil t)
1580     (org-replace-match-keep-properties "\\begin{quote}" t t))
1581   (goto-char (point-min))
1582   (while (search-forward "ORG-BLOCKQUOTE-END" nil t)
1583     (org-replace-match-keep-properties "\\end{quote}" t t))
1584
1585   ;; Convert verse
1586   (goto-char (point-min))
1587   (while (search-forward "ORG-VERSE-START" nil t)
1588     (org-replace-match-keep-properties "\\begin{verse}" t t)
1589     (beginning-of-line 2)
1590     (while (and (not (looking-at "[ \t]*ORG-VERSE-END.*")) (not (eobp)))
1591       (when (looking-at "\\([ \t]+\\)\\([^ \t\n]\\)")
1592         (goto-char (match-end 1))
1593         (org-replace-match-keep-properties
1594          (org-export-latex-protect-string
1595           (concat "\\hspace*{1cm}" (match-string 2))) t t)
1596         (beginning-of-line 1))
1597       (unless (looking-at ".*?[^ \t\n].*?\\\\\\\\[ \t]*$")
1598         (end-of-line 1)
1599         (insert "\\\\"))
1600       (beginning-of-line 2))
1601     (and (looking-at "[ \t]*ORG-VERSE-END.*")
1602          (org-replace-match-keep-properties "\\end{verse}" t t)))
1603
1604   ;; Convert center
1605   (goto-char (point-min))
1606   (while (search-forward "ORG-CENTER-START" nil t)
1607     (org-replace-match-keep-properties "\\begin{center}" t t))
1608   (goto-char (point-min))
1609   (while (search-forward "ORG-CENTER-END" nil t)
1610     (org-replace-match-keep-properties "\\end{center}" t t))
1611
1612   (run-hooks 'org-export-latex-after-blockquotes-hook)
1613
1614   ;; Convert horizontal rules
1615   (goto-char (point-min))
1616   (while (re-search-forward "^----+.$" nil t)
1617     (org-if-unprotected
1618      (replace-match (org-export-latex-protect-string "\\hrule") t t)))
1619
1620   ;; Protect LaTeX commands like \command[...]{...} or \command{...}
1621   (let ((re (concat "\\\\[a-zA-Z]+\\(?:"
1622                     "\\[.*\\]"
1623                     "\\)?"
1624                     (org-create-multibrace-regexp "{" "}" 3))))
1625     (while (re-search-forward re nil t)
1626       (add-text-properties (match-beginning 0) (match-end 0)
1627                            '(org-protected t))))
1628
1629   ;; Protect LaTeX entities
1630   (goto-char (point-min))
1631   (let (a)
1632     (while (re-search-forward org-latex-entities-regexp nil t)
1633       (if (setq a (assoc (match-string 0) org-latex-entities-exceptions))
1634           (replace-match (org-add-props (nth 1 a) nil 'org-protected t)
1635                          t t)
1636         (add-text-properties (match-beginning 0) (match-end 0)
1637                              '(org-protected t)))))
1638
1639   ;; Replace radio links
1640   (goto-char (point-min))
1641   (while (re-search-forward
1642           (concat "<<<?" org-export-latex-all-targets-re
1643                   ">>>?\\((INVISIBLE)\\)?") nil t)
1644     (org-if-unprotected
1645      (replace-match
1646       (org-export-latex-protect-string
1647        (format "\\label{%s}%s" (save-match-data (org-solidify-link-text
1648                                                  (match-string 1)))
1649                (if (match-string 2) "" (match-string 1)))) t t)))
1650
1651   ;; Delete @<...> constructs
1652   ;; Thanks to Daniel Clemente for this regexp
1653   (goto-char (point-min))
1654   (while (re-search-forward "@<\\(?:[^\"\n]\\|\".*\"\\)*?>" nil t)
1655     (org-if-unprotected
1656      (replace-match "")))
1657
1658   ;; When converting to LaTeX, replace footnotes
1659   ;; FIXME: don't protect footnotes from conversion
1660   (when (plist-get org-export-latex-options-plist :footnotes)
1661     (goto-char (point-min))
1662     (while (re-search-forward "\\[\\([0-9]+\\)\\]" nil t)
1663       (org-if-unprotected
1664        (when (save-match-data
1665                (save-excursion (beginning-of-line)
1666                                (looking-at "[^:|#]")))
1667          (let ((foot-beg (match-beginning 0))
1668                (foot-end (match-end 0))
1669                (foot-prefix (match-string 0))
1670                footnote footnote-rpl)
1671            (save-excursion
1672              (if (not (re-search-forward (concat "^" (regexp-quote foot-prefix))
1673                                          nil t))
1674                  (replace-match "$^{\\1}$")
1675                (replace-match "")
1676                (let ((end (save-excursion
1677                             (if (re-search-forward "^$\\|^#.*$\\|\\[[0-9]+\\]" nil t)
1678                                 (match-beginning 0) (point-max)))))
1679                  (setq footnote (concat (org-trim (buffer-substring (point) end))
1680                                         " ")) ; prevent last } being part of a link
1681                  (delete-region (point) end))
1682                (goto-char foot-beg)
1683                (delete-region foot-beg foot-end)
1684                (unless (null footnote)
1685                  (setq footnote-rpl (format "\\footnote{%s}" footnote))
1686                  (add-text-properties 0 10 '(org-protected t) footnote-rpl)
1687                  (add-text-properties (1- (length footnote-rpl))
1688                                       (length footnote-rpl)
1689                                       '(org-protected t) footnote-rpl)
1690                  (insert footnote-rpl)))
1691              )))))
1692
1693     ;; Remove footnote section tag for LaTeX
1694     (goto-char (point-min))
1695     (while (re-search-forward
1696             (concat "^" footnote-section-tag-regexp) nil t)
1697       (org-if-unprotected
1698        (replace-match "")))))
1699
1700 ;;; List handling:
1701
1702 (defun org-export-latex-lists ()
1703   "Convert plain text lists in current buffer into LaTeX lists."
1704   (goto-char (point-min))
1705   (while (re-search-forward org-list-beginning-re nil t)
1706     (org-if-unprotected
1707      (beginning-of-line)
1708      (insert (org-list-to-latex (org-list-parse-list t)
1709                                 org-export-latex-list-parameters))
1710      "\n")))
1711
1712 (defconst org-latex-entities
1713  '("\\!"
1714    "\\'"
1715    "\\+"
1716    "\\,"
1717    "\\-"
1718    "\\:"
1719    "\\;"
1720    "\\<"
1721    "\\="
1722    "\\>"
1723    "\\Huge"
1724    "\\LARGE"
1725    "\\Large"
1726    "\\Styles"
1727    "\\\\"
1728    "\\`"
1729    "\\addcontentsline"
1730    "\\address"
1731    "\\addtocontents"
1732    "\\addtocounter"
1733    "\\addtolength"
1734    "\\addvspace"
1735    "\\alph"
1736    "\\appendix"
1737    "\\arabic"
1738    "\\author"
1739    "\\begin{array}"
1740    "\\begin{center}"
1741    "\\begin{description}"
1742    "\\begin{enumerate}"
1743    "\\begin{eqnarray}"
1744    "\\begin{equation}"
1745    "\\begin{figure}"
1746    "\\begin{flushleft}"
1747    "\\begin{flushright}"
1748    "\\begin{itemize}"
1749    "\\begin{list}"
1750    "\\begin{minipage}"
1751    "\\begin{picture}"
1752    "\\begin{quotation}"
1753    "\\begin{quote}"
1754    "\\begin{tabbing}"
1755    "\\begin{table}"
1756    "\\begin{tabular}"
1757    "\\begin{thebibliography}"
1758    "\\begin{theorem}"
1759    "\\begin{titlepage}"
1760    "\\begin{verbatim}"
1761    "\\begin{verse}"
1762    "\\bf"
1763    "\\bf"
1764    "\\bibitem"
1765    "\\bigskip"
1766    "\\cdots"
1767    "\\centering"
1768    "\\circle"
1769    "\\cite"
1770    "\\cleardoublepage"
1771    "\\clearpage"
1772    "\\cline"
1773    "\\closing"
1774    "\\dashbox"
1775    "\\date"
1776    "\\ddots"
1777    "\\dotfill"
1778    "\\em"
1779    "\\fbox"
1780    "\\flushbottom"
1781    "\\fnsymbol"
1782    "\\footnote"
1783    "\\footnotemark"
1784    "\\footnotesize"
1785    "\\footnotetext"
1786    "\\frac"
1787    "\\frame"
1788    "\\framebox"
1789    "\\hfill"
1790    "\\hline"
1791    "\\hrulespace"
1792    "\\hspace"
1793    "\\huge"
1794    "\\hyphenation"
1795    "\\include"
1796    "\\includeonly"
1797    "\\indent"
1798    "\\input"
1799    "\\it"
1800    "\\kill"
1801    "\\label"
1802    "\\large"
1803    "\\ldots"
1804    "\\line"
1805    "\\linebreak"
1806    "\\linethickness"
1807    "\\listoffigures"
1808    "\\listoftables"
1809    "\\location"
1810    "\\makebox"
1811    "\\maketitle"
1812    "\\mark"
1813    "\\mbox"
1814    "\\medskip"
1815    "\\multicolumn"
1816    "\\multiput"
1817    ("\\nbsp" "~")
1818    "\\newcommand"
1819    "\\newcounter"
1820    "\\newenvironment"
1821    "\\newfont"
1822    "\\newlength"
1823    "\\newline"
1824    "\\newpage"
1825    "\\newsavebox"
1826    "\\newtheorem"
1827    "\\nocite"
1828    "\\nofiles"
1829    "\\noindent"
1830    "\\nolinebreak"
1831    "\\nopagebreak"
1832    "\\normalsize"
1833    "\\onecolumn"
1834    "\\opening"
1835    "\\oval"
1836    "\\overbrace"
1837    "\\overline"
1838    "\\pagebreak"
1839    "\\pagenumbering"
1840    "\\pageref"
1841    "\\pagestyle"
1842    "\\par"
1843    "\\parbox"
1844    "\\put"
1845    "\\raggedbottom"
1846    "\\raggedleft"
1847    "\\raggedright"
1848    "\\raisebox"
1849    "\\ref"
1850    "\\rm"
1851    "\\roman"
1852    "\\rule"
1853    "\\savebox"
1854    "\\sc"
1855    "\\scriptsize"
1856    "\\setcounter"
1857    "\\setlength"
1858    "\\settowidth"
1859    "\\sf"
1860    "\\shortstack"
1861    "\\signature"
1862    "\\sl"
1863    "\\small"
1864    "\\smallskip"
1865    "\\sqrt"
1866    "\\tableofcontents"
1867    "\\telephone"
1868    "\\thanks"
1869    "\\thispagestyle"
1870    "\\tiny"
1871    "\\title"
1872    "\\tt"
1873    "\\twocolumn"
1874    "\\typein"
1875    "\\typeout"
1876    "\\underbrace"
1877    "\\underline"
1878    "\\usebox"
1879    "\\usecounter"
1880    "\\value"
1881    "\\vdots"
1882    "\\vector"
1883    "\\verb"
1884    "\\vfill"
1885    "\\vline"
1886    "\\vspace")
1887  "A list of LaTeX commands to be protected when performing conversion.")
1888
1889 (defvar org-latex-entities-exceptions nil)
1890
1891 (defconst org-latex-entities-regexp
1892   (let (names rest)
1893     (dolist (x org-latex-entities)
1894       (when (consp x)
1895         (add-to-list 'org-latex-entities-exceptions x)
1896         (setq x (car x)))
1897       (if (string-match "[a-z][A-Z]$" x)
1898           (push x names)
1899         (push x rest)))
1900     (concat "\\(" (regexp-opt (nreverse names)) "\\>\\)"
1901             "\\|\\(" (regexp-opt (nreverse rest)) "\\)")))
1902
1903 (provide 'org-export-latex)
1904 (provide 'org-latex)
1905
1906 ;; arch-tag: 23c2b87d-da04-4c2d-ad2d-1eb6487bc3ad
1907
1908 ;;; org-latex.el ends here