lisp/ob-sqlite.el

   1 ;;; ob-sqlite.el --- Babel Functions for SQLite Databases -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2010-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating sqlite source code.
  27
  28 ;;; Code:
  29 (require 'ob)
  30
  31 (declare-function org-fill-template "org" (template alist))
  32 (declare-function org-table-convert-region "org-table"
  33                   (beg0 end0 &optional separator))
  34 (declare-function orgtbl-to-csv "org-table" (table params))
  35 (declare-function org-table-to-lisp "org-table" (&optional txt))
  36
  37 (defvar org-babel-default-header-args:sqlite '())
  38
  39 (defvar org-babel-header-args:sqlite
  40   '((db        . :any)
  41     (header    . :any)
  42     (echo      . :any)
  43     (bail      . :any)
  44     (csv       . :any)
  45     (column    . :any)
  46     (html      . :any)
  47     (line      . :any)
  48     (list      . :any)
  49     (separator . :any)
  50     (nullvalue . :any))
  51   "Sqlite specific header args.")
  52
  53 (defun org-babel-expand-body:sqlite (body params)
  54   "Expand BODY according to the values of PARAMS."
  55   (org-babel-sqlite-expand-vars
  56    body (org-babel--get-vars params)))
  57
  58 (defvar org-babel-sqlite3-command "sqlite3")
  59
  60 (defun org-babel-execute:sqlite (body params)
  61   "Execute a block of Sqlite code with Babel.
  62 This function is called by `org-babel-execute-src-block'."
  63   (let ((result-params (split-string (or (cdr (assq :results params)) "")))
  64         (db (cdr (assq :db params)))
  65         (separator (cdr (assq :separator params)))
  66         (nullvalue (cdr (assq :nullvalue params)))
  67         (headers-p (equal "yes" (cdr (assq :colnames params))))
  68         (others (delq nil (mapcar
  69                            (lambda (arg) (car (assq arg params)))
  70                            (list :header :echo :bail :column
  71                                  :csv :html :line :list)))))
  72     (unless db (error "ob-sqlite: can't evaluate without a database"))
  73     (with-temp-buffer
  74       (insert
  75        (org-babel-eval
  76         (org-fill-template
  77          "%cmd %header %separator %nullvalue %others %csv %db "
  78          (list
  79           (cons "cmd" org-babel-sqlite3-command)
  80           (cons "header" (if headers-p "-header" "-noheader"))
  81           (cons "separator"
  82                 (if separator (format "-separator %s" separator) ""))
  83           (cons "nullvalue"
  84                 (if nullvalue (format "-nullvalue %s" nullvalue) ""))
  85           (cons "others"
  86                 (mapconcat
  87                  (lambda (arg) (format "-%s" (substring (symbol-name arg) 1)))
  88                  others " "))
  89           ;; for easy table parsing, default header type should be -csv
  90           (cons "csv" (if (or (member :csv others) (member :column others)
  91                               (member :line others) (member :list others)
  92                               (member :html others) separator)
  93                           ""
  94                         "-csv"))
  95           (cons "db " db)))
  96         ;; body of the code block
  97         (org-babel-expand-body:sqlite body params)))
  98       (org-babel-result-cond result-params
  99         (buffer-string)
 100         (if (equal (point-min) (point-max))
 101             ""
 102           (org-table-convert-region (point-min) (point-max)
 103                                     (if (or (member :csv others)
 104                                             (member :column others)
 105                                             (member :line others)
 106                                             (member :list others)
 107                                             (member :html others) separator)
 108                                         nil
 109                                       '(4)))
 110           (org-babel-sqlite-table-or-scalar
 111            (org-babel-sqlite-offset-colnames
 112             (org-table-to-lisp) headers-p)))))))
 113
 114 (defun org-babel-sqlite-expand-vars (body vars)
 115   "Expand the variables held in VARS in BODY."
 116   ;; FIXME: Redundancy with org-babel-sql-expand-vars!
 117   (mapc
 118    (lambda (pair)
 119      (setq body
 120            (replace-regexp-in-string
 121             (format "$%s" (car pair))
 122             (let ((val (cdr pair)))
 123               (if (listp val)
 124                   (let ((data-file (org-babel-temp-file "sqlite-data-")))
 125                     (with-temp-file data-file
 126                       (insert (orgtbl-to-csv
 127                                val '(:fmt (lambda (el) (if (stringp el)
 128                                                       el
 129                                                     (format "%S" el)))))))
 130                     data-file)
 131                 (if (stringp val) val (format "%S" val))))
 132             body)))
 133    vars)
 134   body)
 135
 136 (defun org-babel-sqlite-table-or-scalar (result)
 137   "If RESULT looks like a trivial table, then unwrap it."
 138   (if (and (equal 1 (length result))
 139            (equal 1 (length (car result))))
 140       (org-babel-read (caar result))
 141     (mapcar (lambda (row)
 142               (if (eq 'hline row)
 143                   'hline
 144                 (mapcar #'org-babel-string-read row))) result)))
 145
 146 (defun org-babel-sqlite-offset-colnames (table headers-p)
 147   "If HEADERS-P is non-nil then offset the first row as column names."
 148   (if headers-p
 149       (cons (car table) (cons 'hline (cdr table)))
 150     table))
 151
 152 (defun org-babel-prep-session:sqlite (_session _params)
 153   "Raise an error because support for SQLite sessions isn't implemented.
 154 Prepare SESSION according to the header arguments specified in PARAMS."
 155   (error "SQLite sessions not yet implemented"))
 156
 157 (provide 'ob-sqlite)
 158
 159
 160
 161 ;;; ob-sqlite.el ends here