lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>,
   6 ;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.03
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file implements links to BBDB database entries from within Org-mode.
  30 ;; Org-mode loads this module by default - if this is not what you want,
  31 ;; configure the variable `org-modules'.
  32
  33
  34 ;; It also implements an interface (based on Ivar Rummelhoff's
  35 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  36 ;; but who do want to include the anniversaries stored in the BBDB
  37 ;; into the org-agenda.  If you already include the `diary' into the
  38 ;; agenda, you might want to prefer to include the anniversaries in
  39 ;; the diary using bbdb-anniv.el.
  40 ;;
  41 ;; Put the following in /somewhere/at/home/diary.org and make sure
  42 ;; that this file is in `org-agenda-files`
  43 ;;
  44 ;; %%(org-bbdb-anniversaries)
  45 ;;
  46 ;; For example my diary.org looks like:
  47 ;; * Anniversaries
  48 ;; #+CATEGORY: Anniv
  49 ;; %%(org-bbdb-anniversaries)
  50 ;;
  51 ;;
  52 ;; The anniversaries are stored in BBDB in the field `anniversary'
  53 ;; in the format
  54 ;;
  55 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}*
  56 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}*
  57 ;;
  58 ;; CLASS-OR-FORMAT-STRING is one of two things:
  59 ;;
  60 ;;  * an identifier for a class of anniversaries (eg. birthday or
  61 ;;    wedding) from `org-bbdb-anniversary-format-alist'.
  62 ;;  * the (format) string displayed in the diary.
  63 ;;
  64 ;; It defaults to the value of `org-bbdb-default-anniversary-format'
  65 ;; ("birthday" by default).
  66 ;;
  67 ;; The substitutions in the format string are (in order):
  68 ;;  * the name of the record containing this anniversary
  69 ;;  * the number of years
  70 ;;  * an ordinal suffix (st, nd, rd, th) for the year
  71 ;;
  72 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  73 ;; further options.
  74 ;;
  75 ;; Example
  76 ;;
  77 ;;       1973-06-22
  78 ;;       20??-??-?? wedding
  79 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  80
  81 ;;; Code:
  82
  83 (require 'org)
  84 (eval-when-compile
  85   (require 'cl))
  86
  87 ;; Declare external functions and variables
  88
  89 (declare-function bbdb "ext:bbdb-com" (string elidep))
  90 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
  91 (declare-function bbdb-current-record "ext:bbdb-com"
  92                   (&optional planning-on-modifying))
  93 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
  94 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
  95 (declare-function bbdb-record-name "ext:bbdb" (record))
  96 (declare-function bbdb-records "ext:bbdb"
  97           (&optional dont-check-disk already-in-db-buffer))
  98 (declare-function bbdb-split "ext:bbdb" (string separators))
  99 (declare-function bbdb-string-trim "ext:bbdb" (string))
 100 (declare-function calendar-leap-year-p "calendar" (year))
 101 (declare-function diary-ordinal-suffix "diary-lib" (n))
 102
 103 (defvar date)   ;; dynamically scoped from Org
 104
 105 ;; Customization
 106
 107 (defgroup org-bbdb-anniversaries nil
 108   "Customizations for including anniversaries from BBDB into Agenda."
 109   :group 'org-bbdb)
 110
 111 (defcustom org-bbdb-default-anniversary-format "birthday"
 112   "Default anniversary class."
 113   :type  'string
 114   :group 'org-bbdb-anniversaries
 115   :require 'bbdb)
 116
 117 (defcustom org-bbdb-anniversary-format-alist
 118   '( ("birthday" . "Birthday: %s (%d%s)")
 119      ("wedding"  . "%s's %d%s wedding anniversary") )
 120   "How different types of anniversaries should be formatted.
 121 An alist of elements (STRING . FORMAT) where STRING is the name of an
 122 anniversary class and format is either:
 123 1) A format string with the following substitutions (in order):
 124     * the name of the record containing this anniversary
 125     * the number of years
 126     * an ordinal suffix (st, nd, rd, th) for the year
 127
 128 2) A function to be called with three arguments: NAME YEARS SUFFIX
 129    (string int string) returning a string for the diary or nil.
 130
 131 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 132    scope of variables NAME, YEARS and SUFFIX (among others)."
 133   :type 'sexp
 134   :group 'org-bbdb-anniversaries
 135   :require 'bbdb)
 136
 137 (defcustom org-bbdb-anniversary-field 'anniversary
 138   "The BBDB field which contains anniversaries.
 139 The anniversaries are stored in the following format
 140
 141 YYYY-MM-DD Class-or-Format-String
 142
 143 where class is one of the customized classes for anniversaries;
 144 birthday and wedding are predefined.  Format-String can take three
 145 substitutions 1) the name of the record containing this
 146 anniversary, 2) the number of years, and 3) an ordinal suffix for
 147 the year.
 148
 149 Multiple anniversaries can be separated by \\n."
 150   :type    'symbol
 151   :group   'org-bbdb-anniversaries
 152   :require 'bbdb)
 153
 154 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 155   "How to retrieve `month date year' from the anniversary field.
 156
 157 Customize if you have already filled your BBDB with dates
 158 different from YYYY-MM-DD.  The function must return a list (month
 159 date year)."
 160   :type 'function
 161   :group 'org-bbdb-anniversaries
 162   :require 'bbdb)
 163
 164
 165 ;; Install the link type
 166 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 167 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 168
 169 ;; Implementation
 170 (defun org-bbdb-store-link ()
 171   "Store a link to a BBDB database entry."
 172   (when (eq major-mode 'bbdb-mode)
 173     ;; This is BBDB, we make this link!
 174     (let* ((name (bbdb-record-name (bbdb-current-record)))
 175            (company (bbdb-record-getprop (bbdb-current-record) 'company))
 176            (link (org-make-link "bbdb:" name)))
 177       (org-store-link-props :type "bbdb" :name name :company company
 178                             :link link :description name)
 179       link)))
 180
 181 (defun org-bbdb-export (path desc format)
 182   "Create the export version of a BBDB link specified by PATH or DESC.
 183 If exporting to either HTML or LaTeX FORMAT the link will be
 184 italicised, in all other cases it is left unchanged."
 185   (cond
 186    ((eq format 'html) (format "<i>%s</i>" (or desc path)))
 187    ((eq format 'latex) (format "\\textit{%s}" (or desc path)))
 188    (t (or desc path))))
 189
 190 (defun org-bbdb-open (name)
 191   "Follow a BBDB link to NAME."
 192   (require 'bbdb)
 193   (let ((inhibit-redisplay (not debug-on-error))
 194         (bbdb-electric-p nil))
 195     (catch 'exit
 196       ;; Exact match on name
 197       (bbdb-name (concat "\\`" name "\\'") nil)
 198       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 199       ;; Exact match on name
 200       (bbdb-company (concat "\\`" name "\\'") nil)
 201       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 202       ;; Partial match on name
 203       (bbdb-name name nil)
 204       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 205       ;; Partial match on company
 206       (bbdb-company name nil)
 207       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 208       ;; General match including network address and notes
 209       (bbdb name nil)
 210       (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 211         (delete-window (get-buffer-window "*BBDB*"))
 212         (error "No matching BBDB record")))))
 213
 214 (defun org-bbdb-anniv-extract-date (time-str)
 215   "Convert YYYY-MM-DD to (month date year).
 216 Argument TIME-STR is the value retrieved from BBDB."
 217   (multiple-value-bind (y m d) (bbdb-split time-str "-")
 218     (list (string-to-number m)
 219           (string-to-number d)
 220           (string-to-number y))))
 221
 222 (defun org-bbdb-anniv-split (str)
 223   "Split multiple entries in the BBDB anniversary field.
 224 Argument STR is the anniversary field in BBDB."
 225   (let ((pos (string-match "[ \t]" str)))
 226     (if pos (list (substring str 0 pos)
 227                   (bbdb-string-trim (substring str pos)))
 228       (list str nil))))
 229
 230 (defvar org-bbdb-anniv-hash nil
 231   "A hash holding anniversaries extracted from BBDB.
 232 The hash table is created on first use.")
 233
 234 (defvar org-bbdb-updated-p t
 235   "This is non-nil if BBDB has been updated since we last built the hash.")
 236
 237 (defun org-bbdb-make-anniv-hash ()
 238   "Create a hash with anniversaries extracted from BBDB, for fast access.
 239 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 240
 241   (let (split tmp annivs)
 242     (clrhash org-bbdb-anniv-hash)
 243     (dolist (rec (bbdb-records))
 244       (when (setq annivs (bbdb-record-getprop
 245                           rec org-bbdb-anniversary-field))
 246         (setq annivs (bbdb-split annivs "\n"))
 247         (while annivs
 248           (setq split (org-bbdb-anniv-split (pop annivs)))
 249           (multiple-value-bind (m d y)
 250               (funcall org-bbdb-extract-date-fun (car split))
 251             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 252             (puthash (list m d) (cons (list y
 253                                             (bbdb-record-name rec)
 254                                             (cadr split))
 255                                       tmp)
 256                      org-bbdb-anniv-hash))))))
 257   (setq org-bbdb-updated-p nil))
 258
 259 (defun org-bbdb-updated (rec)
 260   "Record the fact that BBDB has been updated.
 261 This is used by Org to re-create the anniversary hash table."
 262   (setq org-bbdb-updated-p t))
 263
 264 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 265
 266 ;;;###autoload
 267 (defun org-bbdb-anniversaries()
 268   "Extract anniversaries from BBDB for display in the agenda."
 269   (require 'diary-lib)
 270   (unless (hash-table-p org-bbdb-anniv-hash)
 271     (setq org-bbdb-anniv-hash
 272           (make-hash-table :test 'equal :size 366)))
 273
 274   (when (or org-bbdb-updated-p
 275             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 276     (org-bbdb-make-anniv-hash))
 277
 278   (let* ((m (car date))    ; month
 279          (d (nth 1 date))  ; day
 280          (y (nth 2 date))  ; year
 281          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 282          (text ())
 283          split class form rec)
 284
 285     ;; we don't want to miss people born on Feb. 29th
 286     (when (and (= m 3) (= d 1) (not (calendar-leap-year-p y)))
 287       (setq annivs (cons annivs (gethash (list 2 29) org-bbdb-anniv-hash))))
 288
 289     (when annivs
 290       (while (setq rec (pop annivs))
 291         (when rec
 292           (let* ((class (or (nth 2 rec)
 293                             org-bbdb-default-anniversary-format))
 294                  (form (or (cdr (assoc class
 295                                        org-bbdb-anniversary-format-alist))
 296                            class))      ; (as format string)
 297                  (name (nth 1 rec))
 298                  (years (- y (car rec)))
 299                  (suffix (diary-ordinal-suffix years))
 300                  (tmp (cond
 301                        ((functionp form)
 302                         (funcall form name years suffix))
 303                        ((listp form) (eval form))
 304                        (t (format form name years suffix)))))
 305             (if text
 306                 (setq text (append text (list tmp)))
 307               (setq text (list tmp)))))
 308         ))
 309     (when text
 310       (mapconcat 'identity text "; "))))
 311
 312 (provide 'org-bbdb)
 313
 314 ;; arch-tag: 9e4f275d-d080-48c1-b040-62247f66b5c2
 315
 316 ;;; org-bbdb.el ends here