lisp/ox-org.el

   1 ;;; ox-org.el --- Org Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'ox)
  28 (declare-function htmlize-buffer "htmlize" (&optional buffer))
  29
  30 (defgroup org-export-org nil
  31   "Options for exporting Org mode files to Org."
  32   :tag "Org Export Org"
  33   :group 'org-export
  34   :version "24.4"
  35   :package-version '(Org . "8.0"))
  36
  37 (define-obsolete-variable-alias
  38   'org-export-htmlized-org-css-url 'org-org-htmlized-css-url "24.4")
  39 (defcustom org-org-htmlized-css-url nil
  40   "URL pointing to the CSS defining colors for htmlized Emacs buffers.
  41 Normally when creating an htmlized version of an Org buffer,
  42 htmlize will create the CSS to define the font colors.  However,
  43 this does not work when converting in batch mode, and it also can
  44 look bad if different people with different fontification setup
  45 work on the same website.  When this variable is non-nil,
  46 creating an htmlized version of an Org buffer using
  47 `org-org-export-as-org' will include a link to this URL if the
  48 setting of `org-html-htmlize-output-type' is 'css."
  49   :group 'org-export-org
  50   :type '(choice
  51           (const :tag "Don't include external stylesheet link" nil)
  52           (string :tag "URL or local href")))
  53
  54 (org-export-define-backend 'org
  55   '((babel-call . org-org-identity)
  56     (bold . org-org-identity)
  57     (center-block . org-org-identity)
  58     (clock . org-org-identity)
  59     (code . org-org-identity)
  60     (comment . (lambda (&rest args) ""))
  61     (comment-block . (lambda (&rest args) ""))
  62     (diary-sexp . org-org-identity)
  63     (drawer . org-org-identity)
  64     (dynamic-block . org-org-identity)
  65     (entity . org-org-identity)
  66     (example-block . org-org-identity)
  67     (fixed-width . org-org-identity)
  68     (footnote-definition . ignore)
  69     (footnote-reference . org-org-identity)
  70     (headline . org-org-headline)
  71     (horizontal-rule . org-org-identity)
  72     (inline-babel-call . org-org-identity)
  73     (inline-src-block . org-org-identity)
  74     (inlinetask . org-org-identity)
  75     (italic . org-org-identity)
  76     (item . org-org-identity)
  77     (keyword . org-org-keyword)
  78     (latex-environment . org-org-identity)
  79     (latex-fragment . org-org-identity)
  80     (line-break . org-org-identity)
  81     (link . org-org-identity)
  82     (node-property . org-org-identity)
  83     (paragraph . org-org-identity)
  84     (plain-list . org-org-identity)
  85     (planning . org-org-identity)
  86     (property-drawer . org-org-identity)
  87     (quote-block . org-org-identity)
  88     (quote-section . org-org-identity)
  89     (radio-target . org-org-identity)
  90     (section . org-org-section)
  91     (special-block . org-org-identity)
  92     (src-block . org-org-identity)
  93     (statistics-cookie . org-org-identity)
  94     (strike-through . org-org-identity)
  95     (subscript . org-org-identity)
  96     (superscript . org-org-identity)
  97     (table . org-org-identity)
  98     (table-cell . org-org-identity)
  99     (table-row . org-org-identity)
 100     (target . org-org-identity)
 101     (timestamp . org-org-identity)
 102     (underline . org-org-identity)
 103     (verbatim . org-org-identity)
 104     (verse-block . org-org-identity))
 105   :menu-entry
 106   '(?O "Export to Org"
 107        ((?O "As Org buffer" org-org-export-as-org)
 108         (?o "As Org file" org-org-export-to-org)
 109         (?v "As Org file and open"
 110             (lambda (a s v b)
 111               (if a (org-org-export-to-org t s v b)
 112                 (org-open-file (org-org-export-to-org nil s v b))))))))
 113
 114 (defun org-org-identity (blob contents info)
 115   "Transcode BLOB element or object back into Org syntax.
 116 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 117   (let ((case-fold-search t))
 118     (replace-regexp-in-string
 119      "^[ \t]*#\\+ATTR_[-_A-Za-z0-9]+:\\(?: .*\\)?\n" ""
 120      (org-export-expand blob contents t))))
 121
 122 (defun org-org-headline (headline contents info)
 123   "Transcode HEADLINE element back into Org syntax.
 124 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 125   (unless (org-element-property :footnote-section-p headline)
 126     (unless (plist-get info :with-todo-keywords)
 127       (org-element-put-property headline :todo-keyword nil))
 128     (unless (plist-get info :with-tags)
 129       (org-element-put-property headline :tags nil))
 130     (unless (plist-get info :with-priority)
 131       (org-element-put-property headline :priority nil))
 132     (org-element-put-property headline :level
 133                               (org-export-get-relative-level headline info))
 134     (org-element-headline-interpreter headline contents)))
 135
 136 (defun org-org-keyword (keyword contents info)
 137   "Transcode KEYWORD element back into Org syntax.
 138 CONTENTS is nil.  INFO is ignored.  This function ignores
 139 keywords targeted at other export back-ends."
 140   (unless (member (org-element-property :key keyword)
 141                   (mapcar
 142                    (lambda (block-cons)
 143                      (and (eq (cdr block-cons) 'org-element-export-block-parser)
 144                           (car block-cons)))
 145                    org-element-block-name-alist))
 146     (org-element-keyword-interpreter keyword nil)))
 147
 148 (defun org-org-section (section contents info)
 149   "Transcode SECTION element back into Org syntax.
 150 CONTENTS is the contents of the section.  INFO is a plist used as
 151 a communication channel."
 152   (concat
 153    (org-element-normalize-string contents)
 154    ;; Insert footnote definitions appearing for the first time in this
 155    ;; section.  Indeed, some of them may not be available to narrowing
 156    ;; so we make sure all of them are included in the result.
 157    (let ((footnotes-alist
 158           (org-element-map section 'footnote-reference
 159             (lambda (fn)
 160               (and (eq (org-element-property :type fn) 'standard)
 161                    (org-export-footnote-first-reference-p fn info)
 162                    (cons (org-element-property :label fn)
 163                          (org-export-get-footnote-definition fn info))))
 164             info)))
 165      (and footnotes-alist
 166           (concat "\n"
 167                   (mapconcat
 168                    (lambda (d)
 169                      (org-element-normalize-string
 170                       (concat (format "[%s] "(car d))
 171                               (org-export-data (cdr d) info))))
 172                    footnotes-alist "\n"))))
 173    (make-string (or (org-element-property :post-blank section) 0) ?\n)))
 174
 175 ;;;###autoload
 176 (defun org-org-export-as-org (&optional async subtreep visible-only ext-plist)
 177   "Export current buffer to an Org buffer.
 178
 179 If narrowing is active in the current buffer, only export its
 180 narrowed part.
 181
 182 If a region is active, export that region.
 183
 184 A non-nil optional argument ASYNC means the process should happen
 185 asynchronously.  The resulting buffer should be accessible
 186 through the `org-export-stack' interface.
 187
 188 When optional argument SUBTREEP is non-nil, export the sub-tree
 189 at point, extracting information from the headline properties
 190 first.
 191
 192 When optional argument VISIBLE-ONLY is non-nil, don't export
 193 contents of hidden elements.
 194
 195 EXT-PLIST, when provided, is a property list with external
 196 parameters overriding Org default settings, but still inferior to
 197 file-local settings.
 198
 199 Export is done in a buffer named \"*Org ORG Export*\", which will
 200 be displayed when `org-export-show-temporary-export-buffer' is
 201 non-nil."
 202   (interactive)
 203   (org-export-to-buffer 'org "*Org ORG Export*"
 204     async subtreep visible-only nil ext-plist (lambda () (org-mode))))
 205
 206 ;;;###autoload
 207 (defun org-org-export-to-org (&optional async subtreep visible-only ext-plist)
 208   "Export current buffer to an org file.
 209
 210 If narrowing is active in the current buffer, only export its
 211 narrowed part.
 212
 213 If a region is active, export that region.
 214
 215 A non-nil optional argument ASYNC means the process should happen
 216 asynchronously.  The resulting file should be accessible through
 217 the `org-export-stack' interface.
 218
 219 When optional argument SUBTREEP is non-nil, export the sub-tree
 220 at point, extracting information from the headline properties
 221 first.
 222
 223 When optional argument VISIBLE-ONLY is non-nil, don't export
 224 contents of hidden elements.
 225
 226 EXT-PLIST, when provided, is a property list with external
 227 parameters overriding Org default settings, but still inferior to
 228 file-local settings.
 229
 230 Return output file name."
 231   (interactive)
 232   (let ((outfile (org-export-output-file-name ".org" subtreep)))
 233     (org-export-to-file 'org outfile
 234       async subtreep visible-only nil ext-plist)))
 235
 236 ;;;###autoload
 237 (defun org-org-publish-to-org (plist filename pub-dir)
 238   "Publish an org file to org.
 239
 240 FILENAME is the filename of the Org file to be published.  PLIST
 241 is the property list for the given project.  PUB-DIR is the
 242 publishing directory.
 243
 244 Return output file name."
 245   (org-publish-org-to 'org filename ".org" plist pub-dir)
 246   (when (plist-get plist :htmlized-source)
 247     (require 'htmlize)
 248     (require 'ox-html)
 249     (let* ((org-inhibit-startup t)
 250            (htmlize-output-type 'css)
 251            (html-ext (concat "." (or (plist-get plist :html-extension)
 252                                      org-html-extension "html")))
 253            (visitingp (find-buffer-visiting filename))
 254            (work-buffer (or visitingp (find-file-noselect filename)))
 255            newbuf)
 256       (with-current-buffer work-buffer
 257         (org-font-lock-ensure)
 258         (show-all)
 259         (org-show-block-all)
 260         (setq newbuf (htmlize-buffer)))
 261       (with-current-buffer newbuf
 262         (when org-org-htmlized-css-url
 263           (goto-char (point-min))
 264           (and (re-search-forward
 265                 "<style type=\"text/css\">[^\000]*?\n[ \t]*</style>.*" nil t)
 266                (replace-match
 267                 (format
 268                  "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">"
 269                  org-org-htmlized-css-url)
 270                 t t)))
 271         (write-file (concat pub-dir (file-name-nondirectory filename) html-ext)))
 272       (kill-buffer newbuf)
 273       (unless visitingp (kill-buffer work-buffer)))
 274     ;; FIXME: Why?  Which buffer is this supposed to apply to?
 275     (set-buffer-modified-p nil)))
 276
 277
 278 (provide 'ox-org)
 279
 280 ;; Local variables:
 281 ;; generated-autoload-file: "org-loaddefs.el"
 282 ;; End:
 283
 284 ;;; ox-org.el ends here