lisp/org-exp-blocks.el

   1 ;;; org-exp-blocks.el --- pre-process blocks when exporting org files
   2
   3 ;; Copyright (C) 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Eric Schulte
   7 ;; Version: 6.36trans
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; This is a utility for pre-processing blocks in org files before
  27 ;; export using the `org-export-preprocess-hook'.  It can be used for
  28 ;; exporting new types of blocks from org-mode files and also for
  29 ;; changing the default export behavior of existing org-mode blocks.
  30 ;; The `org-export-blocks' and `org-export-interblocks' variables can
  31 ;; be used to control how blocks and the spaces between blocks
  32 ;; respectively are processed upon export.
  33 ;;
  34 ;; The type of a block is defined as the string following =#+begin_=,
  35 ;; so for example the following block would be of type ditaa.  Note
  36 ;; that both upper or lower case are allowed in =#+BEGIN_= and
  37 ;; =#+END_=.
  38 ;;
  39 ;; #+begin_ditaa blue.png -r -S
  40 ;; +---------+
  41 ;; | cBLU    |
  42 ;; |         |
  43 ;; |    +----+
  44 ;; |    |cPNK|
  45 ;; |    |    |
  46 ;; +----+----+
  47 ;; #+end_ditaa
  48 ;;
  49 ;;; Currently Implemented Block Types
  50 ;;
  51 ;; ditaa :: Convert ascii pictures to actual images using ditaa
  52 ;;          http://ditaa.sourceforge.net/.  To use this set
  53 ;;          `org-ditaa-jar-path' to the path to ditaa.jar on your
  54 ;;          system (should be set automatically in most cases) .
  55 ;;
  56 ;; dot :: Convert graphs defined using the dot graphing language to
  57 ;;        images using the dot utility.  For information on dot see
  58 ;;        http://www.graphviz.org/
  59 ;;
  60 ;; comment :: Wrap comments with titles and author information, in
  61 ;;            their own divs with author-specific ids allowing for css
  62 ;;            coloring of comments based on the author.
  63 ;;
  64 ;;; Adding new blocks
  65 ;;
  66 ;; When adding a new block type first define a formatting function
  67 ;; along the same lines as `org-export-blocks-format-dot' and then use
  68 ;; `org-export-blocks-add-block' to add your block type to
  69 ;; `org-export-blocks'.
  70
  71 (eval-when-compile
  72   (require 'cl))
  73 (require 'org)
  74
  75 (defvar htmlp)
  76 (defvar latexp)
  77 (defvar docbookp)
  78 (defvar asciip)
  79
  80 (defun org-export-blocks-set (var value)
  81   "Set the value of `org-export-blocks' and install fontification."
  82   (set var value)
  83   (mapc (lambda (spec)
  84           (if (nth 2 spec)
  85               (setq org-protecting-blocks
  86                     (delete (symbol-name (car spec))
  87                             org-protecting-blocks))
  88             (add-to-list 'org-protecting-blocks
  89                          (symbol-name (car spec)))))
  90         value))
  91
  92 (defcustom org-export-blocks
  93   '((comment org-export-blocks-format-comment t)
  94     (ditaa org-export-blocks-format-ditaa nil)
  95     (dot org-export-blocks-format-dot nil))
  96   "Use this a-list to associate block types with block exporting
  97 functions.  The type of a block is determined by the text
  98 immediately following the '#+BEGIN_' portion of the block header.
  99 Each block export function should accept three argumets..."
 100   :group 'org-export-general
 101   :type '(repeat
 102           (list
 103            (symbol :tag "Block name")
 104            (function :tag "Block formatter")
 105            (boolean :tag "Fontify content as Org syntax")))
 106   :set 'org-export-blocks-set)
 107
 108 (defun org-export-blocks-add-block (block-spec)
 109   "Add a new block type to `org-export-blocks'.  BLOCK-SPEC
 110 should be a three element list the first element of which should
 111 indicate the name of the block, the second element should be the
 112 formatting function called by `org-export-blocks-preprocess' and
 113 the third element a flag indicating whether these types of blocks
 114 should be fontified in org-mode buffers (see
 115 `org-protecting-blocks').  For example the BLOCK-SPEC for ditaa
 116 blocks is as follows...
 117
 118   (ditaa org-export-blocks-format-ditaa nil)"
 119   (unless (member block-spec org-export-blocks)
 120     (setq org-export-blocks (cons block-spec org-export-blocks))
 121     (org-export-blocks-set 'org-export-blocks org-export-blocks)))
 122
 123 (defcustom org-export-interblocks
 124   '()
 125   "Use this a-list to associate block types with block exporting
 126 functions.  The type of a block is determined by the text
 127 immediately following the '#+BEGIN_' portion of the block header.
 128 Each block export function should accept three argumets..."
 129   :group 'org-export-general
 130   :type 'alist)
 131
 132 (defcustom org-export-blocks-witheld
 133   '(hidden)
 134   "List of block types (see `org-export-blocks') which should not
 135 be exported."
 136   :group 'org-export-general
 137   :type 'list)
 138
 139 (defcustom org-export-blocks-postblock-hook nil
 140   "Run after blocks have been processed with
 141 `org-export-blocks-preprocess'."
 142   :group 'org-export-general
 143   :type 'hook)
 144
 145 (defun org-export-blocks-html-quote (body &optional open close)
 146   "Protext BODY from org html export.  The optional OPEN and
 147 CLOSE tags will be inserted around BODY."
 148   (concat
 149    "\n#+BEGIN_HTML\n"
 150    (or open "")
 151    body (if (string-match "\n$" body) "" "\n")
 152    (or close "")
 153    "#+END_HTML\n"))
 154
 155 (defun org-export-blocks-latex-quote (body &optional open close)
 156   "Protext BODY from org latex export.  The optional OPEN and
 157 CLOSE tags will be inserted around BODY."
 158   (concat
 159    "\n#+BEGIN_LaTeX\n"
 160    (or open "")
 161    body (if (string-match "\n$" body) "" "\n")
 162    (or close "")
 163    "#+END_LaTeX\n"))
 164
 165 (defun org-export-blocks-preprocess ()
 166   "Export all blocks according to the `org-export-blocks' block
 167 exportation alist.  Does not export block types specified in
 168 specified in BLOCKS which default to the value of
 169 `org-export-blocks-witheld'."
 170   (interactive)
 171   (save-window-excursion
 172     (let ((case-fold-search t)
 173           (types '())
 174           indentation type func start body headers preserve-indent progress-marker)
 175       (flet ((interblock (start end)
 176                          (mapcar (lambda (pair) (funcall (second pair) start end))
 177                                  org-export-interblocks)))
 178         (goto-char (point-min))
 179         (setq start (point))
 180         (while (re-search-forward
 181                 "^\\([ \t]*\\)#\\+begin_\\(\\S-+\\)[ \t]*\\(.*\\)?[\r\n]\\([^\000]*?\\)[\r\n][ \t]*#\\+end_\\S-+.*[\r\n]?" nil t)
 182           (setq indentation (length (match-string 1)))
 183           (setq type (intern (downcase (match-string 2))))
 184           (setq headers (save-match-data (org-split-string (match-string 3) "[ \t]+")))
 185           (setq body (match-string 4))
 186           (setq preserve-indent (or org-src-preserve-indentation (member "-i" headers)))
 187           (unless preserve-indent
 188             (setq body (save-match-data (org-remove-indentation body))))
 189           (unless (memq type types) (setq types (cons type types)))
 190           (save-match-data (interblock start (match-beginning 0)))
 191           (when (setq func (cadr (assoc type org-export-blocks)))
 192             (let ((replacement (save-match-data
 193                                  (if (memq type org-export-blocks-witheld) ""
 194                                    (apply func body headers)))))
 195               (when replacement
 196                 (replace-match replacement t t)
 197                 (unless preserve-indent
 198                   (indent-code-rigidly
 199                    (match-beginning 0) (match-end 0) indentation)))))
 200           (setq start (match-end 0)))
 201         (interblock start (point-max))
 202         (run-hooks 'org-export-blocks-postblock-hook)))))
 203
 204 (add-hook 'org-export-preprocess-hook 'org-export-blocks-preprocess)
 205
 206 ;;================================================================================
 207 ;; type specific functions
 208
 209 ;;--------------------------------------------------------------------------------
 210 ;; ditaa: create images from ASCII art using the ditaa utility
 211 (defvar org-ditaa-jar-path (expand-file-name
 212                             "ditaa.jar"
 213                             (file-name-as-directory
 214                              (expand-file-name
 215                               "scripts"
 216                               (file-name-as-directory
 217                                (expand-file-name
 218                                 "../contrib"
 219                                 (file-name-directory (or load-file-name buffer-file-name)))))))
 220   "Path to the ditaa jar executable")
 221
 222 (defun org-export-blocks-format-ditaa (body &rest headers)
 223   "Pass block BODY to the ditaa utility creating an image.
 224 Specify the path at which the image should be saved as the first
 225 element of headers, any additional elements of headers will be
 226 passed to the ditaa utility as command line arguments."
 227   (message "ditaa-formatting...")
 228   (let* ((args (if (cdr headers) (mapconcat 'identity (cdr headers) " ")))
 229          (data-file (make-temp-file "org-ditaa"))
 230          (hash (sha1 (prin1-to-string (list body args))))
 231          (raw-out-file (if headers (car headers)))
 232          (out-file-parts (if (string-match "\\(.+\\)\\.\\([^\\.]+\\)$" raw-out-file)
 233                              (cons (match-string 1 raw-out-file)
 234                                    (match-string 2 raw-out-file))
 235                            (cons raw-out-file "png")))
 236          (out-file (concat (car out-file-parts) "_" hash "." (cdr out-file-parts))))
 237     (unless (file-exists-p org-ditaa-jar-path)
 238       (error (format "Could not find ditaa.jar at %s" org-ditaa-jar-path)))
 239     (setq body (if (string-match "^\\([^:\\|:[^ ]\\)" body)
 240                    body
 241                  (mapconcat (lambda (x) (substring x (if (> (length x) 1) 2 1)))
 242                             (org-split-string body "\n")
 243                             "\n")))
 244     (cond
 245      ((or htmlp latexp docbookp)
 246       (unless (file-exists-p out-file)
 247         (mapc ;; remove old hashed versions of this file
 248          (lambda (file)
 249            (when (and (string-match (concat (regexp-quote (car out-file-parts))
 250                                             "_\\([[:alnum:]]+\\)\\."
 251                                             (regexp-quote (cdr out-file-parts)))
 252                                     file)
 253                       (= (length (match-string 1 out-file)) 40))
 254              (delete-file (expand-file-name file
 255                                             (file-name-directory out-file)))))
 256          (directory-files (or (file-name-directory out-file)
 257                               default-directory)))
 258         (with-temp-file data-file (insert body))
 259         (message (concat "java -jar " org-ditaa-jar-path " " args " " data-file " " out-file))
 260         (shell-command (concat "java -jar " org-ditaa-jar-path " " args " " data-file " " out-file)))
 261       (format "\n[[file:%s]]\n" out-file))
 262      (t (concat
 263          "\n#+BEGIN_EXAMPLE\n"
 264          body (if (string-match "\n$" body) "" "\n")
 265          "#+END_EXAMPLE\n")))))
 266
 267 ;;--------------------------------------------------------------------------------
 268 ;; dot: create graphs using the dot graphing language
 269 ;;      (require the dot executable to be in your path)
 270 (defun org-export-blocks-format-dot (body &rest headers)
 271   "Pass block BODY to the dot graphing utility creating an image.
 272 Specify the path at which the image should be saved as the first
 273 element of headers, any additional elements of headers will be
 274 passed to the dot utility as command line arguments.  Don't
 275 forget to specify the output type for the dot command, so if you
 276 are exporting to a file with a name like 'image.png' you should
 277 include a '-Tpng' argument, and your block should look like the
 278 following.
 279
 280 #+begin_dot models.png -Tpng
 281 digraph data_relationships {
 282   \"data_requirement\" [shape=Mrecord, label=\"{DataRequirement|description\lformat\l}\"]
 283   \"data_product\" [shape=Mrecord, label=\"{DataProduct|name\lversion\lpoc\lformat\l}\"]
 284   \"data_requirement\" -> \"data_product\"
 285 }
 286 #+end_dot"
 287   (message "dot-formatting...")
 288   (let* ((args (if (cdr headers) (mapconcat 'identity (cdr headers) " ")))
 289          (data-file (make-temp-file "org-ditaa"))
 290          (hash (sha1 (prin1-to-string (list body args))))
 291          (raw-out-file (if headers (car headers)))
 292          (out-file-parts (if (string-match "\\(.+\\)\\.\\([^\\.]+\\)$" raw-out-file)
 293                              (cons (match-string 1 raw-out-file)
 294                                    (match-string 2 raw-out-file))
 295                            (cons raw-out-file "png")))
 296          (out-file (concat (car out-file-parts) "_" hash "." (cdr out-file-parts))))
 297     (cond
 298      ((or htmlp latexp docbookp)
 299       (unless (file-exists-p out-file)
 300         (mapc ;; remove old hashed versions of this file
 301          (lambda (file)
 302            (when (and (string-match (concat (regexp-quote (car out-file-parts))
 303                                             "_\\([[:alnum:]]+\\)\\."
 304                                             (regexp-quote (cdr out-file-parts)))
 305                                     file)
 306                       (= (length (match-string 1 out-file)) 40))
 307              (delete-file (expand-file-name file
 308                                             (file-name-directory out-file)))))
 309          (directory-files (or (file-name-directory out-file)
 310                               default-directory)))
 311         (with-temp-file data-file (insert body))
 312         (message (concat "dot " data-file " " args " -o " out-file))
 313         (shell-command (concat "dot " data-file " " args " -o " out-file)))
 314       (format "\n[[file:%s]]\n" out-file))
 315      (t (concat
 316          "\n#+BEGIN_EXAMPLE\n"
 317          body (if (string-match "\n$" body) "" "\n")
 318          "#+END_EXAMPLE\n")))))
 319
 320 ;;--------------------------------------------------------------------------------
 321 ;; comment: export comments in author-specific css-stylable divs
 322 (defun org-export-blocks-format-comment (body &rest headers)
 323   "Format comment BODY by OWNER and return it formatted for export.
 324 Currently, this only does something for HTML export, for all
 325 other backends, it converts the comment into an EXAMPLE segment."
 326   (let ((owner (if headers (car headers)))
 327         (title (if (cdr headers) (mapconcat 'identity (cdr headers) " "))))
 328     (cond
 329      (htmlp ;; We are exporting to HTML
 330       (concat "#+BEGIN_HTML\n"
 331               "<div class=\"org-comment\""
 332               (if owner (format " id=\"org-comment-%s\" " owner))
 333               ">\n"
 334               (if owner (concat "<b>" owner "</b> ") "")
 335               (if (and title (> (length title) 0)) (concat " -- " title "</br>\n") "</br>\n")
 336               "<p>\n"
 337               "#+END_HTML\n"
 338               body
 339               "#+BEGIN_HTML\n"
 340               "</p>\n"
 341               "</div>\n"
 342               "#+END_HTML\n"))
 343      (t ;; This is not HTML, so just make it an example.
 344       (concat "#+BEGIN_EXAMPLE\n"
 345               (if title (concat "Title:" title "\n") "")
 346               (if owner (concat "By:" owner "\n") "")
 347               body
 348               (if (string-match "\n\\'" body) "" "\n")
 349               "#+END_EXAMPLE\n")))))
 350
 351 (provide 'org-exp-blocks)
 352
 353 ;; arch-tag: 1c365fe9-8808-4f72-bb15-0b00f36d8024
 354 ;;; org-exp-blocks.el ends here