lisp/ob-R.el

   1 ;;; ob-R.el --- org-babel functions for R code evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research, R, statistics
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating R code
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function orgtbl-to-tsv "org-table" (table params))
  34 (declare-function R "ext:essd-r" (&optional start-args))
  35 (declare-function inferior-ess-send-input "ext:ess-inf" ())
  36 (declare-function ess-make-buffer-current "ext:ess-inf" ())
  37 (declare-function ess-eval-buffer "ext:ess-inf" (vis))
  38 (declare-function org-number-sequence "org-compat" (from &optional to inc))
  39 (declare-function org-remove-if-not "org" (predicate seq))
  40
  41 (defconst org-babel-header-args:R
  42   '((width               . :any)
  43     (height              . :any)
  44     (bg                  . :any)
  45     (units               . :any)
  46     (pointsize           . :any)
  47     (antialias           . :any)
  48     (quality             . :any)
  49     (compression         . :any)
  50     (res                 . :any)
  51     (type                . :any)
  52     (family              . :any)
  53     (title               . :any)
  54     (fonts               . :any)
  55     (version             . :any)
  56     (paper               . :any)
  57     (encoding            . :any)
  58     (pagecentre          . :any)
  59     (colormodel          . :any)
  60     (useDingbats         . :any)
  61     (horizontal          . :any)
  62     (results             . ((file list vector table scalar verbatim)
  63                             (raw org html latex code pp wrap)
  64                             (replace silent append prepend)
  65                             (output value graphics))))
  66   "R-specific header arguments.")
  67
  68 (defvar org-babel-default-header-args:R '())
  69
  70 (defcustom org-babel-R-command "R --slave --no-save"
  71   "Name of command to use for executing R code."
  72   :group 'org-babel
  73   :version "24.1"
  74   :type 'string)
  75
  76 (defvar ess-local-process-name) ; dynamically scoped
  77 (defun org-babel-edit-prep:R (info)
  78   (let ((session (cdr (assoc :session (nth 2 info)))))
  79     (when (and session (string-match "^\\*\\(.+?\\)\\*$" session))
  80       (save-match-data (org-babel-R-initiate-session session nil)))))
  81
  82 (defun org-babel-expand-body:R (body params &optional graphics-file)
  83   "Expand BODY according to PARAMS, return the expanded body."
  84   (let ((graphics-file
  85          (or graphics-file (org-babel-R-graphical-output-file params))))
  86     (mapconcat
  87      #'identity
  88      ((lambda (inside)
  89         (if graphics-file
  90             (append
  91              (list (org-babel-R-construct-graphics-device-call
  92                     graphics-file params))
  93              inside
  94              (list "dev.off()"))
  95           inside))
  96       (append (org-babel-variable-assignments:R params)
  97               (list body))) "\n")))
  98
  99 (defun org-babel-execute:R (body params)
 100   "Execute a block of R code.
 101 This function is called by `org-babel-execute-src-block'."
 102   (save-excursion
 103     (let* ((result-params (cdr (assoc :result-params params)))
 104            (result-type (cdr (assoc :result-type params)))
 105            (session (org-babel-R-initiate-session
 106                      (cdr (assoc :session params)) params))
 107            (colnames-p (cdr (assoc :colnames params)))
 108            (rownames-p (cdr (assoc :rownames params)))
 109            (graphics-file (org-babel-R-graphical-output-file params))
 110            (full-body (org-babel-expand-body:R body params graphics-file))
 111            (result
 112             (org-babel-R-evaluate
 113              session full-body result-type result-params
 114              (or (equal "yes" colnames-p)
 115                  (org-babel-pick-name
 116                   (cdr (assoc :colname-names params)) colnames-p))
 117              (or (equal "yes" rownames-p)
 118                  (org-babel-pick-name
 119                   (cdr (assoc :rowname-names params)) rownames-p)))))
 120       (if graphics-file nil result))))
 121
 122 (defun org-babel-prep-session:R (session params)
 123   "Prepare SESSION according to the header arguments specified in PARAMS."
 124   (let* ((session (org-babel-R-initiate-session session params))
 125          (var-lines (org-babel-variable-assignments:R params)))
 126     (org-babel-comint-in-buffer session
 127       (mapc (lambda (var)
 128               (end-of-line 1) (insert var) (comint-send-input nil t)
 129               (org-babel-comint-wait-for-output session)) var-lines))
 130     session))
 131
 132 (defun org-babel-load-session:R (session body params)
 133   "Load BODY into SESSION."
 134   (save-window-excursion
 135     (let ((buffer (org-babel-prep-session:R session params)))
 136       (with-current-buffer buffer
 137         (goto-char (process-mark (get-buffer-process (current-buffer))))
 138         (insert (org-babel-chomp body)))
 139       buffer)))
 140
 141 ;; helper functions
 142
 143 (defun org-babel-variable-assignments:R (params)
 144   "Return list of R statements assigning the block's variables."
 145   (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
 146     (mapcar
 147      (lambda (pair)
 148        (org-babel-R-assign-elisp
 149         (car pair) (cdr pair)
 150         (equal "yes" (cdr (assoc :colnames params)))
 151         (equal "yes" (cdr (assoc :rownames params)))))
 152      (mapcar
 153       (lambda (i)
 154         (cons (car (nth i vars))
 155               (org-babel-reassemble-table
 156                (cdr (nth i vars))
 157                (cdr (nth i (cdr (assoc :colname-names params))))
 158                (cdr (nth i (cdr (assoc :rowname-names params)))))))
 159       (org-number-sequence 0 (1- (length vars)))))))
 160
 161 (defun org-babel-R-quote-tsv-field (s)
 162   "Quote field S for export to R."
 163   (if (stringp s)
 164       (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\"")
 165     (format "%S" s)))
 166
 167 (defun org-babel-R-assign-elisp (name value colnames-p rownames-p)
 168   "Construct R code assigning the elisp VALUE to a variable named NAME."
 169   (if (listp value)
 170       (let ((max (apply #'max (mapcar #'length (org-remove-if-not
 171                                                 #'sequencep value))))
 172             (min (apply #'min (mapcar #'length (org-remove-if-not
 173                                                 #'sequencep value))))
 174             (transition-file (org-babel-temp-file "R-import-")))
 175         ;; ensure VALUE has an orgtbl structure (depth of at least 2)
 176         (unless (listp (car value)) (setq value (list value)))
 177         (with-temp-file transition-file
 178           (insert
 179            (orgtbl-to-tsv value '(:fmt org-babel-R-quote-tsv-field))
 180            "\n"))
 181         (let ((file (org-babel-process-file-name transition-file 'noquote))
 182               (header (if (or (eq (nth 1 value) 'hline) colnames-p)
 183                           "TRUE" "FALSE"))
 184               (row-names (if rownames-p "1" "NULL")))
 185           (if (= max min)
 186               (format "%s <- read.table(\"%s\",
 187                       header=%s,
 188                       row.names=%s,
 189                       sep=\"\\t\",
 190                       as.is=TRUE)" name file header row-names)
 191             (format "%s <- read.table(\"%s\",
 192                    header=%s,
 193                    row.names=%s,
 194                    sep=\"\\t\",
 195                    as.is=TRUE,
 196                    fill=TRUE,
 197                    col.names = paste(\"V\", seq_len(%d), sep =\"\"))"
 198                     name file header row-names max))))
 199     (format "%s <- %s" name (org-babel-R-quote-tsv-field value))))
 200
 201 (defvar ess-ask-for-ess-directory) ; dynamically scoped
 202 (defun org-babel-R-initiate-session (session params)
 203   "If there is not a current R process then create one."
 204   (unless (string= session "none")
 205     (let ((session (or session "*R*"))
 206           (ess-ask-for-ess-directory
 207            (and (and (boundp 'ess-ask-for-ess-directory) ess-ask-for-ess-directory)
 208                 (not (cdr (assoc :dir params))))))
 209       (if (org-babel-comint-buffer-livep session)
 210           session
 211         (save-window-excursion
 212           (when (get-buffer session)
 213             ;; Session buffer exists, but with dead process
 214             (set-buffer session))
 215           (require 'ess) (R)
 216           (rename-buffer
 217            (if (bufferp session)
 218                (buffer-name session)
 219              (if (stringp session)
 220                  session
 221                (buffer-name))))
 222           (current-buffer))))))
 223
 224 (defun org-babel-R-associate-session (session)
 225   "Associate R code buffer with an R session.
 226 Make SESSION be the inferior ESS process associated with the
 227 current code buffer."
 228   (setq ess-local-process-name
 229         (process-name (get-buffer-process session)))
 230   (ess-make-buffer-current))
 231
 232 (defun org-babel-R-graphical-output-file (params)
 233   "Name of file to which R should send graphical output."
 234   (and (member "graphics" (cdr (assq :result-params params)))
 235        (cdr (assq :file params))))
 236
 237 (defun org-babel-R-construct-graphics-device-call (out-file params)
 238   "Construct the call to the graphics device."
 239   (let ((devices
 240          '((:bmp . "bmp")
 241            (:jpg . "jpeg")
 242            (:jpeg . "jpeg")
 243            (:tikz . "tikz")
 244            (:tiff . "tiff")
 245            (:png . "png")
 246            (:svg . "svg")
 247            (:pdf . "pdf")
 248            (:ps . "postscript")
 249            (:postscript . "postscript")))
 250         (allowed-args '(:width :height :bg :units :pointsize
 251                                :antialias :quality :compression :res
 252                                :type :family :title :fonts :version
 253                                :paper :encoding :pagecentre :colormodel
 254                                :useDingbats :horizontal))
 255         (device (and (string-match ".+\\.\\([^.]+\\)" out-file)
 256                      (match-string 1 out-file)))
 257         (extra-args (cdr (assq :R-dev-args params))) filearg args)
 258     (setq device (or (and device (cdr (assq (intern (concat ":" device))
 259                                             devices))) "png"))
 260     (setq filearg
 261           (if (member device '("pdf" "postscript" "svg" "tikz")) "file" "filename"))
 262     (setq args (mapconcat
 263                 (lambda (pair)
 264                   (if (member (car pair) allowed-args)
 265                       (format ",%s=%S"
 266                               (substring (symbol-name (car pair)) 1)
 267                               (cdr pair)) ""))
 268                 params ""))
 269     (format "%s(%s=\"%s\"%s%s%s)"
 270             device filearg out-file args
 271             (if extra-args "," "") (or extra-args ""))))
 272
 273 (defvar org-babel-R-eoe-indicator "'org_babel_R_eoe'")
 274 (defvar org-babel-R-eoe-output "[1] \"org_babel_R_eoe\"")
 275
 276 (defvar org-babel-R-write-object-command "{function(object,transfer.file){object;invisible(if(inherits(try({tfile<-tempfile();write.table(object,file=tfile,sep=\"\\t\",na=\"nil\",row.names=%s,col.names=%s,quote=FALSE);file.rename(tfile,transfer.file)},silent=TRUE),\"try-error\")){if(!file.exists(transfer.file))file.create(transfer.file)})}}(object=%s,transfer.file=\"%s\")")
 277
 278 (defun org-babel-R-evaluate
 279   (session body result-type result-params column-names-p row-names-p)
 280   "Evaluate R code in BODY."
 281   (if session
 282       (org-babel-R-evaluate-session
 283        session body result-type result-params column-names-p row-names-p)
 284     (org-babel-R-evaluate-external-process
 285      body result-type result-params column-names-p row-names-p)))
 286
 287 (defun org-babel-R-evaluate-external-process
 288   (body result-type result-params column-names-p row-names-p)
 289   "Evaluate BODY in external R process.
 290 If RESULT-TYPE equals 'output then return standard output as a
 291 string.  If RESULT-TYPE equals 'value then return the value of the
 292 last statement in BODY, as elisp."
 293   (case result-type
 294     (value
 295      (let ((tmp-file (org-babel-temp-file "R-")))
 296        (org-babel-eval org-babel-R-command
 297                        (format org-babel-R-write-object-command
 298                                (if row-names-p "TRUE" "FALSE")
 299                                (if column-names-p
 300                                    (if row-names-p "NA" "TRUE")
 301                                  "FALSE")
 302                                (format "{function ()\n{\n%s\n}}()" body)
 303                                (org-babel-process-file-name tmp-file 'noquote)))
 304        (org-babel-R-process-value-result
 305         (org-babel-result-cond result-params
 306           (with-temp-buffer
 307             (insert-file-contents tmp-file)
 308             (buffer-string))
 309           (org-babel-import-elisp-from-file tmp-file '(16)))
 310         column-names-p)))
 311     (output (org-babel-eval org-babel-R-command body))))
 312
 313 (defun org-babel-R-evaluate-session
 314   (session body result-type result-params column-names-p row-names-p)
 315   "Evaluate BODY in SESSION.
 316 If RESULT-TYPE equals 'output then return standard output as a
 317 string.  If RESULT-TYPE equals 'value then return the value of the
 318 last statement in BODY, as elisp."
 319   (case result-type
 320     (value
 321      (with-temp-buffer
 322        (insert (org-babel-chomp body))
 323        (let ((ess-local-process-name
 324               (process-name (get-buffer-process session)))
 325              (ess-eval-visibly-p nil))
 326          (ess-eval-buffer nil)))
 327      (let ((tmp-file (org-babel-temp-file "R-")))
 328        (org-babel-comint-eval-invisibly-and-wait-for-file
 329         session tmp-file
 330         (format org-babel-R-write-object-command
 331                 (if row-names-p "TRUE" "FALSE")
 332                 (if column-names-p
 333                     (if row-names-p "NA" "TRUE")
 334                   "FALSE")
 335                 ".Last.value" (org-babel-process-file-name tmp-file 'noquote)))
 336        (org-babel-R-process-value-result
 337         (org-babel-result-cond result-params
 338           (with-temp-buffer
 339             (insert-file-contents tmp-file)
 340             (buffer-string))
 341           (org-babel-import-elisp-from-file tmp-file '(16)))
 342         column-names-p)))
 343     (output
 344      (mapconcat
 345       #'org-babel-chomp
 346       (butlast
 347        (delq nil
 348              (mapcar
 349               (lambda (line) (when (> (length line) 0) line))
 350               (mapcar
 351                (lambda (line) ;; cleanup extra prompts left in output
 352                  (if (string-match
 353                       "^\\([ ]*[>+\\.][ ]?\\)+\\([[0-9]+\\|[ ]\\)" line)
 354                      (substring line (match-end 1))
 355                    line))
 356                (org-babel-comint-with-output (session org-babel-R-eoe-output)
 357                  (insert (mapconcat #'org-babel-chomp
 358                                     (list body org-babel-R-eoe-indicator)
 359                                     "\n"))
 360                  (inferior-ess-send-input)))))) "\n"))))
 361
 362 (defun org-babel-R-process-value-result (result column-names-p)
 363   "R-specific processing of return value.
 364 Insert hline if column names in output have been requested."
 365   (if column-names-p
 366       (cons (car result) (cons 'hline (cdr result)))
 367     result))
 368
 369 (provide 'ob-R)
 370
 371
 372
 373 ;;; ob-R.el ends here