lisp/ob-scala.el

   1 ;;; ob-scala.el --- Babel Functions for Scala        -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Andrzej Lichnerowicz
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;; Currently only supports the external execution.  No session support yet.
  26
  27 ;;; Requirements:
  28 ;; - Scala language :: http://www.scala-lang.org/
  29 ;; - Scala major mode :: Can be installed from Scala sources
  30 ;;  https://github.com/scala/scala-dist/blob/master/tool-support/src/emacs/scala-mode.el
  31
  32 ;;; Code:
  33 (require 'ob)
  34 (eval-when-compile (require 'cl))
  35
  36 (defvar org-babel-tangle-lang-exts) ;; Autoloaded
  37 (add-to-list 'org-babel-tangle-lang-exts '("scala" . "scala"))
  38 (defvar org-babel-default-header-args:scala '())
  39 (defvar org-babel-scala-command "scala"
  40   "Name of the command to use for executing Scala code.")
  41
  42 (defun org-babel-execute:scala (body params)
  43   "Execute a block of Scala code with org-babel.  This function is
  44 called by `org-babel-execute-src-block'"
  45   (message "executing Scala source code block")
  46   (let* ((processed-params (org-babel-process-params params))
  47          (session (org-babel-scala-initiate-session (nth 0 processed-params)))
  48          (result-params (nth 2 processed-params))
  49          (result-type (cdr (assoc :result-type params)))
  50          (full-body (org-babel-expand-body:generic
  51                      body params))
  52          (result (org-babel-scala-evaluate
  53                   session full-body result-type result-params)))
  54
  55     (org-babel-reassemble-table
  56      result
  57      (org-babel-pick-name
  58       (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  59      (org-babel-pick-name
  60       (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))
  61
  62 (defvar org-babel-scala-wrapper-method
  63
  64 "var str_result :String = null;
  65
  66 Console.withOut(new java.io.OutputStream() {def write(b: Int){
  67 }}) {
  68   str_result = {
  69 %s
  70   }.toString
  71 }
  72
  73 print(str_result)
  74 ")
  75
  76
  77 (defun org-babel-scala-evaluate
  78   (session body &optional result-type result-params)
  79   "Evaluate BODY in external Scala process.
  80 If RESULT-TYPE equals `output' then return standard output as a string.
  81 If RESULT-TYPE equals `value' then return the value of the last statement
  82 in BODY as elisp."
  83   (when session (error "Sessions are not (yet) supported for Scala"))
  84   (case result-type
  85     (output
  86      (let ((src-file (org-babel-temp-file "scala-")))
  87        (progn (with-temp-file src-file (insert body))
  88               (org-babel-eval
  89                (concat org-babel-scala-command " " src-file) ""))))
  90     (value
  91      (let* ((src-file (org-babel-temp-file "scala-"))
  92             (wrapper (format org-babel-scala-wrapper-method body)))
  93        (with-temp-file src-file (insert wrapper))
  94        (let ((raw (org-babel-eval
  95                    (concat org-babel-scala-command " " src-file) "")))
  96          (org-babel-result-cond result-params
  97            raw
  98            (org-babel-script-escape raw)))))))
  99
 100
 101 (defun org-babel-prep-session:scala (_session _params)
 102   "Prepare SESSION according to the header arguments specified in PARAMS."
 103   (error "Sessions are not (yet) supported for Scala"))
 104
 105 (defun org-babel-scala-initiate-session (&optional _session)
 106   "If there is not a current inferior-process-buffer in SESSION
 107 then create.  Return the initialized session.  Sessions are not
 108 supported in Scala."
 109   nil)
 110
 111 (provide 'ob-scala)
 112
 113
 114
 115 ;;; ob-scala.el ends here