lisp/org-crypt.el

   1 ;;; org-crypt.el --- Public key encryption for org-mode entries
   2
   3 ;; Copyright (C) 2007, 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-crypt.el
   7 ;; Version: 6.36trans
   8 ;; Keywords: org-mode
   9 ;; Author: John Wiegley <johnw@gnu.org>
  10 ;; Maintainer: Peter Jones <pjones@pmade.com>
  11 ;; Description: Adds public key encryption to org-mode buffers
  12 ;; URL: http://www.newartisans.com/software/emacs.html
  13 ;; Compatibility: Emacs22
  14
  15 ;; This file is part of GNU Emacs.
  16 ;;
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;; Right now this is just a set of functions to play with.  It depends
  33 ;; on the epg library.  Here's how you would use it:
  34 ;;
  35 ;; 1. To mark an entry for encryption, tag the heading with "crypt".
  36 ;;    You can change the tag to any complex tag matching string by
  37 ;;    setting the `org-crypt-tag-matcher' variable.
  38 ;;
  39 ;; 2. Set the encryption key to use in the `org-crypt-key' variable,
  40 ;;    or use `M-x org-set-property' to set the property CRYPTKEY to
  41 ;;    any address in your public keyring.  The text of the entry (but
  42 ;;    not its properties or headline) will be encrypted for this user.
  43 ;;    For them to read it, the corresponding secret key must be
  44 ;;    located in the secret key ring of the account where you try to
  45 ;;    decrypt it.  This makes it possible to leave secure notes that
  46 ;;    only the intended recipient can read in a shared-org-mode-files
  47 ;;    scenario.
  48 ;;    If the key is not set, org-crypt will default to symmetric encryption.
  49 ;;
  50 ;; 3. To later decrypt an entry, use `org-decrypt-entries' or
  51 ;;    `org-decrypt-entry'.  It might be useful to bind this to a key,
  52 ;;    like C-c C-/.  I hope that in the future, C-c C-r can be might
  53 ;;    overloaded to also decrypt an entry if it's encrypted, since
  54 ;;    that fits nicely with the meaning of "reveal".
  55 ;;
  56 ;; 4. To automatically encrypt all necessary entries when saving a
  57 ;;    file, call `org-crypt-use-before-save-magic' after loading
  58 ;;    org-crypt.el.
  59 ;;
  60 ;; TODO:
  61 ;;   - Allow symmetric encryption as well
  62
  63 ;;; Thanks:
  64
  65 ;; - Carsten Dominik
  66 ;; - Vitaly Ostanin
  67
  68 (require 'org)
  69
  70 (declare-function epg-decrypt-string "epg" (context cipher))
  71 (declare-function epg-list-keys "epg" (context &optional name mode))
  72 (declare-function epg-make-context "epg"
  73                   (&optional protocol armor textmode include-certs
  74                              cipher-algorithm digest-algorithm
  75                              compress-algorithm))
  76 (declare-function epg-encrypt-string "epg"
  77                   (context plain recipients &optional sign always-trust))
  78
  79 (defgroup org-crypt nil
  80   "Org Crypt"
  81   :tag "Org Crypt" :group 'org)
  82
  83 (defcustom org-crypt-tag-matcher "crypt"
  84   "The tag matcher used to find headings whose contents should be
  85 encrypted.  See the \"Match syntax\" section of the org manual
  86 for more details."
  87   :type 'string :group 'org-crypt)
  88
  89 (defcustom org-crypt-key nil
  90   "The default key to use when encrypting the contents of a
  91 heading.  This can also be overridden in the CRYPTKEY property."
  92   :type 'string :group 'org-crypt)
  93
  94 (defun org-crypt-key-for-heading ()
  95   "Returns the encryption key for the current heading."
  96   (save-excursion
  97     (org-back-to-heading t)
  98     (or (org-entry-get nil "CRYPTKEY" 'selective)
  99         org-crypt-key
 100         (and (boundp 'epa-file-encrypt-to) epa-file-encrypt-to)
 101         (message "No crypt key set, using symmetric encryption."))))
 102
 103 (defun org-encrypt-entry ()
 104   "Encrypt the content of the current headline."
 105   (interactive)
 106   (require 'epg)
 107   (save-excursion
 108     (org-back-to-heading t)
 109     (let ((start-heading (point)))
 110       (forward-line)
 111       (when (not (looking-at "-----BEGIN PGP MESSAGE-----"))
 112         (let ((folded (org-invisible-p))
 113               (epg-context (epg-make-context nil t t))
 114               (crypt-key (org-crypt-key-for-heading))
 115               (beg (point))
 116               end encrypted-text)
 117           (goto-char start-heading)
 118           (org-end-of-subtree t t)
 119           (org-back-over-empty-lines)
 120           (setq end (point)
 121                 encrypted-text
 122                 (epg-encrypt-string
 123                  epg-context
 124                  (buffer-substring-no-properties beg end)
 125                  (epg-list-keys epg-context crypt-key)))
 126           (delete-region beg end)
 127           (insert encrypted-text)
 128           (when folded
 129             (goto-char start-heading)
 130             (hide-subtree))
 131           nil)))))
 132
 133 (defun org-decrypt-entry ()
 134   "Decrypt the content of the current headline."
 135   (interactive)
 136   (require 'epg)
 137   (save-excursion
 138     (org-back-to-heading t)
 139     (forward-line)
 140     (when (looking-at "-----BEGIN PGP MESSAGE-----")
 141       (let* ((beg (point))
 142              (end (save-excursion
 143                     (search-forward "-----END PGP MESSAGE-----")
 144                     (forward-line)
 145                     (point)))
 146              (epg-context (epg-make-context nil t t))
 147              (decrypted-text
 148               (decode-coding-string
 149                (epg-decrypt-string
 150                 epg-context
 151                 (buffer-substring-no-properties beg end))
 152                'utf-8)))
 153         (delete-region beg end)
 154         (insert decrypted-text)
 155         nil))))
 156
 157 (defun org-encrypt-entries ()
 158   "Encrypt all top-level entries in the current buffer."
 159   (interactive)
 160   (org-scan-tags
 161    'org-encrypt-entry
 162    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 163
 164 (defun org-decrypt-entries ()
 165   "Decrypt all entries in the current buffer."
 166   (interactive)
 167   (org-scan-tags
 168    'org-decrypt-entry
 169    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 170
 171 (defun org-crypt-use-before-save-magic ()
 172   "Adds a hook that will automatically encrypt entries before a
 173 file is saved to disk."
 174   (add-hook
 175    'org-mode-hook
 176    (lambda () (add-hook 'before-save-hook 'org-encrypt-entries nil t))))
 177
 178 (add-hook 'org-reveal-start-hook 'org-decrypt-entry)
 179
 180 (provide 'org-crypt)
 181
 182 ;; arch-tag: 8202ed2c-221e-4001-9e4b-54674a7e846e
 183
 184 ;;; org-crypt.el ends here