lisp/ob-python.el

   1 ;;; ob-python.el --- Babel Functions for Python      -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function org-remove-indentation "org" )
  34 (declare-function org-trim "org" (s &optional keep-lead))
  35 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  36 (declare-function py-toggle-shells "ext:python-mode" (arg))
  37 (declare-function run-python "ext:python" (&optional cmd dedicated show))
  38
  39 (defvar org-babel-tangle-lang-exts)
  40 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  41
  42 (defvar org-babel-default-header-args:python '())
  43
  44 (defcustom org-babel-python-command "python"
  45   "Name of the command for executing Python code."
  46   :version "24.4"
  47   :package-version '(Org . "8.0")
  48   :group 'org-babel
  49   :type 'string)
  50
  51 (defcustom org-babel-python-mode
  52   (if (featurep 'python-mode) 'python-mode 'python)
  53   "Preferred python mode for use in running python interactively.
  54 This will typically be either `python' or `python-mode'."
  55   :group 'org-babel
  56   :version "24.4"
  57   :package-version '(Org . "8.0")
  58   :type 'symbol)
  59
  60 (defcustom org-babel-python-hline-to "None"
  61   "Replace hlines in incoming tables with this when translating to python."
  62   :group 'org-babel
  63   :version "24.4"
  64   :package-version '(Org . "8.0")
  65   :type 'string)
  66
  67 (defcustom org-babel-python-None-to 'hline
  68   "Replace `None' in python tables with this before returning."
  69   :group 'org-babel
  70   :version "24.4"
  71   :package-version '(Org . "8.0")
  72   :type 'symbol)
  73
  74 (defun org-babel-execute:python (body params)
  75   "Execute a block of Python code with Babel.
  76 This function is called by `org-babel-execute-src-block'."
  77   (let* ((session (org-babel-python-initiate-session
  78                    (cdr (assoc :session params))))
  79          (result-params (cdr (assoc :result-params params)))
  80          (result-type (cdr (assoc :result-type params)))
  81          (return-val (when (and (eq result-type 'value) (not session))
  82                        (cdr (assoc :return params))))
  83          (preamble (cdr (assoc :preamble params)))
  84          (org-babel-python-command
  85           (or (cdr (assoc :python params)) org-babel-python-command))
  86          (full-body
  87           (org-babel-expand-body:generic
  88            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  89            params (org-babel-variable-assignments:python params)))
  90          (result (org-babel-python-evaluate
  91                   session full-body result-type result-params preamble)))
  92     (org-babel-reassemble-table
  93      result
  94      (org-babel-pick-name (cdr (assoc :colname-names params))
  95                           (cdr (assoc :colnames params)))
  96      (org-babel-pick-name (cdr (assoc :rowname-names params))
  97                           (cdr (assoc :rownames params))))))
  98
  99 (defun org-babel-prep-session:python (session params)
 100   "Prepare SESSION according to the header arguments in PARAMS.
 101 VARS contains resolved variable references"
 102   (let* ((session (org-babel-python-initiate-session session))
 103          (var-lines
 104           (org-babel-variable-assignments:python params)))
 105     (org-babel-comint-in-buffer session
 106       (mapc (lambda (var)
 107               (end-of-line 1) (insert var) (comint-send-input)
 108               (org-babel-comint-wait-for-output session)) var-lines))
 109     session))
 110
 111 (defun org-babel-load-session:python (session body params)
 112   "Load BODY into SESSION."
 113   (save-window-excursion
 114     (let ((buffer (org-babel-prep-session:python session params)))
 115       (with-current-buffer buffer
 116         (goto-char (process-mark (get-buffer-process (current-buffer))))
 117         (insert (org-babel-chomp body)))
 118       buffer)))
 119
 120 ;; helper functions
 121
 122 (defun org-babel-variable-assignments:python (params)
 123   "Return a list of Python statements assigning the block's variables."
 124   (mapcar
 125    (lambda (pair)
 126      (format "%s=%s"
 127              (car pair)
 128              (org-babel-python-var-to-python (cdr pair))))
 129    (org-babel--get-vars params)))
 130
 131 (defun org-babel-python-var-to-python (var)
 132   "Convert an elisp value to a python variable.
 133 Convert an elisp value, VAR, into a string of python source code
 134 specifying a variable of the same value."
 135   (if (listp var)
 136       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 137     (if (equal var 'hline)
 138         org-babel-python-hline-to
 139       (format
 140        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 141        (if (stringp var) (substring-no-properties var) var)))))
 142
 143 (defun org-babel-python-table-or-string (results)
 144   "Convert RESULTS into an appropriate elisp value.
 145 If the results look like a list or tuple, then convert them into an
 146 Emacs-lisp table, otherwise return the results as a string."
 147   (let ((res (org-babel-script-escape results)))
 148     (if (listp res)
 149         (mapcar (lambda (el) (if (equal el 'None)
 150                             org-babel-python-None-to el))
 151                 res)
 152       res)))
 153
 154 (defvar org-babel-python-buffers '((:default . "*Python*")))
 155
 156 (defun org-babel-python-session-buffer (session)
 157   "Return the buffer associated with SESSION."
 158   (cdr (assoc session org-babel-python-buffers)))
 159
 160 (defun org-babel-python-with-earmuffs (session)
 161   (let ((name (if (stringp session) session (format "%s" session))))
 162     (if (and (string= "*" (substring name 0 1))
 163              (string= "*" (substring name (- (length name) 1))))
 164         name
 165       (format "*%s*" name))))
 166
 167 (defun org-babel-python-without-earmuffs (session)
 168   (let ((name (if (stringp session) session (format "%s" session))))
 169     (if (and (string= "*" (substring name 0 1))
 170              (string= "*" (substring name (- (length name) 1))))
 171         (substring name 1 (- (length name) 1))
 172       name)))
 173
 174 (defvar py-default-interpreter)
 175 (defvar py-which-bufname)
 176 (defvar python-shell-buffer-name)
 177 (defun org-babel-python-initiate-session-by-key (&optional session)
 178   "Initiate a python session.
 179 If there is not a current inferior-process-buffer in SESSION
 180 then create.  Return the initialized session."
 181   (require org-babel-python-mode)
 182   (save-window-excursion
 183     (let* ((session (if session (intern session) :default))
 184            (python-buffer (org-babel-python-session-buffer session))
 185            (cmd (if (member system-type '(cygwin windows-nt ms-dos))
 186                     (concat org-babel-python-command " -i")
 187                   org-babel-python-command)))
 188       (cond
 189        ((and (eq 'python org-babel-python-mode)
 190              (fboundp 'run-python)) ; python.el
 191         (if (not (version< "24.1" emacs-version))
 192             (run-python cmd)
 193           (unless python-buffer
 194             (setq python-buffer (org-babel-python-with-earmuffs session)))
 195           (let ((python-shell-buffer-name
 196                  (org-babel-python-without-earmuffs python-buffer)))
 197             (run-python cmd))))
 198        ((and (eq 'python-mode org-babel-python-mode)
 199              (fboundp 'py-shell)) ; python-mode.el
 200         ;; Make sure that py-which-bufname is initialized, as otherwise
 201         ;; it will be overwritten the first time a Python buffer is
 202         ;; created.
 203         (py-toggle-shells py-default-interpreter)
 204         ;; `py-shell' creates a buffer whose name is the value of
 205         ;; `py-which-bufname' with '*'s at the beginning and end
 206         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 207                             (replace-regexp-in-string ;; zap surrounding *
 208                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 209                           (concat "Python-" (symbol-name session))))
 210                (py-which-bufname bufname))
 211           (py-shell)
 212           (setq python-buffer (org-babel-python-with-earmuffs bufname))))
 213        (t
 214         (error "No function available for running an inferior Python")))
 215       (setq org-babel-python-buffers
 216             (cons (cons session python-buffer)
 217                   (assq-delete-all session org-babel-python-buffers)))
 218       session)))
 219
 220 (defun org-babel-python-initiate-session (&optional session _params)
 221   "Create a session named SESSION according to PARAMS."
 222   (unless (string= session "none")
 223     (org-babel-python-session-buffer
 224      (org-babel-python-initiate-session-by-key session))))
 225
 226 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 227   "A string to indicate that evaluation has completed.")
 228 (defconst org-babel-python-wrapper-method
 229   "
 230 def main():
 231 %s
 232
 233 open('%s', 'w').write( str(main()) )")
 234 (defconst org-babel-python-pp-wrapper-method
 235   "
 236 import pprint
 237 def main():
 238 %s
 239
 240 open('%s', 'w').write( pprint.pformat(main()) )")
 241
 242 (defun org-babel-python-evaluate
 243   (session body &optional result-type result-params preamble)
 244   "Evaluate BODY as Python code."
 245   (if session
 246       (org-babel-python-evaluate-session
 247        session body result-type result-params)
 248     (org-babel-python-evaluate-external-process
 249      body result-type result-params preamble)))
 250
 251 (defun org-babel-python-evaluate-external-process
 252     (body &optional result-type result-params preamble)
 253   "Evaluate BODY in external python process.
 254 If RESULT-TYPE equals `output' then return standard output as a
 255 string.  If RESULT-TYPE equals `value' then return the value of the
 256 last statement in BODY, as elisp."
 257   (let ((raw
 258          (case result-type
 259            (output (org-babel-eval org-babel-python-command
 260                                    (concat (if preamble (concat preamble "\n"))
 261                                            body)))
 262            (value (let ((tmp-file (org-babel-temp-file "python-")))
 263                     (org-babel-eval
 264                      org-babel-python-command
 265                      (concat
 266                       (if preamble (concat preamble "\n") "")
 267                       (format
 268                        (if (member "pp" result-params)
 269                            org-babel-python-pp-wrapper-method
 270                          org-babel-python-wrapper-method)
 271                        (mapconcat
 272                         (lambda (line) (format "\t%s" line))
 273                         (split-string (org-remove-indentation (org-trim body))
 274                                       "[\r\n]")
 275                         "\n")
 276                        (org-babel-process-file-name tmp-file 'noquote))))
 277                     (org-babel-eval-read-file tmp-file))))))
 278     (org-babel-result-cond result-params
 279       raw
 280       (org-babel-python-table-or-string (org-trim raw)))))
 281
 282 (defun org-babel-python-evaluate-session
 283     (session body &optional result-type result-params)
 284   "Pass BODY to the Python process in SESSION.
 285 If RESULT-TYPE equals `output' then return standard output as a
 286 string.  If RESULT-TYPE equals `value' then return the value of the
 287 last statement in BODY, as elisp."
 288   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 289          (dump-last-value
 290           (lambda
 291             (tmp-file pp)
 292             (mapc
 293              (lambda (statement) (insert statement) (funcall send-wait))
 294              (if pp
 295                  (list
 296                   "import pprint"
 297                   (format "open('%s', 'w').write(pprint.pformat(_))"
 298                           (org-babel-process-file-name tmp-file 'noquote)))
 299                (list (format "open('%s', 'w').write(str(_))"
 300                              (org-babel-process-file-name tmp-file
 301                                                           'noquote)))))))
 302          (input-body (lambda (body)
 303                        (mapc (lambda (line) (insert line) (funcall send-wait))
 304                              (split-string body "[\r\n]"))
 305                        (funcall send-wait)))
 306          (results
 307           (case result-type
 308             (output
 309              (mapconcat
 310               #'org-trim
 311               (butlast
 312                (org-babel-comint-with-output
 313                    (session org-babel-python-eoe-indicator t body)
 314                  (funcall input-body body)
 315                  (funcall send-wait) (funcall send-wait)
 316                  (insert org-babel-python-eoe-indicator)
 317                  (funcall send-wait))
 318                2) "\n"))
 319             (value
 320              (let ((tmp-file (org-babel-temp-file "python-")))
 321                (org-babel-comint-with-output
 322                    (session org-babel-python-eoe-indicator nil body)
 323                  (let ((comint-process-echoes nil))
 324                    (funcall input-body body)
 325                    (funcall dump-last-value tmp-file
 326                             (member "pp" result-params))
 327                    (funcall send-wait) (funcall send-wait)
 328                    (insert org-babel-python-eoe-indicator)
 329                    (funcall send-wait)))
 330                (org-babel-eval-read-file tmp-file))))))
 331     (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 332       (org-babel-result-cond result-params
 333         results
 334         (org-babel-python-table-or-string results)))))
 335
 336 (defun org-babel-python-read-string (string)
 337   "Strip \\='s from around Python string."
 338   (if (string-match "^'\\([^\000]+\\)'$" string)
 339       (match-string 1 string)
 340     string))
 341
 342 (provide 'ob-python)
 343
 344
 345
 346 ;;; ob-python.el ends here