lisp/ob-shell.el

   1 ;;; ob-shell.el --- Babel Functions for Shell Evaluation -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: https://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating shell source code.
  27
  28 ;;; Code:
  29 (require 'ob)
  30 (require 'org-macs)
  31 (require 'shell)
  32 (require 'cl-lib)
  33
  34 (declare-function org-babel-comint-in-buffer "ob-comint" (buffer &rest body)
  35                   t)
  36 (declare-function org-babel-comint-wait-for-output "ob-comint" (buffer))
  37 (declare-function org-babel-comint-buffer-livep "ob-comint" (buffer))
  38 (declare-function org-babel-comint-with-output "ob-comint" (meta &rest body)
  39                   t)
  40 (declare-function orgtbl-to-generic "org-table" (table params))
  41
  42 (defvar org-babel-default-header-args:shell '())
  43 (defvar org-babel-shell-names)
  44
  45 (defun org-babel-shell-initialize ()
  46   "Define execution functions associated to shell names.
  47 This function has to be called whenever `org-babel-shell-names'
  48 is modified outside the Customize interface."
  49   (interactive)
  50   (dolist (name org-babel-shell-names)
  51     (eval `(defun ,(intern (concat "org-babel-execute:" name))
  52                (body params)
  53              ,(format "Execute a block of %s commands with Babel." name)
  54              (let ((shell-file-name ,name))
  55                (org-babel-execute:shell body params))))
  56     (eval `(defalias ',(intern (concat "org-babel-variable-assignments:" name))
  57              'org-babel-variable-assignments:shell
  58              ,(format "Return list of %s statements assigning to the block's \
  59 variables."
  60                       name)))
  61     (eval `(defvar ,(intern (concat "org-babel-default-header-args:" name)) '()))))
  62
  63 (defcustom org-babel-shell-names
  64   '("sh" "bash" "zsh" "fish" "csh" "ash" "dash" "ksh" "mksh" "posh")
  65   "List of names of shell supported by babel shell code blocks.
  66 Call `org-babel-shell-initialize' when modifying this variable
  67 outside the Customize interface."
  68   :group 'org-babel
  69   :type '(repeat (string :tag "Shell name: "))
  70   :set (lambda (symbol value)
  71          (set-default symbol value)
  72          (org-babel-shell-initialize)))
  73
  74 (defun org-babel-execute:shell (body params)
  75   "Execute a block of Shell commands with Babel.
  76 This function is called by `org-babel-execute-src-block'."
  77   (let* ((session (org-babel-sh-initiate-session
  78                    (cdr (assq :session params))))
  79          (stdin (let ((stdin (cdr (assq :stdin params))))
  80                   (when stdin (org-babel-sh-var-to-string
  81                                (org-babel-ref-resolve stdin)))))
  82          (cmdline (cdr (assq :cmdline params)))
  83          (full-body (org-babel-expand-body:generic
  84                      body params (org-babel-variable-assignments:shell params))))
  85     (org-babel-reassemble-table
  86      (org-babel-sh-evaluate session full-body params stdin cmdline)
  87      (org-babel-pick-name
  88       (cdr (assq :colname-names params)) (cdr (assq :colnames params)))
  89      (org-babel-pick-name
  90       (cdr (assq :rowname-names params)) (cdr (assq :rownames params))))))
  91
  92 (defun org-babel-prep-session:shell (session params)
  93   "Prepare SESSION according to the header arguments specified in PARAMS."
  94   (let* ((session (org-babel-sh-initiate-session session))
  95          (var-lines (org-babel-variable-assignments:shell params)))
  96     (org-babel-comint-in-buffer session
  97       (mapc (lambda (var)
  98               (insert var) (comint-send-input nil t)
  99               (org-babel-comint-wait-for-output session)) var-lines))
 100     session))
 101
 102 (defun org-babel-load-session:shell (session body params)
 103   "Load BODY into SESSION."
 104   (save-window-excursion
 105     (let ((buffer (org-babel-prep-session:shell session params)))
 106       (with-current-buffer buffer
 107         (goto-char (process-mark (get-buffer-process (current-buffer))))
 108         (insert (org-babel-chomp body)))
 109       buffer)))
 110
 111 \f
 112 ;;; Helper functions
 113 (defun org-babel--variable-assignments:sh-generic
 114     (varname values &optional sep hline)
 115   "Returns a list of statements declaring the values as a generic variable."
 116   (format "%s=%s" varname (org-babel-sh-var-to-sh values sep hline)))
 117
 118 (defun org-babel--variable-assignments:bash_array
 119     (varname values &optional sep hline)
 120   "Returns a list of statements declaring the values as a bash array."
 121   (format "unset %s\ndeclare -a %s=( %s )"
 122           varname varname
 123           (mapconcat
 124            (lambda (value) (org-babel-sh-var-to-sh value sep hline))
 125            values
 126            " ")))
 127
 128 (defun org-babel--variable-assignments:bash_assoc
 129     (varname values &optional sep hline)
 130   "Returns a list of statements declaring the values as bash associative array."
 131   (format "unset %s\ndeclare -A %s\n%s"
 132     varname varname
 133     (mapconcat
 134      (lambda (items)
 135        (format "%s[%s]=%s"
 136                varname
 137                (org-babel-sh-var-to-sh (car items) sep hline)
 138                (org-babel-sh-var-to-sh (cdr items) sep hline)))
 139      values
 140      "\n")))
 141
 142 (defun org-babel--variable-assignments:bash (varname values &optional sep hline)
 143   "Represents the parameters as useful Bash shell variables."
 144   (pcase values
 145     (`((,_ ,_ . ,_) . ,_)               ;two-dimensional array
 146      (org-babel--variable-assignments:bash_assoc varname values sep hline))
 147     (`(,_ . ,_)                         ;simple list
 148      (org-babel--variable-assignments:bash_array varname values sep hline))
 149     (_                                  ;scalar value
 150      (org-babel--variable-assignments:sh-generic varname values sep hline))))
 151
 152 (defun org-babel-variable-assignments:shell (params)
 153   "Return list of shell statements assigning the block's variables."
 154   (let ((sep (cdr (assq :separator params)))
 155         (hline (when (string= "yes" (cdr (assq :hlines params)))
 156                  (or (cdr (assq :hline-string params))
 157                      "hline"))))
 158     (mapcar
 159      (lambda (pair)
 160        (if (string-suffix-p "bash" shell-file-name)
 161            (org-babel--variable-assignments:bash
 162             (car pair) (cdr pair) sep hline)
 163          (org-babel--variable-assignments:sh-generic
 164           (car pair) (cdr pair) sep hline)))
 165      (org-babel--get-vars params))))
 166
 167 (defun org-babel-sh-var-to-sh (var &optional sep hline)
 168   "Convert an elisp value to a shell variable.
 169 Convert an elisp var into a string of shell commands specifying a
 170 var of the same value."
 171   (concat "'" (replace-regexp-in-string
 172                "'" "'\"'\"'"
 173                (org-babel-sh-var-to-string var sep hline))
 174           "'"))
 175
 176 (defun org-babel-sh-var-to-string (var &optional sep hline)
 177   "Convert an elisp value to a string."
 178   (let ((echo-var (lambda (v) (if (stringp v) v (format "%S" v)))))
 179     (cond
 180      ((and (listp var) (or (listp (car var)) (eq (car var) 'hline)))
 181       (orgtbl-to-generic var  (list :sep (or sep "\t") :fmt echo-var
 182                                     :hline hline)))
 183      ((listp var)
 184       (mapconcat echo-var var "\n"))
 185      (t (funcall echo-var var)))))
 186
 187 (defun org-babel-sh-initiate-session (&optional session _params)
 188   "Initiate a session named SESSION according to PARAMS."
 189   (when (and session (not (string= session "none")))
 190     (save-window-excursion
 191       (or (org-babel-comint-buffer-livep session)
 192           (progn
 193             (shell session)
 194             ;; Needed for Emacs 23 since the marker is initially
 195             ;; undefined and the filter functions try to use it without
 196             ;; checking.
 197             (set-marker comint-last-output-start (point))
 198             (get-buffer (current-buffer)))))))
 199
 200 (defvar org-babel-sh-eoe-indicator "echo 'org_babel_sh_eoe'"
 201   "String to indicate that evaluation has completed.")
 202 (defvar org-babel-sh-eoe-output "org_babel_sh_eoe"
 203   "String to indicate that evaluation has completed.")
 204
 205 (defun org-babel-sh-evaluate (session body &optional params stdin cmdline)
 206   "Pass BODY to the Shell process in BUFFER.
 207 If RESULT-TYPE equals `output' then return a list of the outputs
 208 of the statements in BODY, if RESULT-TYPE equals `value' then
 209 return the value of the last statement in BODY."
 210   (let* ((shebang (cdr (assq :shebang params)))
 211          (results
 212           (cond
 213            ((or stdin cmdline)         ; external shell script w/STDIN
 214             (let ((script-file (org-babel-temp-file "sh-script-"))
 215                   (stdin-file (org-babel-temp-file "sh-stdin-"))
 216                   (padline (not (string= "no" (cdr (assq :padline params))))))
 217               (with-temp-file script-file
 218                 (when shebang (insert shebang "\n"))
 219                 (when padline (insert "\n"))
 220                 (insert body))
 221               (set-file-modes script-file #o755)
 222               (with-temp-file stdin-file (insert (or stdin "")))
 223               (with-temp-buffer
 224                 (call-process-shell-command
 225                  (concat (if shebang script-file
 226                            (format "%s %s" shell-file-name script-file))
 227                          (and cmdline (concat " " cmdline)))
 228                  stdin-file
 229                  (current-buffer))
 230                 (buffer-string))))
 231            (session                     ; session evaluation
 232             (mapconcat
 233              #'org-babel-sh-strip-weird-long-prompt
 234              (mapcar
 235               #'org-trim
 236               (butlast
 237                (org-babel-comint-with-output
 238                    (session org-babel-sh-eoe-output t body)
 239                  (dolist (line (append (split-string (org-trim body) "\n")
 240                                        (list org-babel-sh-eoe-indicator)))
 241                    (insert line)
 242                    (comint-send-input nil t)
 243                    (while (save-excursion
 244                             (goto-char comint-last-input-end)
 245                             (not (re-search-forward
 246                                   comint-prompt-regexp nil t)))
 247                      (accept-process-output
 248                       (get-buffer-process (current-buffer))))))
 249                2))
 250              "\n"))
 251            ;; External shell script, with or without a predefined
 252            ;; shebang.
 253            ((org-string-nw-p shebang)
 254             (let ((script-file (org-babel-temp-file "sh-script-"))
 255                   (padline (not (equal "no" (cdr (assq :padline params))))))
 256               (with-temp-file script-file
 257                 (insert shebang "\n")
 258                 (when padline (insert "\n"))
 259                 (insert body))
 260               (set-file-modes script-file #o755)
 261               (org-babel-eval script-file "")))
 262            (t
 263             (org-babel-eval shell-file-name (org-trim body))))))
 264     (when results
 265       (let ((result-params (cdr (assq :result-params params))))
 266         (org-babel-result-cond result-params
 267           results
 268           (let ((tmp-file (org-babel-temp-file "sh-")))
 269             (with-temp-file tmp-file (insert results))
 270             (org-babel-import-elisp-from-file tmp-file)))))))
 271
 272 (defun org-babel-sh-strip-weird-long-prompt (string)
 273   "Remove prompt cruft from a string of shell output."
 274   (while (string-match "^% +[\r\n$]+ *" string)
 275     (setq string (substring string (match-end 0))))
 276   string)
 277
 278 (provide 'ob-shell)
 279
 280
 281
 282 ;;; ob-shell.el ends here