lisp/ox-icalendar.el

   1 ;;; ox-icalendar.el --- iCalendar Back-End for Org Export Engine -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;      Nicolas Goaziou <n dot goaziou at gmail dot com>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; This library implements an iCalendar back-end for Org generic
  28 ;; exporter.  See Org manual for more information.
  29 ;;
  30 ;; It is expected to conform to RFC 5545.
  31
  32 ;;; Code:
  33
  34 (require 'cl-lib)
  35 (require 'ox-ascii)
  36 (declare-function org-bbdb-anniv-export-ical "org-bbdb" nil)
  37
  38
  39 \f
  40 ;;; User-Configurable Variables
  41
  42 (defgroup org-export-icalendar nil
  43   "Options specific for iCalendar export back-end."
  44   :tag "Org Export iCalendar"
  45   :group 'org-export)
  46
  47 (defcustom org-icalendar-combined-agenda-file "~/org.ics"
  48   "The file name for the iCalendar file covering all agenda files.
  49 This file is created with the command `\\[org-icalendar-combine-agenda-files]'.
  50 The file name should be absolute.  It will be overwritten without warning."
  51   :group 'org-export-icalendar
  52   :type 'file)
  53
  54 (defcustom org-icalendar-alarm-time 0
  55   "Number of minutes for triggering an alarm for exported timed events.
  56
  57 A zero value (the default) turns off the definition of an alarm trigger
  58 for timed events.  If non-zero, alarms are created.
  59
  60 - a single alarm per entry is defined
  61 - The alarm will go off N minutes before the event
  62 - only a DISPLAY action is defined."
  63   :group 'org-export-icalendar
  64   :version "24.1"
  65   :type 'integer)
  66
  67 (defcustom org-icalendar-combined-name "OrgMode"
  68   "Calendar name for the combined iCalendar representing all agenda files."
  69   :group 'org-export-icalendar
  70   :type 'string)
  71
  72 (defcustom org-icalendar-combined-description ""
  73   "Calendar description for the combined iCalendar (all agenda files)."
  74   :group 'org-export-icalendar
  75   :type 'string)
  76
  77 (defcustom org-icalendar-exclude-tags nil
  78   "Tags that exclude a tree from export.
  79 This variable allows specifying different exclude tags from other
  80 back-ends.  It can also be set with the ICALENDAR_EXCLUDE_TAGS
  81 keyword."
  82   :group 'org-export-icalendar
  83   :type '(repeat (string :tag "Tag")))
  84
  85 (defcustom org-icalendar-use-deadline '(event-if-not-todo todo-due)
  86   "Contexts where iCalendar export should use a deadline time stamp.
  87
  88 This is a list with possibly several symbols in it.  Valid symbols are:
  89
  90 `event-if-todo'       Deadlines in TODO entries become calendar events.
  91 `event-if-not-todo'   Deadlines in non-TODO entries become calendar events.
  92 `todo-due'            Use deadlines in TODO entries as due-dates."
  93   :group 'org-export-icalendar
  94   :type '(set :greedy t
  95               (const :tag "Deadlines in non-TODO entries become events"
  96                      event-if-not-todo)
  97               (const :tag "Deadline in TODO entries become events"
  98                      event-if-todo)
  99               (const :tag "Deadlines in TODO entries become due-dates"
 100                      todo-due)))
 101
 102 (defcustom org-icalendar-use-scheduled '(todo-start)
 103   "Contexts where iCalendar export should use a scheduling time stamp.
 104
 105 This is a list with possibly several symbols in it.  Valid symbols are:
 106
 107 `event-if-todo'       Scheduling time stamps in TODO entries become an event.
 108 `event-if-not-todo'   Scheduling time stamps in non-TODO entries become an event.
 109 `todo-start'          Scheduling time stamps in TODO entries become start date.
 110                       Some calendar applications show TODO entries only after
 111                       that date."
 112   :group 'org-export-icalendar
 113   :type '(set :greedy t
 114               (const :tag
 115                      "SCHEDULED timestamps in non-TODO entries become events"
 116                      event-if-not-todo)
 117               (const :tag "SCHEDULED timestamps in TODO entries become events"
 118                      event-if-todo)
 119               (const :tag "SCHEDULED in TODO entries become start date"
 120                      todo-start)))
 121
 122 (defcustom org-icalendar-categories '(local-tags category)
 123   "Items that should be entered into the \"categories\" field.
 124
 125 This is a list of symbols, the following are valid:
 126 `category'    The Org mode category of the current file or tree
 127 `todo-state'  The todo state, if any
 128 `local-tags'  The tags, defined in the current line
 129 `all-tags'    All tags, including inherited ones."
 130   :group 'org-export-icalendar
 131   :type '(repeat
 132           (choice
 133            (const :tag "The file or tree category" category)
 134            (const :tag "The TODO state" todo-state)
 135            (const :tag "Tags defined in current line" local-tags)
 136            (const :tag "All tags, including inherited ones" all-tags))))
 137
 138 (defcustom org-icalendar-with-timestamps 'active
 139   "Non-nil means make an event from plain time stamps.
 140
 141 It can be set to `active', `inactive', t or nil, in order to make
 142 an event from, respectively, only active timestamps, only
 143 inactive ones, all of them or none.
 144
 145 This variable has precedence over `org-export-with-timestamps'.
 146 It can also be set with the #+OPTIONS line, e.g. \"<:t\"."
 147   :group 'org-export-icalendar
 148   :type '(choice
 149           (const :tag "All timestamps" t)
 150           (const :tag "Only active timestamps" active)
 151           (const :tag "Only inactive timestamps" inactive)
 152           (const :tag "No timestamp" nil)))
 153
 154 (defcustom org-icalendar-include-todo nil
 155   "Non-nil means create VTODO components from TODO items.
 156
 157 Valid values are:
 158 nil                  don't include any task.
 159 t                    include tasks that are not in DONE state.
 160 `unblocked'          include all TODO items that are not blocked.
 161 `all'                include both done and not done items."
 162   :group 'org-export-icalendar
 163   :type '(choice
 164           (const :tag "None" nil)
 165           (const :tag "Unfinished" t)
 166           (const :tag "Unblocked" unblocked)
 167           (const :tag "All" all)
 168           (repeat :tag "Specific TODO keywords"
 169                   (string :tag "Keyword"))))
 170
 171 (defcustom org-icalendar-include-bbdb-anniversaries nil
 172   "Non-nil means a combined iCalendar file should include anniversaries.
 173 The anniversaries are defined in the BBDB database."
 174   :group 'org-export-icalendar
 175   :type 'boolean)
 176
 177 (defcustom org-icalendar-include-sexps t
 178   "Non-nil means export to iCalendar files should also cover sexp entries.
 179 These are entries like in the diary, but directly in an Org file."
 180   :group 'org-export-icalendar
 181   :type 'boolean)
 182
 183 (defcustom org-icalendar-include-body t
 184   "Amount of text below headline to be included in iCalendar export.
 185 This is a number of characters that should maximally be included.
 186 Properties, scheduling and clocking lines will always be removed.
 187 The text will be inserted into the DESCRIPTION field."
 188   :group 'org-export-icalendar
 189   :type '(choice
 190           (const :tag "Nothing" nil)
 191           (const :tag "Everything" t)
 192           (integer :tag "Max characters")))
 193
 194 (defcustom org-icalendar-store-UID nil
 195   "Non-nil means store any created UIDs in properties.
 196
 197 The iCalendar standard requires that all entries have a unique identifier.
 198 Org will create these identifiers as needed.  When this variable is non-nil,
 199 the created UIDs will be stored in the ID property of the entry.  Then the
 200 next time this entry is exported, it will be exported with the same UID,
 201 superseding the previous form of it.  This is essential for
 202 synchronization services.
 203
 204 This variable is not turned on by default because we want to avoid creating
 205 a property drawer in every entry if people are only playing with this feature,
 206 or if they are only using it locally."
 207   :group 'org-export-icalendar
 208   :type 'boolean)
 209
 210 (defcustom org-icalendar-timezone (getenv "TZ")
 211   "The time zone string for iCalendar export.
 212 When nil or the empty string, use output
 213 from (current-time-zone)."
 214   :group 'org-export-icalendar
 215   :type '(choice
 216           (const :tag "Unspecified" nil)
 217           (string :tag "Time zone")))
 218
 219 (defcustom org-icalendar-date-time-format ":%Y%m%dT%H%M%S"
 220   "Format-string for exporting icalendar DATE-TIME.
 221
 222 See `format-time-string' for a full documentation.  The only
 223 difference is that `org-icalendar-timezone' is used for %Z.
 224
 225 Interesting value are:
 226  - \":%Y%m%dT%H%M%S\" for local time
 227  - \";TZID=%Z:%Y%m%dT%H%M%S\" for local time with explicit timezone
 228  - \":%Y%m%dT%H%M%SZ\" for time expressed in Universal Time"
 229   :group 'org-export-icalendar
 230   :version "24.1"
 231   :type '(choice
 232           (const :tag "Local time" ":%Y%m%dT%H%M%S")
 233           (const :tag "Explicit local time" ";TZID=%Z:%Y%m%dT%H%M%S")
 234           (const :tag "Universal time" ":%Y%m%dT%H%M%SZ")
 235           (string :tag "Explicit format")))
 236
 237 (defvar org-icalendar-after-save-hook nil
 238   "Hook run after an iCalendar file has been saved.
 239 This hook is run with the name of the file as argument.  A good
 240 way to use this is to tell a desktop calendar application to
 241 re-read the iCalendar file.")
 242
 243
 244 \f
 245 ;;; Define Back-End
 246
 247 (org-export-define-derived-backend 'icalendar 'ascii
 248   :translate-alist '((clock . ignore)
 249                      (footnote-definition . ignore)
 250                      (footnote-reference . ignore)
 251                      (headline . org-icalendar-entry)
 252                      (inlinetask . ignore)
 253                      (planning . ignore)
 254                      (section . ignore)
 255                      (inner-template . (lambda (c i) c))
 256                      (template . org-icalendar-template))
 257   :options-alist
 258   '((:exclude-tags
 259      "ICALENDAR_EXCLUDE_TAGS" nil org-icalendar-exclude-tags split)
 260     (:with-timestamps nil "<" org-icalendar-with-timestamps)
 261     ;; Other variables.
 262     (:icalendar-alarm-time nil nil org-icalendar-alarm-time)
 263     (:icalendar-categories nil nil org-icalendar-categories)
 264     (:icalendar-date-time-format nil nil org-icalendar-date-time-format)
 265     (:icalendar-include-bbdb-anniversaries nil nil org-icalendar-include-bbdb-anniversaries)
 266     (:icalendar-include-body nil nil org-icalendar-include-body)
 267     (:icalendar-include-sexps nil nil org-icalendar-include-sexps)
 268     (:icalendar-include-todo nil nil org-icalendar-include-todo)
 269     (:icalendar-store-UID nil nil org-icalendar-store-UID)
 270     (:icalendar-timezone nil nil org-icalendar-timezone)
 271     (:icalendar-use-deadline nil nil org-icalendar-use-deadline)
 272     (:icalendar-use-scheduled nil nil org-icalendar-use-scheduled))
 273   :filters-alist
 274   '((:filter-headline . org-icalendar-clear-blank-lines))
 275   :menu-entry
 276   '(?c "Export to iCalendar"
 277        ((?f "Current file" org-icalendar-export-to-ics)
 278         (?a "All agenda files"
 279             (lambda (a s v b) (org-icalendar-export-agenda-files a)))
 280         (?c "Combine all agenda files"
 281             (lambda (a s v b) (org-icalendar-combine-agenda-files a))))))
 282
 283
 284 \f
 285 ;;; Internal Functions
 286
 287 (defun org-icalendar-create-uid (file &optional bell)
 288   "Set ID property on headlines missing it in FILE.
 289 When optional argument BELL is non-nil, inform the user with
 290 a message if the file was modified."
 291   (let (modified-flag)
 292     (org-map-entries
 293      (lambda ()
 294        (let ((entry (org-element-at-point)))
 295          (unless (org-element-property :ID entry)
 296            (org-id-get-create)
 297            (setq modified-flag t)
 298            (forward-line))))
 299      nil nil 'comment)
 300     (when (and bell modified-flag)
 301       (message "ID properties created in file \"%s\"" file)
 302       (sit-for 2))))
 303
 304 (defun org-icalendar-blocked-headline-p (headline info)
 305   "Non-nil when HEADLINE is considered to be blocked.
 306
 307 INFO is a plist used as a communication channel.
 308
 309 A headline is blocked when either
 310
 311   - it has children which are not all in a completed state;
 312
 313   - it has a parent with the property :ORDERED:, and there are
 314     siblings prior to it with incomplete status;
 315
 316   - its parent is blocked because it has siblings that should be
 317     done first or is a child of a blocked grandparent entry."
 318   (or
 319    ;; Check if any child is not done.
 320    (org-element-map headline 'headline
 321      (lambda (hl) (eq (org-element-property :todo-type hl) 'todo))
 322      info 'first-match)
 323    ;; Check :ORDERED: node property.
 324    (catch 'blockedp
 325      (let ((current headline))
 326        (dolist (parent (org-element-lineage headline))
 327          (cond
 328           ((not (org-element-property :todo-keyword parent))
 329            (throw 'blockedp nil))
 330           ((org-not-nil (org-element-property :ORDERED parent))
 331            (let ((sibling current))
 332              (while (setq sibling (org-export-get-previous-element
 333                                    sibling info))
 334                (when (eq (org-element-property :todo-type sibling) 'todo)
 335                  (throw 'blockedp t)))))
 336           (t (setq current parent))))))))
 337
 338 (defun org-icalendar-use-UTC-date-time-p ()
 339   "Non-nil when `org-icalendar-date-time-format' requires UTC time."
 340   (char-equal (elt org-icalendar-date-time-format
 341                    (1- (length org-icalendar-date-time-format))) ?Z))
 342
 343 (defvar org-agenda-default-appointment-duration) ; From org-agenda.el.
 344 (defun org-icalendar-convert-timestamp (timestamp keyword &optional end utc)
 345   "Convert TIMESTAMP to iCalendar format.
 346
 347 TIMESTAMP is a timestamp object.  KEYWORD is added in front of
 348 it, in order to make a complete line (e.g. \"DTSTART\").
 349
 350 When optional argument END is non-nil, use end of time range.
 351 Also increase the hour by two (if time string contains a time),
 352 or the day by one (if it does not contain a time) when no
 353 explicit ending time is specified.
 354
 355 When optional argument UTC is non-nil, time will be expressed in
 356 Universal Time, ignoring `org-icalendar-date-time-format'."
 357   (let* ((year-start (org-element-property :year-start timestamp))
 358          (year-end (org-element-property :year-end timestamp))
 359          (month-start (org-element-property :month-start timestamp))
 360          (month-end (org-element-property :month-end timestamp))
 361          (day-start (org-element-property :day-start timestamp))
 362          (day-end (org-element-property :day-end timestamp))
 363          (hour-start (org-element-property :hour-start timestamp))
 364          (hour-end (org-element-property :hour-end timestamp))
 365          (minute-start (org-element-property :minute-start timestamp))
 366          (minute-end (org-element-property :minute-end timestamp))
 367          (with-time-p minute-start)
 368          (equal-bounds-p
 369           (equal (list year-start month-start day-start hour-start minute-start)
 370                  (list year-end month-end day-end hour-end minute-end)))
 371          (mi (cond ((not with-time-p) 0)
 372                    ((not end) minute-start)
 373                    ((and org-agenda-default-appointment-duration equal-bounds-p)
 374                     (+ minute-end org-agenda-default-appointment-duration))
 375                    (t minute-end)))
 376          (h (cond ((not with-time-p) 0)
 377                   ((not end) hour-start)
 378                   ((or (not equal-bounds-p)
 379                        org-agenda-default-appointment-duration)
 380                    hour-end)
 381                   (t (+ hour-end 2))))
 382          (d (cond ((not end) day-start)
 383                   ((not with-time-p) (1+ day-end))
 384                   (t day-end)))
 385          (m (if end month-end month-start))
 386          (y (if end year-end year-start)))
 387     (concat
 388      keyword
 389      (format-time-string
 390       (cond (utc ":%Y%m%dT%H%M%SZ")
 391             ((not with-time-p) ";VALUE=DATE:%Y%m%d")
 392             (t (replace-regexp-in-string "%Z"
 393                                          org-icalendar-timezone
 394                                          org-icalendar-date-time-format
 395                                          t)))
 396       ;; Convert timestamp into internal time in order to use
 397       ;; `format-time-string' and fix any mistake (i.e. MI >= 60).
 398       (encode-time 0 mi h d m y)
 399       (and (or utc (and with-time-p (org-icalendar-use-UTC-date-time-p)))
 400            t)))))
 401
 402 (defun org-icalendar-dtstamp ()
 403   "Return DTSTAMP property, as a string."
 404   (format-time-string "DTSTAMP:%Y%m%dT%H%M%SZ" nil t))
 405
 406 (defun org-icalendar-get-categories (entry info)
 407   "Return categories according to `org-icalendar-categories'.
 408 ENTRY is a headline or an inlinetask element.  INFO is a plist
 409 used as a communication channel."
 410   (mapconcat
 411    #'identity
 412    (org-uniquify
 413     (let (categories)
 414       (dolist (type org-icalendar-categories (nreverse categories))
 415         (cl-case type
 416           (category
 417            (push (org-export-get-category entry info) categories))
 418           (todo-state
 419            (let ((todo (org-element-property :todo-keyword entry)))
 420              (and todo (push todo categories))))
 421           (local-tags
 422            (setq categories
 423                  (append (nreverse (org-export-get-tags entry info))
 424                          categories)))
 425           (all-tags
 426            (setq categories
 427                  (append (nreverse (org-export-get-tags entry info nil t))
 428                          categories)))))))
 429    ","))
 430
 431 (defun org-icalendar-transcode-diary-sexp (sexp uid summary)
 432   "Transcode a diary sexp into iCalendar format.
 433 SEXP is the diary sexp being transcoded, as a string.  UID is the
 434 unique identifier for the entry.  SUMMARY defines a short summary
 435 or subject for the event."
 436   (when (require 'icalendar nil t)
 437     (org-element-normalize-string
 438      (with-temp-buffer
 439        (let ((sexp (if (not (string-match "\\`<%%" sexp)) sexp
 440                      (concat (substring sexp 1 -1) " " summary))))
 441          (put-text-property 0 1 'uid uid sexp)
 442          (insert sexp "\n"))
 443        (org-diary-to-ical-string (current-buffer))))))
 444
 445 (defun org-icalendar-cleanup-string (s)
 446   "Cleanup string S according to RFC 5545."
 447   (when s
 448     ;; Protect "\", "," and ";" characters. and replace newline
 449     ;; characters with literal \n.
 450     (replace-regexp-in-string
 451      "[ \t]*\n" "\\n"
 452      (replace-regexp-in-string "[\\,;]" "\\\\\\&" s)
 453      nil t)))
 454
 455 (defun org-icalendar-fold-string (s)
 456   "Fold string S according to RFC 5545."
 457   (org-element-normalize-string
 458    (mapconcat
 459     (lambda (line)
 460       ;; Limit each line to a maximum of 75 characters.  If it is
 461       ;; longer, fold it by using "\r\n " as a continuation marker.
 462       (let ((len (length line)))
 463         (if (<= len 75) line
 464           (let ((folded-line (substring line 0 75))
 465                 (chunk-start 75)
 466                 chunk-end)
 467             ;; Since continuation marker takes up one character on the
 468             ;; line, real contents must be split at 74 chars.
 469             (while (< (setq chunk-end (+ chunk-start 74)) len)
 470               (setq folded-line
 471                     (concat folded-line "\r\n "
 472                             (substring line chunk-start chunk-end))
 473                     chunk-start chunk-end))
 474             (concat folded-line "\r\n " (substring line chunk-start))))))
 475     (org-split-string s "\n") "\r\n")))
 476
 477
 478 \f
 479 ;;; Filters
 480
 481 (defun org-icalendar-clear-blank-lines (headline _back-end _info)
 482   "Remove blank lines in HEADLINE export.
 483 HEADLINE is a string representing a transcoded headline.
 484 BACK-END and INFO are ignored."
 485   (replace-regexp-in-string "^\\(?:[ \t]*\n\\)+" "" headline))
 486
 487
 488 \f
 489 ;;; Transcode Functions
 490
 491 ;;;; Headline and Inlinetasks
 492
 493 ;; The main function is `org-icalendar-entry', which extracts
 494 ;; information from a headline or an inlinetask (summary,
 495 ;; description...) and then delegates code generation to
 496 ;; `org-icalendar--vtodo' and `org-icalendar--vevent', depending
 497 ;; on the component needed.
 498
 499 ;; Obviously, `org-icalendar--valarm' handles alarms, which can
 500 ;; happen within a VTODO component.
 501
 502 (defun org-icalendar-entry (entry contents info)
 503   "Transcode ENTRY element into iCalendar format.
 504
 505 ENTRY is either a headline or an inlinetask.  CONTENTS is
 506 ignored.  INFO is a plist used as a communication channel.
 507
 508 This function is called on every headline, the section below
 509 it (minus inlinetasks) being its contents.  It tries to create
 510 VEVENT and VTODO components out of scheduled date, deadline date,
 511 plain timestamps, diary sexps.  It also calls itself on every
 512 inlinetask within the section."
 513   (unless (org-element-property :footnote-section-p entry)
 514     (let* ((type (org-element-type entry))
 515            ;; Determine contents really associated to the entry.  For
 516            ;; a headline, limit them to section, if any.  For an
 517            ;; inlinetask, this is every element within the task.
 518            (inside
 519             (if (eq type 'inlinetask)
 520                 (cons 'org-data (cons nil (org-element-contents entry)))
 521               (let ((first (car (org-element-contents entry))))
 522                 (and (eq (org-element-type first) 'section)
 523                      (cons 'org-data
 524                            (cons nil (org-element-contents first))))))))
 525       (concat
 526        (let ((todo-type (org-element-property :todo-type entry))
 527              (uid (or (org-element-property :ID entry) (org-id-new)))
 528              (summary (org-icalendar-cleanup-string
 529                        (or (org-element-property :SUMMARY entry)
 530                            (org-export-data
 531                             (org-element-property :title entry) info))))
 532              (loc (org-icalendar-cleanup-string
 533                    (org-element-property :LOCATION entry)))
 534              ;; Build description of the entry from associated section
 535              ;; (headline) or contents (inlinetask).
 536              (desc
 537               (org-icalendar-cleanup-string
 538                (or (org-element-property :DESCRIPTION entry)
 539                    (let ((contents (org-export-data inside info)))
 540                      (cond
 541                       ((not (org-string-nw-p contents)) nil)
 542                       ((wholenump org-icalendar-include-body)
 543                        (let ((contents (org-trim contents)))
 544                          (substring
 545                           contents 0 (min (length contents)
 546                                           org-icalendar-include-body))))
 547                       (org-icalendar-include-body (org-trim contents)))))))
 548              (cat (org-icalendar-get-categories entry info)))
 549          (concat
 550           ;; Events: Delegate to `org-icalendar--vevent' to generate
 551           ;; "VEVENT" component from scheduled, deadline, or any
 552           ;; timestamp in the entry.
 553           (let ((deadline (org-element-property :deadline entry)))
 554             (and deadline
 555                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 556                        org-icalendar-use-deadline)
 557                  (org-icalendar--vevent
 558                   entry deadline (concat "DL-" uid)
 559                   (concat "DL: " summary) loc desc cat)))
 560           (let ((scheduled (org-element-property :scheduled entry)))
 561             (and scheduled
 562                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 563                        org-icalendar-use-scheduled)
 564                  (org-icalendar--vevent
 565                   entry scheduled (concat "SC-" uid)
 566                   (concat "S: " summary) loc desc cat)))
 567           ;; When collecting plain timestamps from a headline and its
 568           ;; title, skip inlinetasks since collection will happen once
 569           ;; ENTRY is one of them.
 570           (let ((counter 0))
 571             (mapconcat
 572              #'identity
 573              (org-element-map (cons (org-element-property :title entry)
 574                                     (org-element-contents inside))
 575                  'timestamp
 576                (lambda (ts)
 577                  (when (let ((type (org-element-property :type ts)))
 578                          (cl-case (plist-get info :with-timestamps)
 579                            (active (memq type '(active active-range)))
 580                            (inactive (memq type '(inactive inactive-range)))
 581                            ((t) t)))
 582                    (let ((uid (format "TS%d-%s" (cl-incf counter) uid)))
 583                      (org-icalendar--vevent
 584                       entry ts uid summary loc desc cat))))
 585                info nil (and (eq type 'headline) 'inlinetask))
 586              ""))
 587           ;; Task: First check if it is appropriate to export it.  If
 588           ;; so, call `org-icalendar--vtodo' to transcode it into
 589           ;; a "VTODO" component.
 590           (when (and todo-type
 591                      (cl-case (plist-get info :icalendar-include-todo)
 592                        (all t)
 593                        (unblocked
 594                         (and (eq type 'headline)
 595                              (not (org-icalendar-blocked-headline-p
 596                                    entry info))))
 597                        ((t) (eq todo-type 'todo))))
 598             (org-icalendar--vtodo entry uid summary loc desc cat))
 599           ;; Diary-sexp: Collect every diary-sexp element within ENTRY
 600           ;; and its title, and transcode them.  If ENTRY is
 601           ;; a headline, skip inlinetasks: they will be handled
 602           ;; separately.
 603           (when org-icalendar-include-sexps
 604             (let ((counter 0))
 605               (mapconcat #'identity
 606                          (org-element-map
 607                              (cons (org-element-property :title entry)
 608                                    (org-element-contents inside))
 609                              'diary-sexp
 610                            (lambda (sexp)
 611                              (org-icalendar-transcode-diary-sexp
 612                               (org-element-property :value sexp)
 613                               (format "DS%d-%s" (cl-incf counter) uid)
 614                               summary))
 615                            info nil (and (eq type 'headline) 'inlinetask))
 616                          "")))))
 617        ;; If ENTRY is a headline, call current function on every
 618        ;; inlinetask within it.  In agenda export, this is independent
 619        ;; from the mark (or lack thereof) on the entry.
 620        (when (eq type 'headline)
 621          (mapconcat #'identity
 622                     (org-element-map inside 'inlinetask
 623                       (lambda (task) (org-icalendar-entry task nil info))
 624                       info) ""))
 625        ;; Don't forget components from inner entries.
 626        contents))))
 627
 628 (defun org-icalendar--vevent
 629     (entry timestamp uid summary location description categories)
 630   "Create a VEVENT component.
 631
 632 ENTRY is either a headline or an inlinetask element.  TIMESTAMP
 633 is a timestamp object defining the date-time of the event.  UID
 634 is the unique identifier for the event.  SUMMARY defines a short
 635 summary or subject for the event.  LOCATION defines the intended
 636 venue for the event.  DESCRIPTION provides the complete
 637 description of the event.  CATEGORIES defines the categories the
 638 event belongs to.
 639
 640 Return VEVENT component as a string."
 641   (org-icalendar-fold-string
 642    (if (eq (org-element-property :type timestamp) 'diary)
 643        (org-icalendar-transcode-diary-sexp
 644         (org-element-property :raw-value timestamp) uid summary)
 645      (concat "BEGIN:VEVENT\n"
 646              (org-icalendar-dtstamp) "\n"
 647              "UID:" uid "\n"
 648              (org-icalendar-convert-timestamp timestamp "DTSTART") "\n"
 649              (org-icalendar-convert-timestamp timestamp "DTEND" t) "\n"
 650              ;; RRULE.
 651              (when (org-element-property :repeater-type timestamp)
 652                (format "RRULE:FREQ=%s;INTERVAL=%d\n"
 653                        (cl-case (org-element-property :repeater-unit timestamp)
 654                          (hour "HOURLY") (day "DAILY") (week "WEEKLY")
 655                          (month "MONTHLY") (year "YEARLY"))
 656                        (org-element-property :repeater-value timestamp)))
 657              "SUMMARY:" summary "\n"
 658              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 659              (and (org-string-nw-p description)
 660                   (format "DESCRIPTION:%s\n" description))
 661              "CATEGORIES:" categories "\n"
 662              ;; VALARM.
 663              (org-icalendar--valarm entry timestamp summary)
 664              "END:VEVENT"))))
 665
 666 (defun org-icalendar--vtodo
 667   (entry uid summary location description categories)
 668   "Create a VTODO component.
 669
 670 ENTRY is either a headline or an inlinetask element.  UID is the
 671 unique identifier for the task.  SUMMARY defines a short summary
 672 or subject for the task.  LOCATION defines the intended venue for
 673 the task.  DESCRIPTION provides the complete description of the
 674 task.  CATEGORIES defines the categories the task belongs to.
 675
 676 Return VTODO component as a string."
 677   (let ((start (or (and (memq 'todo-start org-icalendar-use-scheduled)
 678                         (org-element-property :scheduled entry))
 679                    ;; If we can't use a scheduled time for some
 680                    ;; reason, start task now.
 681                    (let ((now (decode-time)))
 682                      (list 'timestamp
 683                            (list :type 'active
 684                                  :minute-start (nth 1 now)
 685                                  :hour-start (nth 2 now)
 686                                  :day-start (nth 3 now)
 687                                  :month-start (nth 4 now)
 688                                  :year-start (nth 5 now)))))))
 689     (org-icalendar-fold-string
 690      (concat "BEGIN:VTODO\n"
 691              "UID:TODO-" uid "\n"
 692              (org-icalendar-dtstamp) "\n"
 693              (org-icalendar-convert-timestamp start "DTSTART") "\n"
 694              (and (memq 'todo-due org-icalendar-use-deadline)
 695                   (org-element-property :deadline entry)
 696                   (concat (org-icalendar-convert-timestamp
 697                            (org-element-property :deadline entry) "DUE")
 698                           "\n"))
 699              "SUMMARY:" summary "\n"
 700              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 701              (and (org-string-nw-p description)
 702                   (format "DESCRIPTION:%s\n" description))
 703              "CATEGORIES:" categories "\n"
 704              "SEQUENCE:1\n"
 705              (format "PRIORITY:%d\n"
 706                      (let ((pri (or (org-element-property :priority entry)
 707                                     org-default-priority)))
 708                        (floor (- 9 (* 8. (/ (float (- org-lowest-priority pri))
 709                                             (- org-lowest-priority
 710                                                org-highest-priority)))))))
 711              (format "STATUS:%s\n"
 712                      (if (eq (org-element-property :todo-type entry) 'todo)
 713                          "NEEDS-ACTION"
 714                        "COMPLETED"))
 715              "END:VTODO"))))
 716
 717 (defun org-icalendar--valarm (entry timestamp summary)
 718   "Create a VALARM component.
 719
 720 ENTRY is the calendar entry triggering the alarm.  TIMESTAMP is
 721 the start date-time of the entry.  SUMMARY defines a short
 722 summary or subject for the task.
 723
 724 Return VALARM component as a string, or nil if it isn't allowed."
 725   ;; Create a VALARM entry if the entry is timed.  This is not very
 726   ;; general in that:
 727   ;; (a) only one alarm per entry is defined,
 728   ;; (b) only minutes are allowed for the trigger period ahead of the
 729   ;;     start time,
 730   ;; (c) only a DISPLAY action is defined.                       [ESF]
 731   (let ((alarm-time
 732          (let ((warntime
 733                 (org-element-property :APPT_WARNTIME entry)))
 734            (if warntime (string-to-number warntime) 0))))
 735     (and (or (> alarm-time 0) (> org-icalendar-alarm-time 0))
 736          (org-element-property :hour-start timestamp)
 737          (format "BEGIN:VALARM
 738 ACTION:DISPLAY
 739 DESCRIPTION:%s
 740 TRIGGER:-P0DT0H%dM0S
 741 END:VALARM\n"
 742                  summary
 743                  (if (zerop alarm-time) org-icalendar-alarm-time alarm-time)))))
 744
 745
 746 ;;;; Template
 747
 748 (defun org-icalendar-template (contents info)
 749   "Return complete document string after iCalendar conversion.
 750 CONTENTS is the transcoded contents string.  INFO is a plist used
 751 as a communication channel."
 752   (org-icalendar--vcalendar
 753    ;; Name.
 754    (if (not (plist-get info :input-file)) (buffer-name (buffer-base-buffer))
 755      (file-name-nondirectory
 756       (file-name-sans-extension (plist-get info :input-file))))
 757    ;; Owner.
 758    (if (not (plist-get info :with-author)) ""
 759      (org-export-data (plist-get info :author) info))
 760    ;; Timezone.
 761    (if (org-string-nw-p org-icalendar-timezone) org-icalendar-timezone
 762      (cadr (current-time-zone)))
 763    ;; Description.
 764    (org-export-data (plist-get info :title) info)
 765    contents))
 766
 767 (defun org-icalendar--vcalendar (name owner tz description contents)
 768   "Create a VCALENDAR component.
 769 NAME, OWNER, TZ, DESCRIPTION and CONTENTS are all strings giving,
 770 respectively, the name of the calendar, its owner, the timezone
 771 used, a short description and the other components included."
 772   (concat (format "BEGIN:VCALENDAR
 773 VERSION:2.0
 774 X-WR-CALNAME:%s
 775 PRODID:-//%s//Emacs with Org mode//EN
 776 X-WR-TIMEZONE:%s
 777 X-WR-CALDESC:%s
 778 CALSCALE:GREGORIAN\n"
 779                   (org-icalendar-cleanup-string name)
 780                   (org-icalendar-cleanup-string owner)
 781                   (org-icalendar-cleanup-string tz)
 782                   (org-icalendar-cleanup-string description))
 783           contents
 784           "END:VCALENDAR\n"))
 785
 786
 787 \f
 788 ;;; Interactive Functions
 789
 790 ;;;###autoload
 791 (defun org-icalendar-export-to-ics
 792   (&optional async subtreep visible-only body-only)
 793   "Export current buffer to an iCalendar file.
 794
 795 If narrowing is active in the current buffer, only export its
 796 narrowed part.
 797
 798 If a region is active, export that region.
 799
 800 A non-nil optional argument ASYNC means the process should happen
 801 asynchronously.  The resulting file should be accessible through
 802 the `org-export-stack' interface.
 803
 804 When optional argument SUBTREEP is non-nil, export the sub-tree
 805 at point, extracting information from the headline properties
 806 first.
 807
 808 When optional argument VISIBLE-ONLY is non-nil, don't export
 809 contents of hidden elements.
 810
 811 When optional argument BODY-ONLY is non-nil, only write code
 812 between \"BEGIN:VCALENDAR\" and \"END:VCALENDAR\".
 813
 814 Return ICS file name."
 815   (interactive)
 816   (let ((file (buffer-file-name (buffer-base-buffer))))
 817     (when (and file org-icalendar-store-UID)
 818       (org-icalendar-create-uid file 'warn-user)))
 819   ;; Export part.  Since this back-end is backed up by `ascii', ensure
 820   ;; links will not be collected at the end of sections.
 821   (let ((outfile (org-export-output-file-name ".ics" subtreep)))
 822     (org-export-to-file 'icalendar outfile
 823       async subtreep visible-only body-only
 824       '(:ascii-charset utf-8 :ascii-links-to-notes nil)
 825       (lambda (file)
 826         (run-hook-with-args 'org-icalendar-after-save-hook file) nil))))
 827
 828 ;;;###autoload
 829 (defun org-icalendar-export-agenda-files (&optional async)
 830   "Export all agenda files to iCalendar files.
 831 When optional argument ASYNC is non-nil, export happens in an
 832 external process."
 833   (interactive)
 834   (if async
 835       ;; Asynchronous export is not interactive, so we will not call
 836       ;; `org-check-agenda-file'.  Instead we remove any non-existent
 837       ;; agenda file from the list.
 838       (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
 839         (org-export-async-start
 840             (lambda (results)
 841               (dolist (f results) (org-export-add-to-stack f 'icalendar)))
 842           `(let (output-files)
 843              (dolist (file ',files outputfiles)
 844                (with-current-buffer (org-get-agenda-file-buffer file)
 845                  (push (expand-file-name (org-icalendar-export-to-ics))
 846                        output-files))))))
 847     (let ((files (org-agenda-files t)))
 848       (org-agenda-prepare-buffers files)
 849       (unwind-protect
 850           (dolist (file files)
 851             (catch 'nextfile
 852               (org-check-agenda-file file)
 853               (with-current-buffer (org-get-agenda-file-buffer file)
 854                 (org-icalendar-export-to-ics))))
 855         (org-release-buffers org-agenda-new-buffers)))))
 856
 857 ;;;###autoload
 858 (defun org-icalendar-combine-agenda-files (&optional async)
 859   "Combine all agenda files into a single iCalendar file.
 860
 861 A non-nil optional argument ASYNC means the process should happen
 862 asynchronously.  The resulting file should be accessible through
 863 the `org-export-stack' interface.
 864
 865 The file is stored under the name chosen in
 866 `org-icalendar-combined-agenda-file'."
 867   (interactive)
 868   (if async
 869       (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
 870         (org-export-async-start
 871             (lambda (_)
 872               (org-export-add-to-stack
 873                (expand-file-name org-icalendar-combined-agenda-file)
 874                'icalendar))
 875           `(apply #'org-icalendar--combine-files ',files)))
 876     (apply #'org-icalendar--combine-files (org-agenda-files t))))
 877
 878 (defun org-icalendar-export-current-agenda (file)
 879   "Export current agenda view to an iCalendar FILE.
 880 This function assumes major mode for current buffer is
 881 `org-agenda-mode'."
 882   (let* ((org-export-babel-evaluate)    ; Don't evaluate Babel block.
 883          (contents
 884           (org-export-string-as
 885            (with-output-to-string
 886              (save-excursion
 887                (let ((p (point-min)))
 888                  (while (setq p (next-single-property-change p 'org-hd-marker))
 889                    (let ((m (get-text-property p 'org-hd-marker)))
 890                      (when m
 891                        (with-current-buffer (marker-buffer m)
 892                          (org-with-wide-buffer
 893                           (goto-char (marker-position m))
 894                           (princ
 895                            (org-element-normalize-string
 896                             (buffer-substring
 897                              (point) (progn (outline-next-heading) (point)))))))))
 898                    (forward-line)))))
 899            'icalendar t
 900            '(:ascii-charset utf-8 :ascii-links-to-notes nil
 901                             :icalendar-include-todo all))))
 902     (with-temp-file file
 903       (insert
 904        (org-icalendar--vcalendar
 905         org-icalendar-combined-name
 906         user-full-name
 907         (or (org-string-nw-p org-icalendar-timezone) (cadr (current-time-zone)))
 908         org-icalendar-combined-description
 909         contents)))
 910     (run-hook-with-args 'org-icalendar-after-save-hook file)))
 911
 912 (defun org-icalendar--combine-files (&rest files)
 913   "Combine entries from multiple files into an iCalendar file.
 914 FILES is a list of files to build the calendar from."
 915   (org-agenda-prepare-buffers files)
 916   (unwind-protect
 917       (progn
 918         (with-temp-file org-icalendar-combined-agenda-file
 919           (insert
 920            (org-icalendar--vcalendar
 921             ;; Name.
 922             org-icalendar-combined-name
 923             ;; Owner.
 924             user-full-name
 925             ;; Timezone.
 926             (or (org-string-nw-p org-icalendar-timezone)
 927                 (cadr (current-time-zone)))
 928             ;; Description.
 929             org-icalendar-combined-description
 930             ;; Contents.
 931             (concat
 932              ;; Agenda contents.
 933              (mapconcat
 934               (lambda (file)
 935                 (catch 'nextfile
 936                   (org-check-agenda-file file)
 937                   (with-current-buffer (org-get-agenda-file-buffer file)
 938                     ;; Create ID if necessary.
 939                     (when org-icalendar-store-UID
 940                       (org-icalendar-create-uid file t))
 941                     (org-export-as
 942                      'icalendar nil nil t
 943                      '(:ascii-charset utf-8 :ascii-links-to-notes nil)))))
 944               files "")
 945              ;; BBDB anniversaries.
 946              (when (and org-icalendar-include-bbdb-anniversaries
 947                         (require 'org-bbdb nil t))
 948                (with-output-to-string (org-bbdb-anniv-export-ical)))))))
 949         (run-hook-with-args 'org-icalendar-after-save-hook
 950                             org-icalendar-combined-agenda-file))
 951     (org-release-buffers org-agenda-new-buffers)))
 952
 953
 954 (provide 'ox-icalendar)
 955
 956 ;; Local variables:
 957 ;; generated-autoload-file: "org-loaddefs.el"
 958 ;; End:
 959
 960 ;;; ox-icalendar.el ends here