lisp/org-ctags.el

   1 ;;; org-ctags.el - Integrate Emacs "tags" Facility with Org -*- lexical-binding: t; -*-
   2 ;;
   3 ;; Copyright (C) 2007-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Paul Sexton <eeeickythump@gmail.com>
   6
   7
   8 ;; Keywords: org, wp
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;
  26 ;; Synopsis
  27 ;; ========
  28 ;;
  29 ;; Allows org-mode to make use of the Emacs `etags' system.  Defines tag
  30 ;; destinations in org-mode files as any text between <<double angled
  31 ;; brackets>>. This allows the tags-generation program `exuberant ctags' to
  32 ;; parse these files and create tag tables that record where these
  33 ;; destinations are found.  Plain [[links]] in org mode files which do not have
  34 ;; <<matching destinations>> within the same file will then be interpreted as
  35 ;; links to these 'tagged' destinations, allowing seamless navigation between
  36 ;; multiple org-mode files.  Topics can be created in any org mode file and
  37 ;; will always be found by plain links from other files.  Other file types
  38 ;; recognized by ctags (source code files, latex files, etc) will also be
  39 ;; available as destinations for plain links, and similarly, org-mode links
  40 ;; will be available as tags from source files.  Finally, the function
  41 ;; `org-ctags-find-tag-interactive' lets you choose any known tag, using
  42 ;; autocompletion, and quickly jump to it.
  43 ;;
  44 ;; Installation
  45 ;; ============
  46 ;;
  47 ;; Install org mode
  48 ;; Ensure org-ctags.el is somewhere in your emacs load path.
  49 ;; Download and install Exuberant ctags -- "http://ctags.sourceforge.net/"
  50 ;; Edit your .emacs file (see next section) and load emacs.
  51
  52 ;; To put in your init file (.emacs):
  53 ;; ==================================
  54 ;;
  55 ;; Assuming you already have org mode installed and set up:
  56 ;;
  57 ;;    (setq org-ctags-path-to-ctags "/path/to/ctags/executable")
  58 ;;    (add-hook 'org-mode-hook
  59 ;;      (lambda ()
  60 ;;        (define-key org-mode-map "\C-co" 'org-ctags-find-tag-interactive)))
  61 ;;
  62 ;; By default, with org-ctags loaded, org will first try and visit the tag
  63 ;; with the same name as the link; then, if unsuccessful, ask the user if
  64 ;; he/she wants to rebuild the 'TAGS' database and try again; then ask if
  65 ;; the user wishes to append 'tag' as a new toplevel heading at the end of
  66 ;; the buffer; and finally, defer to org's default behavior which is to
  67 ;; search the entire text of the current buffer for 'tag'.
  68 ;;
  69 ;; This behavior can be modified by changing the value of
  70 ;; ORG-CTAGS-OPEN-LINK-FUNCTIONS. For example I have the following in my
  71 ;; .emacs, which describes the same behavior as the above paragraph with
  72 ;; one difference:
  73 ;;
  74 ;; (setq org-ctags-open-link-functions
  75 ;;       '(org-ctags-find-tag
  76 ;;         org-ctags-ask-rebuild-tags-file-then-find-tag
  77 ;;         org-ctags-ask-append-topic
  78 ;;         org-ctags-fail-silently))  ; <-- prevents org default behavior
  79 ;;
  80 ;;
  81 ;; Usage
  82 ;; =====
  83 ;;
  84 ;; When you click on a link "[[foo]]" and org cannot find a matching "<<foo>>"
  85 ;; in the current buffer, the tags facility will take over.  The file TAGS in
  86 ;; the active directory is examined to see if the tags facility knows about
  87 ;; "<<foo>>" in any other files.  If it does, the matching file will be opened
  88 ;; and the cursor will jump to the position of "<<foo>>" in that file.
  89 ;;
  90 ;; User-visible functions:
  91 ;; - `org-ctags-find-tag-interactive': type a tag (plain link) name and visit
  92 ;;   it.  With autocompletion.  Bound to ctrl-O in the above setup.
  93 ;; - All the etags functions should work.  These include:
  94 ;;
  95 ;;      M-.    `find-tag' -- finds the tag at point
  96 ;;
  97 ;;      C-M-.  find-tag based on regular expression
  98 ;;
  99 ;;      M-x tags-search RET -- like C-M-. but searches through ENTIRE TEXT
 100 ;;             of ALL the files referenced in the TAGS file.  A quick way to
 101 ;;             search through an entire 'project'.
 102 ;;
 103 ;;      M-*    "go back" from a tag jump.  Like `org-mark-ring-goto'.
 104 ;;             You may need to bind this key yourself with (eg)
 105 ;;             (global-set-key (kbd "<M-kp-multiply>") 'pop-tag-mark)
 106 ;;
 107 ;;      (see etags chapter in Emacs manual for more)
 108 ;;
 109 ;;
 110 ;; Keeping the TAGS file up to date
 111 ;; ================================
 112 ;;
 113 ;; Tags mode has no way of knowing that you have created new tags by typing in
 114 ;; your org-mode buffer.  New tags make it into the TAGS file in 3 ways:
 115 ;;
 116 ;; 1. You re-run (org-ctags-create-tags "directory") to rebuild the file.
 117 ;; 2. You put the function `org-ctags-ask-rebuild-tags-file-then-find-tag' in
 118 ;;    your `org-open-link-functions' list, as is done in the setup
 119 ;;    above.  This will cause the TAGS file to be rebuilt whenever a link
 120 ;;    cannot be found.  This may be slow with large file collections however.
 121 ;; 3. You run the following from the command line (all 1 line):
 122 ;;
 123 ;;      ctags --langdef=orgmode --langmap=orgmode:.org
 124 ;;        --regex-orgmode="/<<([^>]+)>>/\1/d,definition/"
 125 ;;          -f /your/path/TAGS -e -R /your/path/*.org
 126 ;;
 127 ;; If you are paranoid, you might want to run (org-ctags-create-tags
 128 ;; "/path/to/org/files") at startup, by including the following toplevel form
 129 ;; in .emacs.  However this can cause a pause of several seconds if ctags has
 130 ;; to scan lots of files.
 131 ;;
 132 ;;     (progn
 133 ;;       (message "-- rebuilding tags tables...")
 134 ;;       (mapc 'org-ctags-create-tags tags-table-list))
 135
 136 ;;; Code:
 137
 138 (eval-when-compile (require 'cl))
 139
 140 (require 'org)
 141
 142 (declare-function org-pop-to-buffer-same-window "org-compat" (&optional buffer-or-name norecord label))
 143
 144 (defgroup org-ctags nil
 145   "Options concerning use of ctags within org mode."
 146   :tag "Org-Ctags"
 147   :group 'org-link)
 148
 149 (defvar org-ctags-enabled-p t
 150   "Activate ctags support in org mode?")
 151
 152 (defvar org-ctags-tag-regexp "/<<([^>]+)>>/\\1/d,definition/"
 153   "Regexp expression used by ctags external program.
 154 The regexp matches tag destinations in org-mode files.
 155 Format is: /REGEXP/TAGNAME/FLAGS,TAGTYPE/
 156 See the ctags documentation for more information.")
 157
 158 (defcustom org-ctags-path-to-ctags
 159   (if (executable-find "ctags-exuberant") "ctags-exuberant" "ctags")
 160   "Name of the ctags executable file."
 161   :group 'org-ctags
 162   :version "24.1"
 163   :type 'file)
 164
 165 (defcustom org-ctags-open-link-functions
 166   '(org-ctags-find-tag
 167     org-ctags-ask-rebuild-tags-file-then-find-tag
 168     org-ctags-ask-append-topic)
 169   "List of functions to be prepended to ORG-OPEN-LINK-FUNCTIONS when ORG-CTAGS is active."
 170   :group 'org-ctags
 171   :version "24.1"
 172   :type 'hook
 173   :options '(org-ctags-find-tag
 174              org-ctags-ask-rebuild-tags-file-then-find-tag
 175              org-ctags-rebuild-tags-file-then-find-tag
 176              org-ctags-ask-append-topic
 177              org-ctags-append-topic
 178              org-ctags-ask-visit-buffer-or-file
 179              org-ctags-visit-buffer-or-file
 180              org-ctags-fail-silently))
 181
 182
 183 (defvar org-ctags-tag-list nil
 184   "List of all tags in the active TAGS file.
 185 Created as a local variable in each buffer.")
 186
 187 (defcustom org-ctags-new-topic-template
 188   "* <<%t>>\n\n\n\n\n\n"
 189   "Text to insert when creating a new org file via opening a hyperlink.
 190 The following patterns are replaced in the string:
 191     `%t' - replaced with the capitalized title of the hyperlink"
 192   :group 'org-ctags
 193   :version "24.1"
 194   :type 'string)
 195
 196
 197 (add-hook 'org-mode-hook
 198           (lambda ()
 199             (when (and org-ctags-enabled-p
 200                        (buffer-file-name))
 201               ;; Make sure this file's directory is added to default
 202               ;; directories in which to search for tags.
 203               (let ((tags-filename
 204                      (expand-file-name
 205                       (concat (file-name-directory (buffer-file-name))
 206                               "/TAGS"))))
 207                 (when (file-exists-p tags-filename)
 208                   (visit-tags-table tags-filename))))))
 209
 210
 211 (defadvice visit-tags-table (after org-ctags-load-tag-list activate compile)
 212   (when (and org-ctags-enabled-p tags-file-name)
 213     (setq-local org-ctags-tag-list
 214                 (org-ctags-all-tags-in-current-tags-table))))
 215
 216
 217 (defun org-ctags-enable ()
 218   (put 'org-mode 'find-tag-default-function 'org-ctags-find-tag-at-point)
 219   (setq org-ctags-enabled-p t)
 220   (dolist (fn org-ctags-open-link-functions)
 221     (add-hook 'org-open-link-functions fn t)))
 222
 223
 224 ;;; General utility functions.  ===============================================
 225 ;; These work outside org-ctags mode.
 226
 227 (defun org-ctags-get-filename-for-tag (tag)
 228   "TAG is a string.  Search the active TAGS file for a matching tag.
 229 If the tag is found, return a list containing the filename, line number, and
 230 buffer position where the tag is found."
 231   (interactive "sTag: ")
 232   (unless tags-file-name
 233     (call-interactively (visit-tags-table)))
 234   (save-excursion
 235     (visit-tags-table-buffer 'same)
 236     (when tags-file-name
 237       (with-current-buffer (get-file-buffer tags-file-name)
 238         (goto-char (point-min))
 239         (cond
 240          ((re-search-forward (format "^.*\x7f%s\x01\\([0-9]+\\),\\([0-9]+\\)$"
 241                                      (regexp-quote tag)) nil t)
 242           (let ((line (string-to-number (match-string 1)))
 243                 (pos (string-to-number (match-string 2))))
 244             (cond
 245              ((re-search-backward "\f\n\\(.*\\),[0-9]+\n")
 246               (list (match-string 1) line pos))
 247              (t              ; can't find a file name preceding the matched
 248                                         ; tag??
 249               (error "Malformed TAGS file: %s" (buffer-name))))))
 250          (t                               ; tag not found
 251           nil))))))
 252
 253
 254 (defun org-ctags-all-tags-in-current-tags-table ()
 255   "Read all tags defined in the active TAGS file, into a list of strings.
 256 Return the list."
 257   (interactive)
 258   (let ((taglist nil))
 259     (unless tags-file-name
 260       (call-interactively (visit-tags-table)))
 261     (save-excursion
 262       (visit-tags-table-buffer 'same)
 263       (with-current-buffer (get-file-buffer tags-file-name)
 264         (goto-char (point-min))
 265         (while (re-search-forward "^.*\x7f\\(.*\\)\x01\\([0-9]+\\),\\([0-9]+\\)$"
 266                                   nil t)
 267           (push (substring-no-properties (match-string 1)) taglist)))
 268       taglist)))
 269
 270
 271 (defun org-ctags-string-search-and-replace (search replace string)
 272   "Replace all instances of SEARCH with REPLACE in STRING."
 273   (replace-regexp-in-string (regexp-quote search) replace string t t))
 274
 275
 276 ;;; Internal functions =======================================================
 277
 278
 279 (defun org-ctags-open-file (name &optional title)
 280   "Visit or create a file called `NAME.org', and insert a new topic.
 281 The new topic will be titled NAME (or TITLE if supplied)."
 282   (interactive "sFile name: ")
 283   (condition-case v
 284       (progn
 285         (org-open-file name t)
 286         (message "Opened file OK")
 287         (goto-char (point-max))
 288         (insert (org-ctags-string-search-and-replace
 289                  "%t" (capitalize (or title name))
 290                  org-ctags-new-topic-template))
 291         (message "Inserted new file text OK")
 292         (org-mode-restart))
 293     (error (error "Error %S in org-ctags-open-file" v))))
 294
 295
 296 ;;;; Misc interoperability with etags system =================================
 297
 298
 299 (defadvice xref-find-definitions
 300     (before org-ctags-set-org-mark-before-finding-tag activate compile)
 301   "Before trying to find a tag, save our current position on org mark ring."
 302   (save-excursion
 303     (when (and (derived-mode-p 'org-mode) org-ctags-enabled-p)
 304       (org-mark-ring-push))))
 305
 306
 307
 308 (defun org-ctags-find-tag-at-point ()
 309   "Determine default tag to search for, based on text at point.
 310 If there is no plausible default, return nil."
 311   (let (from to bound)
 312     (when (or (ignore-errors
 313                 ;; Look for hyperlink around `point'.
 314                 (save-excursion
 315                   (search-backward "[[") (setq from (+ 2 (point))))
 316                 (save-excursion
 317                   (goto-char from)
 318                   (search-forward "]") (setq to (- (point) 1)))
 319                 (and (> to from) (>= (point) from) (<= (point) to)))
 320               (progn
 321                 ;; Look at text around `point'.
 322                 (save-excursion
 323                   (skip-syntax-backward "w_") (setq from (point)))
 324                 (save-excursion
 325                   (skip-syntax-forward "w_") (setq to (point)))
 326                 (> to from))
 327               ;; Look between `line-beginning-position' and `point'.
 328               (save-excursion
 329                 (and (setq bound (line-beginning-position))
 330                      (skip-syntax-backward "^w_" bound)
 331                      (> (setq to (point)) bound)
 332                      (skip-syntax-backward "w_")
 333                      (setq from (point))))
 334               ;; Look between `point' and `line-end-position'.
 335               (save-excursion
 336                 (and (setq bound (line-end-position))
 337                      (skip-syntax-forward "^w_" bound)
 338                      (< (setq from (point)) bound)
 339                      (skip-syntax-forward "w_")
 340                      (setq to (point)))))
 341       (buffer-substring-no-properties from to))))
 342
 343
 344 ;;; Functions for use with 'org-open-link-functions' hook =================
 345
 346
 347 (defun org-ctags-find-tag (name)
 348   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 349 Look for a tag called `NAME' in the current TAGS table.  If it is found,
 350 visit the file and location where the tag is found."
 351   (interactive "sTag: ")
 352   (let ((old-buf (current-buffer))
 353         (old-pnt (point-marker))
 354         (old-mark (copy-marker (mark-marker))))
 355     (condition-case nil
 356         (progn (xref-find-definitions name)
 357                t)
 358       (error
 359        ;; only restore old location if find-tag raises error
 360        (set-buffer old-buf)
 361        (goto-char old-pnt)
 362        (set-marker (mark-marker) old-mark)
 363        nil))))
 364
 365
 366 (defun org-ctags-visit-buffer-or-file (name &optional create)
 367   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 368 Visit buffer named `NAME.org'.  If there is no such buffer, visit the file
 369 with the same name if it exists.  If the file does not exist, then behavior
 370 depends on the value of CREATE.
 371
 372 If CREATE is nil (default), then return nil.  Do not create a new file.
 373 If CREATE is t, create the new file and visit it.
 374 If CREATE is the symbol `ask', then ask the user if they wish to create
 375 the new file."
 376   (interactive)
 377   (let ((filename (concat (substitute-in-file-name
 378                            (expand-file-name name))
 379                           ".org")))
 380     (cond
 381      ((get-buffer (concat name ".org"))
 382       ;; Buffer is already open
 383       (org-pop-to-buffer-same-window (get-buffer (concat name ".org"))))
 384      ((file-exists-p filename)
 385       ;; File exists but is not open --> open it
 386       (message "Opening existing org file `%S'..."
 387                filename)
 388       (org-open-file filename t))
 389      ((or (eql create t)
 390           (and (eql create 'ask)
 391                (y-or-n-p (format-message
 392                           "File `%s.org' not found; create?" name))))
 393       (org-ctags-open-file filename name))
 394      (t ;; File does not exist, and we don't want to create it.
 395       nil))))
 396
 397
 398 (defun org-ctags-ask-visit-buffer-or-file (name)
 399   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 400 Wrapper for org-ctags-visit-buffer-or-file, which ensures the user is
 401 asked before creating a new file."
 402   (org-ctags-visit-buffer-or-file name 'ask))
 403
 404
 405 (defun org-ctags-append-topic (name &optional narrowp)
 406   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 407 Append a new toplevel heading to the end of the current buffer.  The
 408 heading contains NAME surrounded by <<angular brackets>>, thus making
 409 the heading a destination for the tag `NAME'."
 410   (interactive "sTopic: ")
 411   (widen)
 412   (goto-char (point-max))
 413   (newline 2)
 414   (message "Adding topic in buffer %s" (buffer-name))
 415   (insert (org-ctags-string-search-and-replace
 416            "%t" (capitalize name) org-ctags-new-topic-template))
 417   (backward-char 4)
 418   (org-update-radio-target-regexp)
 419   (end-of-line)
 420   (forward-line 2)
 421   (when narrowp
 422     ;;(org-tree-to-indirect-buffer 1)  ;; opens new frame
 423     (org-narrow-to-subtree))
 424   t)
 425
 426
 427 (defun org-ctags-ask-append-topic (name &optional narrowp)
 428   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 429 Wrapper for org-ctags-append-topic, which first asks the user if they want
 430 to append a new topic."
 431   (if (y-or-n-p (format-message
 432                  "Topic `%s' not found; append to end of buffer?" name))
 433       (org-ctags-append-topic name narrowp)
 434     nil))
 435
 436
 437 (defun org-ctags-rebuild-tags-file-then-find-tag (name)
 438   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 439 Like ORG-CTAGS-FIND-TAG, but calls the external ctags program first,
 440 to rebuild (update) the TAGS file."
 441   (unless tags-file-name
 442     (call-interactively (visit-tags-table)))
 443   (when (buffer-file-name)
 444     (org-ctags-create-tags))
 445   (org-ctags-find-tag name))
 446
 447
 448 (defun org-ctags-ask-rebuild-tags-file-then-find-tag (name)
 449   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 450 Wrapper for org-ctags-rebuild-tags-file-then-find-tag."
 451   (if (and (buffer-file-name)
 452            (y-or-n-p
 453             (format-message
 454              "Tag `%s' not found.  Rebuild table `%s/TAGS' and look again?"
 455              name
 456              (file-name-directory (buffer-file-name)))))
 457       (org-ctags-rebuild-tags-file-then-find-tag name)
 458     nil))
 459
 460
 461 (defun org-ctags-fail-silently (_name)
 462   "This function is intended to be used in ORG-OPEN-LINK-FUNCTIONS.
 463 Put as the last function in the list if you want to prevent Org's
 464 default behavior of free text search."
 465   t)
 466
 467
 468 ;;; User-visible functions ===================================================
 469
 470
 471 (defun org-ctags-create-tags (&optional directory-name)
 472   "(Re)create tags file in the directory of the active buffer.
 473 The file will contain tag definitions for all the files in the
 474 directory and its subdirectories which are recognized by ctags.
 475 This will include files ending in `.org' as well as most other
 476 source files (.C, .H, .EL, .LISP, etc).  All the resulting tags
 477 end up in one file, called TAGS, located in the directory.  This
 478 function may take several seconds to finish if the directory or
 479 its subdirectories contain large numbers of taggable files."
 480   (interactive)
 481   (assert (buffer-file-name))
 482   (let ((dir-name (or directory-name
 483                       (file-name-directory (buffer-file-name))))
 484         (exitcode nil))
 485     (save-excursion
 486       (setq exitcode
 487             (shell-command
 488              (format (concat "%s --langdef=orgmode --langmap=orgmode:.org "
 489                              "--regex-orgmode=\"%s\" -f \"%s\" -e -R \"%s\"")
 490                      org-ctags-path-to-ctags
 491                      org-ctags-tag-regexp
 492                      (expand-file-name (concat dir-name "/TAGS"))
 493                      (expand-file-name (concat dir-name "/*")))))
 494       (cond
 495        ((eql 0 exitcode)
 496         (setq-local org-ctags-tag-list
 497                     (org-ctags-all-tags-in-current-tags-table)))
 498        (t
 499         ;; This seems to behave differently on Linux, so just ignore
 500         ;; error codes for now
 501         ;;(error "Calling ctags executable resulted in error code: %s"
 502         ;;       exitcode)
 503         nil)))))
 504
 505
 506 (defvar org-ctags-find-tag-history nil
 507   "History of tags visited by org-ctags-find-tag-interactive.")
 508
 509 (defun org-ctags-find-tag-interactive ()
 510   "Prompt for the name of a tag, with autocompletion, then visit the named tag.
 511 Uses `ido-mode' if available.
 512 If the user enters a string that does not match an existing tag, create
 513 a new topic."
 514   (interactive)
 515   (let* ((completing-read-fn (if (fboundp 'ido-completing-read)
 516                                  'ido-completing-read
 517                                'completing-read))
 518          (tag (funcall completing-read-fn "Topic: " org-ctags-tag-list
 519                        nil 'confirm nil 'org-ctags-find-tag-history)))
 520     (when tag
 521       (cond
 522        ((member tag org-ctags-tag-list)
 523         ;; Existing tag
 524         (push tag org-ctags-find-tag-history)
 525         (xref-find-definitions tag))
 526        (t
 527         ;; New tag
 528         (run-hook-with-args-until-success
 529          'org-open-link-functions tag))))))
 530
 531
 532 (org-ctags-enable)
 533
 534 (provide 'org-ctags)
 535
 536 ;;; org-ctags.el ends here