lisp/ob-ref.el

   1 ;;; ob-ref.el --- Babel Functions for Referencing External Data -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for referencing data from the header arguments of a
  28 ;; org-babel block.  The syntax of such a reference should be
  29
  30 ;;   #+VAR: variable-name=file:resource-id
  31
  32 ;; - variable-name :: the name of the variable to which the value
  33 ;;                    will be assigned
  34
  35 ;; - file :: path to the file containing the resource, or omitted if
  36 ;;           resource is in the current file
  37
  38 ;; - resource-id :: the id or name of the resource
  39
  40 ;; So an example of a simple src block referencing table data in the
  41 ;; same file would be
  42
  43 ;;  #+NAME: sandbox
  44 ;;  | 1 |         2 | 3 |
  45 ;;  | 4 | org-babel | 6 |
  46 ;;
  47 ;;  #+begin_src emacs-lisp :var table=sandbox
  48 ;;    (message table)
  49 ;;  #+end_src
  50
  51 ;;; Code:
  52 (require 'ob-core)
  53 (require 'cl-lib)
  54
  55 (declare-function org-babel-lob-get-info "ob-lob" (&optional datum))
  56 (declare-function org-element-at-point "org-element" ())
  57 (declare-function org-element-property "org-element" (property element))
  58 (declare-function org-element-type "org-element" (element))
  59 (declare-function org-end-of-meta-data "org" (&optional full))
  60 (declare-function org-find-property "org" (property &optional value))
  61 (declare-function org-id-find-id-file "org-id" (id))
  62 (declare-function org-id-find-id-in-file "org-id" (id file &optional markerp))
  63 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  64 (declare-function org-narrow-to-subtree "org" ())
  65 (declare-function org-pop-to-buffer-same-window "org-compat"
  66                   (&optional buffer-or-name norecord label))
  67 (declare-function org-show-context "org" (&optional key))
  68
  69
  70 (defvar org-babel-ref-split-regexp
  71   "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  72
  73 (defvar org-babel-update-intermediate nil
  74   "Update the in-buffer results of code blocks executed to resolve references.")
  75
  76 (defun org-babel-ref-parse (assignment)
  77   "Parse a variable ASSIGNMENT in a header argument.
  78 If the right hand side of the assignment has a literal value
  79 return that value, otherwise interpret as a reference to an
  80 external resource and find its value using
  81 `org-babel-ref-resolve'.  Return a list with two elements.  The
  82 first element of the list will be the name of the variable, and
  83 the second will be an emacs-lisp representation of the value of
  84 the variable."
  85   (when (string-match org-babel-ref-split-regexp assignment)
  86     (let ((var (match-string 1 assignment))
  87           (ref (match-string 2 assignment)))
  88       (cons (intern var)
  89             (let ((out (save-excursion
  90                          (when org-babel-current-src-block-location
  91                            (goto-char (if (markerp org-babel-current-src-block-location)
  92                                           (marker-position org-babel-current-src-block-location)
  93                                         org-babel-current-src-block-location)))
  94                          (org-babel-read ref))))
  95               (if (equal out ref)
  96                   (if (string-match "^\".*\"$" ref)
  97                       (read ref)
  98                     (org-babel-ref-resolve ref))
  99                 out))))))
 100
 101 (defun org-babel-ref-goto-headline-id (id)
 102   (or (let ((h (org-find-property "CUSTOM_ID" id)))
 103         (when h (goto-char h)))
 104       (let* ((file (org-id-find-id-file id))
 105              (m (when file (org-id-find-id-in-file id file 'marker))))
 106         (when (and file m)
 107           (message "file:%S" file)
 108           (org-pop-to-buffer-same-window (marker-buffer m))
 109           (goto-char m)
 110           (move-marker m nil)
 111           (org-show-context)
 112           t))))
 113
 114 (defun org-babel-ref-headline-body ()
 115   (save-restriction
 116     (org-narrow-to-subtree)
 117     (buffer-substring
 118      (save-excursion (goto-char (point-min))
 119                      (org-end-of-meta-data)
 120                      (point))
 121      (point-max))))
 122
 123 (defvar org-babel-library-of-babel)
 124 (defun org-babel-ref-resolve (ref)
 125   "Resolve the reference REF and return its value."
 126   (save-window-excursion
 127     (with-current-buffer (or org-babel-exp-reference-buffer (current-buffer))
 128       (save-excursion
 129         (let ((case-fold-search t)
 130               args new-refere new-header-args new-referent split-file split-ref
 131               index)
 132           ;; if ref is indexed grab the indices -- beware nested indices
 133           (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
 134                      (let ((str (substring ref 0 (match-beginning 0))))
 135                        (= (cl-count ?( str) (cl-count ?) str))))
 136             (setq index (match-string 1 ref))
 137             (setq ref (substring ref 0 (match-beginning 0))))
 138           ;; assign any arguments to pass to source block
 139           (when (string-match
 140                  "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)(\\(.*\\))$" ref)
 141             (setq new-refere      (match-string 1 ref))
 142             (setq new-header-args (match-string 3 ref))
 143             (setq new-referent    (match-string 5 ref))
 144             (when (> (length new-refere) 0)
 145               (when (> (length new-referent) 0)
 146                 (setq args (mapcar (lambda (ref) (cons :var ref))
 147                                    (org-babel-ref-split-args new-referent))))
 148               (when (> (length new-header-args) 0)
 149                 (setq args (append (org-babel-parse-header-arguments
 150                                     new-header-args) args)))
 151               (setq ref new-refere)))
 152           (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
 153             (setq split-file (match-string 1 ref))
 154             (setq split-ref (match-string 2 ref))
 155             (find-file split-file)
 156             (setq ref split-ref))
 157           (org-with-wide-buffer
 158            (goto-char (point-min))
 159            (let* ((params (append args '((:results . "silent"))))
 160                   (regexp (org-babel-named-data-regexp-for-name ref))
 161                   (result
 162                    (catch :found
 163                      ;; Check for code blocks or named data.
 164                      (while (re-search-forward regexp nil t)
 165                        ;; Ignore COMMENTed headings and orphaned
 166                        ;; affiliated keywords.
 167                        (unless (org-in-commented-heading-p)
 168                          (let ((e (org-element-at-point)))
 169                            (when (equal (org-element-property :name e) ref)
 170                              (goto-char
 171                               (org-element-property :post-affiliated e))
 172                              (pcase (org-element-type e)
 173                                (`babel-call
 174                                 (throw :found
 175                                        (org-babel-execute-src-block
 176                                         nil (org-babel-lob-get-info e) params)))
 177                                (`src-block
 178                                 (throw :found
 179                                        (org-babel-execute-src-block
 180                                         nil nil
 181                                         (and
 182                                          (not org-babel-update-intermediate)
 183                                          params))))
 184                                ((and (let v (org-babel-read-element e))
 185                                      (guard v))
 186                                 (throw :found v))
 187                                (_ (error "Reference not found")))))))
 188                      ;; Check for local or global headlines by ID.
 189                      (when (org-babel-ref-goto-headline-id ref)
 190                        (throw :found (org-babel-ref-headline-body)))
 191                      ;; Check the Library of Babel.
 192                      (let ((info (cdr (assq (intern ref)
 193                                             org-babel-library-of-babel))))
 194                        (when info
 195                          (throw :found
 196                                 (org-babel-execute-src-block nil info params))))
 197                      (error "Reference `%s' not found in this buffer" ref))))
 198              (cond
 199               ((symbolp result) (format "%S" result))
 200               ((and index (listp result))
 201                (org-babel-ref-index-list index result))
 202               (t result)))))))))
 203
 204 (defun org-babel-ref-index-list (index lis)
 205   "Return the subset of LIS indexed by INDEX.
 206
 207 Indices are 0 based and negative indices count from the end of
 208 LIS, so 0 references the first element of LIS and -1 references
 209 the last.  If INDEX is separated by \",\"s then each \"portion\"
 210 is assumed to index into the next deepest nesting or dimension.
 211
 212 A valid \"portion\" can consist of either an integer index, two
 213 integers separated by a \":\" in which case the entire range is
 214 returned, or an empty string or \"*\" both of which are
 215 interpreted to mean the entire range and as such are equivalent
 216 to \"0:-1\"."
 217   (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
 218       (let* ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\\*\\)")
 219              (lgth (length lis))
 220              (portion (match-string 1 index))
 221              (remainder (substring index (match-end 0)))
 222              (wrap (lambda (num) (if (< num 0) (+ lgth num) num)))
 223              (open (lambda (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls))))
 224         (funcall
 225          open
 226          (mapcar
 227           (lambda (sub-lis)
 228             (if (listp sub-lis)
 229                 (org-babel-ref-index-list remainder sub-lis)
 230               sub-lis))
 231           (if (or (= 0 (length portion)) (string-match ind-re portion))
 232               (mapcar
 233                (lambda (n) (nth n lis))
 234                (apply 'org-number-sequence
 235                       (if (and (> (length portion) 0) (match-string 2 portion))
 236                           (list
 237                            (funcall wrap (string-to-number (match-string 2 portion)))
 238                            (funcall wrap (string-to-number (match-string 3 portion))))
 239                         (list (funcall wrap 0) (funcall wrap -1)))))
 240             (list (nth (funcall wrap (string-to-number portion)) lis))))))
 241     lis))
 242
 243 (defun org-babel-ref-split-args (arg-string)
 244   "Split ARG-STRING into top-level arguments of balanced parenthesis."
 245   (mapcar #'org-babel-trim (org-babel-balanced-split arg-string 44)))
 246
 247
 248 (provide 'ob-ref)
 249
 250 ;;; ob-ref.el ends here