contrib/lisp/ox-rss.el

   1 ;;; ox-rss.el --- RSS 2.0 Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013, 2014  Bastien Guerry
   4
   5 ;; Author: Bastien Guerry <bzg@gnu.org>
   6 ;; Keywords: org, wp, blog, feed, rss
   7
   8 ;; This file is not yet part of GNU Emacs.
   9
  10 ;; This program is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a RSS 2.0 back-end for Org exporter, based on
  26 ;; the `html' back-end.
  27 ;;
  28 ;; It requires Emacs 24.1 at least.
  29 ;;
  30 ;; It provides two commands for export, depending on the desired output:
  31 ;; `org-rss-export-as-rss' (temporary buffer) and `org-rss-export-to-rss'
  32 ;; (as a ".xml" file).
  33 ;;
  34 ;; This backend understands two new option keywords:
  35 ;;
  36 ;; #+RSS_EXTENSION: xml
  37 ;; #+RSS_IMAGE_URL: http://myblog.org/mypicture.jpg
  38 ;;
  39 ;; It uses #+HTML_LINK_HOME: to set the base url of the feed.
  40 ;;
  41 ;; Exporting an Org file to RSS modifies each top-level entry by adding a
  42 ;; PUBDATE property.  If `org-rss-use-entry-url-as-guid', it will also add
  43 ;; an ID property, later used as the guid for the feed's item.
  44 ;;
  45 ;; You typically want to use it within a publishing project like this:
  46 ;;
  47 ;; (add-to-list
  48 ;;  'org-publish-project-alist
  49 ;;  '("homepage_rss"
  50 ;;    :base-directory "~/myhomepage/"
  51 ;;    :base-extension "org"
  52 ;;    :rss-image-url "http://lumiere.ens.fr/~guerry/images/faces/15.png"
  53 ;;    :html-link-home "http://lumiere.ens.fr/~guerry/"
  54 ;;    :html-link-use-abs-url t
  55 ;;    :rss-extension "xml"
  56 ;;    :publishing-directory "/home/guerry/public_html/"
  57 ;;    :publishing-function (org-rss-publish-to-rss)
  58 ;;    :section-numbers nil
  59 ;;    :exclude ".*"            ;; To exclude all files...
  60 ;;    :include ("index.org")   ;; ... except index.org.
  61 ;;    :table-of-contents nil))
  62 ;;
  63 ;; ... then rsync /home/guerry/public_html/ with your server.
  64 ;;
  65 ;; By default, the permalink for a blog entry points to the headline.
  66 ;; You can specify a different one by using the :RSS_PERMALINK:
  67 ;; property within an entry.
  68
  69 ;;; Code:
  70
  71 (require 'ox-html)
  72 (declare-function url-encode-url "url-util" (url))
  73
  74 ;;; Variables and options
  75
  76 (defgroup org-export-rss nil
  77   "Options specific to RSS export back-end."
  78   :tag "Org RSS"
  79   :group 'org-export
  80   :version "24.4"
  81   :package-version '(Org . "8.0"))
  82
  83 (defcustom org-rss-image-url "http://orgmode.org/img/org-mode-unicorn-logo.png"
  84   "The URL of the an image for the RSS feed."
  85   :group 'org-export-rss
  86   :type 'string)
  87
  88 (defcustom org-rss-extension "xml"
  89   "File extension for the RSS 2.0 feed."
  90   :group 'org-export-rss
  91   :type 'string)
  92
  93 (defcustom org-rss-categories 'from-tags
  94   "Where to extract items category information from.
  95 The default is to extract categories from the tags of the
  96 headlines.  When set to another value, extract the category
  97 from the :CATEGORY: property of the entry."
  98   :group 'org-export-rss
  99   :type '(choice
 100           (const :tag "From tags" from-tags)
 101           (const :tag "From the category property" from-category)))
 102
 103 (defcustom org-rss-use-entry-url-as-guid t
 104   "Use the URL for the <guid> metatag?
 105 When nil, Org will create ids using `org-icalendar-create-uid'."
 106   :group 'org-export-rss
 107   :type 'boolean)
 108
 109 ;;; Define backend
 110
 111 (org-export-define-derived-backend 'rss 'html
 112   :menu-entry
 113   '(?r "Export to RSS"
 114        ((?R "As RSS buffer"
 115             (lambda (a s v b) (org-rss-export-as-rss a s v)))
 116         (?r "As RSS file" (lambda (a s v b) (org-rss-export-to-rss a s v)))
 117         (?o "As RSS file and open"
 118             (lambda (a s v b)
 119               (if a (org-rss-export-to-rss t s v)
 120                 (org-open-file (org-rss-export-to-rss nil s v)))))))
 121   :options-alist
 122   '((:with-toc nil nil nil) ;; Never include HTML's toc
 123     (:rss-extension "RSS_EXTENSION" nil org-rss-extension)
 124     (:rss-image-url "RSS_IMAGE_URL" nil org-rss-image-url)
 125     (:rss-categories nil nil org-rss-categories))
 126   :filters-alist '((:filter-final-output . org-rss-final-function))
 127   :translate-alist '((headline . org-rss-headline)
 128                      (comment . (lambda (&rest args) ""))
 129                      (comment-block . (lambda (&rest args) ""))
 130                      (timestamp . (lambda (&rest args) ""))
 131                      (plain-text . org-rss-plain-text)
 132                      (section . org-rss-section)
 133                      (template . org-rss-template)))
 134
 135 ;;; Export functions
 136
 137 ;;;###autoload
 138 (defun org-rss-export-as-rss (&optional async subtreep visible-only)
 139   "Export current buffer to a RSS buffer.
 140
 141 If narrowing is active in the current buffer, only export its
 142 narrowed part.
 143
 144 If a region is active, export that region.
 145
 146 A non-nil optional argument ASYNC means the process should happen
 147 asynchronously.  The resulting buffer should be accessible
 148 through the `org-export-stack' interface.
 149
 150 When optional argument SUBTREEP is non-nil, export the sub-tree
 151 at point, extracting information from the headline properties
 152 first.
 153
 154 When optional argument VISIBLE-ONLY is non-nil, don't export
 155 contents of hidden elements.
 156
 157 Export is done in a buffer named \"*Org RSS Export*\", which will
 158 be displayed when `org-export-show-temporary-export-buffer' is
 159 non-nil."
 160   (interactive)
 161   (let ((file (buffer-file-name (buffer-base-buffer))))
 162     (org-icalendar-create-uid file 'warn-user)
 163     (org-rss-add-pubdate-property))
 164   (org-export-to-buffer 'rss "*Org RSS Export*"
 165     async subtreep visible-only nil nil (lambda () (text-mode))))
 166
 167 ;;;###autoload
 168 (defun org-rss-export-to-rss (&optional async subtreep visible-only)
 169   "Export current buffer to a RSS file.
 170
 171 If narrowing is active in the current buffer, only export its
 172 narrowed part.
 173
 174 If a region is active, export that region.
 175
 176 A non-nil optional argument ASYNC means the process should happen
 177 asynchronously.  The resulting file should be accessible through
 178 the `org-export-stack' interface.
 179
 180 When optional argument SUBTREEP is non-nil, export the sub-tree
 181 at point, extracting information from the headline properties
 182 first.
 183
 184 When optional argument VISIBLE-ONLY is non-nil, don't export
 185 contents of hidden elements.
 186
 187 Return output file's name."
 188   (interactive)
 189   (let ((file (buffer-file-name (buffer-base-buffer))))
 190     (org-icalendar-create-uid file 'warn-user)
 191     (org-rss-add-pubdate-property))
 192   (let ((outfile (org-export-output-file-name
 193                   (concat "." org-rss-extension) subtreep)))
 194     (org-export-to-file 'rss outfile async subtreep visible-only)))
 195
 196 ;;;###autoload
 197 (defun org-rss-publish-to-rss (plist filename pub-dir)
 198   "Publish an org file to RSS.
 199
 200 FILENAME is the filename of the Org file to be published.  PLIST
 201 is the property list for the given project.  PUB-DIR is the
 202 publishing directory.
 203
 204 Return output file name."
 205   (let ((bf (get-file-buffer filename)))
 206     (if bf
 207         (with-current-buffer bf
 208           (org-rss-add-pubdate-property)
 209           (write-file filename))
 210       (find-file filename)
 211       (org-rss-add-pubdate-property)
 212       (write-file filename) (kill-buffer)))
 213   (org-publish-org-to
 214    'rss filename (concat "." org-rss-extension) plist pub-dir))
 215
 216 ;;; Main transcoding functions
 217
 218 (defun org-rss-headline (headline contents info)
 219   "Transcode HEADLINE element into RSS format.
 220 CONTENTS is the headline contents.  INFO is a plist used as a
 221 communication channel."
 222   (unless (or (org-element-property :footnote-section-p headline)
 223               ;; Only consider first-level headlines
 224               (> (org-export-get-relative-level headline info) 1))
 225     (let* ((htmlext (plist-get info :html-extension))
 226            (hl-number (org-export-get-headline-number headline info))
 227            (hl-home (file-name-as-directory (plist-get info :html-link-home)))
 228            (hl-pdir (plist-get info :publishing-directory))
 229            (hl-perm (org-element-property :RSS_PERMALINK headline))
 230            (anchor
 231             (org-export-solidify-link-text
 232              (or (org-element-property :CUSTOM_ID headline)
 233                  (concat "sec-" (mapconcat 'number-to-string hl-number "-")))))
 234            (category (org-rss-plain-text
 235                       (or (org-element-property :CATEGORY headline) "") info))
 236            (pubdate
 237             (let ((system-time-locale "C"))
 238               (format-time-string
 239                "%a, %d %b %Y %H:%M:%S %z"
 240                (org-time-string-to-time
 241                 (or (org-element-property :PUBDATE headline)
 242                     (error "Missing PUBDATE property"))))))
 243            (title (replace-regexp-in-string
 244                    org-bracket-link-regexp
 245                    (lambda (m) (or (match-string 3 m)
 246                                    (match-string 1 m)))
 247                    (org-element-property :raw-value headline)))
 248            (publink
 249             (or (and hl-perm (concat (or hl-home hl-pdir) hl-perm))
 250                 (concat
 251                  (or hl-home hl-pdir)
 252                  (file-name-nondirectory
 253                   (file-name-sans-extension
 254                    (plist-get info :input-file))) "." htmlext "#" anchor)))
 255            (guid (if org-rss-use-entry-url-as-guid
 256                      publink
 257                    (org-rss-plain-text
 258                     (or (org-element-property :ID headline)
 259                         (org-element-property :CUSTOM_ID headline)
 260                         publink)
 261                     info))))
 262       (format
 263        (concat
 264         "<item>\n"
 265         "<title>%s</title>\n"
 266         "<link>%s</link>\n"
 267         "<guid isPermaLink=\"false\">%s</guid>\n"
 268         "<pubDate>%s</pubDate>\n"
 269         (org-rss-build-categories headline info) "\n"
 270         "<description><![CDATA[%s]]></description>\n"
 271         "</item>\n")
 272        title publink guid pubdate contents))))
 273
 274 (defun org-rss-build-categories (headline info)
 275   "Build categories for the RSS item."
 276   (if (eq (plist-get info :rss-categories) 'from-tags)
 277       (mapconcat
 278        (lambda (c) (format "<category><![CDATA[%s]]></category>" c))
 279        (org-element-property :tags headline)
 280        "\n")
 281     (let ((c (org-element-property :CATEGORY headline)))
 282       (format "<category><![CDATA[%s]]></category>" c))))
 283
 284 (defun org-rss-template (contents info)
 285   "Return complete document string after RSS conversion.
 286 CONTENTS is the transcoded contents string.  INFO is a plist used
 287 as a communication channel."
 288   (concat
 289    (format "<?xml version=\"1.0\" encoding=\"%s\"?>"
 290            (symbol-name org-html-coding-system))
 291    "\n<rss version=\"2.0\"
 292         xmlns:content=\"http://purl.org/rss/1.0/modules/content/\"
 293         xmlns:wfw=\"http://wellformedweb.org/CommentAPI/\"
 294         xmlns:dc=\"http://purl.org/dc/elements/1.1/\"
 295         xmlns:atom=\"http://www.w3.org/2005/Atom\"
 296         xmlns:sy=\"http://purl.org/rss/1.0/modules/syndication/\"
 297         xmlns:slash=\"http://purl.org/rss/1.0/modules/slash/\"
 298         xmlns:georss=\"http://www.georss.org/georss\"
 299         xmlns:geo=\"http://www.w3.org/2003/01/geo/wgs84_pos#\"
 300         xmlns:media=\"http://search.yahoo.com/mrss/\">"
 301    "<channel>"
 302    (org-rss-build-channel-info info) "\n"
 303    contents
 304    "</channel>\n"
 305    "</rss>"))
 306
 307 (defun org-rss-build-channel-info (info)
 308   "Build the RSS channel information."
 309   (let* ((system-time-locale "C")
 310          (title (plist-get info :title))
 311          (email (org-export-data (plist-get info :email) info))
 312          (author (and (plist-get info :with-author)
 313                       (let ((auth (plist-get info :author)))
 314                         (and auth (org-export-data auth info)))))
 315          (date (format-time-string "%a, %d %b %Y %H:%M:%S %z")) ;; RFC 882
 316          (description (org-export-data (plist-get info :description) info))
 317          (lang (plist-get info :language))
 318          (keywords (plist-get info :keywords))
 319          (rssext (plist-get info :rss-extension))
 320          (blogurl (or (plist-get info :html-link-home)
 321                       (plist-get info :publishing-directory)))
 322          (image (url-encode-url (plist-get info :rss-image-url)))
 323          (ifile (plist-get info :input-file))
 324          (publink
 325           (concat (file-name-as-directory blogurl)
 326                   (file-name-nondirectory
 327                    (file-name-sans-extension ifile))
 328                   "." rssext)))
 329     (format
 330      "\n<title>%s</title>
 331 <atom:link href=\"%s\" rel=\"self\" type=\"application/rss+xml\" />
 332 <link>%s</link>
 333 <description><![CDATA[%s]]></description>
 334 <language>%s</language>
 335 <pubDate>%s</pubDate>
 336 <lastBuildDate>%s</lastBuildDate>
 337 <generator>%s</generator>
 338 <webMaster>%s (%s)</webMaster>
 339 <image>
 340 <url>%s</url>
 341 <title>%s</title>
 342 <link>%s</link>
 343 </image>
 344 "
 345      title publink blogurl description lang date date
 346      (concat (format "Emacs %d.%d"
 347                      emacs-major-version
 348                      emacs-minor-version)
 349              " Org-mode " (org-version))
 350      email author image title blogurl)))
 351
 352 (defun org-rss-section (section contents info)
 353   "Transcode SECTION element into RSS format.
 354 CONTENTS is the section contents.  INFO is a plist used as
 355 a communication channel."
 356   contents)
 357
 358 (defun org-rss-timestamp (timestamp contents info)
 359   "Transcode a TIMESTAMP object from Org to RSS.
 360 CONTENTS is nil.  INFO is a plist holding contextual
 361 information."
 362   (org-html-encode-plain-text
 363    (org-timestamp-translate timestamp)))
 364
 365 (defun org-rss-plain-text (contents info)
 366   "Convert plain text into RSS encoded text."
 367   (let (output)
 368     (setq output (org-html-encode-plain-text contents)
 369           output (org-export-activate-smart-quotes
 370                   output :html info))))
 371
 372 ;;; Filters
 373
 374 (defun org-rss-final-function (contents backend info)
 375   "Prettify the RSS output."
 376   (with-temp-buffer
 377     (xml-mode)
 378     (insert contents)
 379     (indent-region (point-min) (point-max))
 380     (buffer-substring-no-properties (point-min) (point-max))))
 381
 382 ;;; Miscellaneous
 383
 384 (defun org-rss-add-pubdate-property ()
 385   "Set the PUBDATE property for top-level headlines."
 386   (let (msg)
 387     (org-map-entries
 388      (lambda ()
 389        (let* ((entry (org-element-at-point))
 390               (level (org-element-property :level entry)))
 391          (when (= level 1)
 392            (unless (org-entry-get (point) "PUBDATE")
 393              (setq msg t)
 394              (org-set-property
 395               "PUBDATE" (format-time-string
 396                          (cdr org-time-stamp-formats)))))))
 397      nil nil 'comment 'archive)
 398     (when msg
 399       (message "Property PUBDATE added to top-level entries in %s"
 400                (buffer-file-name))
 401       (sit-for 2))))
 402
 403 (provide 'ox-rss)
 404
 405 ;;; ox-rss.el ends here