lisp/org-inlinetask.el

   1 ;;; org-inlinetask.el --- Tasks Independent of Outline Hierarchy -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28 ;;
  29 ;; This module implements inline tasks in Org mode.  Inline tasks are
  30 ;; tasks that have all the properties of normal outline nodes,
  31 ;; including the ability to store meta data like scheduling dates,
  32 ;; TODO state, tags and properties.  However, these nodes are treated
  33 ;; specially by the visibility cycling.
  34 ;;
  35 ;; Visibility cycling exempts these nodes from cycling.  So whenever
  36 ;; their parent is opened, so are these tasks.  This will only work
  37 ;; with `org-cycle', so if you are also using other commands to
  38 ;; show/hide entries, you will occasionally find these tasks to behave
  39 ;; like all other outline nodes, seemingly splitting the text of the
  40 ;; parent into children.
  41 ;;
  42 ;; Special fontification of inline tasks, so that they can be
  43 ;; immediately recognized.  From the stars of the headline, only the
  44 ;; first and the last two will be visible, the others will be hidden
  45 ;; using the `org-hide' face.
  46 ;;
  47 ;; An inline task is identified solely by a minimum outline level,
  48 ;; given by the variable `org-inlinetask-min-level', default 15.
  49 ;;
  50 ;; If you need to have a time planning line (DEADLINE etc), drawers,
  51 ;; for example LOGBOOK of PROPERTIES, or even normal text as part of
  52 ;; the inline task, you must add an "END" headline with the same
  53 ;; number of stars.
  54 ;;
  55 ;; As an example, here are two valid inline tasks:
  56 ;;
  57 ;;    **************** TODO a small task
  58 ;;
  59 ;; and
  60 ;;
  61 ;;    **************** TODO another small task
  62 ;;                     DEADLINE: <2009-03-30 Mon>
  63 ;;                     :PROPERTIES:
  64 ;;                       :SOMETHING: or other
  65 ;;                     :END:
  66 ;;                     And here is some extra text
  67 ;;    **************** END
  68 ;;
  69 ;; Also, if you want to use refiling and archiving for inline tasks,
  70 ;; The END line must be present to make things work properly.
  71 ;;
  72 ;; Note that you should not try to use inline tasks within plain list,
  73 ;; visibility cycling is known to be problematic when doing so.
  74 ;;
  75 ;; This package installs one new command:
  76 ;;
  77 ;; C-c C-x t      Insert a new inline task with END line
  78
  79 ;;; Code:
  80
  81 (require 'org)
  82
  83 (defgroup org-inlinetask nil
  84   "Options concerning inline tasks in Org mode."
  85   :tag "Org Inline Tasks"
  86   :group 'org-structure)
  87
  88 (defcustom org-inlinetask-min-level 15
  89   "Minimum level a headline must have before it is treated as an inline task.
  90 Don't set it to something higher than `29' or clocking will break since this
  91 is the hardcoded maximum number of stars `org-clock-sum' will work with.
  92
  93 It is strongly recommended that you set `org-cycle-max-level' not at all,
  94 or to a number smaller than this one.  In fact, when `org-cycle-max-level' is
  95 not set, it will be assumed to be one less than the value of smaller than
  96 the value of this variable."
  97   :group 'org-inlinetask
  98   :type '(choice
  99           (const :tag "Off" nil)
 100           (integer)))
 101
 102 (defcustom org-inlinetask-show-first-star nil
 103   "Non-nil means display the first star of an inline task as additional marker.
 104 When nil, the first star is not shown."
 105   :tag "Org Inline Tasks"
 106   :group 'org-structure
 107   :type 'boolean)
 108
 109 (defvar org-odd-levels-only)
 110 (defvar org-keyword-time-regexp)
 111 (defvar org-complex-heading-regexp)
 112 (defvar org-property-end-re)
 113
 114 (defcustom org-inlinetask-default-state nil
 115   "Non-nil means make inline tasks have a TODO keyword initially.
 116 This should be the state `org-inlinetask-insert-task' should use by
 117 default, or nil of no state should be assigned."
 118   :group 'org-inlinetask
 119   :version "24.1"
 120   :type '(choice
 121           (const :tag "No state" nil)
 122           (string :tag "Specific state")))
 123
 124 (defun org-inlinetask-insert-task (&optional no-state)
 125   "Insert an inline task.
 126 If prefix arg NO-STATE is set, ignore `org-inlinetask-default-state'."
 127   (interactive "P")
 128   ;; Error when inside an inline task, except if point was at its very
 129   ;; beginning, in which case the new inline task will be inserted
 130   ;; before this one.
 131   (when (and (org-inlinetask-in-task-p)
 132              (not (and (org-inlinetask-at-task-p) (bolp))))
 133     (error "Cannot nest inline tasks"))
 134   (or (bolp) (newline))
 135   (let* ((indent (if org-odd-levels-only
 136                      (1- (* 2 org-inlinetask-min-level))
 137                    org-inlinetask-min-level))
 138          (indent-string (concat (make-string indent ?*) " ")))
 139     (insert indent-string
 140             (if (or no-state (not org-inlinetask-default-state))
 141                 "\n"
 142               (concat org-inlinetask-default-state " \n"))
 143             indent-string "END\n"))
 144   (end-of-line -1))
 145 (define-key org-mode-map "\C-c\C-xt" 'org-inlinetask-insert-task)
 146
 147 (defun org-inlinetask-outline-regexp ()
 148   "Return string matching an inline task heading.
 149 The number of levels is controlled by `org-inlinetask-min-level'."
 150   (let ((nstars (if org-odd-levels-only
 151                     (1- (* org-inlinetask-min-level 2))
 152                   org-inlinetask-min-level)))
 153     (format "^\\(\\*\\{%d,\\}\\)[ \t]+" nstars)))
 154
 155 (defun org-inlinetask-at-task-p ()
 156   "Return true if point is at beginning of an inline task."
 157   (save-excursion
 158     (beginning-of-line)
 159     (and (looking-at (concat (org-inlinetask-outline-regexp)  "\\(.*\\)"))
 160          (not (string-match "^end[ \t]*$" (downcase (match-string 2)))))))
 161
 162 (defun org-inlinetask-in-task-p ()
 163   "Return true if point is inside an inline task."
 164   (save-excursion
 165     (beginning-of-line)
 166     (let* ((case-fold-search t)
 167            (stars-re (org-inlinetask-outline-regexp))
 168            (task-beg-re (concat stars-re "\\(?:.*\\)"))
 169            (task-end-re (concat stars-re "END[ \t]*$")))
 170       (or (looking-at-p task-beg-re)
 171           (and (re-search-forward "^\\*+[ \t]+" nil t)
 172                (progn (beginning-of-line) (looking-at-p task-end-re)))))))
 173
 174 (defun org-inlinetask-goto-beginning ()
 175   "Go to the beginning of the inline task at point."
 176   (end-of-line)
 177   (let ((case-fold-search t)
 178         (inlinetask-re (org-inlinetask-outline-regexp)))
 179     (re-search-backward inlinetask-re nil t)
 180     (when (looking-at-p (concat inlinetask-re "END[ \t]*$"))
 181       (re-search-backward inlinetask-re nil t))))
 182
 183 (defun org-inlinetask-goto-end ()
 184   "Go to the end of the inline task at point.
 185 Return point."
 186   (save-match-data
 187     (beginning-of-line)
 188     (let* ((case-fold-search t)
 189            (inlinetask-re (org-inlinetask-outline-regexp))
 190            (task-end-re (concat inlinetask-re "END[ \t]*$")))
 191       (cond
 192        ((looking-at task-end-re))
 193        ((looking-at inlinetask-re)
 194         (forward-line)
 195         (cond
 196          ((looking-at task-end-re))
 197          ((looking-at inlinetask-re))
 198          ((org-inlinetask-in-task-p)
 199           (re-search-forward inlinetask-re nil t))))
 200        (t (re-search-forward inlinetask-re nil t)))
 201       (end-of-line)
 202       (point))))
 203
 204 (defun org-inlinetask-get-task-level ()
 205   "Get the level of the inline task around.
 206 This assumes the point is inside an inline task."
 207   (save-excursion
 208     (end-of-line)
 209     (re-search-backward (org-inlinetask-outline-regexp) nil t)
 210     (- (match-end 1) (match-beginning 1))))
 211
 212 (defun org-inlinetask-promote ()
 213   "Promote the inline task at point.
 214 If the task has an end part, promote it.  Also, prevents level from
 215 going below `org-inlinetask-min-level'."
 216   (interactive)
 217   (if (not (org-inlinetask-in-task-p))
 218       (error "Not in an inline task")
 219     (save-excursion
 220       (let* ((lvl (org-inlinetask-get-task-level))
 221              (next-lvl (org-get-valid-level lvl -1))
 222              (diff (- next-lvl lvl))
 223              (down-task (concat (make-string next-lvl ?*)))
 224              beg)
 225         (if (< next-lvl org-inlinetask-min-level)
 226             (error "Cannot promote an inline task at minimum level")
 227           (org-inlinetask-goto-beginning)
 228           (setq beg (point))
 229           (replace-match down-task nil t nil 1)
 230           (org-inlinetask-goto-end)
 231           (if (eobp) (beginning-of-line) (forward-line -1))
 232           (unless (= (point) beg)
 233             (replace-match down-task nil t nil 1)
 234             (when org-adapt-indentation
 235               (goto-char beg)
 236               (org-fixup-indentation diff))))))))
 237
 238 (defun org-inlinetask-demote ()
 239   "Demote the inline task at point.
 240 If the task has an end part, also demote it."
 241   (interactive)
 242   (if (not (org-inlinetask-in-task-p))
 243       (error "Not in an inline task")
 244     (save-excursion
 245       (let* ((lvl (org-inlinetask-get-task-level))
 246              (next-lvl (org-get-valid-level lvl 1))
 247              (diff (- next-lvl lvl))
 248              (down-task (concat (make-string next-lvl ?*)))
 249              beg)
 250         (org-inlinetask-goto-beginning)
 251         (setq beg (point))
 252         (replace-match down-task nil t nil 1)
 253         (org-inlinetask-goto-end)
 254         (if (eobp) (beginning-of-line) (forward-line -1))
 255         (unless (= (point) beg)
 256           (replace-match down-task nil t nil 1)
 257           (when org-adapt-indentation
 258             (goto-char beg)
 259             (org-fixup-indentation diff)))))))
 260
 261 (defun org-inlinetask-get-current-indentation ()
 262   "Get the indentation of the last non-while line above this one."
 263   (save-excursion
 264     (beginning-of-line 1)
 265     (skip-chars-backward " \t\n")
 266     (beginning-of-line 1)
 267     (or (org-at-item-p)
 268         (looking-at "[ \t]*"))
 269     (goto-char (match-end 0))
 270     (current-column)))
 271
 272 (defvar org-indent-indentation-per-level) ; defined in org-indent.el
 273
 274 (defface org-inlinetask '((t :inherit shadow))
 275   "Face for inlinetask headlines."
 276   :group 'org-faces)
 277
 278 (defun org-inlinetask-fontify (limit)
 279   "Fontify the inline tasks down to LIMIT."
 280   (let* ((nstars (if org-odd-levels-only
 281                      (1- (* 2 (or org-inlinetask-min-level 200)))
 282                    (or org-inlinetask-min-level 200)))
 283          (re (concat "^\\(\\*\\)\\(\\*\\{"
 284                      (format "%d" (- nstars 3))
 285                      ",\\}\\)\\(\\*\\* .*\\)"))
 286          ;; Virtual indentation will add the warning face on the first
 287          ;; star.  Thus, in that case, only hide it.
 288          (start-face (if (and (bound-and-true-p org-indent-mode)
 289                               (> org-indent-indentation-per-level 1))
 290                          'org-hide
 291                        'org-warning)))
 292     (while (re-search-forward re limit t)
 293       (if org-inlinetask-show-first-star
 294           (add-text-properties (match-beginning 1) (match-end 1)
 295                                `(face ,start-face font-lock-fontified t)))
 296       (add-text-properties (match-beginning
 297                             (if org-inlinetask-show-first-star 2 1))
 298                            (match-end 2)
 299                            '(face org-hide font-lock-fontified t))
 300       (add-text-properties (match-beginning 3) (match-end 3)
 301                            '(face org-inlinetask font-lock-fontified t)))))
 302
 303 (defun org-inlinetask-toggle-visibility ()
 304   "Toggle visibility of inline task at point."
 305   (let ((end (save-excursion
 306                (org-inlinetask-goto-end)
 307                (if (bolp) (1- (point)) (point))))
 308         (start (save-excursion
 309                  (org-inlinetask-goto-beginning)
 310                  (point-at-eol))))
 311     (cond
 312      ;; Nothing to show/hide.
 313      ((= end start))
 314      ;; Inlinetask was folded: expand it.
 315      ((eq (get-char-property (1+ start) 'invisible) 'outline)
 316       (outline-flag-region start end nil)
 317       (org-cycle-hide-drawers 'children))
 318      (t (outline-flag-region start end t)))))
 319
 320 (defun org-inlinetask-hide-tasks (state)
 321   "Hide inline tasks in buffer when STATE is `contents' or `children'.
 322 This function is meant to be used in `org-cycle-hook'."
 323   (pcase state
 324     (`contents
 325      (let ((regexp (org-inlinetask-outline-regexp)))
 326        (save-excursion
 327          (goto-char (point-min))
 328          (while (re-search-forward regexp nil t)
 329            (org-inlinetask-toggle-visibility)
 330            (org-inlinetask-goto-end)))))
 331     (`children
 332      (save-excursion
 333        (while (and (outline-next-heading) (org-inlinetask-at-task-p))
 334          (org-inlinetask-toggle-visibility)
 335          (org-inlinetask-goto-end))))))
 336
 337 (defun org-inlinetask-remove-END-maybe ()
 338   "Remove an END line when present."
 339   (when (looking-at (format "\\([ \t]*\n\\)*\\*\\{%d,\\}[ \t]+END[ \t]*$"
 340                             org-inlinetask-min-level))
 341     (replace-match "")))
 342
 343 (add-hook 'org-font-lock-hook 'org-inlinetask-fontify)
 344 (add-hook 'org-cycle-hook 'org-inlinetask-hide-tasks)
 345
 346 (provide 'org-inlinetask)
 347
 348 ;;; org-inlinetask.el ends here