lisp/ob-exp.el

   1 ;;; ob-exp.el --- Exportation of org-babel source blocks
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; See the online documentation for more information
  28 ;;
  29 ;;   http://orgmode.org/worg/org-contrib/babel/
  30
  31 ;;; Code:
  32 (require 'ob)
  33 (require 'org-exp-blocks)
  34 (eval-when-compile
  35   (require 'cl))
  36
  37 (defvar obe-marker nil)
  38 (defvar org-current-export-file)
  39 (defvar org-babel-lob-one-liner-regexp)
  40 (defvar org-babel-ref-split-regexp)
  41 (declare-function org-babel-lob-get-info "ob-lob" ())
  42 (declare-function org-babel-eval-wipe-error-buffer "ob-eval" ())
  43 (add-to-list 'org-export-interblocks '(src org-babel-exp-inline-src-blocks))
  44 (add-to-list 'org-export-interblocks '(lob org-babel-exp-lob-one-liners))
  45 (add-hook 'org-export-blocks-postblock-hook 'org-exp-res/src-name-cleanup)
  46
  47 (org-export-blocks-add-block '(src org-babel-exp-src-block nil))
  48
  49 (defcustom org-export-babel-evaluate t
  50   "Switch controlling code evaluation during export.
  51 When set to nil no code will be evaluated as part of the export
  52 process."
  53   :group 'org-babel
  54   :type 'boolean)
  55 (put 'org-export-babel-evaluate 'safe-local-variable (lambda (x) (eq x nil)))
  56
  57 (defvar org-babel-function-def-export-keyword "function"
  58   "The keyword to substitute for the source name line on export.
  59 When exporting a source block function, this keyword will
  60 appear in the exported version in the place of source name
  61 line. A source block is considered to be a source block function
  62 if the source name is present and is followed by a parenthesized
  63 argument list. The parentheses may be empty or contain
  64 whitespace. An example is the following which generates n random
  65 \(uniform) numbers.
  66
  67 #+source: rand(n)
  68 #+begin_src R
  69   runif(n)
  70 #+end_src")
  71
  72 (defvar org-babel-function-def-export-indent 4
  73   "Number of characters to indent a source block on export.
  74 When exporting a source block function, the block contents will
  75 be indented by this many characters. See
  76 `org-babel-function-def-export-name' for the definition of a
  77 source block function.")
  78
  79 (defmacro org-babel-exp-in-export-file (lang &rest body)
  80   (declare (indent 1))
  81   `(let* ((lang-headers (intern (concat "org-babel-default-header-args:" ,lang)))
  82           (heading (nth 4 (ignore-errors (org-heading-components))))
  83           (link (when org-current-export-file
  84                   (org-make-link-string
  85                    (if heading
  86                        (concat org-current-export-file "::" heading)
  87                      org-current-export-file))))
  88           (export-buffer (current-buffer)) results)
  89      (when link
  90        ;; resolve parameters in the original file so that
  91        ;; headline and file-wide parameters are included, attempt
  92        ;; to go to the same heading in the original file
  93        (set-buffer (get-file-buffer org-current-export-file))
  94        (save-restriction
  95          (condition-case nil
  96              (org-open-link-from-string link)
  97            (error (when heading
  98                     (goto-char (point-min))
  99                     (re-search-forward (regexp-quote heading) nil t))))
 100          (setq results ,@body))
 101        (set-buffer export-buffer)
 102        results)))
 103
 104 (defun org-babel-exp-src-block (body &rest headers)
 105   "Process source block for export.
 106 Depending on the 'export' headers argument in replace the source
 107 code block with...
 108
 109 both ---- display the code and the results
 110
 111 code ---- the default, display the code inside the block but do
 112           not process
 113
 114 results - just like none only the block is run on export ensuring
 115           that it's results are present in the org-mode buffer
 116
 117 none ----- do not display either code or results upon export"
 118   (interactive)
 119   (message "org-babel-exp processing...")
 120   (save-excursion
 121     (goto-char (match-beginning 0))
 122     (let* ((info (org-babel-get-src-block-info 'light))
 123            (lang (nth 0 info))
 124            (raw-params (nth 2 info)) hash)
 125       ;; bail if we couldn't get any info from the block
 126       (when info
 127         ;; if we're actually going to need the parameters
 128         (when (member (cdr (assoc :exports (nth 2 info))) '("both" "results"))
 129           (org-babel-exp-in-export-file lang
 130             (setf (nth 2 info)
 131                   (org-babel-process-params
 132                    (org-babel-merge-params
 133                     org-babel-default-header-args
 134                     (org-babel-params-from-buffer)
 135                     (org-babel-params-from-properties lang)
 136                     (if (boundp lang-headers) (eval lang-headers) nil)
 137                     raw-params))))
 138           (setf hash (org-babel-sha1-hash info)))
 139         ;; expand noweb references in the original file
 140         (setf (nth 1 info)
 141               (if (and (cdr (assoc :noweb (nth 2 info)))
 142                        (string= "yes" (cdr (assoc :noweb (nth 2 info)))))
 143                   (org-babel-expand-noweb-references
 144                    info (get-file-buffer org-current-export-file))
 145                 (nth 1 info)))
 146         (org-babel-exp-do-export info 'block hash)))))
 147
 148 (defun org-babel-exp-inline-src-blocks (start end)
 149   "Process inline source blocks between START and END for export.
 150 See `org-babel-exp-src-block' for export options, currently the
 151 options and are taken from `org-babel-default-inline-header-args'."
 152   (interactive)
 153   (save-excursion
 154     (goto-char start)
 155     (while (and (< (point) end)
 156                 (re-search-forward org-babel-inline-src-block-regexp end t))
 157       (let* ((info (save-match-data (org-babel-parse-inline-src-block-match)))
 158              (params (nth 2 info)) code-replacement)
 159         (save-match-data
 160           (goto-char (match-beginning 2))
 161           (when (not (org-babel-in-example-or-verbatim))
 162             ;; expand noweb references in the original file
 163             (setf (nth 1 info)
 164                   (if (and (cdr (assoc :noweb params))
 165                            (string= "yes" (cdr (assoc :noweb params))))
 166                       (org-babel-expand-noweb-references
 167                        info (get-file-buffer org-current-export-file))
 168                     (nth 1 info)))
 169             (setq code-replacement (org-babel-exp-do-export info 'inline))))
 170         (if code-replacement
 171             (replace-match code-replacement nil nil nil 1)
 172           (org-babel-examplize-region (match-beginning 1) (match-end 1))
 173           (forward-char 2))))))
 174
 175 (defun org-exp-res/src-name-cleanup ()
 176   "Clean up #+results and #+srcname lines for export.
 177 This function should only be called after all block processing
 178 has taken place."
 179   (interactive)
 180   (save-excursion
 181     (goto-char (point-min))
 182     (while (org-re-search-forward-unprotected
 183             (concat
 184              "\\("org-babel-src-name-regexp"\\|"org-babel-result-regexp"\\)")
 185             nil t)
 186       (delete-region
 187        (progn (beginning-of-line) (point))
 188        (progn (end-of-line) (+ 1 (point)))))))
 189
 190 (defun org-babel-in-example-or-verbatim ()
 191   "Return true if point is in example or verbatim code.
 192 Example and verbatim code include escaped portions of
 193 an org-mode buffer code that should be treated as normal
 194 org-mode text."
 195   (or (org-in-indented-comment-line)
 196       (save-excursion
 197         (save-match-data
 198           (goto-char (point-at-bol))
 199           (looking-at "[ \t]*:[ \t]")))
 200       (org-in-regexps-block-p "^[ \t]*#\\+begin_src" "^[ \t]*#\\+end_src")))
 201
 202 (defun org-babel-exp-lob-one-liners (start end)
 203   "Process Library of Babel calls between START and END for export.
 204 See `org-babel-exp-src-block' for export options. Currently the
 205 options are taken from `org-babel-default-header-args'."
 206   (interactive)
 207   (let (replacement)
 208     (save-excursion
 209       (goto-char start)
 210       (while (and (< (point) end)
 211                   (re-search-forward org-babel-lob-one-liner-regexp nil t))
 212         (setq replacement
 213               (let ((lob-info (org-babel-lob-get-info)))
 214                 (save-match-data
 215                   (org-babel-exp-do-export
 216                    (list "emacs-lisp" "results"
 217                          (org-babel-merge-params
 218                           org-babel-default-header-args
 219                           (org-babel-params-from-buffer)
 220                           (org-babel-params-from-properties)
 221                           (org-babel-parse-header-arguments
 222                            (org-babel-clean-text-properties
 223                             (concat ":var results="
 224                                     (mapconcat #'identity
 225                                                (butlast lob-info) " ")))))
 226                          (car (last lob-info)))
 227                    'lob))))
 228         (setq end (+ end (- (length replacement) (length (match-string 0)))))
 229         (if replacement (replace-match replacement t t))))))
 230
 231 (defun org-babel-exp-do-export (info type &optional hash)
 232   "Return a string with the exported content of a code block.
 233 The function respects the value of the :exports header argument."
 234   (flet ((silently () (let ((session (cdr (assoc :session (nth 2 info)))))
 235                         (when (and session (not (equal "none" session)))
 236                           (org-babel-exp-results info type 'silent))))
 237          (clean () (unless (eq type 'inline) (org-babel-remove-result info))))
 238     (case (intern (or (cdr (assoc :exports (nth 2 info))) "code"))
 239       ('none (silently) (clean) "")
 240       ('code (silently) (clean) nil)
 241       ('results (org-babel-exp-results info type nil hash) "")
 242       ('both (org-babel-exp-results info type nil hash) nil))))
 243
 244 (defun org-babel-exp-results (info type &optional silent hash)
 245   "Evaluate and return the results of the current code block for export.
 246 Results are prepared in a manner suitable for export by org-mode.
 247 This function is called by `org-babel-exp-do-export'.  The code
 248 block will be evaluated.  Optional argument SILENT can be used to
 249 inhibit insertion of results into the buffer."
 250   (when (and org-export-babel-evaluate
 251              (not (and hash
 252                        (equal hash (org-babel-exp-in-export-file (nth 0 info)
 253                                      (org-babel-result-hash))))))
 254     (let ((lang (nth 0 info))
 255           (body (nth 1 info)))
 256       ;; skip code blocks which we can't evaluate
 257       (when (fboundp (intern (concat "org-babel-execute:" lang)))
 258         (org-babel-eval-wipe-error-buffer)
 259         (prog1 nil
 260           (setf (nth 2 info)
 261                 (org-babel-exp-in-export-file lang
 262                   (org-babel-process-params
 263                    (org-babel-merge-params
 264                     (nth 2 info)
 265                     `((:results . ,(if silent "silent" "replace")))))))
 266           (cond
 267            ((or (equal type 'block) (equal type 'inline))
 268             (org-babel-execute-src-block nil info))
 269            ((equal type 'lob)
 270             (save-excursion
 271               (re-search-backward org-babel-lob-one-liner-regexp nil t)
 272               (org-babel-execute-src-block nil info)))))))))
 273
 274 (provide 'ob-exp)
 275
 276 ;; arch-tag: 523abf4c-76d1-44ed-9f27-e3bddf34bf0f
 277
 278 ;;; ob-exp.el ends here