lisp/org-latex.el

   1 ;;; org-latex.el --- LaTeX exporter for org-mode
   2 ;;
   3 ;; Copyright (C) 2007, 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-latex.el
   7 ;; Version: 6.27
   8 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   9 ;; Maintainer: Carsten Dominik <carsten.dominik AT gmail DOT com>
  10 ;; Keywords: org, wp, tex
  11 ;; Description: Converts an org-mode buffer into LaTeX
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29 ;;
  30 ;; This library implements a LaTeX exporter for org-mode.
  31 ;;
  32 ;; It is part of Org and will be autoloaded
  33 ;;
  34 ;; The interactive functions are similar to those of the HTML exporter:
  35 ;;
  36 ;; M-x `org-export-as-latex'
  37 ;; M-x `org-export-as-pdf'
  38 ;; M-x `org-export-as-pdf-and-open'
  39 ;; M-x `org-export-as-latex-batch'
  40 ;; M-x `org-export-as-latex-to-buffer'
  41 ;; M-x `org-export-region-as-latex'
  42 ;; M-x `org-replace-region-by-latex'
  43 ;;
  44 ;;; Code:
  45
  46 (eval-when-compile
  47   (require 'cl))
  48
  49 (require 'footnote)
  50 (require 'org)
  51 (require 'org-exp)
  52
  53 ;;; Variables:
  54 (defvar org-export-latex-class nil)
  55 (defvar org-export-latex-header nil)
  56 (defvar org-export-latex-append-header nil)
  57 (defvar org-export-latex-options-plist nil)
  58 (defvar org-export-latex-todo-keywords-1 nil)
  59 (defvar org-export-latex-complex-heading-re nil)
  60 (defvar org-export-latex-not-done-keywords nil)
  61 (defvar org-export-latex-done-keywords nil)
  62 (defvar org-export-latex-display-custom-times nil)
  63 (defvar org-export-latex-all-targets-re nil)
  64 (defvar org-export-latex-add-level 0)
  65 (defvar org-export-latex-sectioning "")
  66 (defvar org-export-latex-sectioning-depth 0)
  67 (defvar org-export-latex-special-keyword-regexp
  68   (concat "\\<\\(" org-scheduled-string "\\|"
  69           org-deadline-string "\\|"
  70           org-closed-string"\\)")
  71   "Regexp matching special time planning keywords plus the time after it.")
  72
  73 (defvar latexp)    ; dynamically scoped from org.el
  74 (defvar re-quote)  ; dynamically scoped from org.el
  75 (defvar commentsp) ; dynamically scoped from org.el
  76
  77 ;;; User variables:
  78
  79 (defgroup org-export-latex nil
  80   "Options for exporting Org-mode files to LaTeX."
  81   :tag "Org Export LaTeX"
  82   :group 'org-export)
  83
  84 (defcustom org-export-latex-default-class "article"
  85   "The default LaTeX class."
  86   :group 'org-export-latex
  87   :type '(string :tag "LaTeX class"))
  88
  89 (defcustom org-export-latex-classes
  90   '(("article"
  91      "\\documentclass[11pt]{article}
  92 \\usepackage[utf8]{inputenc}
  93 \\usepackage[T1]{fontenc}
  94 \\usepackage{graphicx}
  95 \\usepackage{longtable}
  96 \\usepackage{hyperref}"
  97      ("\\section{%s}" . "\\section*{%s}")
  98      ("\\subsection{%s}" . "\\subsection*{%s}")
  99      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
 100      ("\\paragraph{%s}" . "\\paragraph*{%s}")
 101      ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 102     ("report"
 103      "\\documentclass[11pt]{report}
 104 \\usepackage[utf8]{inputenc}
 105 \\usepackage[T1]{fontenc}
 106 \\usepackage{graphicx}
 107 \\usepackage{longtable}
 108 \\usepackage{hyperref}"
 109      ("\\part{%s}" . "\\part*{%s}")
 110      ("\\chapter{%s}" . "\\chapter*{%s}")
 111      ("\\section{%s}" . "\\section*{%s}")
 112      ("\\subsection{%s}" . "\\subsection*{%s}")
 113      ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))
 114     ("book"
 115      "\\documentclass[11pt]{book}
 116 \\usepackage[utf8]{inputenc}
 117 \\usepackage[T1]{fontenc}
 118 \\usepackage{graphicx}
 119 \\usepackage{longtable}
 120 \\usepackage{hyperref}"
 121      ("\\part{%s}" . "\\part*{%s}")
 122      ("\\chapter{%s}" . "\\chapter*{%s}")
 123      ("\\section{%s}" . "\\section*{%s}")
 124      ("\\subsection{%s}" . "\\subsection*{%s}")
 125      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")))
 126   "Alist of LaTeX classes and associated header and structure.
 127 If #+LaTeX_CLASS is set in the buffer, use its value and the
 128 associated information.  Here is the structure of each cell:
 129
 130   \(class-name
 131     header-string
 132     (numbered-section . unnumbered-section\)
 133     ...\)
 134
 135 A %s formatter is mandatory in each section string and will be
 136 replaced by the title of the section.
 137
 138 Instead of a cons cell (numbered . unnumbered), you can also provide a list
 139 of 2-4 elements,
 140
 141   (numbered-open numbered-close)
 142
 143 or
 144
 145   (numbered-open numbered-close unnumbered-open unnumbered-close)
 146
 147 providing opening and closing strings for an environment that should
 148 represent the document section.  The opening clause should have a %s
 149 to represent the section title."
 150   :group 'org-export-latex
 151   :type '(repeat
 152           (list (string :tag "LaTeX class")
 153                 (string :tag "LaTeX header")
 154                 (repeat :tag "Levels" :inline t
 155                         (choice
 156                          (cons :tag "Heading"
 157                                (string :tag "numbered")
 158                                (string :tag "unnumbered)"))
 159                          (list :tag "Environment"
 160                                (string :tag "Opening (numbered)  ")
 161                                (string :tag "Closing (numbered)  ")
 162                                (string :tag "Opening (unnumbered)")
 163                                (string :tag "Closing (unnumbered)")))))))
 164
 165 (defcustom org-export-latex-emphasis-alist
 166   '(("*" "\\textbf{%s}" nil)
 167     ("/" "\\emph{%s}" nil)
 168     ("_" "\\underline{%s}" nil)
 169     ("+" "\\texttt{%s}" nil)
 170     ("=" "\\verb" t)
 171     ("~" "\\verb" t))
 172   "Alist of LaTeX expressions to convert emphasis fontifiers.
 173 Each element of the list is a list of three elements.
 174 The first element is the character used as a marker for fontification.
 175 The second element is a formatting string to wrap fontified text with.
 176 If it is \"\\verb\", Org will automatically select a deimiter
 177 character that is not in the string.
 178 The third element decides whether to protect converted text from other
 179 conversions."
 180   :group 'org-export-latex
 181   :type 'alist)
 182
 183 (defcustom org-export-latex-title-command "\\maketitle"
 184   "The command used to insert the title just after \\begin{document}.
 185 If this string contains the formatting specification \"%s\" then
 186 it will be used as a formatting string, passing the title as an
 187 argument."
 188   :group 'org-export-latex
 189   :type 'string)
 190
 191 (defcustom org-export-latex-import-inbuffer-stuff nil
 192   "Non-nil means define TeX macros for Org's inbuffer definitions.
 193 For example \orgTITLE for #+TITLE."
 194   :group 'org-export-latex
 195   :type 'boolean)
 196
 197 (defcustom org-export-latex-date-format
 198   "%d %B %Y"
 199   "Format string for \\date{...}."
 200   :group 'org-export-latex
 201   :type 'string)
 202
 203 (defcustom org-export-latex-todo-keyword-markup "\\textbf{%s}"
 204   "Markup for TODO keywords, as a printf format.
 205 This can be a single format for all keywords, a cons cell with separate
 206 formats for not-done and done states, or an association list with setup
 207 for individual keywords.  If a keyword shows up for which there is no
 208 markup defined, the first one in the association list will be used."
 209   :group 'org-export-latex
 210   :type '(choice
 211           (string :tag "Default")
 212           (cons :tag "Distinguish undone and done"
 213                 (string :tag "Not-DONE states")
 214                 (string :tag "DONE states"))
 215           (repeat :tag "Per keyword markup"
 216                   (cons
 217                    (string :tag "Keyword")
 218                    (string :tag "Markup")))))
 219
 220 (defcustom org-export-latex-timestamp-markup "\\textit{%s}"
 221   "A printf format string to be applied to time stamps."
 222   :group 'org-export-latex
 223   :type 'string)
 224
 225 (defcustom org-export-latex-timestamp-keyword-markup "\\texttt{%s}"
 226   "A printf format string to be applied to time stamps."
 227   :group 'org-export-latex
 228   :type 'string)
 229
 230 (defcustom org-export-latex-tables-verbatim nil
 231   "When non-nil, tables are exported verbatim."
 232   :group 'org-export-latex
 233   :type 'boolean)
 234
 235 (defcustom org-export-latex-tables-centered t
 236   "When non-nil, tables are exported in a center environment."
 237   :group 'org-export-latex
 238   :type 'boolean)
 239
 240 (defcustom org-export-latex-tables-column-borders nil
 241   "When non-nil, grouping columns can cause outer vertical lines in tables.
 242 When nil, grouping causes only separation lines between groups."
 243   :group 'org-export-latex
 244   :type 'boolean)
 245
 246 (defcustom org-export-latex-packages-alist nil
 247   "Alist of packages to be inserted in the header.
 248 Each cell is of the forma \( \"option\" . \"package\" \)."
 249   :group 'org-export-latex
 250   :type 'alist)
 251
 252 (defcustom org-export-latex-low-levels 'itemize
 253   "How to convert sections below the current level of sectioning.
 254 This is specified by the `org-export-headline-levels' option or the
 255 value of \"H:\" in Org's #+OPTION line.
 256
 257 This can be either nil (skip the sections), `description', `itemize',
 258 or `enumerate' (convert the sections as the corresponding list type), or
 259 a string to be used instead of \\section{%s}.  In this latter case,
 260 the %s stands here for the inserted headline and is mandatory."
 261   :group 'org-export-latex
 262   :type '(choice (const :tag "Ignore" nil)
 263                  (const :tag "Convert as descriptive list" description)
 264                  (const :tag "Convert as itemized list" itemize)
 265                  (const :tag "Convert as enumerated list" enumerate)
 266                  (string :tag "Use a section string" :value "\\subparagraph{%s}")))
 267
 268 (defcustom org-export-latex-list-parameters
 269   '(:cbon "\\texttt{[X]}" :cboff "\\texttt{[ ]}")
 270   "Parameters for the LaTeX list exporter.
 271 These parameters will be passed on to `org-list-to-latex', which in turn
 272 will pass them (combined with the LaTeX default list parameters) to
 273 `org-list-to-generic'."
 274   :group 'org-export-latex
 275   :type 'plist)
 276
 277 (defcustom org-export-latex-remove-from-headlines
 278   '(:todo nil :priority nil :tags nil)
 279   "A plist of keywords to remove from headlines. OBSOLETE.
 280 Non-nil means remove this keyword type from the headline.
 281
 282 Don't remove the keys, just change their values.
 283
 284 Obsolete, this variable is no longer used.  Use the separate
 285 variables `org-export-with-todo-keywords', `org-export-with-priority',
 286 and `org-export-with-tags' instead."
 287   :type 'plist
 288   :group 'org-export-latex)
 289
 290 (defcustom org-export-latex-image-default-option "width=10em"
 291   "Default option for images."
 292   :group 'org-export-latex
 293   :type 'string)
 294
 295 (defcustom org-export-latex-inline-image-extensions
 296   '("pdf" "jpeg" "jpg" "png")
 297   "Extensions of image files that can be inlined into LaTeX.
 298 Note that this depends on the way the LaTeX file is processed.
 299 The default setting (pdf and jpg) assumes that pdflatex is doing the
 300 processing.  If you are using latex and dvips or something similar,
 301 only postscript files can be included."
 302   :group 'org-export-latex
 303   :type '(repeat (string :tag "Extension")))
 304
 305 (defcustom org-export-latex-coding-system nil
 306   "Coding system for the exported LaTex file."
 307   :group 'org-export-latex
 308   :type 'coding-system)
 309
 310 (defgroup org-export-pdf nil
 311   "Options for exporting Org-mode files to PDF, via LaTeX."
 312   :tag "Org Export LaTeX"
 313   :group 'org-export-latex
 314   :group 'org-export)
 315
 316 (defcustom org-latex-to-pdf-process
 317   '("pdflatex -interaction nonstopmode %s"
 318     "pdflatex -interaction nonstopmode %s")
 319   "Commands to process a LaTeX file to a PDF file.
 320 This is a list of strings, each of them will be given to the shell
 321 as a command.  %s in the command will be replaced by the full file name, %b
 322 by the file base name (i.e. without extension).
 323 The reason why this is a list is that it usually takes several runs of
 324 pdflatex, maybe mixed with a call to bibtex.  Org does not have a clever
 325 mechanism to detect whihc of these commands have to be run to get to a stable
 326 result, and it also does not do any error checking.
 327
 328 Alternatively, this may be a Lisp function that does the processing, so you
 329 could use this to apply the machinery of AUCTeX or the Emacs LaTeX mode.
 330 THis function should accept the file name as its single argument."
 331   :group 'org-export-latex
 332   :type '(choice (repeat :tag "Shell command sequence"
 333                   (string :tag "Shell command"))
 334                  (function)))
 335
 336 (defcustom org-export-pdf-remove-logfiles t
 337   "Non-nil means, remove the logfiles produced by PDF production.
 338 These are the .aux, .log, .out, and .toc files."
 339   :group 'org-export-pdf
 340   :type 'boolean)
 341
 342 ;;; Hooks
 343
 344 (defvar org-export-latex-after-blockquotes-hook nil
 345   "Hook run during LaTeX export, after blockquote, verse, center are done.")
 346
 347 ;;; Autoload functions:
 348
 349 ;;;###autoload
 350 (defun org-export-as-latex-batch ()
 351   "Call `org-export-as-latex', may be used in batch processing.
 352 For example:
 353
 354 emacs   --batch
 355         --load=$HOME/lib/emacs/org.el
 356         --eval \"(setq org-export-headline-levels 2)\"
 357         --visit=MyFile --funcall org-export-as-latex-batch"
 358   (org-export-as-latex org-export-headline-levels 'hidden))
 359
 360 ;;;###autoload
 361 (defun org-export-as-latex-to-buffer (arg)
 362   "Call `org-export-as-latex` with output to a temporary buffer.
 363 No file is created.  The prefix ARG is passed through to `org-export-as-latex'."
 364   (interactive "P")
 365   (org-export-as-latex arg nil nil "*Org LaTeX Export*")
 366   (when org-export-show-temporary-export-buffer
 367     (switch-to-buffer-other-window "*Org LaTeX Export*")))
 368
 369 ;;;###autoload
 370 (defun org-replace-region-by-latex (beg end)
 371   "Replace the region from BEG to END with its LaTeX export.
 372 It assumes the region has `org-mode' syntax, and then convert it to
 373 LaTeX.  This can be used in any buffer.  For example, you could
 374 write an itemized list in `org-mode' syntax in an LaTeX buffer and
 375 then use this command to convert it."
 376   (interactive "r")
 377   (let (reg latex buf)
 378     (save-window-excursion
 379       (if (org-mode-p)
 380           (setq latex (org-export-region-as-latex
 381                        beg end t 'string))
 382         (setq reg (buffer-substring beg end)
 383               buf (get-buffer-create "*Org tmp*"))
 384         (save-excursion
 385           (set-buffer buf)
 386           (erase-buffer)
 387           (insert reg)
 388           (org-mode)
 389           (setq latex (org-export-region-as-latex
 390                        (point-min) (point-max) t 'string)))
 391         (kill-buffer buf)))
 392     (delete-region beg end)
 393     (insert latex)))
 394
 395 ;;;###autoload
 396 (defun org-export-region-as-latex (beg end &optional body-only buffer)
 397   "Convert region from BEG to END in `org-mode' buffer to LaTeX.
 398 If prefix arg BODY-ONLY is set, omit file header, footer, and table of
 399 contents, and only produce the region of converted text, useful for
 400 cut-and-paste operations.
 401 If BUFFER is a buffer or a string, use/create that buffer as a target
 402 of the converted LaTeX.  If BUFFER is the symbol `string', return the
 403 produced LaTeX as a string and leave no buffer behind.  For example,
 404 a Lisp program could call this function in the following way:
 405
 406   (setq latex (org-export-region-as-latex beg end t 'string))
 407
 408 When called interactively, the output buffer is selected, and shown
 409 in a window.  A non-interactive call will only return the buffer."
 410   (interactive "r\nP")
 411   (when (interactive-p)
 412     (setq buffer "*Org LaTeX Export*"))
 413   (let ((transient-mark-mode t) (zmacs-regions t)
 414         ext-plist rtn)
 415     (setq ext-plist (plist-put ext-plist :ignore-subree-p t))
 416     (goto-char end)
 417     (set-mark (point)) ;; to activate the region
 418     (goto-char beg)
 419     (setq rtn (org-export-as-latex
 420                nil nil ext-plist
 421                buffer body-only))
 422     (if (fboundp 'deactivate-mark) (deactivate-mark))
 423     (if (and (interactive-p) (bufferp rtn))
 424         (switch-to-buffer-other-window rtn)
 425       rtn)))
 426
 427 ;;;###autoload
 428 (defun org-export-as-latex (arg &optional hidden ext-plist
 429                                 to-buffer body-only pub-dir)
 430   "Export current buffer to a LaTeX file.
 431 If there is an active region, export only the region.  The prefix
 432 ARG specifies how many levels of the outline should become
 433 headlines.  The default is 3.  Lower levels will be exported
 434 depending on `org-export-latex-low-levels'.  The default is to
 435 convert them as description lists.
 436 HIDDEN is obsolete and does nothing.
 437 EXT-PLIST is a property list with
 438 external parameters overriding org-mode's default settings, but
 439 still inferior to file-local settings.  When TO-BUFFER is
 440 non-nil, create a buffer with that name and export to that
 441 buffer.  If TO-BUFFER is the symbol `string', don't leave any
 442 buffer behind but just return the resulting LaTeX as a string.
 443 When BODY-ONLY is set, don't produce the file header and footer,
 444 simply return the content of \begin{document}...\end{document},
 445 without even the \begin{document} and \end{document} commands.
 446 when PUB-DIR is set, use this as the publishing directory."
 447   (interactive "P")
 448   ;; Make sure we have a file name when we need it.
 449   (when (and (not (or to-buffer body-only))
 450              (not buffer-file-name))
 451     (if (buffer-base-buffer)
 452         (org-set-local 'buffer-file-name
 453                        (with-current-buffer (buffer-base-buffer)
 454                          buffer-file-name))
 455       (error "Need a file name to be able to export")))
 456
 457   (message "Exporting to LaTeX...")
 458   (org-unmodified
 459    (remove-text-properties (point-min) (point-max)
 460                            '(:org-license-to-kill nil)))
 461   (org-update-radio-target-regexp)
 462   (org-export-latex-set-initial-vars ext-plist arg)
 463   (let* ((wcf (current-window-configuration))
 464          (opt-plist org-export-latex-options-plist)
 465          (region-p (org-region-active-p))
 466          (rbeg (and region-p (region-beginning)))
 467          (rend (and region-p (region-end)))
 468          (subtree-p
 469           (if (plist-get opt-plist :ignore-subree-p)
 470               nil
 471             (when region-p
 472               (save-excursion
 473                 (goto-char rbeg)
 474                 (and (org-at-heading-p)
 475                      (>= (org-end-of-subtree t t) rend))))))
 476          (opt-plist (setq org-export-opt-plist
 477                           (if subtree-p
 478                               (org-export-add-subtree-options opt-plist rbeg)
 479                             opt-plist)))
 480          ;; Make sure the variable contains the updated values.
 481          (org-export-latex-options-plist opt-plist)
 482          (title (or (and subtree-p (org-export-get-title-from-subtree))
 483                     (plist-get opt-plist :title)
 484                     (and (not
 485                           (plist-get opt-plist :skip-before-1st-heading))
 486                          (org-export-grab-title-from-buffer))
 487                     (file-name-sans-extension
 488                      (file-name-nondirectory buffer-file-name))))
 489          (filename (concat (file-name-as-directory
 490                             (or pub-dir
 491                                 (org-export-directory :LaTeX ext-plist)))
 492                            (file-name-sans-extension
 493                             (or (and subtree-p
 494                                      (org-entry-get rbeg "EXPORT_FILE_NAME" t))
 495                                 (file-name-nondirectory ;sans-extension
 496                                  buffer-file-name)))
 497                            ".tex"))
 498          (filename (if (equal (file-truename filename)
 499                               (file-truename buffer-file-name))
 500                        (concat filename ".tex")
 501                      filename))
 502          (buffer (if to-buffer
 503                      (cond
 504                       ((eq to-buffer 'string) (get-buffer-create
 505                                                "*Org LaTeX Export*"))
 506                       (t (get-buffer-create to-buffer)))
 507                    (find-file-noselect filename)))
 508          (odd org-odd-levels-only)
 509          (header (org-export-latex-make-header title opt-plist))
 510          (skip (cond (subtree-p nil)
 511                      (region-p nil)
 512                      (t (plist-get opt-plist :skip-before-1st-heading))))
 513          (text (plist-get opt-plist :text))
 514          (org-export-preprocess-hook
 515           (cons
 516            `(lambda () (org-set-local 'org-complex-heading-regexp
 517                                       ,org-export-latex-complex-heading-re))
 518            org-export-preprocess-hook))
 519          (first-lines (if skip "" (org-export-latex-first-lines
 520                                    opt-plist
 521                                    (if subtree-p
 522                                        (save-excursion
 523                                          (goto-char rbeg)
 524                                          (point-at-bol 2))
 525                                      rbeg)
 526                                    (if region-p rend))))
 527          (coding-system (and (boundp 'buffer-file-coding-system)
 528                              buffer-file-coding-system))
 529          (coding-system-for-write (or org-export-latex-coding-system
 530                                       coding-system))
 531          (save-buffer-coding-system (or org-export-latex-coding-system
 532                                         coding-system))
 533          (region (buffer-substring
 534                   (if region-p (region-beginning) (point-min))
 535                   (if region-p (region-end) (point-max))))
 536          (string-for-export
 537           (org-export-preprocess-string
 538            region
 539            :emph-multiline t
 540            :for-LaTeX t
 541            :comments nil
 542            :tags (plist-get opt-plist :tags)
 543            :priority (plist-get opt-plist :priority)
 544            :footnotes (plist-get opt-plist :footnotes)
 545            :timestamps (plist-get opt-plist :timestamps)
 546            :todo-keywords (plist-get opt-plist :todo-keywords)
 547            :add-text (if (eq to-buffer 'string) nil text)
 548            :skip-before-1st-heading skip
 549            :select-tags (plist-get opt-plist :select-tags)
 550            :exclude-tags (plist-get opt-plist :exclude-tags)
 551            :LaTeX-fragments nil)))
 552
 553     (set-buffer buffer)
 554     (erase-buffer)
 555
 556     (and (fboundp 'set-buffer-file-coding-system)
 557          (set-buffer-file-coding-system coding-system-for-write))
 558
 559     ;; insert the header and initial document commands
 560     (unless (or (eq to-buffer 'string) body-only)
 561       (insert header))
 562
 563     ;; insert text found in #+TEXT
 564     (when (and text (not (eq to-buffer 'string)))
 565       (insert (org-export-latex-content
 566                text '(lists tables fixed-width keywords))
 567                "\n\n"))
 568
 569     ;; insert lines before the first headline
 570     (unless skip
 571       (insert first-lines))
 572
 573     ;; export the content of headlines
 574     (org-export-latex-global
 575      (with-temp-buffer
 576        (insert string-for-export)
 577        (goto-char (point-min))
 578        (when (re-search-forward "^\\(\\*+\\) " nil t)
 579          (let* ((asters (length (match-string 1)))
 580                 (level (if odd (- asters 2) (- asters 1))))
 581            (setq org-export-latex-add-level
 582                  (if odd (1- (/ (1+ asters) 2)) (1- asters)))
 583            (org-export-latex-parse-global level odd)))))
 584
 585     ;; finalization
 586     (unless body-only (insert "\n\\end{document}"))
 587     (or to-buffer (save-buffer))
 588     (goto-char (point-min))
 589     (or (org-export-push-to-kill-ring "LaTeX")
 590         (message "Exporting to LaTeX...done"))
 591     (prog1
 592         (if (eq to-buffer 'string)
 593             (prog1 (buffer-substring (point-min) (point-max))
 594               (kill-buffer (current-buffer)))
 595           (current-buffer))
 596       (set-window-configuration wcf))))
 597
 598 ;;;###autoload
 599 (defun org-export-as-pdf (arg &optional hidden ext-plist
 600                               to-buffer body-only pub-dir)
 601   "Export as LaTeX, then process through to PDF."
 602   (interactive "P")
 603   (message "Exporting to PDF...")
 604   (let* ((wconfig (current-window-configuration))
 605          (lbuf (org-export-as-latex arg hidden ext-plist
 606                                     to-buffer body-only pub-dir))
 607          (file (buffer-file-name lbuf))
 608          (base (file-name-sans-extension (buffer-file-name lbuf)))
 609          (pdffile (concat base ".pdf"))
 610          (cmds org-latex-to-pdf-process)
 611          (outbuf (get-buffer-create "*Org PDF LaTeX Output*"))
 612          (bibtex-p (with-current-buffer lbuf
 613                      (save-excursion
 614                        (goto-char (point-min))
 615                        (re-search-forward "\\\\bibliography{" nil t))))
 616          cmd)
 617     (with-current-buffer outbuf (erase-buffer))
 618     (and (file-exists-p pdffile) (delete-file pdffile))
 619     (message "Processing LaTeX file...")
 620     (if (and cmds (symbolp cmds))
 621         (funcall cmds file)
 622       (while cmds
 623         (setq cmd (pop cmds))
 624         (while (string-match "%b" cmd)
 625           (setq cmd (replace-match (shell-quote-argument base) t t cmd)))
 626         (while (string-match "%s" cmd)
 627           (setq cmd (replace-match (shell-quote-argument file) t t cmd)))
 628         (shell-command cmd outbuf outbuf)))
 629     (message "Processing LaTeX file...done")
 630     (if (not (file-exists-p pdffile))
 631         (error "PDF file was not produced")
 632       (set-window-configuration wconfig)
 633       (when org-export-pdf-remove-logfiles
 634         (dolist (ext '("aux" "log" "out" "toc"))
 635           (setq file (concat base "." ext))
 636           (and (file-exists-p file) (delete-file file))))
 637       (message "Exporting to PDF...done")
 638       pdffile)))
 639
 640 ;;;###autoload
 641 (defun org-export-as-pdf-and-open (arg)
 642   "Export as LaTeX, then process through to PDF, and open."
 643   (interactive "P")
 644   (let ((pdffile (org-export-as-pdf arg)))
 645     (if pdffile
 646         (org-open-file pdffile)
 647       (error "PDF file was not produced"))))
 648
 649 ;;; Parsing functions:
 650
 651 (defun org-export-latex-parse-global (level odd)
 652   "Parse the current buffer recursively, starting at LEVEL.
 653 If ODD is non-nil, assume the buffer only contains odd sections.
 654 Return a list reflecting the document structure."
 655   (save-excursion
 656     (goto-char (point-min))
 657     (let* ((cnt 0) output
 658            (depth org-export-latex-sectioning-depth))
 659       (while (re-search-forward
 660               (concat "^\\(\\(?:\\*\\)\\{"
 661                       (number-to-string (+ (if odd 2 1) level))
 662                       "\\}\\) \\(.*\\)$")
 663               ;; make sure that there is no upper heading
 664               (when (> level 0)
 665                 (save-excursion
 666                   (save-match-data
 667                     (re-search-forward
 668                      (concat "^\\(\\(?:\\*\\)\\{"
 669                              (number-to-string level)
 670                              "\\}\\) \\(.*\\)$") nil t)))) t)
 671         (setq cnt (1+ cnt))
 672         (let* ((pos (match-beginning 0))
 673                (heading (match-string 2))
 674                (nlevel (if odd (/ (+ 3 level) 2) (1+ level))))
 675           (save-excursion
 676             (narrow-to-region
 677              (point)
 678              (save-match-data
 679                (if (re-search-forward
 680                     (concat "^\\(\\(?:\\*\\)\\{"
 681                             (number-to-string (+ (if odd 2 1) level))
 682                             "\\}\\) \\(.*\\)$") nil t)
 683                    (match-beginning 0)
 684                  (point-max))))
 685             (goto-char (point-min))
 686             (setq output
 687                   (append output
 688                           (list
 689                            (list
 690                             `(pos . ,pos)
 691                             `(level . ,nlevel)
 692                             `(occur . ,cnt)
 693                             `(heading . ,heading)
 694                             `(content . ,(org-export-latex-parse-content))
 695                             `(subcontent . ,(org-export-latex-parse-subcontent
 696                                              level odd)))))))
 697           (widen)))
 698       (list output))))
 699
 700 (defun org-export-latex-parse-content ()
 701   "Extract the content of a section."
 702   (let ((beg (point))
 703         (end (if (re-search-forward "^\\(\\*\\)+ .*$" nil t)
 704                  (progn (beginning-of-line) (point))
 705                (point-max))))
 706     (buffer-substring beg end)))
 707
 708 (defun org-export-latex-parse-subcontent (level odd)
 709   "Extract the subcontent of a section at LEVEL.
 710 If ODD Is non-nil, assume subcontent only contains odd sections."
 711   (if (not (re-search-forward
 712             (concat "^\\(\\(?:\\*\\)\\{"
 713                     (number-to-string (+ (if odd 4 2) level))
 714                     "\\}\\) \\(.*\\)$")
 715             nil t))
 716       nil ; subcontent is nil
 717     (org-export-latex-parse-global (+ (if odd 2 1) level) odd)))
 718
 719 ;;; Rendering functions:
 720 (defun org-export-latex-global (content)
 721   "Export CONTENT to LaTeX.
 722 CONTENT is an element of the list produced by
 723 `org-export-latex-parse-global'."
 724   (if (eq (car content) 'subcontent)
 725       (mapc 'org-export-latex-sub (cdr content))
 726     (org-export-latex-sub (car content))))
 727
 728 (defun org-export-latex-sub (subcontent)
 729   "Export the list SUBCONTENT to LaTeX.
 730 SUBCONTENT is an alist containing information about the headline
 731 and its content."
 732   (let ((num (plist-get org-export-latex-options-plist :section-numbers)))
 733     (mapc (lambda(x) (org-export-latex-subcontent x num)) subcontent)))
 734
 735 (defun org-export-latex-subcontent (subcontent num)
 736   "Export each cell of SUBCONTENT to LaTeX.
 737 If NUM, export sections as numerical sections."
 738   (let* ((heading (org-export-latex-fontify-headline
 739                    (cdr (assoc 'heading subcontent))))
 740          (level (- (cdr (assoc 'level subcontent))
 741                    org-export-latex-add-level))
 742          (occur (number-to-string (cdr (assoc 'occur subcontent))))
 743          (content (cdr (assoc 'content subcontent)))
 744          (subcontent (cadr (assoc 'subcontent subcontent)))
 745          (label (org-get-text-property-any 0 'target heading))
 746          (label-list (cons label (cdr (assoc label
 747                                              org-export-target-aliases)))))
 748     (cond
 749      ;; Normal conversion
 750      ((<= level org-export-latex-sectioning-depth)
 751       (let* ((sec (nth (1- level) org-export-latex-sectioning))
 752              start end)
 753         (if (consp (cdr sec))
 754             (setq start (nth (if num 0 2) sec)
 755                   end (nth (if num 1 3) sec))
 756           (setq start (if num (car sec) (cdr sec))))
 757         (insert (format start heading) "\n")
 758         (when label
 759           (insert (mapconcat (lambda (l) (format "\\label{%s}" l))
 760                              label-list "\n") "\n"))
 761         (insert (org-export-latex-content content))
 762         (cond ((stringp subcontent) (insert subcontent))
 763               ((listp subcontent) (org-export-latex-sub subcontent)))
 764         (if end (insert end "\n"))))
 765      ;; At a level under the hl option: we can drop this subsection
 766      ((> level org-export-latex-sectioning-depth)
 767       (cond ((eq org-export-latex-low-levels 'description)
 768              (if (string-match "% ends low level$"
 769                                (buffer-substring (point-at-bol 0) (point)))
 770                  (delete-region (point-at-bol 0) (point))
 771                (insert "\\begin{description}\n"))
 772              (insert (format "\n\\item[%s]%s~\n\n"
 773                              heading
 774                              (if label (format "\\label{%s}" label) "")))
 775              (insert (org-export-latex-content content))
 776              (cond ((stringp subcontent) (insert subcontent))
 777                    ((listp subcontent) (org-export-latex-sub subcontent)))
 778              (insert "\\end{description} % ends low level\n"))
 779             ((memq org-export-latex-low-levels '(itemize enumerate))
 780              (if (string-match "% ends low level$"
 781                                (buffer-substring (point-at-bol 0) (point)))
 782                  (delete-region (point-at-bol 0) (point))
 783                (insert (format "\\begin{%s}\n"
 784                                (symbol-name org-export-latex-low-levels))))
 785              (insert (format "\n\\item %s\\\\\n%s\n"
 786                              heading
 787                              (if label (format "\\label{%s}" label) "")))
 788              (insert (org-export-latex-content content))
 789              (cond ((stringp subcontent) (insert subcontent))
 790                    ((listp subcontent) (org-export-latex-sub subcontent)))
 791              (insert (format "\\end{%s} %% ends low level\n"
 792                              (symbol-name org-export-latex-low-levels))))
 793             ((stringp org-export-latex-low-levels)
 794              (insert (format org-export-latex-low-levels heading) "\n")
 795              (when label (insert (format "\\label{%s}\n" label)))
 796              (insert (org-export-latex-content content))
 797              (cond ((stringp subcontent) (insert subcontent))
 798                    ((listp subcontent) (org-export-latex-sub subcontent)))))))))
 799
 800 ;;; Exporting internals:
 801 (defun org-export-latex-set-initial-vars (ext-plist level)
 802   "Store org local variables required for LaTeX export.
 803 EXT-PLIST is an optional additional plist.
 804 LEVEL indicates the default depth for export."
 805   (setq org-export-latex-todo-keywords-1 org-todo-keywords-1
 806         org-export-latex-done-keywords org-done-keywords
 807         org-export-latex-not-done-keywords org-not-done-keywords
 808         org-export-latex-complex-heading-re org-complex-heading-regexp
 809         org-export-latex-display-custom-times org-display-custom-times
 810         org-export-latex-all-targets-re
 811         (org-make-target-link-regexp (org-all-targets))
 812         org-export-latex-options-plist
 813         (org-combine-plists (org-default-export-plist) ext-plist
 814                             (org-infile-export-plist))
 815         org-export-latex-class
 816         (or (and (org-region-active-p)
 817                  (save-excursion
 818                    (goto-char (region-beginning))
 819                    (and (looking-at org-complex-heading-regexp)
 820                         (org-entry-get nil "LaTeX_CLASS" 'selective))))
 821             (save-excursion
 822               (save-restriction
 823                 (widen)
 824                 (goto-char (point-min))
 825                 (and (re-search-forward "^#\\+LaTeX_CLASS:[ \t]*\\([a-zA-Z]+\\)" nil t)
 826                      (match-string 1))))
 827             org-export-latex-default-class)
 828         org-export-latex-class
 829         (or (car (assoc org-export-latex-class org-export-latex-classes))
 830             (error "No definition for class `%s' in `org-export-latex-classes'"
 831                    org-export-latex-class))
 832         org-export-latex-header
 833         (cadr (assoc org-export-latex-class org-export-latex-classes))
 834         org-export-latex-sectioning
 835         (cddr (assoc org-export-latex-class org-export-latex-classes))
 836         org-export-latex-sectioning-depth
 837         (or level
 838             (let ((hl-levels
 839                    (plist-get org-export-latex-options-plist :headline-levels))
 840                   (sec-depth (length org-export-latex-sectioning)))
 841               (if (> hl-levels sec-depth) sec-depth hl-levels)))))
 842
 843 (defun org-export-latex-make-header (title opt-plist)
 844   "Make the LaTeX header and return it as a string.
 845 TITLE is the current title from the buffer or region.
 846 OPT-PLIST is the options plist for current buffer."
 847   (let ((toc (plist-get opt-plist :table-of-contents))
 848         (author (plist-get opt-plist :author)))
 849     (concat
 850      (if (plist-get opt-plist :time-stamp-file)
 851          (format-time-string "%% Created %Y-%m-%d %a %H:%M\n"))
 852      ;; insert LaTeX custom header
 853      (org-export-apply-macros-in-string org-export-latex-header)
 854      "\n"
 855      ;; insert information on LaTeX packages
 856      (when org-export-latex-packages-alist
 857        (mapconcat (lambda(p)
 858                     (if (equal "" (car p))
 859                         (format "\\usepackage{%s}" (cadr p))
 860                       (format "\\usepackage[%s]{%s}"
 861                               (car p) (cadr p))))
 862                   org-export-latex-packages-alist "\n"))
 863      ;; insert additional commands in the header
 864      (org-export-apply-macros-in-string
 865       (plist-get opt-plist :latex-header-extra))
 866      (org-export-apply-macros-in-string org-export-latex-append-header)
 867      ;; insert the title
 868      (format
 869       "\n\n\\title{%s}\n"
 870       ;; convert the title
 871       (org-export-latex-content
 872        title '(lists tables fixed-width keywords)))
 873      ;; insert author info
 874      (if (plist-get opt-plist :author-info)
 875          (format "\\author{%s}\n"
 876                  (or author user-full-name))
 877        (format "%%\\author{%s}\n"
 878                (or author user-full-name)))
 879      ;; insert the date
 880      (format "\\date{%s}\n"
 881              (format-time-string
 882               (or (plist-get opt-plist :date)
 883                   org-export-latex-date-format)))
 884      ;; beginning of the document
 885      "\n\\begin{document}\n\n"
 886      ;; insert the title command
 887      (if (string-match "%s" org-export-latex-title-command)
 888          (format org-export-latex-title-command title)
 889        org-export-latex-title-command)
 890      "\n\n"
 891      ;; table of contents
 892      (when (and org-export-with-toc
 893                 (plist-get opt-plist :section-numbers))
 894        (cond ((numberp toc)
 895               (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\\vspace*{1cm}\n"
 896                       (min toc (plist-get opt-plist :headline-levels))))
 897              (toc (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\\vspace*{1cm}\n"
 898                           (plist-get opt-plist :headline-levels))))))))
 899
 900 (defun org-export-latex-first-lines (opt-plist &optional beg end)
 901   "Export the first lines before first headline.
 902 If BEG is non-nil, it is the beginning of the region.
 903 If END is non-nil, it is the end of the region."
 904   (save-excursion
 905     (goto-char (or beg (point-min)))
 906     (let* ((pt (point))
 907            (end (if (re-search-forward "^\\*+ " end t)
 908                     (goto-char (match-beginning 0))
 909                   (goto-char (point-max)))))
 910       (prog1
 911           (org-export-latex-content
 912            (org-export-preprocess-string
 913             (buffer-substring pt end)
 914             :for-LaTeX t
 915             :emph-multiline t
 916             :add-text nil
 917             :comments nil
 918             :skip-before-1st-heading nil
 919             :LaTeX-fragments nil
 920             :timestamps (plist-get opt-plist :timestamps)
 921             :footnotes (plist-get opt-plist :footnotes)))
 922         (org-unmodified
 923          (add-text-properties pt (max pt (1- end))
 924                               '(:org-license-to-kill t)))))))
 925
 926 (defvar org-export-latex-header-defs nil
 927   "The header definitions that might be used in the LaTeX body.")
 928 (defvar org-export-latex-header-defs-re nil
 929   "The header definitions that might be used in the LaTeX body.")
 930
 931 (defun org-export-latex-content (content &optional exclude-list)
 932   "Convert CONTENT string to LaTeX.
 933 Don't perform conversions that are in EXCLUDE-LIST.  Recognized
 934 conversion types are: quotation-marks, emphasis, sub-superscript,
 935 links, keywords, lists, tables, fixed-width"
 936   (with-temp-buffer
 937    (insert content)
 938    (unless (memq 'timestamps exclude-list)
 939      (org-export-latex-time-stamps))
 940    (unless (memq 'quotation-marks exclude-list)
 941      (org-export-latex-quotation-marks))
 942    (unless (memq 'emphasis exclude-list)
 943      (when (plist-get org-export-latex-options-plist :emphasize)
 944        (org-export-latex-fontify)))
 945    (unless (memq 'sub-superscript exclude-list)
 946      (org-export-latex-special-chars
 947       (plist-get org-export-latex-options-plist :sub-superscript)))
 948    (unless (memq 'links exclude-list)
 949      (org-export-latex-links))
 950    (unless (memq 'keywords exclude-list)
 951      (org-export-latex-keywords))
 952    (unless (memq 'lists exclude-list)
 953      (org-export-latex-lists))
 954    (unless (memq 'tables exclude-list)
 955      (org-export-latex-tables
 956       (plist-get org-export-latex-options-plist :tables)))
 957    (unless (memq 'fixed-width exclude-list)
 958      (org-export-latex-fixed-width
 959       (plist-get org-export-latex-options-plist :fixed-width)))
 960    ;; return string
 961    (buffer-substring (point-min) (point-max))))
 962
 963 (defun org-export-latex-protect-string (s)
 964   "Add the org-protected property to string S."
 965   (add-text-properties 0 (length s) '(org-protected t) s) s)
 966
 967 (defun org-export-latex-protect-char-in-string (char-list string)
 968   "Add org-protected text-property to char from CHAR-LIST in STRING."
 969   (with-temp-buffer
 970     (save-match-data
 971       (insert string)
 972       (goto-char (point-min))
 973       (while (re-search-forward (regexp-opt char-list) nil t)
 974         (add-text-properties (match-beginning 0)
 975                              (match-end 0) '(org-protected t)))
 976       (buffer-string))))
 977
 978 (defun org-export-latex-keywords-maybe (&optional remove-list)
 979   "Maybe remove keywords depending on rules in REMOVE-LIST."
 980   (goto-char (point-min))
 981   (let ((re-todo (mapconcat 'identity org-export-latex-todo-keywords-1 "\\|"))
 982         (case-fold-search nil)
 983         (todo-markup org-export-latex-todo-keyword-markup)
 984         fmt)
 985     ;; convert TODO keywords
 986     (when (re-search-forward (concat "^\\(" re-todo "\\)") nil t)
 987       (if (plist-get remove-list :todo)
 988           (replace-match "")
 989         (setq fmt (cond
 990                    ((stringp todo-markup) todo-markup)
 991                    ((and (consp todo-markup) (stringp (car todo-markup)))
 992                     (if (member (match-string 1) org-export-latex-done-keywords)
 993                         (cdr todo-markup) (car todo-markup)))
 994                    (t (cdr (or (assoc (match-string 1) todo-markup)
 995                                (car todo-markup))))))
 996         (replace-match (format fmt (match-string 1)) t t)))
 997     ;; convert priority string
 998     (when (re-search-forward "\\[\\\\#.\\]" nil t)
 999       (if (plist-get remove-list :priority)
1000           (replace-match "")
1001         (replace-match (format "\\textbf{%s}" (match-string 0)) t t)))
1002     ;; convert tags
1003     (when (re-search-forward "\\(:[a-zA-Z0-9_@]+\\)+:" nil t)
1004       (if (or (not org-export-with-tags)
1005               (plist-get remove-list :tags))
1006           (replace-match "")
1007         (replace-match
1008          (org-export-latex-protect-string
1009           (format "\\textbf{%s}"
1010                   (save-match-data
1011                     (replace-regexp-in-string
1012                      "_" "\\\\_" (match-string 0)))))
1013          t t)))))
1014
1015 (defun org-export-latex-fontify-headline (string)
1016   "Fontify special words in STRING."
1017   (with-temp-buffer
1018     ;; FIXME: org-inside-LaTeX-fragment-p doesn't work when the $...$ is at
1019     ;; the beginning of the buffer - inserting "\n" is safe here though.
1020     (insert "\n" string)
1021     (goto-char (point-min))
1022     (when (plist-get org-export-latex-options-plist :emphasize)
1023       (org-export-latex-fontify))
1024     (org-export-latex-keywords-maybe)
1025     (org-export-latex-special-chars
1026      (plist-get org-export-latex-options-plist :sub-superscript))
1027     (org-export-latex-links)
1028     (org-trim (buffer-string))))
1029
1030 (defun org-export-latex-time-stamps ()
1031   "Format time stamps."
1032   (goto-char (point-min))
1033   (let ((org-display-custom-times org-export-latex-display-custom-times))
1034     (while (re-search-forward org-ts-regexp-both nil t)
1035       (org-if-unprotected-at (1- (point))
1036        (replace-match
1037         (org-export-latex-protect-string
1038          (format org-export-latex-timestamp-markup
1039                  (substring (org-translate-time (match-string 0)) 1 -1)))
1040         t t)))))
1041
1042 (defun org-export-latex-quotation-marks ()
1043   "Export quotation marks depending on language conventions."
1044   (let* ((lang (plist-get org-export-latex-options-plist :language))
1045          (quote-rpl (if (equal lang "fr")
1046                         '(("\\(\\s-\\)\"" "«~")
1047                           ("\\(\\S-\\)\"" "~»")
1048                           ("\\(\\s-\\)'" "`"))
1049                       '(("\\(\\s-\\)\"" "``")
1050                         ("\\(\\S-\\)\"" "''")
1051                         ("\\(\\s-\\)'" "`")))))
1052     (mapc (lambda(l) (goto-char (point-min))
1053             (while (re-search-forward (car l) nil t)
1054               (let ((rpl (concat (match-string 1) (cadr l))))
1055                 (org-export-latex-protect-string rpl)
1056                 (org-if-unprotected-1
1057                  (replace-match rpl t t))))) quote-rpl)))
1058
1059 (defun org-export-latex-special-chars (sub-superscript)
1060   "Export special characters to LaTeX.
1061 If SUB-SUPERSCRIPT is non-nil, convert \\ and ^.
1062 See the `org-export-latex.el' code for a complete conversion table."
1063   (goto-char (point-min))
1064   (mapc (lambda(c)
1065           (goto-char (point-min))
1066           (while (re-search-forward c nil t)
1067             ;; Put the point where to check for org-protected
1068             (unless (get-text-property (match-beginning 2) 'org-protected)
1069               (cond ((member (match-string 2) '("\\$" "$"))
1070                      (if (equal (match-string 2) "\\$")
1071                          nil
1072                        (replace-match "\\$" t t)))
1073                     ((member (match-string 2) '("&" "%" "#"))
1074                      (if (equal (match-string 1) "\\")
1075                          (replace-match (match-string 2) t t)
1076                        (replace-match (concat (match-string 1) "\\"
1077                                               (match-string 2)) t t)))
1078                     ((equal (match-string 2) "...")
1079                      (replace-match
1080                       (concat (match-string 1)
1081                               (org-export-latex-protect-string "\\ldots{}")) t t))
1082                     ((equal (match-string 2) "~")
1083                      (cond ((equal (match-string 1) "\\") nil)
1084                            ((eq 'org-link (get-text-property 0 'face (match-string 2)))
1085                             (replace-match (concat (match-string 1) "\\~") t t))
1086                            (t (replace-match
1087                                (org-export-latex-protect-string
1088                                 (concat (match-string 1) "\\~{}")) t t))))
1089                     ((member (match-string 2) '("{" "}"))
1090                      (unless (save-match-data (org-inside-latex-math-p))
1091                        (if (equal (match-string 1) "\\")
1092                            (replace-match (match-string 2) t t)
1093                          (replace-match (concat (match-string 1) "\\"
1094                                                 (match-string 2)) t t)))))
1095               (unless (save-match-data (org-inside-latex-math-p))
1096                 (cond ((equal (match-string 2) "\\")
1097                        (replace-match (or (save-match-data
1098                                             (org-export-latex-treat-backslash-char
1099                                              (match-string 1)
1100                                              (or (match-string 3) "")))
1101                                           "") t t))
1102                       ((member (match-string 2) '("_" "^"))
1103                        (replace-match (or (save-match-data
1104                                             (org-export-latex-treat-sub-super-char
1105                                              sub-superscript
1106                                              (match-string 2)
1107                                              (match-string 1)
1108                                              (match-string 3))) "") t t)))))))
1109         '(;"^\\([^\n$]*?\\|^\\)\\(\\\\?\\$\\)\\([^\n$]*\\)$"
1110           "\\(\\(\\\\?\\$\\)\\)"
1111           "\\([a-za-z0-9]+\\|[ \t\n]\\|\\b\\|\\\\\\)\\(_\\|\\^\\)\\({[^{}]+}\\|[a-za-z0-9]+\\|[ \t\n]\\|[:punct:]\\|{[a-za-z0-9]+}\\|([a-za-z0-9]+)\\)"
1112           "\\(.\\|^\\)\\(\\\\\\)\\([ \t\n]\\|[a-zA-Z&#%{}\"]+\\)"
1113           "\\(.\\|^\\)\\(&\\)"
1114           "\\(.\\|^\\)\\(#\\)"
1115           "\\(.\\|^\\)\\(%\\)"
1116           "\\(.\\|^\\)\\({\\)"
1117           "\\(.\\|^\\)\\(}\\)"
1118           "\\(.\\|^\\)\\(~\\)"
1119           "\\(.\\|^\\)\\(\\.\\.\\.\\)"
1120           ;; (?\< . "\\textless{}")
1121           ;; (?\> . "\\textgreater{}")
1122           )))
1123
1124 (defun org-inside-latex-math-p ()
1125   (get-text-property (point) 'org-latex-math))
1126
1127 (defun org-export-latex-treat-sub-super-char
1128   (subsup char string-before string-after)
1129   "Convert the \"_\" and \"^\" characters to LaTeX.
1130 SUBSUP corresponds to the ^: option in the #+OPTIONS line.
1131 Convert CHAR depending on STRING-BEFORE and STRING-AFTER."
1132   (cond ((equal string-before "\\")
1133          (concat string-before char string-after))
1134         ;; this is part of a math formula
1135         ((and (string-match "\\S-+" string-before)
1136               (string-match "\\S-+" string-after))
1137          (cond ((eq 'org-link (get-text-property 0 'face char))
1138                 (concat string-before "\\" char string-after))
1139                ((save-match-data (org-inside-latex-math-p))
1140                 (if subsup
1141                     (cond ((eq 1 (length string-after))
1142                            (concat string-before char string-after))
1143                           ((string-match "[({]?\\([^)}]+\\)[)}]?" string-after)
1144                            (format "%s%s{%s}" string-before char
1145                                    (match-string 1 string-after))))))
1146                ((and (> (length string-after) 1)
1147                      (or (eq subsup t)
1148                          (and (equal subsup '{}) (eq (string-to-char string-after) ?\{)))
1149                      (string-match "[({]?\\([^)}]+\\)[)}]?" string-after))
1150                 (org-export-latex-protect-string
1151                  (format "%s$%s{%s}$" string-before char
1152                          (if (and (> (match-end 1) (1+ (match-beginning 1)))
1153                                   (not (equal (substring string-after 0 2) "{\\")))
1154                              (concat "\\mathrm{" (match-string 1 string-after) "}")
1155                            (match-string 1 string-after)))))
1156                ((eq subsup t) (concat string-before "$" char string-after "$"))
1157                (t (org-export-latex-protect-string
1158                    (concat string-before "\\" char "{}" string-after)))))
1159         (t (org-export-latex-protect-string
1160             (concat string-before "\\" char "{}" string-after)))))
1161
1162 (defun org-export-latex-treat-backslash-char (string-before string-after)
1163   "Convert the \"$\" special character to LaTeX.
1164 The conversion is made depending of STRING-BEFORE and STRING-AFTER."
1165   (cond ((member (list string-after) org-html-entities)
1166          ;; backslash is part of a special entity (like "\alpha")
1167          (concat string-before "$\\"
1168                  (or (cdar (member (list string-after) org-html-entities))
1169                      string-after) "$"))
1170         ((and (not (string-match "^[ \n\t]" string-after))
1171               (not (string-match "[ \t]\\'\\|^" string-before)))
1172          ;; backslash is inside a word
1173          (org-export-latex-protect-string
1174           (concat string-before "\\textbackslash{}" string-after)))
1175         ((not (or (equal string-after "")
1176                   (string-match "^[ \t\n]" string-after)))
1177          ;; backslash might escape a character (like \#) or a user TeX
1178          ;; macro (like \setcounter)
1179          (org-export-latex-protect-string
1180           (concat string-before "\\" string-after)))
1181         ((and (string-match "^[ \t\n]" string-after)
1182               (string-match "[ \t\n]\\'" string-before))
1183          ;; backslash is alone, convert it to $\backslash$
1184          (org-export-latex-protect-string
1185           (concat string-before "\\textbackslash{}" string-after)))
1186         (t (org-export-latex-protect-string
1187             (concat string-before "\\textbackslash{}" string-after)))))
1188
1189 (defun org-export-latex-keywords ()
1190   "Convert special keywords to LaTeX."
1191   (goto-char (point-min))
1192   (while (re-search-forward org-export-latex-special-keyword-regexp nil t)
1193     (replace-match (format org-export-latex-timestamp-keyword-markup
1194                            (match-string 0)) t t)
1195     (save-excursion
1196       (beginning-of-line 1)
1197       (unless (looking-at ".*\\\\newline[ \t]*$")
1198         (end-of-line 1)
1199         (insert "\\newline")))))
1200
1201 (defun org-export-latex-fixed-width (opt)
1202   "When OPT is non-nil convert fixed-width sections to LaTeX."
1203   (goto-char (point-min))
1204   (while (re-search-forward "^[ \t]*:\\([ \t]\\|$\\)" nil t)
1205     (if opt
1206         (progn (goto-char (match-beginning 0))
1207                (insert "\\begin{verbatim}\n")
1208                (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1209                  (replace-match (concat (match-string 1)
1210                                         (match-string 2)) t t)
1211                  (forward-line))
1212                (insert "\\end{verbatim}\n\n"))
1213       (progn (goto-char (match-beginning 0))
1214              (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1215                (replace-match (concat "%" (match-string 1)
1216                                       (match-string 2)) t t)
1217                (forward-line))))))
1218
1219
1220 (defvar org-table-last-alignment) ; defined in org-table.el
1221 (declare-function orgtbl-to-latex "org-table" (table params) t)
1222 (defun org-export-latex-tables (insert)
1223   "Convert tables to LaTeX and INSERT it."
1224   (goto-char (point-min))
1225   (while (re-search-forward "^\\([ \t]*\\)|" nil t)
1226     ;; FIXME really need to save-excursion?
1227     (save-excursion (org-table-align))
1228     (let* ((beg (org-table-begin))
1229            (end (org-table-end))
1230            (raw-table (buffer-substring beg end))
1231            fnum fields line lines olines gr colgropen line-fmt align
1232            caption label attr floatp longtblp)
1233       (if org-export-latex-tables-verbatim
1234           (let* ((tbl (concat "\\begin{verbatim}\n" raw-table
1235                               "\\end{verbatim}\n")))
1236             (apply 'delete-region (list beg end))
1237             (insert (org-export-latex-protect-string tbl)))
1238         (progn
1239           (setq caption (org-find-text-property-in-string
1240                          'org-caption raw-table)
1241                 attr (org-find-text-property-in-string
1242                       'org-attributes raw-table)
1243                 label (org-find-text-property-in-string
1244                        'org-label raw-table)
1245                 longtblp (and attr (stringp attr)
1246                               (string-match "\\<longtable\\>" attr))
1247                 align (and attr (stringp attr)
1248                            (string-match "\\<align=\\([^ \t\n\r,]+\\)" attr)
1249                            (match-string 1 attr))
1250                 floatp (or caption label))
1251           (setq lines (org-split-string raw-table "\n"))
1252           (apply 'delete-region (list beg end))
1253           (when org-export-table-remove-special-lines
1254             (setq lines (org-table-clean-before-export lines 'maybe-quoted)))
1255           ;; make a formatting string to reflect aligment
1256           (setq olines lines)
1257           (while (and (not line-fmt) (setq line (pop olines)))
1258             (unless (string-match "^[ \t]*|-" line)
1259               (setq fields (org-split-string line "[ \t]*|[ \t]*"))
1260               (setq fnum (make-vector (length fields) 0))
1261               (setq line-fmt
1262                     (mapconcat
1263                      (lambda (x)
1264                        (setq gr (pop org-table-colgroup-info))
1265                        (format "%s%%s%s"
1266                                (cond ((eq gr :start)
1267                                       (prog1 (if colgropen "|" "|")
1268                                         (setq colgropen t)))
1269                                      ((eq gr :startend)
1270                                       (prog1 (if colgropen "|" "|")
1271                                         (setq colgropen nil)))
1272                                      (t ""))
1273                                (if (memq gr '(:end :startend))
1274                                    (progn (setq colgropen nil) "|")
1275                                  "")))
1276                      fnum ""))))
1277           ;; fix double || in line-fmt
1278           (setq line-fmt (replace-regexp-in-string "||" "|" line-fmt))
1279           ;; maybe remove the first and last "|"
1280           (when (and (not org-export-latex-tables-column-borders)
1281                      (string-match "^\\(|\\)?\\(.+\\)|$" line-fmt))
1282             (setq line-fmt (match-string 2 line-fmt)))
1283           ;; format alignment
1284           (unless align
1285             (setq align (apply 'format
1286                                (cons line-fmt
1287                                      (mapcar (lambda (x) (if x "r" "l"))
1288                                              org-table-last-alignment)))))
1289           ;; prepare the table to send to orgtbl-to-latex
1290           (setq lines
1291                 (mapcar
1292                  (lambda(elem)
1293                    (or (and (string-match "[ \t]*|-+" elem) 'hline)
1294                        (org-split-string (org-trim elem) "|")))
1295                  lines))
1296           (when insert
1297             (insert (org-export-latex-protect-string
1298                      (concat
1299                       (if longtblp
1300                           (concat "\\begin{longtable}{" align "}\n")
1301                         (if floatp "\\begin{table}[htb]\n"))
1302                       (if (or floatp longtblp)
1303                           (format
1304                            "\\caption{%s%s}"
1305                            (if label (concat "\\\label{" label "}") "")
1306                            (or caption "")))
1307                       (if longtblp "\\\\\n" "\n")
1308                       (if (and org-export-latex-tables-centered (not longtblp))
1309                           "\\begin{center}\n")
1310                       (if (not longtblp) (concat "\\begin{tabular}{" align "}\n"))
1311                       (orgtbl-to-latex
1312                        lines
1313                        `(:tstart nil :tend nil
1314                                  :hlend ,(if longtblp
1315                                              (format "\\\\
1316 \\hline
1317 \\endhead
1318 \\hline\\multicolumn{%d}{r}{Continued on next page}\\
1319 \\endfoot
1320 \\endlastfoot" (length org-table-last-alignment))
1321                                            nil)))
1322                       (if (not longtblp) (concat "\n\\end{tabular}"))
1323                       (if longtblp "\n" (if org-export-latex-tables-centered
1324                                             "\n\\end{center}\n" "\n"))
1325                       (if longtblp
1326                           "\\end{longtable}"
1327                         (if floatp "\\end{table}"))))
1328                     "\n\n")))))))
1329
1330 (defun org-export-latex-fontify ()
1331   "Convert fontification to LaTeX."
1332   (goto-char (point-min))
1333   (while (re-search-forward org-emph-re nil t)
1334     ;; The match goes one char after the *string*
1335     (let ((emph (assoc (match-string 3)
1336                        org-export-latex-emphasis-alist))
1337           (beg (match-beginning 0))
1338           (end (match-end 0))
1339           rpl)
1340       (unless emph
1341         (message "`org-export-latex-emphasis-alist' has no entry for formatting triggered by \"%s\""
1342                  (match-string 3)))
1343       (unless (or (get-text-property (1- (point)) 'org-protected)
1344                   (save-excursion
1345                     (goto-char (match-beginning 1))
1346                     (save-match-data
1347                       (and (org-at-table-p)
1348                            (string-match
1349                             "[|\n]" (buffer-substring beg end))))))
1350         (setq rpl (concat (match-string 1)
1351                           (org-export-latex-emph-format (cadr emph)
1352                                                         (match-string 4))
1353                           (match-string 5)))
1354         (if (caddr emph)
1355             (setq rpl (org-export-latex-protect-string rpl)))
1356         (replace-match rpl t t)))
1357     (backward-char)))
1358
1359 (defun org-export-latex-emph-format (format string)
1360   "Format an emphasis string and handle the \\verb special case."
1361   (when (equal format "\\verb")
1362     (save-match-data
1363       (let ((ll "~,./?;':\"|!@#%^&-_=+abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ<>()[]{}"))
1364         (catch 'exit
1365           (loop for i from 0 to (1- (length ll)) do
1366                 (if (not (string-match (regexp-quote (substring ll i (1+ i)))
1367                                        string))
1368                     (progn
1369                       (setq format (concat "\\verb" (substring ll i (1+ i))
1370                                            "%s" (substring ll i (1+ i))))
1371                       (throw 'exit nil))))))))
1372   (setq string (org-export-latex-protect-string
1373                 (format format string))))
1374
1375 (defun org-export-latex-links ()
1376   ;; Make sure to use the LaTeX hyperref and graphicx package
1377   ;; or send some warnings.
1378   "Convert links to LaTeX."
1379   (goto-char (point-min))
1380   (while (re-search-forward org-bracket-link-analytic-regexp++ nil t)
1381     (org-if-unprotected
1382      (goto-char (match-beginning 0))
1383      (let* ((re-radio org-export-latex-all-targets-re)
1384             (remove (list (match-beginning 0) (match-end 0)))
1385             (raw-path (org-extract-attributes (match-string 3)))
1386             (full-raw-path (concat (match-string 1) raw-path))
1387             (desc (match-string 5))
1388             (type (or (match-string 2)
1389                       (if (or (file-name-absolute-p raw-path)
1390                               (string-match "^\\.\\.?/" raw-path))
1391                           "file")))
1392             (coderefp (equal type "coderef"))
1393             (caption (org-find-text-property-in-string 'org-caption raw-path))
1394             (attr (or (org-find-text-property-in-string 'org-attributes raw-path)
1395                       (plist-get org-export-latex-options-plist :latex-image-options)))
1396             (label (org-find-text-property-in-string 'org-label raw-path))
1397             (floatp (or label caption))
1398             imgp radiop
1399             ;; define the path of the link
1400             (path (cond
1401                    ((member type '("coderef"))
1402                     raw-path)
1403                    ((member type '("http" "https" "ftp"))
1404                     (concat type ":" raw-path))
1405                    ((and re-radio (string-match re-radio raw-path))
1406                     (setq radiop t))
1407                    ((equal type "mailto")
1408                     (concat type ":" raw-path))
1409                    ((equal type "file")
1410                     (if (and (org-file-image-p
1411                               (expand-file-name
1412                                raw-path)
1413                               org-export-latex-inline-image-extensions)
1414                              (equal desc full-raw-path))
1415                         (setq imgp t)
1416                       (progn (when (string-match "\\(.+\\)::.+" raw-path)
1417                                (setq raw-path (match-string 1 raw-path)))
1418                              (if (file-exists-p raw-path)
1419                                  (concat type "://" (expand-file-name raw-path))
1420                                (concat type "://" (org-export-directory
1421                                                    :LaTeX org-export-latex-options-plist)
1422                                        raw-path))))))))
1423        ;; process with link inserting
1424        (apply 'delete-region remove)
1425        (cond ((and imgp (plist-get org-export-latex-options-plist :inline-images))
1426               (insert
1427                (concat
1428                 (if floatp "\\begin{figure}[htb]\n")
1429                 (format "\\centerline{\\includegraphics[%s]{%s}}\n"
1430                         attr
1431                         (if (file-name-absolute-p raw-path)
1432                             (expand-file-name raw-path)
1433                           raw-path))
1434                 (if floatp
1435                     (format "\\caption{%s%s}\n"
1436                             (if label (concat "\\label{" label "}") "")
1437                             (or caption "")))
1438                 (if floatp "\\end{figure}\n"))))
1439              (coderefp
1440               (insert (format
1441                        (org-export-get-coderef-format path desc)
1442                        (cdr (assoc path org-export-code-refs)))))
1443              (radiop (insert (format "\\hyperref[%s]{%s}"
1444                                      (org-solidify-link-text raw-path) desc)))
1445              ((not type)
1446               (insert (format "\\hyperref[%s]{%s}"
1447                               (org-solidify-link-text raw-path) desc)))
1448              (path (insert (format "\\href{%s}{%s}" path desc)))
1449              (t (insert "\\texttt{" desc "}")))))))
1450
1451 (defvar org-latex-entities)   ; defined below
1452 (defvar org-latex-entities-regexp)   ; defined below
1453
1454 (defun org-export-latex-preprocess (parameters)
1455   "Clean stuff in the LaTeX export."
1456   ;; Preserve line breaks
1457   (goto-char (point-min))
1458   (while (re-search-forward "\\\\\\\\" nil t)
1459     (add-text-properties (match-beginning 0) (match-end 0)
1460                          '(org-protected t)))
1461
1462   ;; Preserve latex environments
1463   (goto-char (point-min))
1464   (while (re-search-forward "^[ \t]*\\\\begin{\\([a-zA-Z]+\\*?\\)}" nil t)
1465     (let* ((start (progn (beginning-of-line) (point)))
1466            (end (or (and (re-search-forward
1467                           (concat "^[ \t]*\\\\end{"
1468                                   (regexp-quote (match-string 1))
1469                                   "}") nil t)
1470                          (point-at-eol))
1471                     (point-max))))
1472       (add-text-properties start end '(org-protected t))))
1473
1474   ;; Preserve math snippets
1475
1476   (let* ((matchers (plist-get org-format-latex-options :matchers))
1477          (re-list org-latex-regexps)
1478          beg end re e m n block off)
1479     ;; Check the different regular expressions
1480     (while (setq e (pop re-list))
1481       (setq m (car e) re (nth 1 e) n (nth 2 e)
1482             block (if (nth 3 e) "\n\n" ""))
1483       (setq off (if (member m '("$" "$1")) 1 0))
1484       (when (and (member m matchers) (not (equal m "begin")))
1485         (goto-char (point-min))
1486         (while (re-search-forward re nil t)
1487           (setq beg (+ (match-beginning 0) off) end (- (match-end 0) 0))
1488           (add-text-properties beg end '(org-protected t org-latex-math t))))))
1489
1490   ;; Convert LaTeX to \LaTeX{}
1491   (goto-char (point-min))
1492   (let ((case-fold-search nil))
1493     (while (re-search-forward "\\([^+_]\\)LaTeX" nil t)
1494       (org-if-unprotected
1495        (replace-match (org-export-latex-protect-string
1496                        (concat (match-string 1) "\\LaTeX{}")) t t))))
1497
1498   ;; Convert blockquotes
1499   (goto-char (point-min))
1500   (while (search-forward "ORG-BLOCKQUOTE-START" nil t)
1501     (replace-match "\\begin{quote}" t t))
1502   (goto-char (point-min))
1503   (while (search-forward "ORG-BLOCKQUOTE-END" nil t)
1504     (replace-match "\\end{quote}" t t))
1505
1506   ;; Convert verse
1507   (goto-char (point-min))
1508   (while (search-forward "ORG-VERSE-START" nil t)
1509     (replace-match "\\begin{verse}" t t)
1510     (beginning-of-line 2)
1511     (while (and (not (looking-at "[ \t]*ORG-VERSE-END.*")) (not (eobp)))
1512       (when (looking-at "\\([ \t]+\\)\\([^ \t\n]\\)")
1513         (goto-char (match-end 1))
1514         (replace-match
1515          (org-export-latex-protect-string
1516           (concat "\\hspace*{1cm}" (match-string 2))) t t)
1517         (beginning-of-line 1))
1518       (unless (looking-at ".*?[^ \t\n].*?\\\\\\\\[ \t]*$")
1519         (end-of-line 1)
1520         (insert "\\\\"))
1521       (beginning-of-line 2))
1522     (and (looking-at "[ \t]*ORG-VERSE-END.*")
1523          (replace-match "\\end{verse}" t t)))
1524
1525   ;; Convert center
1526   (goto-char (point-min))
1527   (while (search-forward "ORG-CENTER-START" nil t)
1528     (replace-match "\\begin{center}" t t))
1529   (goto-char (point-min))
1530   (while (search-forward "ORG-CENTER-END" nil t)
1531     (replace-match "\\end{center}" t t))
1532
1533   (run-hooks 'org-export-latex-after-blockquotes-hook)
1534
1535   ;; Convert horizontal rules
1536   (goto-char (point-min))
1537   (while (re-search-forward "^----+.$" nil t)
1538     (org-if-unprotected
1539      (replace-match (org-export-latex-protect-string "\\hrule") t t)))
1540
1541   ;; Protect LaTeX commands like \command[...]{...} or \command{...}
1542   (let ((re (concat "\\\\[a-zA-Z]+\\(?:"
1543                     "\\[.*\\]"
1544                     "\\)?"
1545                     (org-create-multibrace-regexp "{" "}" 3))))
1546     (while (re-search-forward re nil t)
1547       (add-text-properties (match-beginning 0) (match-end 0)
1548                            '(org-protected t))))
1549
1550   ;; Protect LaTeX entities
1551   (goto-char (point-min))
1552   (while (re-search-forward org-latex-entities-regexp nil t)
1553     (add-text-properties (match-beginning 0) (match-end 0)
1554                          '(org-protected t)))
1555
1556   ;; Replace radio links
1557   (goto-char (point-min))
1558   (while (re-search-forward
1559           (concat "<<<?" org-export-latex-all-targets-re
1560                   ">>>?\\((INVISIBLE)\\)?") nil t)
1561     (org-if-unprotected
1562      (replace-match
1563       (org-export-latex-protect-string
1564        (format "\\label{%s}%s" (save-match-data (org-solidify-link-text
1565                                                  (match-string 1)))
1566                (if (match-string 2) "" (match-string 1)))) t t)))
1567
1568   ;; Delete @<...> constructs
1569   ;; Thanks to Daniel Clemente for this regexp
1570   (goto-char (point-min))
1571   (while (re-search-forward "@<\\(?:[^\"\n]\\|\".*\"\\)*?>" nil t)
1572     (org-if-unprotected
1573      (replace-match "")))
1574
1575   ;; When converting to LaTeX, replace footnotes
1576   ;; FIXME: don't protect footnotes from conversion
1577   (when (plist-get org-export-latex-options-plist :footnotes)
1578     (goto-char (point-min))
1579     (while (re-search-forward "\\[\\([0-9]+\\)\\]" nil t)
1580       (org-if-unprotected
1581        (when (save-match-data
1582                (save-excursion (beginning-of-line)
1583                                (looking-at "[^:|#]")))
1584          (let ((foot-beg (match-beginning 0))
1585                (foot-end (match-end 0))
1586                (foot-prefix (match-string 0))
1587                footnote footnote-rpl)
1588            (save-excursion
1589              (if (not (re-search-forward (concat "^" (regexp-quote foot-prefix))
1590                                          nil t))
1591                  (replace-match "$^{\\1}$")
1592                (replace-match "")
1593                (let ((end (save-excursion
1594                             (if (re-search-forward "^$\\|^#.*$\\|\\[[0-9]+\\]" nil t)
1595                                 (match-beginning 0) (point-max)))))
1596                  (setq footnote (concat (org-trim (buffer-substring (point) end))
1597                                         " ")) ; prevent last } being part of a link
1598                  (delete-region (point) end))
1599                (goto-char foot-beg)
1600                (delete-region foot-beg foot-end)
1601                (unless (null footnote)
1602                  (setq footnote-rpl (format "\\footnote{%s}" footnote))
1603                  (add-text-properties 0 10 '(org-protected t) footnote-rpl)
1604                  (add-text-properties (1- (length footnote-rpl))
1605                                       (length footnote-rpl)
1606                                       '(org-protected t) footnote-rpl)
1607                  (insert footnote-rpl)))
1608              )))))
1609
1610     ;; Remove footnote section tag for LaTeX
1611     (goto-char (point-min))
1612     (while (re-search-forward
1613             (concat "^" footnote-section-tag-regexp) nil t)
1614       (org-if-unprotected
1615        (replace-match "")))))
1616
1617 ;;; List handling:
1618
1619 (defun org-export-latex-lists ()
1620   "Convert plain text lists in current buffer into LaTeX lists."
1621   (goto-char (point-min))
1622   (while (re-search-forward org-list-beginning-re nil t)
1623     (org-if-unprotected
1624      (beginning-of-line)
1625      (insert (org-list-to-latex (org-list-parse-list t)
1626                                 org-export-latex-list-parameters))
1627      "\n")))
1628
1629 (defconst org-latex-entities
1630  '("\\!"
1631    "\\'"
1632    "\\+"
1633    "\\,"
1634    "\\-"
1635    "\\:"
1636    "\\;"
1637    "\\<"
1638    "\\="
1639    "\\>"
1640    "\\Huge"
1641    "\\LARGE"
1642    "\\Large"
1643    "\\Styles"
1644    "\\\\"
1645    "\\`"
1646    "\\addcontentsline"
1647    "\\address"
1648    "\\addtocontents"
1649    "\\addtocounter"
1650    "\\addtolength"
1651    "\\addvspace"
1652    "\\alph"
1653    "\\appendix"
1654    "\\arabic"
1655    "\\author"
1656    "\\begin{array}"
1657    "\\begin{center}"
1658    "\\begin{description}"
1659    "\\begin{enumerate}"
1660    "\\begin{eqnarray}"
1661    "\\begin{equation}"
1662    "\\begin{figure}"
1663    "\\begin{flushleft}"
1664    "\\begin{flushright}"
1665    "\\begin{itemize}"
1666    "\\begin{list}"
1667    "\\begin{minipage}"
1668    "\\begin{picture}"
1669    "\\begin{quotation}"
1670    "\\begin{quote}"
1671    "\\begin{tabbing}"
1672    "\\begin{table}"
1673    "\\begin{tabular}"
1674    "\\begin{thebibliography}"
1675    "\\begin{theorem}"
1676    "\\begin{titlepage}"
1677    "\\begin{verbatim}"
1678    "\\begin{verse}"
1679    "\\bf"
1680    "\\bf"
1681    "\\bibitem"
1682    "\\bigskip"
1683    "\\cdots"
1684    "\\centering"
1685    "\\circle"
1686    "\\cite"
1687    "\\cleardoublepage"
1688    "\\clearpage"
1689    "\\cline"
1690    "\\closing"
1691    "\\dashbox"
1692    "\\date"
1693    "\\ddots"
1694    "\\dotfill"
1695    "\\em"
1696    "\\fbox"
1697    "\\flushbottom"
1698    "\\fnsymbol"
1699    "\\footnote"
1700    "\\footnotemark"
1701    "\\footnotesize"
1702    "\\footnotetext"
1703    "\\frac"
1704    "\\frame"
1705    "\\framebox"
1706    "\\hfill"
1707    "\\hline"
1708    "\\hrulespace"
1709    "\\hspace"
1710    "\\huge"
1711    "\\hyphenation"
1712    "\\include"
1713    "\\includeonly"
1714    "\\indent"
1715    "\\input"
1716    "\\it"
1717    "\\kill"
1718    "\\label"
1719    "\\large"
1720    "\\ldots"
1721    "\\line"
1722    "\\linebreak"
1723    "\\linethickness"
1724    "\\listoffigures"
1725    "\\listoftables"
1726    "\\location"
1727    "\\makebox"
1728    "\\maketitle"
1729    "\\mark"
1730    "\\mbox"
1731    "\\medskip"
1732    "\\multicolumn"
1733    "\\multiput"
1734    "\\newcommand"
1735    "\\newcounter"
1736    "\\newenvironment"
1737    "\\newfont"
1738    "\\newlength"
1739    "\\newline"
1740    "\\newpage"
1741    "\\newsavebox"
1742    "\\newtheorem"
1743    "\\nocite"
1744    "\\nofiles"
1745    "\\noindent"
1746    "\\nolinebreak"
1747    "\\nopagebreak"
1748    "\\normalsize"
1749    "\\onecolumn"
1750    "\\opening"
1751    "\\oval"
1752    "\\overbrace"
1753    "\\overline"
1754    "\\pagebreak"
1755    "\\pagenumbering"
1756    "\\pageref"
1757    "\\pagestyle"
1758    "\\par"
1759    "\\parbox"
1760    "\\put"
1761    "\\raggedbottom"
1762    "\\raggedleft"
1763    "\\raggedright"
1764    "\\raisebox"
1765    "\\ref"
1766    "\\rm"
1767    "\\roman"
1768    "\\rule"
1769    "\\savebox"
1770    "\\sc"
1771    "\\scriptsize"
1772    "\\setcounter"
1773    "\\setlength"
1774    "\\settowidth"
1775    "\\sf"
1776    "\\shortstack"
1777    "\\signature"
1778    "\\sl"
1779    "\\small"
1780    "\\smallskip"
1781    "\\sqrt"
1782    "\\tableofcontents"
1783    "\\telephone"
1784    "\\thanks"
1785    "\\thispagestyle"
1786    "\\tiny"
1787    "\\title"
1788    "\\tt"
1789    "\\twocolumn"
1790    "\\typein"
1791    "\\typeout"
1792    "\\underbrace"
1793    "\\underline"
1794    "\\usebox"
1795    "\\usecounter"
1796    "\\value"
1797    "\\vdots"
1798    "\\vector"
1799    "\\verb"
1800    "\\vfill"
1801    "\\vline"
1802    "\\vspace")
1803  "A list of LaTeX commands to be protected when performing conversion.")
1804
1805 (defconst org-latex-entities-regexp
1806   (let (names rest)
1807     (dolist (x org-latex-entities)
1808       (if (string-match "[a-z][A-Z]$" x)
1809           (push x names)
1810         (push x rest)))
1811     (concat "\\(" (regexp-opt (nreverse names)) "\\>\\)"
1812             "\\|\\(" (regexp-opt (nreverse rest)) "\\)")))
1813
1814 (provide 'org-export-latex)
1815 (provide 'org-latex)
1816
1817 ;; arch-tag: 23c2b87d-da04-4c2d-ad2d-1eb6487bc3ad
1818
1819 ;;; org-latex.el ends here