lisp/ob-haskell.el

   1 ;;; ob-haskell.el --- org-babel functions for haskell evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating haskell source code.  This one will
  28 ;; be sort of tricky because haskell programs must be compiled before
  29 ;; they can be run, but haskell code can also be run through an
  30 ;; interactive interpreter.
  31 ;;
  32 ;; For now lets only allow evaluation using the haskell interpreter.
  33
  34 ;;; Requirements:
  35
  36 ;; - haskell-mode :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  37 ;;
  38 ;; - inf-haskell :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  39 ;;
  40 ;; - (optionally) lhs2tex :: http://people.cs.uu.nl/andres/lhs2tex/
  41
  42 ;;; Code:
  43 (require 'ob)
  44 (require 'ob-comint)
  45 (require 'comint)
  46 (eval-when-compile (require 'cl))
  47
  48 (declare-function org-remove-indentation "org" (code &optional n))
  49 (declare-function haskell-mode "ext:haskell-mode" ())
  50 (declare-function run-haskell "ext:inf-haskell" (&optional arg))
  51 (declare-function inferior-haskell-load-file
  52                   "ext:inf-haskell" (&optional reload))
  53
  54 (add-to-list 'org-babel-tangle-lang-exts '("haskell" . "hs"))
  55
  56 (defvar org-babel-default-header-args:haskell '())
  57
  58 (defvar org-babel-haskell-lhs2tex-command "lhs2tex")
  59
  60 (defvar org-babel-haskell-eoe "\"org-babel-haskell-eoe\"")
  61
  62 (defun org-babel-execute:haskell (body params)
  63   "Execute a block of Haskell code."
  64   (let* ((session (cdr (assoc :session params)))
  65          (vars (mapcar #'cdr (org-babel-get-header params :var)))
  66          (result-type (cdr (assoc :result-type params)))
  67          (full-body (org-babel-expand-body:generic
  68                      body params
  69                      (org-babel-variable-assignments:haskell params)))
  70          (session (org-babel-haskell-initiate-session session params))
  71          (raw (org-babel-comint-with-output
  72                   (session org-babel-haskell-eoe t full-body)
  73                 (insert (org-babel-trim full-body))
  74                 (comint-send-input nil t)
  75                 (insert org-babel-haskell-eoe)
  76                 (comint-send-input nil t)))
  77          (results (mapcar
  78                    #'org-babel-haskell-read-string
  79                    (cdr (member org-babel-haskell-eoe
  80                                 (reverse (mapcar #'org-babel-trim raw)))))))
  81     (org-babel-reassemble-table
  82      (cond
  83       ((equal result-type 'output)
  84        (mapconcat #'identity (reverse (cdr results)) "\n"))
  85       ((equal result-type 'value)
  86        (org-babel-haskell-table-or-string (car results))))
  87      (org-babel-pick-name (cdr (assoc :colname-names params))
  88                           (cdr (assoc :colname-names params)))
  89      (org-babel-pick-name (cdr (assoc :rowname-names params))
  90                           (cdr (assoc :rowname-names params))))))
  91
  92 (defun org-babel-haskell-read-string (string)
  93   "Strip \\\"s from around a haskell string."
  94   (if (string-match "^\"\\([^\000]+\\)\"$" string)
  95       (match-string 1 string)
  96     string))
  97
  98 (defun org-babel-haskell-initiate-session (&optional session params)
  99   "Initiate a haskell session.
 100 If there is not a current inferior-process-buffer in SESSION
 101 then create one.  Return the initialized session."
 102   (require 'inf-haskell)
 103   (or (get-buffer "*haskell*")
 104       (save-window-excursion (run-haskell) (sleep-for 0.25) (current-buffer))))
 105
 106 (defun org-babel-load-session:haskell (session body params)
 107   "Load BODY into SESSION."
 108   (save-window-excursion
 109     (let* ((buffer (org-babel-prep-session:haskell session params))
 110            (load-file (concat (org-babel-temp-file "haskell-load-") ".hs")))
 111       (with-temp-buffer
 112         (insert body) (write-file load-file)
 113         (haskell-mode) (inferior-haskell-load-file))
 114       buffer)))
 115
 116 (defun org-babel-prep-session:haskell (session params)
 117   "Prepare SESSION according to the header arguments in PARAMS."
 118   (save-window-excursion
 119     (let ((buffer (org-babel-haskell-initiate-session session)))
 120       (org-babel-comint-in-buffer buffer
 121         (mapc (lambda (line)
 122                 (insert line)
 123                 (comint-send-input nil t))
 124               (org-babel-variable-assignments:haskell params)))
 125       (current-buffer))))
 126
 127 (defun org-babel-variable-assignments:haskell (params)
 128   "Return list of haskell statements assigning the block's variables"
 129   (mapcar (lambda (pair)
 130             (format "let %s = %s"
 131                     (car pair)
 132                     (org-babel-haskell-var-to-haskell (cdr pair))))
 133    (mapcar #'cdr (org-babel-get-header params :var))))
 134
 135 (defun org-babel-haskell-table-or-string (results)
 136   "Convert RESULTS to an Emacs-lisp table or string.
 137 If RESULTS look like a table, then convert them into an
 138 Emacs-lisp table, otherwise return the results as a string."
 139   (org-babel-script-escape results))
 140
 141 (defun org-babel-haskell-var-to-haskell (var)
 142   "Convert an elisp value VAR into a haskell variable.
 143 The elisp VAR is converted to a string of haskell source code
 144 specifying a variable of the same value."
 145   (if (listp var)
 146       (concat "[" (mapconcat #'org-babel-haskell-var-to-haskell var ", ") "]")
 147     (format "%S" var)))
 148
 149 (defvar org-src-preserve-indentation)
 150 (defun org-babel-haskell-export-to-lhs (&optional arg)
 151   "Export to a .lhs file with all haskell code blocks escaped.
 152 When called with a prefix argument the resulting
 153 .lhs file will be exported to a .tex file.  This function will
 154 create two new files, base-name.lhs and base-name.tex where
 155 base-name is the name of the current org-mode file.
 156
 157 Note that all standard Babel literate programming
 158 constructs (header arguments, no-web syntax etc...) are ignored."
 159   (interactive "P")
 160   (let* ((contents (buffer-string))
 161          (haskell-regexp
 162           (concat "^\\([ \t]*\\)#\\+begin_src[ \t]haskell*\\(.*\\)?[\r\n]"
 163                   "\\([^\000]*?\\)[\r\n][ \t]*#\\+end_src.*"))
 164          (base-name (file-name-sans-extension (buffer-file-name)))
 165          (tmp-file (org-babel-temp-file "haskell-"))
 166          (tmp-org-file (concat tmp-file ".org"))
 167          (tmp-tex-file (concat tmp-file ".tex"))
 168          (lhs-file (concat base-name ".lhs"))
 169          (tex-file (concat base-name ".tex"))
 170          (command (concat org-babel-haskell-lhs2tex-command
 171                           " " (org-babel-process-file-name lhs-file)
 172                           " > " (org-babel-process-file-name tex-file)))
 173          (preserve-indentp org-src-preserve-indentation)
 174          indentation)
 175     ;; escape haskell source-code blocks
 176     (with-temp-file tmp-org-file
 177       (insert contents)
 178       (goto-char (point-min))
 179       (while (re-search-forward haskell-regexp nil t)
 180         (save-match-data (setq indentation (length (match-string 1))))
 181         (replace-match (save-match-data
 182                          (concat
 183                           "#+begin_latex\n\\begin{code}\n"
 184                           (if (or preserve-indentp
 185                                   (string-match "-i" (match-string 2)))
 186                               (match-string 3)
 187                             (org-remove-indentation (match-string 3)))
 188                           "\n\\end{code}\n#+end_latex\n"))
 189                        t t)
 190         (indent-code-rigidly (match-beginning 0) (match-end 0) indentation)))
 191     (save-excursion
 192       ;; export to latex w/org and save as .lhs
 193       (find-file tmp-org-file) (funcall 'org-export-as-latex nil)
 194       (kill-buffer)
 195       (delete-file tmp-org-file)
 196       (find-file tmp-tex-file)
 197       (goto-char (point-min)) (forward-line 2)
 198       (insert "%include polycode.fmt\n")
 199       ;; ensure all \begin/end{code} statements start at the first column
 200       (while (re-search-forward "^[ \t]+\\\\begin{code}[^\000]+\\\\end{code}" nil t)
 201         (replace-match (save-match-data (org-remove-indentation (match-string 0)))
 202                        t t))
 203       (setq contents (buffer-string))
 204       (save-buffer) (kill-buffer))
 205     (delete-file tmp-tex-file)
 206     ;; save org exported latex to a .lhs file
 207     (with-temp-file lhs-file (insert contents))
 208     (if (not arg)
 209         (find-file lhs-file)
 210       ;; process .lhs file with lhs2tex
 211       (message "running %s" command) (shell-command command) (find-file tex-file))))
 212
 213 (provide 'ob-haskell)
 214
 215 ;; arch-tag: b53f75f3-ba1a-4b05-82d9-a2a0d4e70804
 216
 217 ;;; ob-haskell.el ends here