lisp/ox-icalendar.el

   1 ;;; ox-icalendar.el --- iCalendar Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;      Nicolas Goaziou <n dot goaziou at gmail dot com>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; This library implements an iCalendar back-end for Org generic
  28 ;; exporter.  See Org manual for more information.
  29 ;;
  30 ;; It is expected to conform to RFC 5545.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35 (require 'ox-ascii)
  36 (declare-function org-bbdb-anniv-export-ical "org-bbdb" nil)
  37
  38
  39 \f
  40 ;;; User-Configurable Variables
  41
  42 (defgroup org-export-icalendar nil
  43   "Options specific for iCalendar export back-end."
  44   :tag "Org Export iCalendar"
  45   :group 'org-export)
  46
  47 (defcustom org-icalendar-combined-agenda-file "~/org.ics"
  48   "The file name for the iCalendar file covering all agenda files.
  49 This file is created with the command \\[org-icalendar-combine-agenda-files].
  50 The file name should be absolute.  It will be overwritten without warning."
  51   :group 'org-export-icalendar
  52   :type 'file)
  53
  54 (defcustom org-icalendar-alarm-time 0
  55   "Number of minutes for triggering an alarm for exported timed events.
  56
  57 A zero value (the default) turns off the definition of an alarm trigger
  58 for timed events.  If non-zero, alarms are created.
  59
  60 - a single alarm per entry is defined
  61 - The alarm will go off N minutes before the event
  62 - only a DISPLAY action is defined."
  63   :group 'org-export-icalendar
  64   :version "24.1"
  65   :type 'integer)
  66
  67 (defcustom org-icalendar-combined-name "OrgMode"
  68   "Calendar name for the combined iCalendar representing all agenda files."
  69   :group 'org-export-icalendar
  70   :type 'string)
  71
  72 (defcustom org-icalendar-combined-description ""
  73   "Calendar description for the combined iCalendar (all agenda files)."
  74   :group 'org-export-icalendar
  75   :type 'string)
  76
  77 (defcustom org-icalendar-exclude-tags nil
  78   "Tags that exclude a tree from export.
  79 This variable allows to specify different exclude tags from other
  80 back-ends.  It can also be set with the ICAL_EXCLUDE_TAGS
  81 keyword."
  82   :group 'org-export-icalendar
  83   :type '(repeat (string :tag "Tag")))
  84
  85 (defcustom org-icalendar-use-deadline '(event-if-not-todo todo-due)
  86   "Contexts where iCalendar export should use a deadline time stamp.
  87
  88 This is a list with possibly several symbols in it.  Valid symbols are:
  89
  90 `event-if-todo'       Deadlines in TODO entries become calendar events.
  91 `event-if-not-todo'   Deadlines in non-TODO entries become calendar events.
  92 `todo-due'            Use deadlines in TODO entries as due-dates."
  93   :group 'org-export-icalendar
  94   :type '(set :greedy t
  95               (const :tag "Deadlines in non-TODO entries become events"
  96                      event-if-not-todo)
  97               (const :tag "Deadline in TODO entries become events"
  98                      event-if-todo)
  99               (const :tag "Deadlines in TODO entries become due-dates"
 100                      todo-due)))
 101
 102 (defcustom org-icalendar-use-scheduled '(todo-start)
 103   "Contexts where iCalendar export should use a scheduling time stamp.
 104
 105 This is a list with possibly several symbols in it.  Valid symbols are:
 106
 107 `event-if-todo'       Scheduling time stamps in TODO entries become an event.
 108 `event-if-not-todo'   Scheduling time stamps in non-TODO entries become an event.
 109 `todo-start'          Scheduling time stamps in TODO entries become start date.
 110                       Some calendar applications show TODO entries only after
 111                       that date."
 112   :group 'org-export-icalendar
 113   :type '(set :greedy t
 114               (const :tag
 115                      "SCHEDULED timestamps in non-TODO entries become events"
 116                      event-if-not-todo)
 117               (const :tag "SCHEDULED timestamps in TODO entries become events"
 118                      event-if-todo)
 119               (const :tag "SCHEDULED in TODO entries become start date"
 120                      todo-start)))
 121
 122 (defcustom org-icalendar-categories '(local-tags category)
 123   "Items that should be entered into the \"categories\" field.
 124
 125 This is a list of symbols, the following are valid:
 126 `category'    The Org mode category of the current file or tree
 127 `todo-state'  The todo state, if any
 128 `local-tags'  The tags, defined in the current line
 129 `all-tags'    All tags, including inherited ones."
 130   :group 'org-export-icalendar
 131   :type '(repeat
 132           (choice
 133            (const :tag "The file or tree category" category)
 134            (const :tag "The TODO state" todo-state)
 135            (const :tag "Tags defined in current line" local-tags)
 136            (const :tag "All tags, including inherited ones" all-tags))))
 137
 138 (defcustom org-icalendar-with-timestamps 'active
 139   "Non-nil means make an event from plain time stamps.
 140
 141 It can be set to `active', `inactive', t or nil, in order to make
 142 an event from, respectively, only active timestamps, only
 143 inactive ones, all of them or none.
 144
 145 This variable has precedence over `org-export-with-timestamps'.
 146 It can also be set with the #+OPTIONS line, e.g. \"<:t\"."
 147   :group 'org-export-icalendar
 148   :type '(choice
 149           (const :tag "All timestamps" t)
 150           (const :tag "Only active timestamps" active)
 151           (const :tag "Only inactive timestamps" inactive)
 152           (const :tag "No timestamp" nil)))
 153
 154 (defcustom org-icalendar-include-todo nil
 155   "Non-nil means create VTODO components from TODO items.
 156
 157 Valid values are:
 158 nil                  don't include any task.
 159 t                    include tasks that are not in DONE state.
 160 `unblocked'          include all TODO items that are not blocked.
 161 `all'                include both done and not done items."
 162   :group 'org-export-icalendar
 163   :type '(choice
 164           (const :tag "None" nil)
 165           (const :tag "Unfinished" t)
 166           (const :tag "Unblocked" unblocked)
 167           (const :tag "All" all)
 168           (repeat :tag "Specific TODO keywords"
 169                   (string :tag "Keyword"))))
 170
 171 (defcustom org-icalendar-include-bbdb-anniversaries nil
 172   "Non-nil means a combined iCalendar file should include anniversaries.
 173 The anniversaries are defined in the BBDB database."
 174   :group 'org-export-icalendar
 175   :type 'boolean)
 176
 177 (defcustom org-icalendar-include-sexps t
 178   "Non-nil means export to iCalendar files should also cover sexp entries.
 179 These are entries like in the diary, but directly in an Org file."
 180   :group 'org-export-icalendar
 181   :type 'boolean)
 182
 183 (defcustom org-icalendar-include-body t
 184   "Amount of text below headline to be included in iCalendar export.
 185 This is a number of characters that should maximally be included.
 186 Properties, scheduling and clocking lines will always be removed.
 187 The text will be inserted into the DESCRIPTION field."
 188   :group 'org-export-icalendar
 189   :type '(choice
 190           (const :tag "Nothing" nil)
 191           (const :tag "Everything" t)
 192           (integer :tag "Max characters")))
 193
 194 (defcustom org-icalendar-store-UID nil
 195   "Non-nil means store any created UIDs in properties.
 196
 197 The iCalendar standard requires that all entries have a unique identifier.
 198 Org will create these identifiers as needed.  When this variable is non-nil,
 199 the created UIDs will be stored in the ID property of the entry.  Then the
 200 next time this entry is exported, it will be exported with the same UID,
 201 superseding the previous form of it.  This is essential for
 202 synchronization services.
 203
 204 This variable is not turned on by default because we want to avoid creating
 205 a property drawer in every entry if people are only playing with this feature,
 206 or if they are only using it locally."
 207   :group 'org-export-icalendar
 208   :type 'boolean)
 209
 210 (defcustom org-icalendar-timezone (getenv "TZ")
 211   "The time zone string for iCalendar export.
 212 When nil or the empty string, use output
 213 from (current-time-zone)."
 214   :group 'org-export-icalendar
 215   :type '(choice
 216           (const :tag "Unspecified" nil)
 217           (string :tag "Time zone")))
 218
 219 (defcustom org-icalendar-date-time-format ":%Y%m%dT%H%M%S"
 220   "Format-string for exporting icalendar DATE-TIME.
 221
 222 See `format-time-string' for a full documentation.  The only
 223 difference is that `org-icalendar-timezone' is used for %Z.
 224
 225 Interesting value are:
 226  - \":%Y%m%dT%H%M%S\" for local time
 227  - \";TZID=%Z:%Y%m%dT%H%M%S\" for local time with explicit timezone
 228  - \":%Y%m%dT%H%M%SZ\" for time expressed in Universal Time"
 229   :group 'org-export-icalendar
 230   :version "24.1"
 231   :type '(choice
 232           (const :tag "Local time" ":%Y%m%dT%H%M%S")
 233           (const :tag "Explicit local time" ";TZID=%Z:%Y%m%dT%H%M%S")
 234           (const :tag "Universal time" ":%Y%m%dT%H%M%SZ")
 235           (string :tag "Explicit format")))
 236
 237 (defvar org-icalendar-after-save-hook nil
 238   "Hook run after an iCalendar file has been saved.
 239 This hook is run with the name of the file as argument.  A good
 240 way to use this is to tell a desktop calendar application to
 241 re-read the iCalendar file.")
 242
 243
 244 \f
 245 ;;; Define Back-End
 246
 247 (org-export-define-derived-backend 'icalendar 'ascii
 248   :translate-alist '((clock . ignore)
 249                      (footnote-definition . ignore)
 250                      (footnote-reference . ignore)
 251                      (headline . org-icalendar-entry)
 252                      (inlinetask . ignore)
 253                      (planning . ignore)
 254                      (section . ignore)
 255                      (inner-template . (lambda (c i) c))
 256                      (template . org-icalendar-template))
 257   :options-alist
 258   '((:exclude-tags
 259      "ICALENDAR_EXCLUDE_TAGS" nil org-icalendar-exclude-tags split)
 260     (:with-timestamps nil "<" org-icalendar-with-timestamps)
 261     ;; Other variables.
 262     (:icalendar-alarm-time nil nil org-icalendar-alarm-time)
 263     (:icalendar-categories nil nil org-icalendar-categories)
 264     (:icalendar-date-time-format nil nil org-icalendar-date-time-format)
 265     (:icalendar-include-bbdb-anniversaries nil nil org-icalendar-include-bbdb-anniversaries)
 266     (:icalendar-include-body nil nil org-icalendar-include-body)
 267     (:icalendar-include-sexps nil nil org-icalendar-include-sexps)
 268     (:icalendar-include-todo nil nil org-icalendar-include-todo)
 269     (:icalendar-store-UID nil nil org-icalendar-store-UID)
 270     (:icalendar-timezone nil nil org-icalendar-timezone)
 271     (:icalendar-use-deadline nil nil org-icalendar-use-deadline)
 272     (:icalendar-use-scheduled nil nil org-icalendar-use-scheduled))
 273   :filters-alist
 274   '((:filter-headline . org-icalendar-clear-blank-lines))
 275   :menu-entry
 276   '(?c "Export to iCalendar"
 277        ((?f "Current file" org-icalendar-export-to-ics)
 278         (?a "All agenda files"
 279             (lambda (a s v b) (org-icalendar-export-agenda-files a)))
 280         (?c "Combine all agenda files"
 281             (lambda (a s v b) (org-icalendar-combine-agenda-files a))))))
 282
 283
 284 \f
 285 ;;; Internal Functions
 286
 287 (defun org-icalendar-create-uid (file &optional bell)
 288   "Set ID property on headlines missing it in FILE.
 289 When optional argument BELL is non-nil, inform the user with
 290 a message if the file was modified."
 291   (let (modified-flag)
 292     (org-map-entries
 293      (lambda ()
 294        (let ((entry (org-element-at-point)))
 295          (unless (org-element-property :ID entry)
 296            (org-id-get-create)
 297            (setq modified-flag t)
 298            (forward-line))))
 299      nil nil 'comment)
 300     (when (and bell modified-flag)
 301       (message "ID properties created in file \"%s\"" file)
 302       (sit-for 2))))
 303
 304 (defun org-icalendar-blocked-headline-p (headline info)
 305   "Non-nil when HEADLINE is considered to be blocked.
 306
 307 INFO is a plist used as a communication channel.
 308
 309 A headline is blocked when either
 310
 311   - it has children which are not all in a completed state;
 312
 313   - it has a parent with the property :ORDERED:, and there are
 314     siblings prior to it with incomplete status;
 315
 316   - its parent is blocked because it has siblings that should be
 317     done first or is a child of a blocked grandparent entry."
 318   (or
 319    ;; Check if any child is not done.
 320    (org-element-map headline 'headline
 321      (lambda (hl) (eq (org-element-property :todo-type hl) 'todo))
 322      info 'first-match)
 323    ;; Check :ORDERED: node property.
 324    (catch 'blockedp
 325      (let ((current headline))
 326        (dolist (parent (org-element-lineage headline))
 327          (cond
 328           ((not (org-element-property :todo-keyword parent))
 329            (throw 'blockedp nil))
 330           ((org-not-nil (org-element-property :ORDERED parent))
 331            (let ((sibling current))
 332              (while (setq sibling (org-export-get-previous-element
 333                                    sibling info))
 334                (when (eq (org-element-property :todo-type sibling) 'todo)
 335                  (throw 'blockedp t)))))
 336           (t (setq current parent))))))))
 337
 338 (defun org-icalendar-use-UTC-date-time-p ()
 339   "Non-nil when `org-icalendar-date-time-format' requires UTC time."
 340   (char-equal (elt org-icalendar-date-time-format
 341                    (1- (length org-icalendar-date-time-format))) ?Z))
 342
 343 (defvar org-agenda-default-appointment-duration) ; From org-agenda.el.
 344 (defun org-icalendar-convert-timestamp (timestamp keyword &optional end utc)
 345   "Convert TIMESTAMP to iCalendar format.
 346
 347 TIMESTAMP is a timestamp object.  KEYWORD is added in front of
 348 it, in order to make a complete line (e.g. \"DTSTART\").
 349
 350 When optional argument END is non-nil, use end of time range.
 351 Also increase the hour by two (if time string contains a time),
 352 or the day by one (if it does not contain a time) when no
 353 explicit ending time is specified.
 354
 355 When optional argument UTC is non-nil, time will be expressed in
 356 Universal Time, ignoring `org-icalendar-date-time-format'."
 357   (let* ((year-start (org-element-property :year-start timestamp))
 358          (year-end (org-element-property :year-end timestamp))
 359          (month-start (org-element-property :month-start timestamp))
 360          (month-end (org-element-property :month-end timestamp))
 361          (day-start (org-element-property :day-start timestamp))
 362          (day-end (org-element-property :day-end timestamp))
 363          (hour-start (org-element-property :hour-start timestamp))
 364          (hour-end (org-element-property :hour-end timestamp))
 365          (minute-start (org-element-property :minute-start timestamp))
 366          (minute-end (org-element-property :minute-end timestamp))
 367          (with-time-p minute-start)
 368          (equal-bounds-p
 369           (equal (list year-start month-start day-start hour-start minute-start)
 370                  (list year-end month-end day-end hour-end minute-end)))
 371          (mi (cond ((not with-time-p) 0)
 372                    ((not end) minute-start)
 373                    ((and org-agenda-default-appointment-duration equal-bounds-p)
 374                     (+ minute-end org-agenda-default-appointment-duration))
 375                    (t minute-end)))
 376          (h (cond ((not with-time-p) 0)
 377                   ((not end) hour-start)
 378                   ((or (not equal-bounds-p)
 379                        org-agenda-default-appointment-duration)
 380                    hour-end)
 381                   (t (+ hour-end 2))))
 382          (d (cond ((not end) day-start)
 383                   ((not with-time-p) (1+ day-end))
 384                   (t day-end)))
 385          (m (if end month-end month-start))
 386          (y (if end year-end year-start)))
 387     (concat
 388      keyword
 389      (format-time-string
 390       (cond (utc ":%Y%m%dT%H%M%SZ")
 391             ((not with-time-p) ";VALUE=DATE:%Y%m%d")
 392             (t (replace-regexp-in-string "%Z"
 393                                          org-icalendar-timezone
 394                                          org-icalendar-date-time-format
 395                                          t)))
 396       ;; Convert timestamp into internal time in order to use
 397       ;; `format-time-string' and fix any mistake (i.e. MI >= 60).
 398       (encode-time 0 mi h d m y)
 399       (or utc (and with-time-p (org-icalendar-use-UTC-date-time-p)))))))
 400
 401 (defun org-icalendar-dtstamp ()
 402   "Return DTSTAMP property, as a string."
 403   (format-time-string "DTSTAMP:%Y%m%dT%H%M%SZ" nil t))
 404
 405 (defun org-icalendar-get-categories (entry info)
 406   "Return categories according to `org-icalendar-categories'.
 407 ENTRY is a headline or an inlinetask element.  INFO is a plist
 408 used as a communication channel."
 409   (mapconcat
 410    'identity
 411    (org-uniquify
 412     (let (categories)
 413       (mapc (lambda (type)
 414               (case type
 415                 (category
 416                  (push (org-export-get-category entry info) categories))
 417                 (todo-state
 418                  (let ((todo (org-element-property :todo-keyword entry)))
 419                    (and todo (push todo categories))))
 420                 (local-tags
 421                  (setq categories
 422                        (append (nreverse (org-export-get-tags entry info))
 423                                categories)))
 424                 (all-tags
 425                  (setq categories
 426                        (append (nreverse (org-export-get-tags entry info nil t))
 427                                categories)))))
 428             org-icalendar-categories)
 429       ;; Return list of categories, following specified order.
 430       (nreverse categories))) ","))
 431
 432 (defun org-icalendar-transcode-diary-sexp (sexp uid summary)
 433   "Transcode a diary sexp into iCalendar format.
 434 SEXP is the diary sexp being transcoded, as a string.  UID is the
 435 unique identifier for the entry.  SUMMARY defines a short summary
 436 or subject for the event."
 437   (when (require 'icalendar nil t)
 438     (org-element-normalize-string
 439      (with-temp-buffer
 440        (let ((sexp (if (not (string-match "\\`<%%" sexp)) sexp
 441                      (concat (substring sexp 1 -1) " " summary))))
 442          (put-text-property 0 1 'uid uid sexp)
 443          (insert sexp "\n"))
 444        (org-diary-to-ical-string (current-buffer))))))
 445
 446 (defun org-icalendar-cleanup-string (s)
 447   "Cleanup string S according to RFC 5545."
 448   (when s
 449     ;; Protect "\", "," and ";" characters. and replace newline
 450     ;; characters with literal \n.
 451     (replace-regexp-in-string
 452      "[ \t]*\n" "\\n"
 453      (replace-regexp-in-string "[\\,;]" "\\\&" s)
 454      nil t)))
 455
 456 (defun org-icalendar-fold-string (s)
 457   "Fold string S according to RFC 5545."
 458   (org-element-normalize-string
 459    (mapconcat
 460     (lambda (line)
 461       ;; Limit each line to a maximum of 75 characters.  If it is
 462       ;; longer, fold it by using "\n " as a continuation marker.
 463       (let ((len (length line)))
 464         (if (<= len 75) line
 465           (let ((folded-line (substring line 0 75))
 466                 (chunk-start 75)
 467                 chunk-end)
 468             ;; Since continuation marker takes up one character on the
 469             ;; line, real contents must be split at 74 chars.
 470             (while (< (setq chunk-end (+ chunk-start 74)) len)
 471               (setq folded-line
 472                     (concat folded-line "\n "
 473                             (substring line chunk-start chunk-end))
 474                     chunk-start chunk-end))
 475             (concat folded-line "\n " (substring line chunk-start))))))
 476     (org-split-string s "\n") "\n")))
 477
 478
 479 \f
 480 ;;; Filters
 481
 482 (defun org-icalendar-clear-blank-lines (headline back-end info)
 483   "Remove blank lines in HEADLINE export.
 484 HEADLINE is a string representing a transcoded headline.
 485 BACK-END and INFO are ignored."
 486   (replace-regexp-in-string "^\\(?:[ \t]*\n\\)+" "" headline))
 487
 488
 489 \f
 490 ;;; Transcode Functions
 491
 492 ;;;; Headline and Inlinetasks
 493
 494 ;; The main function is `org-icalendar-entry', which extracts
 495 ;; information from a headline or an inlinetask (summary,
 496 ;; description...) and then delegates code generation to
 497 ;; `org-icalendar--vtodo' and `org-icalendar--vevent', depending
 498 ;; on the component needed.
 499
 500 ;; Obviously, `org-icalendar--valarm' handles alarms, which can
 501 ;; happen within a VTODO component.
 502
 503 (defun org-icalendar-entry (entry contents info)
 504   "Transcode ENTRY element into iCalendar format.
 505
 506 ENTRY is either a headline or an inlinetask.  CONTENTS is
 507 ignored.  INFO is a plist used as a communication channel.
 508
 509 This function is called on every headline, the section below
 510 it (minus inlinetasks) being its contents.  It tries to create
 511 VEVENT and VTODO components out of scheduled date, deadline date,
 512 plain timestamps, diary sexps.  It also calls itself on every
 513 inlinetask within the section."
 514   (unless (org-element-property :footnote-section-p entry)
 515     (let* ((type (org-element-type entry))
 516            ;; Determine contents really associated to the entry.  For
 517            ;; a headline, limit them to section, if any.  For an
 518            ;; inlinetask, this is every element within the task.
 519            (inside
 520             (if (eq type 'inlinetask)
 521                 (cons 'org-data (cons nil (org-element-contents entry)))
 522               (let ((first (car (org-element-contents entry))))
 523                 (and (eq (org-element-type first) 'section)
 524                      (cons 'org-data
 525                            (cons nil (org-element-contents first))))))))
 526       (concat
 527        (let ((todo-type (org-element-property :todo-type entry))
 528              (uid (or (org-element-property :ID entry) (org-id-new)))
 529              (summary (org-icalendar-cleanup-string
 530                        (or (org-element-property :SUMMARY entry)
 531                            (org-export-data
 532                             (org-element-property :title entry) info))))
 533              (loc (org-icalendar-cleanup-string
 534                    (org-element-property :LOCATION entry)))
 535              ;; Build description of the entry from associated section
 536              ;; (headline) or contents (inlinetask).
 537              (desc
 538               (org-icalendar-cleanup-string
 539                (or (org-element-property :DESCRIPTION entry)
 540                    (let ((contents (org-export-data inside info)))
 541                      (cond
 542                       ((not (org-string-nw-p contents)) nil)
 543                       ((wholenump org-icalendar-include-body)
 544                        (let ((contents (org-trim contents)))
 545                          (substring
 546                           contents 0 (min (length contents)
 547                                           org-icalendar-include-body))))
 548                       (org-icalendar-include-body (org-trim contents)))))))
 549              (cat (org-icalendar-get-categories entry info)))
 550          (concat
 551           ;; Events: Delegate to `org-icalendar--vevent' to generate
 552           ;; "VEVENT" component from scheduled, deadline, or any
 553           ;; timestamp in the entry.
 554           (let ((deadline (org-element-property :deadline entry)))
 555             (and deadline
 556                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 557                        org-icalendar-use-deadline)
 558                  (org-icalendar--vevent
 559                   entry deadline (concat "DL-" uid)
 560                   (concat "DL: " summary) loc desc cat)))
 561           (let ((scheduled (org-element-property :scheduled entry)))
 562             (and scheduled
 563                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 564                        org-icalendar-use-scheduled)
 565                  (org-icalendar--vevent
 566                   entry scheduled (concat "SC-" uid)
 567                   (concat "S: " summary) loc desc cat)))
 568           ;; When collecting plain timestamps from a headline and its
 569           ;; title, skip inlinetasks since collection will happen once
 570           ;; ENTRY is one of them.
 571           (let ((counter 0))
 572             (mapconcat
 573              #'identity
 574              (org-element-map (cons (org-element-property :title entry)
 575                                     (org-element-contents inside))
 576                  'timestamp
 577                (lambda (ts)
 578                  (when (let ((type (org-element-property :type ts)))
 579                          (case (plist-get info :with-timestamps)
 580                            (active (memq type '(active active-range)))
 581                            (inactive (memq type '(inactive inactive-range)))
 582                            ((t) t)))
 583                    (let ((uid (format "TS%d-%s" (incf counter) uid)))
 584                      (org-icalendar--vevent
 585                       entry ts uid summary loc desc cat))))
 586                info nil (and (eq type 'headline) 'inlinetask))
 587              ""))
 588           ;; Task: First check if it is appropriate to export it.  If
 589           ;; so, call `org-icalendar--vtodo' to transcode it into
 590           ;; a "VTODO" component.
 591           (when (and todo-type
 592                      (case (plist-get info :icalendar-include-todo)
 593                        (all t)
 594                        (unblocked
 595                         (and (eq type 'headline)
 596                              (not (org-icalendar-blocked-headline-p
 597                                    entry info))))
 598                        ((t) (eq todo-type 'todo))))
 599             (org-icalendar--vtodo entry uid summary loc desc cat))
 600           ;; Diary-sexp: Collect every diary-sexp element within ENTRY
 601           ;; and its title, and transcode them.  If ENTRY is
 602           ;; a headline, skip inlinetasks: they will be handled
 603           ;; separately.
 604           (when org-icalendar-include-sexps
 605             (let ((counter 0))
 606               (mapconcat #'identity
 607                          (org-element-map
 608                              (cons (org-element-property :title entry)
 609                                    (org-element-contents inside))
 610                              'diary-sexp
 611                            (lambda (sexp)
 612                              (org-icalendar-transcode-diary-sexp
 613                               (org-element-property :value sexp)
 614                               (format "DS%d-%s" (incf counter) uid)
 615                               summary))
 616                            info nil (and (eq type 'headline) 'inlinetask))
 617                          "")))))
 618        ;; If ENTRY is a headline, call current function on every
 619        ;; inlinetask within it.  In agenda export, this is independent
 620        ;; from the mark (or lack thereof) on the entry.
 621        (when (eq type 'headline)
 622          (mapconcat #'identity
 623                     (org-element-map inside 'inlinetask
 624                       (lambda (task) (org-icalendar-entry task nil info))
 625                       info) ""))
 626        ;; Don't forget components from inner entries.
 627        contents))))
 628
 629 (defun org-icalendar--vevent
 630   (entry timestamp uid summary location description categories)
 631   "Create a VEVENT component.
 632
 633 ENTRY is either a headline or an inlinetask element.  TIMESTAMP
 634 is a timestamp object defining the date-time of the event.  UID
 635 is the unique identifier for the event.  SUMMARY defines a short
 636 summary or subject for the event.  LOCATION defines the intended
 637 venue for the event.  DESCRIPTION provides the complete
 638 description of the event.  CATEGORIES defines the categories the
 639 event belongs to.
 640
 641 Return VEVENT component as a string."
 642   (org-icalendar-fold-string
 643    (if (eq (org-element-property :type timestamp) 'diary)
 644        (org-icalendar-transcode-diary-sexp
 645         (org-element-property :raw-value timestamp) uid summary)
 646      (concat "BEGIN:VEVENT\n"
 647              (org-icalendar-dtstamp) "\n"
 648              "UID:" uid "\n"
 649              (org-icalendar-convert-timestamp timestamp "DTSTART") "\n"
 650              (org-icalendar-convert-timestamp timestamp "DTEND" t) "\n"
 651              ;; RRULE.
 652              (when (org-element-property :repeater-type timestamp)
 653                (format "RRULE:FREQ=%s;INTERVAL=%d\n"
 654                        (case (org-element-property :repeater-unit timestamp)
 655                          (hour "HOURLY") (day "DAILY") (week "WEEKLY")
 656                          (month "MONTHLY") (year "YEARLY"))
 657                        (org-element-property :repeater-value timestamp)))
 658              "SUMMARY:" summary "\n"
 659              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 660              (and (org-string-nw-p description)
 661                   (format "DESCRIPTION:%s\n" description))
 662              "CATEGORIES:" categories "\n"
 663              ;; VALARM.
 664              (org-icalendar--valarm entry timestamp summary)
 665              "END:VEVENT"))))
 666
 667 (defun org-icalendar--vtodo
 668   (entry uid summary location description categories)
 669   "Create a VTODO component.
 670
 671 ENTRY is either a headline or an inlinetask element.  UID is the
 672 unique identifier for the task.  SUMMARY defines a short summary
 673 or subject for the task.  LOCATION defines the intended venue for
 674 the task.  DESCRIPTION provides the complete description of the
 675 task.  CATEGORIES defines the categories the task belongs to.
 676
 677 Return VTODO component as a string."
 678   (let ((start (or (and (memq 'todo-start org-icalendar-use-scheduled)
 679                         (org-element-property :scheduled entry))
 680                    ;; If we can't use a scheduled time for some
 681                    ;; reason, start task now.
 682                    (let ((now (decode-time (current-time))))
 683                      (list 'timestamp
 684                            (list :type 'active
 685                                  :minute-start (nth 1 now)
 686                                  :hour-start (nth 2 now)
 687                                  :day-start (nth 3 now)
 688                                  :month-start (nth 4 now)
 689                                  :year-start (nth 5 now)))))))
 690     (org-icalendar-fold-string
 691      (concat "BEGIN:VTODO\n"
 692              "UID:TODO-" uid "\n"
 693              (org-icalendar-dtstamp) "\n"
 694              (org-icalendar-convert-timestamp start "DTSTART") "\n"
 695              (and (memq 'todo-due org-icalendar-use-deadline)
 696                   (org-element-property :deadline entry)
 697                   (concat (org-icalendar-convert-timestamp
 698                            (org-element-property :deadline entry) "DUE")
 699                           "\n"))
 700              "SUMMARY:" summary "\n"
 701              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 702              (and (org-string-nw-p description)
 703                   (format "DESCRIPTION:%s\n" description))
 704              "CATEGORIES:" categories "\n"
 705              "SEQUENCE:1\n"
 706              (format "PRIORITY:%d\n"
 707                      (let ((pri (or (org-element-property :priority entry)
 708                                     org-default-priority)))
 709                        (floor (- 9 (* 8. (/ (float (- org-lowest-priority pri))
 710                                             (- org-lowest-priority
 711                                                org-highest-priority)))))))
 712              (format "STATUS:%s\n"
 713                      (if (eq (org-element-property :todo-type entry) 'todo)
 714                          "NEEDS-ACTION"
 715                        "COMPLETED"))
 716              "END:VTODO"))))
 717
 718 (defun org-icalendar--valarm (entry timestamp summary)
 719   "Create a VALARM component.
 720
 721 ENTRY is the calendar entry triggering the alarm.  TIMESTAMP is
 722 the start date-time of the entry.  SUMMARY defines a short
 723 summary or subject for the task.
 724
 725 Return VALARM component as a string, or nil if it isn't allowed."
 726   ;; Create a VALARM entry if the entry is timed.  This is not very
 727   ;; general in that:
 728   ;; (a) only one alarm per entry is defined,
 729   ;; (b) only minutes are allowed for the trigger period ahead of the
 730   ;;     start time,
 731   ;; (c) only a DISPLAY action is defined.                       [ESF]
 732   (let ((alarm-time
 733          (let ((warntime
 734                 (org-element-property :APPT_WARNTIME entry)))
 735            (if warntime (string-to-number warntime) 0))))
 736     (and (or (> alarm-time 0) (> org-icalendar-alarm-time 0))
 737          (org-element-property :hour-start timestamp)
 738          (format "BEGIN:VALARM
 739 ACTION:DISPLAY
 740 DESCRIPTION:%s
 741 TRIGGER:-P0DT0H%dM0S
 742 END:VALARM\n"
 743                  summary
 744                  (if (zerop alarm-time) org-icalendar-alarm-time alarm-time)))))
 745
 746
 747 ;;;; Template
 748
 749 (defun org-icalendar-template (contents info)
 750   "Return complete document string after iCalendar conversion.
 751 CONTENTS is the transcoded contents string.  INFO is a plist used
 752 as a communication channel."
 753   (org-icalendar--vcalendar
 754    ;; Name.
 755    (if (not (plist-get info :input-file)) (buffer-name (buffer-base-buffer))
 756      (file-name-nondirectory
 757       (file-name-sans-extension (plist-get info :input-file))))
 758    ;; Owner.
 759    (if (not (plist-get info :with-author)) ""
 760      (org-export-data (plist-get info :author) info))
 761    ;; Timezone.
 762    (if (org-string-nw-p org-icalendar-timezone) org-icalendar-timezone
 763      (cadr (current-time-zone)))
 764    ;; Description.
 765    (org-export-data (plist-get info :title) info)
 766    contents))
 767
 768 (defun org-icalendar--vcalendar (name owner tz description contents)
 769   "Create a VCALENDAR component.
 770 NAME, OWNER, TZ, DESCRIPTION and CONTENTS are all strings giving,
 771 respectively, the name of the calendar, its owner, the timezone
 772 used, a short description and the other components included."
 773   (concat (format "BEGIN:VCALENDAR
 774 VERSION:2.0
 775 X-WR-CALNAME:%s
 776 PRODID:-//%s//Emacs with Org mode//EN
 777 X-WR-TIMEZONE:%s
 778 X-WR-CALDESC:%s
 779 CALSCALE:GREGORIAN\n"
 780                   (org-icalendar-cleanup-string name)
 781                   (org-icalendar-cleanup-string owner)
 782                   (org-icalendar-cleanup-string tz)
 783                   (org-icalendar-cleanup-string description))
 784           contents
 785           "END:VCALENDAR\n"))
 786
 787
 788 \f
 789 ;;; Interactive Functions
 790
 791 ;;;###autoload
 792 (defun org-icalendar-export-to-ics
 793   (&optional async subtreep visible-only body-only)
 794   "Export current buffer to an iCalendar file.
 795
 796 If narrowing is active in the current buffer, only export its
 797 narrowed part.
 798
 799 If a region is active, export that region.
 800
 801 A non-nil optional argument ASYNC means the process should happen
 802 asynchronously.  The resulting file should be accessible through
 803 the `org-export-stack' interface.
 804
 805 When optional argument SUBTREEP is non-nil, export the sub-tree
 806 at point, extracting information from the headline properties
 807 first.
 808
 809 When optional argument VISIBLE-ONLY is non-nil, don't export
 810 contents of hidden elements.
 811
 812 When optional argument BODY-ONLY is non-nil, only write code
 813 between \"BEGIN:VCALENDAR\" and \"END:VCALENDAR\".
 814
 815 Return ICS file name."
 816   (interactive)
 817   (let ((file (buffer-file-name (buffer-base-buffer))))
 818     (when (and file org-icalendar-store-UID)
 819       (org-icalendar-create-uid file 'warn-user)))
 820   ;; Export part.  Since this back-end is backed up by `ascii', ensure
 821   ;; links will not be collected at the end of sections.
 822   (let ((outfile (org-export-output-file-name ".ics" subtreep)))
 823     (org-export-to-file 'icalendar outfile
 824       async subtreep visible-only body-only
 825       '(:ascii-charset utf-8 :ascii-links-to-notes nil)
 826       (lambda (file)
 827         (run-hook-with-args 'org-icalendar-after-save-hook file) nil))))
 828
 829 ;;;###autoload
 830 (defun org-icalendar-export-agenda-files (&optional async)
 831   "Export all agenda files to iCalendar files.
 832 When optional argument ASYNC is non-nil, export happens in an
 833 external process."
 834   (interactive)
 835   (if async
 836       ;; Asynchronous export is not interactive, so we will not call
 837       ;; `org-check-agenda-file'.  Instead we remove any non-existent
 838       ;; agenda file from the list.
 839       (let ((files (org-remove-if-not 'file-exists-p (org-agenda-files t))))
 840         (org-export-async-start
 841             (lambda (results)
 842               (mapc (lambda (f) (org-export-add-to-stack f 'icalendar))
 843                     results))
 844           `(let (output-files)
 845              (mapc (lambda (file)
 846                      (with-current-buffer (org-get-agenda-file-buffer file)
 847                        (push (expand-file-name (org-icalendar-export-to-ics))
 848                              output-files)))
 849                    ',files)
 850              output-files)))
 851     (let ((files (org-agenda-files t)))
 852       (org-agenda-prepare-buffers files)
 853       (unwind-protect
 854           (mapc (lambda (file)
 855                   (catch 'nextfile
 856                     (org-check-agenda-file file)
 857                     (with-current-buffer (org-get-agenda-file-buffer file)
 858                       (org-icalendar-export-to-ics))))
 859                 files)
 860         (org-release-buffers org-agenda-new-buffers)))))
 861
 862 ;;;###autoload
 863 (defun org-icalendar-combine-agenda-files (&optional async)
 864   "Combine all agenda files into a single iCalendar file.
 865
 866 A non-nil optional argument ASYNC means the process should happen
 867 asynchronously.  The resulting file should be accessible through
 868 the `org-export-stack' interface.
 869
 870 The file is stored under the name chosen in
 871 `org-icalendar-combined-agenda-file'."
 872   (interactive)
 873   (if async
 874       (let ((files (org-remove-if-not 'file-exists-p (org-agenda-files t))))
 875         (org-export-async-start
 876             (lambda (dummy)
 877               (org-export-add-to-stack
 878                (expand-file-name org-icalendar-combined-agenda-file)
 879                'icalendar))
 880           `(apply 'org-icalendar--combine-files ',files)))
 881     (apply 'org-icalendar--combine-files (org-agenda-files t))))
 882
 883 (defun org-icalendar-export-current-agenda (file)
 884   "Export current agenda view to an iCalendar FILE.
 885 This function assumes major mode for current buffer is
 886 `org-agenda-mode'."
 887   (let* ((org-export-babel-evaluate)    ; Don't evaluate Babel block.
 888          (contents
 889           (org-export-string-as
 890            (with-output-to-string
 891              (save-excursion
 892                (let ((p (point-min)))
 893                  (while (setq p (next-single-property-change p 'org-hd-marker))
 894                    (let ((m (get-text-property p 'org-hd-marker)))
 895                      (when m
 896                        (with-current-buffer (marker-buffer m)
 897                          (org-with-wide-buffer
 898                           (goto-char (marker-position m))
 899                           (princ
 900                            (org-element-normalize-string
 901                             (buffer-substring
 902                              (point) (progn (outline-next-heading) (point)))))))))
 903                    (forward-line)))))
 904            'icalendar t '(:ascii-charset utf-8 :ascii-links-to-notes nil))))
 905     (with-temp-file file
 906       (insert
 907        (org-icalendar--vcalendar
 908         org-icalendar-combined-name
 909         user-full-name
 910         org-icalendar-combined-description
 911         (or (org-string-nw-p org-icalendar-timezone) (cadr (current-time-zone)))
 912         contents)))
 913     (run-hook-with-args 'org-icalendar-after-save-hook file)))
 914
 915 (defun org-icalendar--combine-files (&rest files)
 916   "Combine entries from multiple files into an iCalendar file.
 917 FILES is a list of files to build the calendar from."
 918   (org-agenda-prepare-buffers files)
 919   (unwind-protect
 920       (progn
 921         (with-temp-file org-icalendar-combined-agenda-file
 922           (insert
 923            (org-icalendar--vcalendar
 924             ;; Name.
 925             org-icalendar-combined-name
 926             ;; Owner.
 927             user-full-name
 928             ;; Timezone.
 929             (or (org-string-nw-p org-icalendar-timezone)
 930                 (cadr (current-time-zone)))
 931             ;; Description.
 932             org-icalendar-combined-description
 933             ;; Contents.
 934             (concat
 935              ;; Agenda contents.
 936              (mapconcat
 937               (lambda (file)
 938                 (catch 'nextfile
 939                   (org-check-agenda-file file)
 940                   (with-current-buffer (org-get-agenda-file-buffer file)
 941                     ;; Create ID if necessary.
 942                     (when org-icalendar-store-UID
 943                       (org-icalendar-create-uid file t))
 944                     (org-export-as
 945                      'icalendar nil nil t
 946                      '(:ascii-charset utf-8 :ascii-links-to-notes nil)))))
 947               files "")
 948              ;; BBDB anniversaries.
 949              (when (and org-icalendar-include-bbdb-anniversaries
 950                         (require 'org-bbdb nil t))
 951                (with-output-to-string (org-bbdb-anniv-export-ical)))))))
 952         (run-hook-with-args 'org-icalendar-after-save-hook
 953                             org-icalendar-combined-agenda-file))
 954     (org-release-buffers org-agenda-new-buffers)))
 955
 956
 957 (provide 'ox-icalendar)
 958
 959 ;; Local variables:
 960 ;; generated-autoload-file: "org-loaddefs.el"
 961 ;; End:
 962
 963 ;;; ox-icalendar.el ends here