lisp/org-wl.el

   1 ;;; org-wl.el --- Support for links to Wanderlust messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
   7 ;;         David Maus <dmaus at ictsoc dot de>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 7.01
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to Wanderlust messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37
  38 (defgroup org-wl nil
  39  "Options concerning the Wanderlust link."
  40  :tag "Org Startup"
  41  :group 'org-link)
  42
  43 (defcustom org-wl-link-to-refile-destination t
  44   "Create a link to the refile destination if the message is marked as refile."
  45   :group 'org-wl
  46   :type 'boolean)
  47
  48 (defcustom org-wl-link-remove-filter nil
  49   "Remove filter condition if message is filter folder."
  50   :group 'org-wl
  51   :type 'boolean)
  52
  53 (defcustom org-wl-shimbun-prefer-web-links nil
  54   "If non-nil create web links for shimbun messages."
  55   :group 'org-wl
  56   :type 'boolean)
  57
  58 (defcustom org-wl-nntp-prefer-web-links nil
  59   "If non-nil create web links for nntp messages.
  60 When folder name contains string \"gmane\" link to gmane,
  61 googlegroups otherwise."
  62   :type 'boolean
  63   :group 'org-wl)
  64
  65 (defcustom org-wl-disable-folder-check t
  66   "Disable check for new messages when open a link."
  67   :type 'boolean
  68   :group 'org-wl)
  69
  70 (defcustom org-wl-namazu-default-index nil
  71   "Default namazu search index."
  72   :type 'directory
  73   :group 'org-wl)
  74
  75 ;; Declare external functions and variables
  76 (declare-function elmo-folder-exists-p "ext:elmo" (folder) t)
  77 (declare-function elmo-message-entity-field "ext:elmo-msgdb"
  78                   (entity field &optional type))
  79 (declare-function elmo-message-field "ext:elmo"
  80                   (folder number field &optional type) t)
  81 (declare-function elmo-msgdb-overview-get-entity "ext:elmo" (id msgdb) t)
  82 ;; Backward compatibility to old version of wl
  83 (declare-function wl "ext:wl" () t)
  84 (declare-function wl-summary-buffer-msgdb "ext:wl-folder" () t)
  85 (declare-function wl-summary-jump-to-msg-by-message-id "ext:wl-summary"
  86                   (&optional id))
  87 (declare-function wl-summary-line-from "ext:wl-summary" ())
  88 (declare-function wl-summary-line-subject "ext:wl-summary" ())
  89 (declare-function wl-summary-message-number "ext:wl-summary" ())
  90 (declare-function wl-summary-redisplay "ext:wl-summary" (&optional arg))
  91 (declare-function wl-summary-registered-temp-mark "ext:wl-action" (number))
  92 (declare-function wl-folder-goto-folder-subr "ext:wl-folder"
  93                   (&optional folder sticky))
  94 (declare-function wl-folder-get-petname "ext:wl-folder" (name))
  95 (declare-function wl-folder-get-entity-from-buffer "ext:wl-folder"
  96                   (&optional getid))
  97 (declare-function wl-folder-buffer-group-p "ext:wl-folder")
  98 (defvar wl-init)
  99 (defvar wl-summary-buffer-elmo-folder)
 100 (defvar wl-summary-buffer-folder-name)
 101 (defvar wl-folder-group-regexp)
 102 (defvar wl-auto-check-folder-name)
 103
 104 (defconst org-wl-folder-types
 105   '(("%" . imap) ("-" . nntp) ("+" . mh) ("=" . spool)
 106     ("$" . archive) ("&" . pop) ("@" . shimbun) ("[" . search)
 107     ("*" . multi) ("/" . filter) ("|" . pipe) ("'" . internal))
 108   "List of folder indicators.  See Wanderlust manual, section 3.")
 109
 110 ;; Install the link type
 111 (org-add-link-type "wl" 'org-wl-open)
 112 (add-hook 'org-store-link-functions 'org-wl-store-link)
 113
 114 ;; Implementation
 115
 116 (defun org-wl-folder-type (folder)
 117   "Return symbol that indicates the type of FOLDER.
 118 FOLDER is the wanderlust folder name.  The first character of the
 119 folder name determines the the folder type."
 120   (let* ((indicator (substring folder 0 1))
 121          (type (cdr (assoc indicator org-wl-folder-types))))
 122     ;; maybe access or file folder
 123     (when (not type)
 124       (setq type
 125             (cond
 126              ((and (>= (length folder) 5)
 127                    (string= (substring folder 0 5) "file:"))
 128               'file)
 129              ((and (>= (length folder) 7)
 130                    (string= (substring folder 0 7) "access:"))
 131               'access)
 132              (t
 133               nil))))
 134     type))
 135
 136 (defun org-wl-message-field (field entity)
 137   "Return content of FIELD in ENTITY.
 138 FIELD is a symbol of a rfc822 message header field.
 139 ENTITY is a message entity."
 140   (let ((content (elmo-message-entity-field entity field)))
 141     (if (listp content) (car content) content)))
 142
 143 (defun org-wl-store-link ()
 144   "Store a link to a WL message or folder."
 145   (cond
 146    ((memq major-mode '(wl-summary-mode mime-view-mode))
 147     (org-wl-store-link-message))
 148    ((eq major-mode 'wl-folder-mode)
 149     (org-wl-store-link-folder))
 150    (t
 151     nil)))
 152
 153 (defun org-wl-store-link-folder ()
 154   "Store a link to a WL folder."
 155   (let* ((folder (wl-folder-get-entity-from-buffer))
 156          (petname (wl-folder-get-petname folder))
 157          (link (org-make-link "wl:" folder)))
 158     (save-excursion
 159       (beginning-of-line)
 160       (unless (and (wl-folder-buffer-group-p)
 161                    (looking-at wl-folder-group-regexp))
 162         (org-store-link-props :type "wl" :description petname
 163                               :link link)
 164         link))))
 165
 166 (defun org-wl-store-link-message ()
 167   "Store a link to a WL message."
 168   (save-excursion
 169     (let ((buf (if (eq major-mode 'wl-summary-mode)
 170                    (current-buffer)
 171                  (and (boundp 'wl-message-buffer-cur-summary-buffer)
 172                       wl-message-buffer-cur-summary-buffer))))
 173       (when buf
 174         (with-current-buffer buf
 175           (let* ((msgnum (wl-summary-message-number))
 176                  (mark-info (wl-summary-registered-temp-mark msgnum))
 177                  (folder-name
 178                   (if (and org-wl-link-to-refile-destination
 179                            mark-info
 180                            (equal (nth 1 mark-info) "o")) ; marked as refile
 181                       (nth 2 mark-info)
 182                     wl-summary-buffer-folder-name))
 183                  (folder-type (org-wl-folder-type folder-name))
 184                  (wl-message-entity
 185                   (if (fboundp 'elmo-message-entity)
 186                       (elmo-message-entity
 187                        wl-summary-buffer-elmo-folder msgnum)
 188                     (elmo-msgdb-overview-get-entity
 189                      msgnum (wl-summary-buffer-msgdb))))
 190                  (message-id
 191                   (org-wl-message-field 'message-id wl-message-entity))
 192                  (from (org-wl-message-field 'from wl-message-entity))
 193                  (to (org-wl-message-field 'to wl-message-entity))
 194                  (xref (org-wl-message-field 'xref wl-message-entity))
 195                  (subject (org-wl-message-field 'subject wl-message-entity))
 196                  desc link)
 197
 198             ;; remove text properties of subject string to avoid possible bug
 199             ;; when formatting the subject
 200             ;; (Emacs bug #5306, fixed)
 201             (set-text-properties 0 (length subject) nil subject)
 202
 203             ;; maybe remove filter condition
 204             (when (and (eq folder-type 'filter) org-wl-link-remove-filter)
 205               (while (eq (org-wl-folder-type folder-name) 'filter)
 206                 (setq folder-name
 207                       (replace-regexp-in-string "^/[^/]+/" "" folder-name))))
 208
 209             ;; maybe create http link
 210             (cond
 211              ((and (eq folder-type 'shimbun)
 212                    org-wl-shimbun-prefer-web-links xref)
 213               (org-store-link-props :type "http" :link xref :description subject
 214                                     :from from :to to :message-id message-id
 215                                     :subject subject))
 216              ((and (eq folder-type 'nntp) org-wl-nntp-prefer-web-links)
 217               (setq link
 218                     (format
 219                      (if (string-match "gmane\\." folder-name)
 220                          "http://mid.gmane.org/%s"
 221                        "http://groups.google.com/groups/search?as_umsgid=%s")
 222                      (org-fixup-message-id-for-http message-id)))
 223               (org-store-link-props :type "http" :link link :description subject
 224                                     :from from :to to :message-id message-id
 225                                     :subject subject))
 226              (t
 227               (org-store-link-props :type "wl" :from from :to to
 228                                     :subject subject :message-id message-id)
 229               (setq message-id (org-remove-angle-brackets message-id))
 230               (setq desc (org-email-link-description))
 231               (setq link (org-make-link "wl:" folder-name "#" message-id))
 232               (org-add-link-props :link link :description desc)))
 233             (or link xref)))))))
 234
 235 (defun org-wl-open (path)
 236   "Follow the WL message link specified by PATH.
 237 When called with one prefix, open message in namazu search folder
 238 with `org-wl-namazu-default-index' as search index.  When called
 239 with two prefixes or `org-wl-namazu-default-index' is nil, ask
 240 for namazu index."
 241   (require 'wl)
 242   (let ((wl-auto-check-folder-name
 243          (if org-wl-disable-folder-check
 244              'none
 245            wl-auto-check-folder-name)))
 246     (unless wl-init (wl))
 247     ;; XXX: The imap-uw's MH folder names start with "%#".
 248     (if (not (string-match "\\`\\(\\(?:%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path))
 249         (error "Error in Wanderlust link"))
 250     (let ((folder (match-string 1 path))
 251           (article (match-string 3 path)))
 252       ;; maybe open message in namazu search folder
 253       (when current-prefix-arg
 254         (setq folder (concat "[" article "]"
 255                              (if (and (equal current-prefix-arg '(4))
 256                                       org-wl-namazu-default-index)
 257                                  org-wl-namazu-default-index
 258                                (read-directory-name "Namazu index: ")))))
 259       (if (not (elmo-folder-exists-p (org-no-warnings
 260                                       (wl-folder-get-elmo-folder folder))))
 261           (error "No such folder: %s" folder))
 262       (let ((old-buf (current-buffer))
 263             (old-point (point-marker)))
 264         (wl-folder-goto-folder-subr folder)
 265         (with-current-buffer old-buf
 266           ;; XXX: `wl-folder-goto-folder-subr' moves point to the
 267           ;; beginning of the current line.  So, restore the point
 268           ;; in the old buffer.
 269           (goto-char old-point))
 270         (and article (wl-summary-jump-to-msg-by-message-id (org-add-angle-brackets
 271                                                             article))
 272              (wl-summary-redisplay))))))
 273
 274 (provide 'org-wl)
 275
 276 ;; arch-tag: 29b75a0f-ef2e-430b-8abc-acff75bde54a
 277
 278 ;;; org-wl.el ends here