lisp/ox-org.el

   1 ;;; ox-org.el --- Org Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; This library implements an Org back-end for Org exporter.
  24 ;;
  25 ;; It introduces two interactive functions, `org-org-export-as-org'
  26 ;; and `org-org-export-to-org', which export, respectively, to
  27 ;; a temporary buffer and to a file.
  28 ;;
  29 ;; A publishing function is also provided: `org-org-publish-to-org'.
  30
  31 ;;; Code:
  32 (require 'ox)
  33 (declare-function htmlize-buffer "htmlize" (&optional buffer))
  34
  35 (defgroup org-export-org nil
  36   "Options for exporting Org mode files to Org."
  37   :tag "Org Export Org"
  38   :group 'org-export
  39   :version "24.4"
  40   :package-version '(Org . "8.0"))
  41
  42 (define-obsolete-variable-alias
  43   'org-export-htmlized-org-css-url 'org-org-htmlized-css-url "24.4")
  44 (defcustom org-org-htmlized-css-url nil
  45   "URL pointing to the CSS defining colors for htmlized Emacs buffers.
  46 Normally when creating an htmlized version of an Org buffer,
  47 htmlize will create the CSS to define the font colors.  However,
  48 this does not work when converting in batch mode, and it also can
  49 look bad if different people with different fontification setup
  50 work on the same website.  When this variable is non-nil,
  51 creating an htmlized version of an Org buffer using
  52 `org-org-export-as-org' will include a link to this URL if the
  53 setting of `org-html-htmlize-output-type' is 'css."
  54   :group 'org-export-org
  55   :type '(choice
  56           (const :tag "Don't include external stylesheet link" nil)
  57           (string :tag "URL or local href")))
  58
  59 (org-export-define-backend 'org
  60   '((babel-call . org-org-identity)
  61     (bold . org-org-identity)
  62     (center-block . org-org-identity)
  63     (clock . org-org-identity)
  64     (code . org-org-identity)
  65     (comment . (lambda (&rest args) ""))
  66     (comment-block . (lambda (&rest args) ""))
  67     (diary-sexp . org-org-identity)
  68     (drawer . org-org-identity)
  69     (dynamic-block . org-org-identity)
  70     (entity . org-org-identity)
  71     (example-block . org-org-identity)
  72     (fixed-width . org-org-identity)
  73     (footnote-definition . org-org-identity)
  74     (footnote-reference . org-org-identity)
  75     (headline . org-org-headline)
  76     (horizontal-rule . org-org-identity)
  77     (inline-babel-call . org-org-identity)
  78     (inline-src-block . org-org-identity)
  79     (inlinetask . org-org-identity)
  80     (italic . org-org-identity)
  81     (item . org-org-identity)
  82     (keyword . org-org-keyword)
  83     (latex-environment . org-org-identity)
  84     (latex-fragment . org-org-identity)
  85     (line-break . org-org-identity)
  86     (link . org-org-identity)
  87     (node-property . org-org-identity)
  88     (paragraph . org-org-identity)
  89     (plain-list . org-org-identity)
  90     (planning . org-org-identity)
  91     (property-drawer . org-org-identity)
  92     (quote-block . org-org-identity)
  93     (quote-section . org-org-identity)
  94     (radio-target . org-org-identity)
  95     (section . org-org-identity)
  96     (special-block . org-org-identity)
  97     (src-block . org-org-identity)
  98     (statistics-cookie . org-org-identity)
  99     (strike-through . org-org-identity)
 100     (subscript . org-org-identity)
 101     (superscript . org-org-identity)
 102     (table . org-org-identity)
 103     (table-cell . org-org-identity)
 104     (table-row . org-org-identity)
 105     (target . org-org-identity)
 106     (timestamp . org-org-identity)
 107     (underline . org-org-identity)
 108     (verbatim . org-org-identity)
 109     (verse-block . org-org-identity))
 110   :menu-entry
 111   '(?O "Export to Org"
 112        ((?O "As Org buffer" org-org-export-as-org)
 113         (?o "As Org file" org-org-export-to-org)
 114         (?v "As Org file and open"
 115             (lambda (a s v b)
 116               (if a (org-org-export-to-org t s v b)
 117                 (org-open-file (org-org-export-to-org nil s v b))))))))
 118
 119 (defun org-org-identity (blob contents info)
 120   "Transcode BLOB element or object back into Org syntax."
 121   (funcall
 122    (intern (format "org-element-%s-interpreter" (org-element-type blob)))
 123    blob contents))
 124
 125 (defun org-org-headline (headline contents info)
 126   "Transcode HEADLINE element back into Org syntax."
 127   (unless (plist-get info :with-todo-keywords)
 128     (org-element-put-property headline :todo-keyword nil))
 129   (unless (plist-get info :with-tags)
 130     (org-element-put-property headline :tags nil))
 131   (unless (plist-get info :with-priority)
 132     (org-element-put-property headline :priority nil))
 133   (org-element-headline-interpreter headline contents))
 134
 135 (defun org-org-keyword (keyword contents info)
 136   "Transcode KEYWORD element back into Org syntax.
 137 Ignore keywords targeted at other export back-ends."
 138   (unless (member (org-element-property :key keyword)
 139                   (mapcar
 140                    (lambda (block-cons)
 141                      (and (eq (cdr block-cons) 'org-element-export-block-parser)
 142                           (car block-cons)))
 143                    org-element-block-name-alist))
 144     (org-element-keyword-interpreter keyword nil)))
 145
 146 ;;;###autoload
 147 (defun org-org-export-as-org (&optional async subtreep visible-only ext-plist)
 148   "Export current buffer to an Org buffer.
 149
 150 If narrowing is active in the current buffer, only export its
 151 narrowed part.
 152
 153 If a region is active, export that region.
 154
 155 A non-nil optional argument ASYNC means the process should happen
 156 asynchronously.  The resulting buffer should be accessible
 157 through the `org-export-stack' interface.
 158
 159 When optional argument SUBTREEP is non-nil, export the sub-tree
 160 at point, extracting information from the headline properties
 161 first.
 162
 163 When optional argument VISIBLE-ONLY is non-nil, don't export
 164 contents of hidden elements.
 165
 166 EXT-PLIST, when provided, is a property list with external
 167 parameters overriding Org default settings, but still inferior to
 168 file-local settings.
 169
 170 Export is done in a buffer named \"*Org ORG Export*\", which will
 171 be displayed when `org-export-show-temporary-export-buffer' is
 172 non-nil."
 173   (interactive)
 174   (if async
 175       (org-export-async-start
 176           (lambda (output)
 177             (with-current-buffer (get-buffer-create "*Org ORG Export*")
 178               (erase-buffer)
 179               (insert output)
 180               (goto-char (point-min))
 181               (org-mode)
 182               (org-export-add-to-stack (current-buffer) 'org)))
 183         `(org-export-as 'org ,subtreep ,visible-only nil ',ext-plist))
 184     (let ((outbuf
 185            (org-export-to-buffer
 186             'org "*Org ORG Export*" subtreep visible-only nil ext-plist)))
 187       (with-current-buffer outbuf (org-mode))
 188       (when org-export-show-temporary-export-buffer
 189         (switch-to-buffer-other-window outbuf)))))
 190
 191 ;;;###autoload
 192 (defun org-org-export-to-org (&optional async subtreep visible-only ext-plist)
 193   "Export current buffer to an org file.
 194
 195 If narrowing is active in the current buffer, only export its
 196 narrowed part.
 197
 198 If a region is active, export that region.
 199
 200 A non-nil optional argument ASYNC means the process should happen
 201 asynchronously.  The resulting file should be accessible through
 202 the `org-export-stack' interface.
 203
 204 When optional argument SUBTREEP is non-nil, export the sub-tree
 205 at point, extracting information from the headline properties
 206 first.
 207
 208 When optional argument VISIBLE-ONLY is non-nil, don't export
 209 contents of hidden elements.
 210
 211 EXT-PLIST, when provided, is a property list with external
 212 parameters overriding Org default settings, but still inferior to
 213 file-local settings.
 214
 215 Return output file name."
 216   (interactive)
 217   (let ((outfile (org-export-output-file-name ".org" subtreep)))
 218     (if async
 219         (org-export-async-start
 220             (lambda (f) (org-export-add-to-stack f 'org))
 221           `(expand-file-name
 222             (org-export-to-file
 223              'org ,outfile ,subtreep ,visible-only nil ',ext-plist)))
 224       (org-export-to-file 'org outfile subtreep visible-only nil ext-plist))))
 225
 226 ;;;###autoload
 227 (defun org-org-publish-to-org (plist filename pub-dir)
 228   "Publish an org file to org.
 229
 230 FILENAME is the filename of the Org file to be published.  PLIST
 231 is the property list for the given project.  PUB-DIR is the
 232 publishing directory.
 233
 234 Return output file name."
 235   (org-publish-org-to 'org filename ".org" plist pub-dir)
 236   (when (plist-get plist :htmlized-source)
 237     (require 'htmlize)
 238     (require 'ox-html)
 239     (let* ((org-inhibit-startup t)
 240            (htmlize-output-type 'css)
 241            (html-ext (concat "." (or (plist-get plist :html-extension)
 242                                      org-html-extension "html")))
 243            (visitingp (find-buffer-visiting filename))
 244            (work-buffer (or visitingp (find-file filename)))
 245            newbuf)
 246       (font-lock-fontify-buffer)
 247       (setq newbuf (htmlize-buffer))
 248       (with-current-buffer newbuf
 249         (when org-org-htmlized-css-url
 250           (goto-char (point-min))
 251           (and (re-search-forward
 252                 "<style type=\"text/css\">[^\000]*?\n[ \t]*</style>.*" nil t)
 253                (replace-match
 254                 (format
 255                  "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">"
 256                  org-org-htmlized-css-url) t t)))
 257         (write-file (concat pub-dir (file-name-nondirectory filename) html-ext)))
 258       (kill-buffer newbuf)
 259       (unless visitingp (kill-buffer work-buffer)))
 260     (set-buffer-modified-p nil)))
 261
 262
 263 (provide 'ox-org)
 264
 265 ;; Local variables:
 266 ;; generated-autoload-file: "org-loaddefs.el"
 267 ;; End:
 268
 269 ;;; ox-org.el ends here