lisp/org-indent.el

   1 ;;; org-indent.el --- Dynamic indentation for Org    -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2018 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: https://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23 ;;
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This is an implementation of dynamic virtual indentation.  It works
  29 ;; by adding text properties to a buffer to make sure lines are
  30 ;; indented according to outline structure.
  31 ;;
  32 ;; The process is synchronous, toggled at every buffer modification.
  33 ;; Though, the initialization (indentation of text already in the
  34 ;; buffer), which can take a few seconds in large buffers, happens on
  35 ;; idle time.
  36 ;;
  37 ;;; Code:
  38
  39 (require 'org-macs)
  40 (require 'org-compat)
  41 (require 'org)
  42
  43 (require 'cl-lib)
  44
  45 (declare-function org-inlinetask-get-task-level "org-inlinetask" ())
  46 (declare-function org-inlinetask-in-task-p "org-inlinetask" ())
  47 (declare-function org-list-item-body-column "org-list" (item))
  48 (defvar org-inlinetask-show-first-star)
  49
  50 (defgroup org-indent nil
  51   "Options concerning dynamic virtual outline indentation."
  52   :tag "Org Indent"
  53   :group 'org)
  54
  55 (defvar org-indent-inlinetask-first-star (org-add-props "*" '(face org-warning))
  56   "First star of inline tasks, with correct face.")
  57 (defvar org-indent-agent-timer nil
  58   "Timer running the initialize agent.")
  59 (defvar org-indent-agentized-buffers nil
  60   "List of buffers watched by the initialize agent.")
  61 (defvar org-indent-agent-resume-timer nil
  62   "Timer to reschedule agent after switching to other idle processes.")
  63 (defvar org-indent-agent-active-delay '(0 2 0)
  64   "Time to run agent before switching to other idle processes.
  65 Delay used when the buffer to initialize is current.")
  66 (defvar org-indent-agent-passive-delay '(0 0 400000)
  67   "Time to run agent before switching to other idle processes.
  68 Delay used when the buffer to initialize isn't current.")
  69 (defvar org-indent-agent-resume-delay '(0 0 100000)
  70   "Minimal time for other idle processes before switching back to agent.")
  71 (defvar org-indent--initial-marker nil
  72   "Position of initialization before interrupt.
  73 This is used locally in each buffer being initialized.")
  74 (defvar org-hide-leading-stars-before-indent-mode nil
  75   "Used locally.")
  76 (defvar org-indent-modified-headline-flag nil
  77   "Non-nil means the last deletion operated on a headline.
  78 It is modified by `org-indent-notify-modified-headline'.")
  79
  80
  81 (defcustom org-indent-boundary-char ?\s
  82   "The end of the virtual indentation strings, a single-character string.
  83 The default is just a space, but if you wish, you can use \"|\" or so.
  84 This can be useful on a terminal window - under a windowing system,
  85 it may be prettier to customize the `org-indent' face."
  86   :group 'org-indent
  87   :type 'character)
  88
  89 (defcustom org-indent-mode-turns-off-org-adapt-indentation t
  90   "Non-nil means setting the variable `org-indent-mode' will \
  91 turn off indentation adaptation.
  92 For details see the variable `org-adapt-indentation'."
  93   :group 'org-indent
  94   :type 'boolean)
  95
  96 (defcustom org-indent-mode-turns-on-hiding-stars t
  97   "Non-nil means setting the variable `org-indent-mode' will \
  98 turn on `org-hide-leading-stars'."
  99   :group 'org-indent
 100   :type 'boolean)
 101
 102 (defcustom org-indent-indentation-per-level 2
 103   "Indentation per level in number of characters."
 104   :group 'org-indent
 105   :type 'integer)
 106
 107 (defface org-indent '((t (:inherit org-hide)))
 108   "Face for outline indentation.
 109 The default is to make it look like whitespace.  But you may find it
 110 useful to make it ever so slightly different."
 111   :group 'org-faces)
 112
 113 (defvar org-indent--text-line-prefixes nil
 114   "Vector containing line prefixes strings for regular text.")
 115
 116 (defvar org-indent--heading-line-prefixes nil
 117   "Vector containing line prefix strings for headlines.")
 118
 119 (defvar org-indent--inlinetask-line-prefixes nil
 120   "Vector containing line prefix strings for inline tasks.")
 121
 122 (defconst org-indent--deepest-level 50
 123   "Maximum theoretical headline depth.")
 124
 125 (defun org-indent--compute-prefixes ()
 126   "Compute prefix strings for regular text and headlines."
 127   (setq org-indent--heading-line-prefixes
 128         (make-vector org-indent--deepest-level nil))
 129   (setq org-indent--inlinetask-line-prefixes
 130         (make-vector org-indent--deepest-level nil))
 131   (setq org-indent--text-line-prefixes
 132         (make-vector org-indent--deepest-level nil))
 133   (dotimes (n org-indent--deepest-level)
 134     (let ((indentation (if (<= n 1) 0
 135                          (* (1- org-indent-indentation-per-level)
 136                             (1- n)))))
 137       ;; Headlines line prefixes.
 138       (let ((heading-prefix (make-string indentation ?*)))
 139         (aset org-indent--heading-line-prefixes
 140               n
 141               (org-add-props heading-prefix nil 'face 'org-indent))
 142         ;; Inline tasks line prefixes
 143         (aset org-indent--inlinetask-line-prefixes
 144               n
 145               (cond ((<= n 1) "")
 146                     ((bound-and-true-p org-inlinetask-show-first-star)
 147                      (concat org-indent-inlinetask-first-star
 148                              (substring heading-prefix 1)))
 149                     (t (org-add-props heading-prefix nil 'face 'org-indent)))))
 150       ;; Text line prefixes.
 151       (aset org-indent--text-line-prefixes
 152             n
 153             (org-add-props
 154                 (concat (make-string (+ n indentation) ?\s)
 155                         (and (> n 0)
 156                              (char-to-string org-indent-boundary-char)))
 157                 nil 'face 'org-indent)))))
 158
 159 (defsubst org-indent-remove-properties (beg end)
 160   "Remove indentations between BEG and END."
 161   (with-silent-modifications
 162     (remove-text-properties beg end '(line-prefix nil wrap-prefix nil))))
 163
 164 ;;;###autoload
 165 (define-minor-mode org-indent-mode
 166   "When active, indent text according to outline structure.
 167
 168 Internally this works by adding `line-prefix' and `wrap-prefix'
 169 properties, after each buffer modification, on the modified zone.
 170
 171 The process is synchronous.  Though, initial indentation of
 172 buffer, which can take a few seconds on large buffers, is done
 173 during idle time."
 174   nil " Ind" nil
 175   (cond
 176    (org-indent-mode
 177     ;; mode was turned on.
 178     (setq-local indent-tabs-mode nil)
 179     (setq-local org-indent--initial-marker (copy-marker 1))
 180     (when org-indent-mode-turns-off-org-adapt-indentation
 181       (setq-local org-adapt-indentation nil))
 182     (when org-indent-mode-turns-on-hiding-stars
 183       (setq-local org-hide-leading-stars-before-indent-mode
 184                   org-hide-leading-stars)
 185       (setq-local org-hide-leading-stars t))
 186     (org-indent--compute-prefixes)
 187     (add-hook 'filter-buffer-substring-functions
 188               (lambda (fun start end delete)
 189                 (org-indent-remove-properties-from-string
 190                  (funcall fun start end delete)))
 191               nil t)
 192     (add-hook 'after-change-functions 'org-indent-refresh-maybe nil 'local)
 193     (add-hook 'before-change-functions
 194               'org-indent-notify-modified-headline nil 'local)
 195     (and font-lock-mode (org-restart-font-lock))
 196     (org-indent-remove-properties (point-min) (point-max))
 197     ;; Submit current buffer to initialize agent.  If it's the first
 198     ;; buffer submitted, also start the agent.  Current buffer is
 199     ;; pushed in both cases to avoid a race condition.
 200     (if org-indent-agentized-buffers
 201         (push (current-buffer) org-indent-agentized-buffers)
 202       (push (current-buffer) org-indent-agentized-buffers)
 203       (setq org-indent-agent-timer
 204             (run-with-idle-timer 0.2 t #'org-indent-initialize-agent))))
 205    (t
 206     ;; mode was turned off (or we refused to turn it on)
 207     (kill-local-variable 'org-adapt-indentation)
 208     (setq org-indent-agentized-buffers
 209           (delq (current-buffer) org-indent-agentized-buffers))
 210     (when (markerp org-indent--initial-marker)
 211       (set-marker org-indent--initial-marker nil))
 212     (when (boundp 'org-hide-leading-stars-before-indent-mode)
 213       (setq-local org-hide-leading-stars
 214                   org-hide-leading-stars-before-indent-mode))
 215     (remove-hook 'filter-buffer-substring-functions
 216                  (lambda (fun start end delete)
 217                    (org-indent-remove-properties-from-string
 218                     (funcall fun start end delete))))
 219     (remove-hook 'after-change-functions 'org-indent-refresh-maybe 'local)
 220     (remove-hook 'before-change-functions
 221                  'org-indent-notify-modified-headline 'local)
 222     (org-with-wide-buffer
 223      (org-indent-remove-properties (point-min) (point-max)))
 224     (and font-lock-mode (org-restart-font-lock))
 225     (redraw-display))))
 226
 227 (defun org-indent-indent-buffer ()
 228   "Add indentation properties to the accessible part of the buffer."
 229   (interactive)
 230   (if (not (derived-mode-p 'org-mode))
 231       (error "Not in Org mode")
 232     (message "Setting buffer indentation.  It may take a few seconds...")
 233     (org-indent-remove-properties (point-min) (point-max))
 234     (org-indent-add-properties (point-min) (point-max))
 235     (message "Indentation of buffer set.")))
 236
 237 (defun org-indent-remove-properties-from-string (string)
 238   "Remove indentation properties from STRING."
 239   (remove-text-properties 0 (length string)
 240                           '(line-prefix nil wrap-prefix nil) string)
 241   string)
 242
 243 (defun org-indent-initialize-agent ()
 244   "Start or resume current buffer initialization.
 245 Only buffers in `org-indent-agentized-buffers' trigger an action.
 246 When no more buffer is being watched, the agent suppress itself."
 247   (when org-indent-agent-resume-timer
 248     (cancel-timer org-indent-agent-resume-timer))
 249   (setq org-indent-agentized-buffers
 250         (cl-remove-if-not #'buffer-live-p org-indent-agentized-buffers))
 251   (cond
 252    ;; Job done:  kill agent.
 253    ((not org-indent-agentized-buffers) (cancel-timer org-indent-agent-timer))
 254    ;; Current buffer is agentized: start/resume initialization
 255    ;; somewhat aggressively.
 256    ((memq (current-buffer) org-indent-agentized-buffers)
 257     (org-indent-initialize-buffer (current-buffer)
 258                                   org-indent-agent-active-delay))
 259    ;; Else, start/resume initialization of the last agentized buffer,
 260    ;; softly.
 261    (t (org-indent-initialize-buffer (car org-indent-agentized-buffers)
 262                                     org-indent-agent-passive-delay))))
 263
 264 (defun org-indent-initialize-buffer (buffer delay)
 265   "Set virtual indentation for the buffer BUFFER, asynchronously.
 266 Give hand to other idle processes if it takes longer than DELAY,
 267 a time value."
 268   (with-current-buffer buffer
 269     (when org-indent-mode
 270       (org-with-wide-buffer
 271        (let ((interruptp
 272               ;; Always nil unless interrupted.
 273               (catch 'interrupt
 274                 (and org-indent--initial-marker
 275                      (marker-position org-indent--initial-marker)
 276                      (equal (marker-buffer org-indent--initial-marker)
 277                             buffer)
 278                      (org-indent-add-properties org-indent--initial-marker
 279                                                 (point-max)
 280                                                 delay)
 281                      nil))))
 282          (move-marker org-indent--initial-marker interruptp)
 283          ;; Job is complete: un-agentize buffer.
 284          (unless interruptp
 285            (setq org-indent-agentized-buffers
 286                  (delq buffer org-indent-agentized-buffers))))))))
 287
 288 (defun org-indent-set-line-properties (level indentation &optional heading)
 289   "Set prefix properties on current line an move to next one.
 290
 291 LEVEL is the current level of heading.  INDENTATION is the
 292 expected indentation when wrapping line.
 293
 294 When optional argument HEADING is non-nil, assume line is at
 295 a heading.  Moreover, if is is `inlinetask', the first star will
 296 have `org-warning' face."
 297   (let* ((line (aref (pcase heading
 298                        (`nil org-indent--text-line-prefixes)
 299                        (`inlinetask org-indent--inlinetask-line-prefixes)
 300                        (_ org-indent--heading-line-prefixes))
 301                      level))
 302          (wrap
 303           (org-add-props
 304               (concat line
 305                       (if heading (concat (make-string level ?*) " ")
 306                         (make-string indentation ?\s)))
 307               nil 'face 'org-indent)))
 308     ;; Add properties down to the next line to indent empty lines.
 309     (add-text-properties (line-beginning-position) (line-beginning-position 2)
 310                          `(line-prefix ,line wrap-prefix ,wrap)))
 311   (forward-line))
 312
 313 (defun org-indent-add-properties (beg end &optional delay)
 314   "Add indentation properties between BEG and END.
 315
 316 When DELAY is non-nil, it must be a time value.  In that case,
 317 the process is asynchronous and can be interrupted, either by
 318 user request, or after DELAY.  This is done by throwing the
 319 `interrupt' tag along with the buffer position where the process
 320 stopped."
 321   (save-match-data
 322     (org-with-wide-buffer
 323      (goto-char beg)
 324      (beginning-of-line)
 325      ;; Initialize prefix at BEG, according to current entry's level.
 326      (let* ((case-fold-search t)
 327             (limited-re (org-get-limited-outline-regexp))
 328             (level (or (org-current-level) 0))
 329             (time-limit (and delay (time-add (current-time) delay))))
 330        ;; For each line, set `line-prefix' and `wrap-prefix'
 331        ;; properties depending on the type of line (headline, inline
 332        ;; task, item or other).
 333        (with-silent-modifications
 334          (while (and (<= (point) end) (not (eobp)))
 335            (cond
 336             ;; When in asynchronous mode, check if interrupt is
 337             ;; required.
 338             ((and delay (input-pending-p)) (throw 'interrupt (point)))
 339             ;; In asynchronous mode, take a break of
 340             ;; `org-indent-agent-resume-delay' every DELAY to avoid
 341             ;; blocking any other idle timer or process output.
 342             ((and delay (time-less-p time-limit (current-time)))
 343              (setq org-indent-agent-resume-timer
 344                    (run-with-idle-timer
 345                     (time-add (current-idle-time) org-indent-agent-resume-delay)
 346                     nil #'org-indent-initialize-agent))
 347              (throw 'interrupt (point)))
 348             ;; Headline or inline task.
 349             ((looking-at org-outline-regexp)
 350              (let* ((nstars (- (match-end 0) (match-beginning 0) 1))
 351                     (type (or (looking-at-p limited-re) 'inlinetask)))
 352                (org-indent-set-line-properties nstars 0 type)
 353                ;; At an headline, define new value for LEVEL.
 354                (unless (eq type 'inlinetask) (setq level nstars))))
 355             ;; List item: `wrap-prefix' is set where body starts.
 356             ((org-at-item-p)
 357              (org-indent-set-line-properties
 358               level (org-list-item-body-column (point))))
 359             ;; Regular line.
 360             (t
 361              (org-indent-set-line-properties level (current-indentation))))))))))
 362
 363 (defun org-indent-notify-modified-headline (beg end)
 364   "Set `org-indent-modified-headline-flag' depending on context.
 365
 366 BEG and END are the positions of the beginning and end of the
 367 range of deleted text.
 368
 369 This function is meant to be called by `before-change-functions'.
 370 Flag will be non-nil if command is going to modify or delete an
 371 headline."
 372   (when org-indent-mode
 373     (setq org-indent-modified-headline-flag
 374           (org-with-wide-buffer
 375            (goto-char beg)
 376            (save-match-data
 377              (or (and (org-at-heading-p) (< beg (match-end 0)))
 378                  (re-search-forward
 379                   (org-with-limited-levels org-outline-regexp-bol) end t)))))))
 380
 381 (defun org-indent-refresh-maybe (beg end _)
 382   "Refresh indentation properties in an adequate portion of buffer.
 383 BEG and END are the positions of the beginning and end of the
 384 range of inserted text.  DUMMY is an unused argument.
 385
 386 This function is meant to be called by `after-change-functions'."
 387   (when org-indent-mode
 388     (save-match-data
 389       ;; If a headline was modified or inserted, set properties until
 390       ;; next headline.
 391       (org-with-wide-buffer
 392        (if (or org-indent-modified-headline-flag
 393                (save-excursion
 394                  (goto-char beg)
 395                  (beginning-of-line)
 396                  (re-search-forward
 397                   (org-with-limited-levels org-outline-regexp-bol) end t)))
 398            (let ((end (save-excursion
 399                         (goto-char end)
 400                         (org-with-limited-levels (outline-next-heading))
 401                         (point))))
 402              (setq org-indent-modified-headline-flag nil)
 403              (org-indent-add-properties beg end))
 404          ;; Otherwise, only set properties on modified area.
 405          (org-indent-add-properties beg end))))))
 406
 407 (provide 'org-indent)
 408
 409 ;; Local variables:
 410 ;; generated-autoload-file: "org-loaddefs.el"
 411 ;; End:
 412
 413 ;;; org-indent.el ends here