lisp/ob-python.el

   1 ;;; ob-python.el --- Babel Functions for Python      -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31
  32 (declare-function org-remove-indentation "org" )
  33 (declare-function org-trim "org" (s &optional keep-lead))
  34 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  35 (declare-function py-toggle-shells "ext:python-mode" (arg))
  36 (declare-function run-python "ext:python" (&optional cmd dedicated show))
  37
  38 (defvar org-babel-tangle-lang-exts)
  39 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  40
  41 (defvar org-babel-default-header-args:python '())
  42
  43 (defcustom org-babel-python-command "python"
  44   "Name of the command for executing Python code."
  45   :version "24.4"
  46   :package-version '(Org . "8.0")
  47   :group 'org-babel
  48   :type 'string)
  49
  50 (defcustom org-babel-python-mode
  51   (if (featurep 'python-mode) 'python-mode 'python)
  52   "Preferred python mode for use in running python interactively.
  53 This will typically be either `python' or `python-mode'."
  54   :group 'org-babel
  55   :version "24.4"
  56   :package-version '(Org . "8.0")
  57   :type 'symbol)
  58
  59 (defcustom org-babel-python-hline-to "None"
  60   "Replace hlines in incoming tables with this when translating to python."
  61   :group 'org-babel
  62   :version "24.4"
  63   :package-version '(Org . "8.0")
  64   :type 'string)
  65
  66 (defcustom org-babel-python-None-to 'hline
  67   "Replace `None' in python tables with this before returning."
  68   :group 'org-babel
  69   :version "24.4"
  70   :package-version '(Org . "8.0")
  71   :type 'symbol)
  72
  73 (defun org-babel-execute:python (body params)
  74   "Execute a block of Python code with Babel.
  75 This function is called by `org-babel-execute-src-block'."
  76   (let* ((session (org-babel-python-initiate-session
  77                    (cdr (assq :session params))))
  78          (result-params (cdr (assq :result-params params)))
  79          (result-type (cdr (assq :result-type params)))
  80          (return-val (when (and (eq result-type 'value) (not session))
  81                        (cdr (assq :return params))))
  82          (preamble (cdr (assq :preamble params)))
  83          (org-babel-python-command
  84           (or (cdr (assq :python params)) org-babel-python-command))
  85          (full-body
  86           (org-babel-expand-body:generic
  87            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  88            params (org-babel-variable-assignments:python params)))
  89          (result (org-babel-python-evaluate
  90                   session full-body result-type result-params preamble)))
  91     (org-babel-reassemble-table
  92      result
  93      (org-babel-pick-name (cdr (assq :colname-names params))
  94                           (cdr (assq :colnames params)))
  95      (org-babel-pick-name (cdr (assq :rowname-names params))
  96                           (cdr (assq :rownames params))))))
  97
  98 (defun org-babel-prep-session:python (session params)
  99   "Prepare SESSION according to the header arguments in PARAMS.
 100 VARS contains resolved variable references"
 101   (let* ((session (org-babel-python-initiate-session session))
 102          (var-lines
 103           (org-babel-variable-assignments:python params)))
 104     (org-babel-comint-in-buffer session
 105       (mapc (lambda (var)
 106               (end-of-line 1) (insert var) (comint-send-input)
 107               (org-babel-comint-wait-for-output session)) var-lines))
 108     session))
 109
 110 (defun org-babel-load-session:python (session body params)
 111   "Load BODY into SESSION."
 112   (save-window-excursion
 113     (let ((buffer (org-babel-prep-session:python session params)))
 114       (with-current-buffer buffer
 115         (goto-char (process-mark (get-buffer-process (current-buffer))))
 116         (insert (org-babel-chomp body)))
 117       buffer)))
 118
 119 ;; helper functions
 120
 121 (defun org-babel-variable-assignments:python (params)
 122   "Return a list of Python statements assigning the block's variables."
 123   (mapcar
 124    (lambda (pair)
 125      (format "%s=%s"
 126              (car pair)
 127              (org-babel-python-var-to-python (cdr pair))))
 128    (org-babel--get-vars params)))
 129
 130 (defun org-babel-python-var-to-python (var)
 131   "Convert an elisp value to a python variable.
 132 Convert an elisp value, VAR, into a string of python source code
 133 specifying a variable of the same value."
 134   (if (listp var)
 135       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 136     (if (eq var 'hline)
 137         org-babel-python-hline-to
 138       (format
 139        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 140        (if (stringp var) (substring-no-properties var) var)))))
 141
 142 (defun org-babel-python-table-or-string (results)
 143   "Convert RESULTS into an appropriate elisp value.
 144 If the results look like a list or tuple, then convert them into an
 145 Emacs-lisp table, otherwise return the results as a string."
 146   (let ((res (org-babel-script-escape results)))
 147     (if (listp res)
 148         (mapcar (lambda (el) (if (eq el 'None)
 149                             org-babel-python-None-to el))
 150                 res)
 151       res)))
 152
 153 (defvar org-babel-python-buffers '((:default . "*Python*")))
 154
 155 (defun org-babel-python-session-buffer (session)
 156   "Return the buffer associated with SESSION."
 157   (cdr (assoc session org-babel-python-buffers)))
 158
 159 (defun org-babel-python-with-earmuffs (session)
 160   (let ((name (if (stringp session) session (format "%s" session))))
 161     (if (and (string= "*" (substring name 0 1))
 162              (string= "*" (substring name (- (length name) 1))))
 163         name
 164       (format "*%s*" name))))
 165
 166 (defun org-babel-python-without-earmuffs (session)
 167   (let ((name (if (stringp session) session (format "%s" session))))
 168     (if (and (string= "*" (substring name 0 1))
 169              (string= "*" (substring name (- (length name) 1))))
 170         (substring name 1 (- (length name) 1))
 171       name)))
 172
 173 (defvar py-default-interpreter)
 174 (defvar py-which-bufname)
 175 (defvar python-shell-buffer-name)
 176 (defun org-babel-python-initiate-session-by-key (&optional session)
 177   "Initiate a python session.
 178 If there is not a current inferior-process-buffer in SESSION
 179 then create.  Return the initialized session."
 180   (require org-babel-python-mode)
 181   (save-window-excursion
 182     (let* ((session (if session (intern session) :default))
 183            (python-buffer (org-babel-python-session-buffer session))
 184            (cmd (if (member system-type '(cygwin windows-nt ms-dos))
 185                     (concat org-babel-python-command " -i")
 186                   org-babel-python-command)))
 187       (cond
 188        ((and (eq 'python org-babel-python-mode)
 189              (fboundp 'run-python)) ; python.el
 190         (if (not (version< "24.1" emacs-version))
 191             (run-python cmd)
 192           (unless python-buffer
 193             (setq python-buffer (org-babel-python-with-earmuffs session)))
 194           (let ((python-shell-buffer-name
 195                  (org-babel-python-without-earmuffs python-buffer)))
 196             (run-python cmd))))
 197        ((and (eq 'python-mode org-babel-python-mode)
 198              (fboundp 'py-shell)) ; python-mode.el
 199         ;; Make sure that py-which-bufname is initialized, as otherwise
 200         ;; it will be overwritten the first time a Python buffer is
 201         ;; created.
 202         (py-toggle-shells py-default-interpreter)
 203         ;; `py-shell' creates a buffer whose name is the value of
 204         ;; `py-which-bufname' with '*'s at the beginning and end
 205         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 206                             (replace-regexp-in-string ;; zap surrounding *
 207                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 208                           (concat "Python-" (symbol-name session))))
 209                (py-which-bufname bufname))
 210           (py-shell)
 211           (setq python-buffer (org-babel-python-with-earmuffs bufname))))
 212        (t
 213         (error "No function available for running an inferior Python")))
 214       (setq org-babel-python-buffers
 215             (cons (cons session python-buffer)
 216                   (assq-delete-all session org-babel-python-buffers)))
 217       session)))
 218
 219 (defun org-babel-python-initiate-session (&optional session _params)
 220   "Create a session named SESSION according to PARAMS."
 221   (unless (string= session "none")
 222     (org-babel-python-session-buffer
 223      (org-babel-python-initiate-session-by-key session))))
 224
 225 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 226   "A string to indicate that evaluation has completed.")
 227 (defconst org-babel-python-wrapper-method
 228   "
 229 def main():
 230 %s
 231
 232 open('%s', 'w').write( str(main()) )")
 233 (defconst org-babel-python-pp-wrapper-method
 234   "
 235 import pprint
 236 def main():
 237 %s
 238
 239 open('%s', 'w').write( pprint.pformat(main()) )")
 240
 241 (defun org-babel-python-evaluate
 242   (session body &optional result-type result-params preamble)
 243   "Evaluate BODY as Python code."
 244   (if session
 245       (org-babel-python-evaluate-session
 246        session body result-type result-params)
 247     (org-babel-python-evaluate-external-process
 248      body result-type result-params preamble)))
 249
 250 (defun org-babel-python-evaluate-external-process
 251     (body &optional result-type result-params preamble)
 252   "Evaluate BODY in external python process.
 253 If RESULT-TYPE equals `output' then return standard output as a
 254 string.  If RESULT-TYPE equals `value' then return the value of the
 255 last statement in BODY, as elisp."
 256   (let ((raw
 257          (pcase result-type
 258            (`output (org-babel-eval org-babel-python-command
 259                                     (concat (if preamble (concat preamble "\n"))
 260                                             body)))
 261            (`value (let ((tmp-file (org-babel-temp-file "python-")))
 262                      (org-babel-eval
 263                       org-babel-python-command
 264                       (concat
 265                        (if preamble (concat preamble "\n") "")
 266                        (format
 267                         (if (member "pp" result-params)
 268                             org-babel-python-pp-wrapper-method
 269                           org-babel-python-wrapper-method)
 270                         (mapconcat
 271                          (lambda (line) (format "\t%s" line))
 272                          (split-string (org-remove-indentation (org-trim body))
 273                                        "[\r\n]")
 274                          "\n")
 275                         (org-babel-process-file-name tmp-file 'noquote))))
 276                      (org-babel-eval-read-file tmp-file))))))
 277     (org-babel-result-cond result-params
 278       raw
 279       (org-babel-python-table-or-string (org-trim raw)))))
 280
 281 (defun org-babel-python-evaluate-session
 282     (session body &optional result-type result-params)
 283   "Pass BODY to the Python process in SESSION.
 284 If RESULT-TYPE equals `output' then return standard output as a
 285 string.  If RESULT-TYPE equals `value' then return the value of the
 286 last statement in BODY, as elisp."
 287   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 288          (dump-last-value
 289           (lambda
 290             (tmp-file pp)
 291             (mapc
 292              (lambda (statement) (insert statement) (funcall send-wait))
 293              (if pp
 294                  (list
 295                   "import pprint"
 296                   (format "open('%s', 'w').write(pprint.pformat(_))"
 297                           (org-babel-process-file-name tmp-file 'noquote)))
 298                (list (format "open('%s', 'w').write(str(_))"
 299                              (org-babel-process-file-name tmp-file
 300                                                           'noquote)))))))
 301          (input-body (lambda (body)
 302                        (mapc (lambda (line) (insert line) (funcall send-wait))
 303                              (split-string body "[\r\n]"))
 304                        (funcall send-wait)))
 305          (results
 306           (pcase result-type
 307             (`output
 308              (mapconcat
 309               #'org-trim
 310               (butlast
 311                (org-babel-comint-with-output
 312                    (session org-babel-python-eoe-indicator t body)
 313                  (funcall input-body body)
 314                  (funcall send-wait) (funcall send-wait)
 315                  (insert org-babel-python-eoe-indicator)
 316                  (funcall send-wait))
 317                2) "\n"))
 318             (`value
 319              (let ((tmp-file (org-babel-temp-file "python-")))
 320                (org-babel-comint-with-output
 321                    (session org-babel-python-eoe-indicator nil body)
 322                  (let ((comint-process-echoes nil))
 323                    (funcall input-body body)
 324                    (funcall dump-last-value tmp-file
 325                             (member "pp" result-params))
 326                    (funcall send-wait) (funcall send-wait)
 327                    (insert org-babel-python-eoe-indicator)
 328                    (funcall send-wait)))
 329                (org-babel-eval-read-file tmp-file))))))
 330     (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 331       (org-babel-result-cond result-params
 332         results
 333         (org-babel-python-table-or-string results)))))
 334
 335 (defun org-babel-python-read-string (string)
 336   "Strip \\='s from around Python string."
 337   (if (and (string-prefix-p "'" string)
 338            (string-suffix-p "'" string))
 339       (substring string 1 -1)
 340     string))
 341
 342 (provide 'ob-python)
 343
 344
 345
 346 ;;; ob-python.el ends here