lisp/ob-exp.el

   1 ;;; ob-exp.el --- Exportation of org-babel source blocks
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (require 'ob-core)
  27 (eval-when-compile
  28   (require 'cl))
  29
  30 (defvar org-current-export-file)
  31 (defvar org-babel-lob-one-liner-regexp)
  32 (defvar org-babel-ref-split-regexp)
  33 (defvar org-list-forbidden-blocks)
  34
  35 (declare-function org-babel-lob-get-info "ob-lob" ())
  36 (declare-function org-babel-eval-wipe-error-buffer "ob-eval" ())
  37 (declare-function org-between-regexps-p "org"
  38                   (start-re end-re &optional lim-up lim-down))
  39 (declare-function org-get-indentation "org" (&optional line))
  40 (declare-function org-heading-components "org" ())
  41 (declare-function org-in-block-p "org" (names))
  42 (declare-function org-in-verbatim-emphasis "org" ())
  43 (declare-function org-link-search "org" (s &optional type avoid-pos stealth))
  44 (declare-function org-fill-template "org" (template alist))
  45 (declare-function org-split-string "org" (string &optional separators))
  46 (declare-function org-element-at-point "org-element" (&optional keep-trail))
  47 (declare-function org-element-context "org-element" ())
  48 (declare-function org-element-property "org-element" (property element))
  49 (declare-function org-element-type "org-element" (element))
  50 (declare-function org-escape-code-in-string "org-src" (s))
  51
  52 (defcustom org-export-babel-evaluate t
  53   "Switch controlling code evaluation during export.
  54 When set to nil no code will be evaluated as part of the export
  55 process.  When set to 'inline-only, only inline code blocks will
  56 be executed."
  57   :group 'org-babel
  58   :version "24.1"
  59   :type '(choice (const :tag "Never" nil)
  60                  (const :tag "Only inline code" inline-only)
  61                  (const :tag "Always" t)))
  62 (put 'org-export-babel-evaluate 'safe-local-variable (lambda (x) (eq x nil)))
  63
  64 (defun org-babel-exp-get-export-buffer ()
  65   "Return the current export buffer if possible."
  66   (cond
  67    ((bufferp org-current-export-file) org-current-export-file)
  68    (org-current-export-file (get-file-buffer org-current-export-file))
  69    ('otherwise
  70     (error "Requested export buffer when `org-current-export-file' is nil"))))
  71
  72 (defvar org-link-search-inhibit-query)
  73
  74 (defmacro org-babel-exp-in-export-file (lang &rest body)
  75   (declare (indent 1))
  76   `(let* ((lang-headers (intern (concat "org-babel-default-header-args:" ,lang)))
  77           (heading (nth 4 (ignore-errors (org-heading-components))))
  78           (export-buffer (current-buffer))
  79           (original-buffer (org-babel-exp-get-export-buffer)) results)
  80      (when original-buffer
  81        ;; resolve parameters in the original file so that
  82        ;; headline and file-wide parameters are included, attempt
  83        ;; to go to the same heading in the original file
  84        (set-buffer original-buffer)
  85        (save-restriction
  86          (when heading
  87            (condition-case nil
  88                (let ((org-link-search-inhibit-query t))
  89                  (org-link-search heading))
  90              (error (when heading
  91                       (goto-char (point-min))
  92                       (re-search-forward (regexp-quote heading) nil t)))))
  93          (setq results ,@body))
  94        (set-buffer export-buffer)
  95        results)))
  96 (def-edebug-spec org-babel-exp-in-export-file (form body))
  97
  98 (defun org-babel-exp-src-block (&rest headers)
  99   "Process source block for export.
 100 Depending on the 'export' headers argument, replace the source
 101 code block like this:
 102
 103 both ---- display the code and the results
 104
 105 code ---- the default, display the code inside the block but do
 106           not process
 107
 108 results - just like none only the block is run on export ensuring
 109           that it's results are present in the org-mode buffer
 110
 111 none ---- do not display either code or results upon export
 112
 113 Assume point is at the beginning of block's starting line."
 114   (interactive)
 115   (unless noninteractive (message "org-babel-exp processing..."))
 116   (save-excursion
 117     (let* ((info (org-babel-get-src-block-info 'light))
 118            (lang (nth 0 info))
 119            (raw-params (nth 2 info)) hash)
 120       ;; bail if we couldn't get any info from the block
 121       (when info
 122         ;; if we're actually going to need the parameters
 123         (when (member (cdr (assoc :exports (nth 2 info))) '("both" "results"))
 124           (org-babel-exp-in-export-file lang
 125             (setf (nth 2 info)
 126                   (org-babel-process-params
 127                    (apply #'org-babel-merge-params
 128                           org-babel-default-header-args
 129                           (if (boundp lang-headers) (eval lang-headers) nil)
 130                           (append (org-babel-params-from-properties lang)
 131                                   (list raw-params))))))
 132           (setf hash (org-babel-sha1-hash info)))
 133         (org-babel-exp-do-export info 'block hash)))))
 134
 135 (defcustom org-babel-exp-call-line-template
 136   ""
 137   "Template used to export call lines.
 138 This template may be customized to include the call line name
 139 with any export markup.  The template is filled out using
 140 `org-fill-template', and the following %keys may be used.
 141
 142  line --- call line
 143
 144 An example value would be \"\\n: call: %line\" to export the call line
 145 wrapped in a verbatim environment.
 146
 147 Note: the results are inserted separately after the contents of
 148 this template."
 149   :group 'org-babel
 150   :type 'string)
 151
 152 (defvar org-babel-default-lob-header-args)
 153 (defun org-babel-exp-process-buffer ()
 154   "Execute all Babel blocks in current buffer."
 155   (interactive)
 156   (save-window-excursion
 157     (save-excursion
 158       (let ((case-fold-search t)
 159             (regexp (concat org-babel-inline-src-block-regexp "\\|"
 160                             org-babel-lob-one-liner-regexp "\\|"
 161                             "^[ \t]*#\\+BEGIN_SRC")))
 162         (goto-char (point-min))
 163         (while (re-search-forward regexp nil t)
 164           (let* ((element (save-excursion
 165                             ;; If match is inline, point is at its
 166                             ;; end.  Move backward so
 167                             ;; `org-element-context' can get the
 168                             ;; object, not the following one.
 169                             (backward-char)
 170                             (save-match-data (org-element-context))))
 171                  (type (org-element-type element))
 172                  (begin (copy-marker (org-element-property :begin element)))
 173                  (end (copy-marker
 174                        (save-excursion
 175                          (goto-char (org-element-property :end element))
 176                          (skip-chars-backward " \r\t\n")
 177                          (point)))))
 178             (case type
 179               (inline-src-block
 180                (let* ((info (org-babel-parse-inline-src-block-match))
 181                       (params (nth 2 info)))
 182                  (setf (nth 1 info)
 183                        (if (and (cdr (assoc :noweb params))
 184                                 (string= "yes" (cdr (assoc :noweb params))))
 185                            (org-babel-expand-noweb-references
 186                             info (org-babel-exp-get-export-buffer))
 187                          (nth 1 info)))
 188                  (goto-char begin)
 189                  (let ((replacement (org-babel-exp-do-export info 'inline)))
 190                    (if (equal replacement "")
 191                        ;; Replacement code is empty: remove inline src
 192                        ;; block, including extra white space that
 193                        ;; might have been created when inserting
 194                        ;; results.
 195                        (delete-region begin
 196                                       (progn (goto-char end)
 197                                              (skip-chars-forward " \t")
 198                                              (point)))
 199                      ;; Otherwise: remove inline src block but
 200                      ;; preserve following white spaces.  Then insert
 201                      ;; value.
 202                      (delete-region begin end)
 203                      (insert replacement)))))
 204               ((babel-call inline-babel-call)
 205                (let* ((lob-info (org-babel-lob-get-info))
 206                       (results
 207                        (org-babel-exp-do-export
 208                         (list "emacs-lisp" "results"
 209                               (apply #'org-babel-merge-params
 210                                      org-babel-default-header-args
 211                                      org-babel-default-lob-header-args
 212                                      (append
 213                                       (org-babel-params-from-properties)
 214                                       (list
 215                                        (org-babel-parse-header-arguments
 216                                         (org-no-properties
 217                                          (concat
 218                                           ":var results="
 219                                           (mapconcat 'identity
 220                                                      (butlast lob-info 2)
 221                                                      " ")))))))
 222                               "" (nth 3 lob-info) (nth 2 lob-info))
 223                         'lob))
 224                       (rep (org-fill-template
 225                             org-babel-exp-call-line-template
 226                             `(("line"  . ,(nth 0 lob-info))))))
 227                  ;; If replacement is empty, completely remove the
 228                  ;; object/element, including any extra white space
 229                  ;; that might have been created when including
 230                  ;; results.
 231                  (if (equal rep "")
 232                      (delete-region
 233                       begin
 234                       (progn (goto-char end)
 235                              (if (not (eq type 'babel-call))
 236                                  (progn (skip-chars-forward " \t") (point))
 237                                (skip-chars-forward " \r\t\n")
 238                                (line-beginning-position))))
 239                    ;; Otherwise, preserve following white
 240                    ;; spaces/newlines and then, insert replacement
 241                    ;; string.
 242                    (goto-char begin)
 243                    (delete-region begin end)
 244                    (insert rep))))
 245               (src-block
 246                (let* ((match-start (copy-marker (match-beginning 0)))
 247                       (ind (org-get-indentation))
 248                       (headers
 249                        (cons
 250                         (org-element-property :language element)
 251                         (let ((params (org-element-property :parameters
 252                                                             element)))
 253                           (and params (org-split-string params "[ \t]+"))))))
 254                  ;; Take care of matched block: compute replacement
 255                  ;; string.  In particular, a nil REPLACEMENT means
 256                  ;; the block should be left as-is while an empty
 257                  ;; string should remove the block.
 258                  (let ((replacement (progn (goto-char match-start)
 259                                            (org-babel-exp-src-block headers))))
 260                    (cond ((not replacement) (goto-char end))
 261                          ((equal replacement "")
 262                           (goto-char end)
 263                           (skip-chars-forward " \r\t\n")
 264                           (beginning-of-line)
 265                           (delete-region begin (point)))
 266                          (t
 267                           (goto-char match-start)
 268                           (delete-region (point)
 269                                          (save-excursion (goto-char end)
 270                                                          (line-end-position)))
 271                           (insert replacement)
 272                           (if (org-element-property :preserve-indent element)
 273                               ;; Indent only the code block markers.
 274                               (save-excursion (skip-chars-backward " \r\t\n")
 275                                               (indent-line-to ind)
 276                                               (goto-char match-start)
 277                                               (indent-line-to ind))
 278                             ;; Indent everything.
 279                             (indent-rigidly match-start (point) ind)))))
 280                  (set-marker match-start nil))))
 281             (set-marker begin nil)
 282             (set-marker end nil)))))))
 283
 284 (defun org-babel-in-example-or-verbatim ()
 285   "Return true if point is in example or verbatim code.
 286 Example and verbatim code include escaped portions of
 287 an org-mode buffer code that should be treated as normal
 288 org-mode text."
 289   (or (save-match-data
 290         (save-excursion
 291           (goto-char (point-at-bol))
 292           (looking-at "[ \t]*:[ \t]")))
 293       (org-in-verbatim-emphasis)
 294       (org-in-block-p org-list-forbidden-blocks)
 295       (org-between-regexps-p "^[ \t]*#\\+begin_src" "^[ \t]*#\\+end_src")))
 296
 297 (defun org-babel-exp-do-export (info type &optional hash)
 298   "Return a string with the exported content of a code block.
 299 The function respects the value of the :exports header argument."
 300   (let ((silently (lambda () (let ((session (cdr (assoc :session (nth 2 info)))))
 301                                (when (not (and session (equal "none" session)))
 302                                  (org-babel-exp-results info type 'silent)))))
 303         (clean (lambda () (unless (eq type 'inline) (org-babel-remove-result info)))))
 304     (case (intern (or (cdr (assoc :exports (nth 2 info))) "code"))
 305       ('none (funcall silently) (funcall clean) "")
 306       ('code (funcall silently) (funcall clean) (org-babel-exp-code info))
 307       ('results (org-babel-exp-results info type nil hash) "")
 308       ('both (org-babel-exp-results info type nil hash)
 309              (org-babel-exp-code info)))))
 310
 311 (defcustom org-babel-exp-code-template
 312   "#+BEGIN_SRC %lang%flags\n%body\n#+END_SRC"
 313   "Template used to export the body of code blocks.
 314 This template may be customized to include additional information
 315 such as the code block name, or the values of particular header
 316 arguments.  The template is filled out using `org-fill-template',
 317 and the following %keys may be used.
 318
 319  lang ------ the language of the code block
 320  name ------ the name of the code block
 321  body ------ the body of the code block
 322  flags ----- the flags passed to the code block
 323
 324 In addition to the keys mentioned above, every header argument
 325 defined for the code block may be used as a key and will be
 326 replaced with its value."
 327   :group 'org-babel
 328   :type 'string)
 329
 330 (defun org-babel-exp-code (info)
 331   "Return the original code block formatted for export."
 332   (setf (nth 1 info)
 333         (if (string= "strip-export" (cdr (assoc :noweb (nth 2 info))))
 334             (replace-regexp-in-string
 335              (org-babel-noweb-wrap) "" (nth 1 info))
 336           (if (org-babel-noweb-p (nth 2 info) :export)
 337               (org-babel-expand-noweb-references
 338                info (org-babel-exp-get-export-buffer))
 339             (nth 1 info))))
 340   (org-fill-template
 341    org-babel-exp-code-template
 342    `(("lang"  . ,(nth 0 info))
 343      ("body"  . ,(org-escape-code-in-string (nth 1 info)))
 344      ("flags" . ,(let ((f (assq :flags (nth 2 info))))
 345                    (when f (concat " " (cdr f)))))
 346      ,@(mapcar (lambda (pair)
 347                  (cons (substring (symbol-name (car pair)) 1)
 348                        (format "%S" (cdr pair))))
 349                (nth 2 info))
 350      ("name"  . ,(or (nth 4 info) "")))))
 351
 352 (defun org-babel-exp-results (info type &optional silent hash)
 353   "Evaluate and return the results of the current code block for export.
 354 Results are prepared in a manner suitable for export by org-mode.
 355 This function is called by `org-babel-exp-do-export'.  The code
 356 block will be evaluated.  Optional argument SILENT can be used to
 357 inhibit insertion of results into the buffer."
 358   (when (and (or (eq org-export-babel-evaluate t)
 359                  (and (eq type 'inline)
 360                       (eq org-export-babel-evaluate 'inline-only)))
 361              (not (and hash (equal hash (org-babel-current-result-hash)))))
 362     (let ((lang (nth 0 info))
 363           (body (if (org-babel-noweb-p (nth 2 info) :eval)
 364                     (org-babel-expand-noweb-references
 365                      info (org-babel-exp-get-export-buffer))
 366                   (nth 1 info)))
 367           (info (copy-sequence info))
 368           (org-babel-current-src-block-location (point-marker)))
 369       ;; skip code blocks which we can't evaluate
 370       (when (fboundp (intern (concat "org-babel-execute:" lang)))
 371         (org-babel-eval-wipe-error-buffer)
 372         (prog1 nil
 373           (setf (nth 1 info) body)
 374           (setf (nth 2 info)
 375                 (org-babel-exp-in-export-file lang
 376                   (org-babel-process-params
 377                    (org-babel-merge-params
 378                     (nth 2 info)
 379                     `((:results . ,(if silent "silent" "replace")))))))
 380           (cond
 381            ((equal type 'block)
 382             (org-babel-execute-src-block nil info))
 383            ((equal type 'inline)
 384             ;; position the point on the inline source block allowing
 385             ;; `org-babel-insert-result' to check that the block is
 386             ;; inline
 387             (re-search-backward "[ \f\t\n\r\v]" nil t)
 388             (re-search-forward org-babel-inline-src-block-regexp nil t)
 389             (re-search-backward "src_" nil t)
 390             (org-babel-execute-src-block nil info))
 391            ((equal type 'lob)
 392             (save-excursion
 393               (re-search-backward org-babel-lob-one-liner-regexp nil t)
 394               (let (org-confirm-babel-evaluate)
 395                 (org-babel-execute-src-block nil info))))))))))
 396
 397
 398 (provide 'ob-exp)
 399
 400 ;;; ob-exp.el ends here