lisp/ob-js.el

   1 ;;; ob-js.el --- Babel Functions for Javascript      -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2010-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research, js
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Now working with SBCL for both session and external evaluation.
  27 ;;
  28 ;; This certainly isn't optimally robust, but it seems to be working
  29 ;; for the basic use cases.
  30
  31 ;;; Requirements:
  32
  33 ;; - a non-browser javascript engine such as node.js http://nodejs.org/
  34 ;;   or mozrepl http://wiki.github.com/bard/mozrepl/
  35 ;;
  36 ;; - for session based evaluation mozrepl and moz.el are required see
  37 ;;   http://wiki.github.com/bard/mozrepl/emacs-integration for
  38 ;;   configuration instructions
  39
  40 ;;; Code:
  41 (require 'ob)
  42
  43 (declare-function run-mozilla "ext:moz" (arg))
  44
  45 (defvar org-babel-default-header-args:js '()
  46   "Default header arguments for js code blocks.")
  47
  48 (defvar org-babel-js-eoe "org-babel-js-eoe"
  49   "String to indicate that evaluation has completed.")
  50
  51 (defcustom org-babel-js-cmd "node"
  52   "Name of command used to evaluate js blocks."
  53   :group 'org-babel
  54   :version "24.1"
  55   :type 'string)
  56
  57 (defvar org-babel-js-function-wrapper
  58   "require('sys').print(require('sys').inspect(function(){%s}()));"
  59   "Javascript code to print value of body.")
  60
  61 (defun org-babel-execute:js (body params)
  62   "Execute a block of Javascript code with org-babel.
  63 This function is called by `org-babel-execute-src-block'"
  64   (let* ((org-babel-js-cmd (or (cdr (assq :cmd params)) org-babel-js-cmd))
  65          (result-type (cdr (assq :result-type params)))
  66          (full-body (org-babel-expand-body:generic
  67                      body params (org-babel-variable-assignments:js params)))
  68          (result (if (not (string= (cdr (assq :session params)) "none"))
  69                      ;; session evaluation
  70                      (let ((session (org-babel-prep-session:js
  71                                      (cdr (assq :session params)) params)))
  72                        (nth 1
  73                             (org-babel-comint-with-output
  74                                 (session (format "%S" org-babel-js-eoe) t body)
  75                               (mapc
  76                                (lambda (line)
  77                                  (insert (org-babel-chomp line))
  78                                  (comint-send-input nil t))
  79                                (list body (format "%S" org-babel-js-eoe))))))
  80                    ;; external evaluation
  81                    (let ((script-file (org-babel-temp-file "js-script-")))
  82                      (with-temp-file script-file
  83                        (insert
  84                         ;; return the value or the output
  85                         (if (string= result-type "value")
  86                             (format org-babel-js-function-wrapper full-body)
  87                           full-body)))
  88                      (org-babel-eval
  89                       (format "%s %s" org-babel-js-cmd
  90                               (org-babel-process-file-name script-file)) "")))))
  91     (org-babel-result-cond (cdr (assq :result-params params))
  92       result (org-babel-js-read result))))
  93
  94 (defun org-babel-js-read (results)
  95   "Convert RESULTS into an appropriate elisp value.
  96 If RESULTS look like a table, then convert them into an
  97 Emacs-lisp table, otherwise return the results as a string."
  98   (org-babel-read
  99    (if (and (stringp results)
 100             (string-prefix-p "[" results)
 101             (string-suffix-p "]" results))
 102        (org-babel-read
 103         (concat "'"
 104                 (replace-regexp-in-string
 105                  "\\[" "(" (replace-regexp-in-string
 106                             "\\]" ")" (replace-regexp-in-string
 107                                        ",[[:space:]]" " "
 108                                        (replace-regexp-in-string
 109                                         "'" "\"" results))))))
 110      results)))
 111
 112 (defun org-babel-js-var-to-js (var)
 113   "Convert VAR into a js variable.
 114 Convert an elisp value into a string of js source code
 115 specifying a variable of the same value."
 116   (if (listp var)
 117       (concat "[" (mapconcat #'org-babel-js-var-to-js var ", ") "]")
 118     (replace-regexp-in-string "\n" "\\\\n" (format "%S" var))))
 119
 120 (defun org-babel-prep-session:js (session params)
 121   "Prepare SESSION according to the header arguments specified in PARAMS."
 122   (let* ((session (org-babel-js-initiate-session session))
 123          (var-lines (org-babel-variable-assignments:js params)))
 124     (when session
 125       (org-babel-comint-in-buffer session
 126         (sit-for .5) (goto-char (point-max))
 127         (mapc (lambda (var)
 128                 (insert var) (comint-send-input nil t)
 129                 (org-babel-comint-wait-for-output session)
 130                 (sit-for .1) (goto-char (point-max))) var-lines)))
 131     session))
 132
 133 (defun org-babel-variable-assignments:js (params)
 134   "Return list of Javascript statements assigning the block's variables."
 135   (mapcar
 136    (lambda (pair) (format "var %s=%s;"
 137                           (car pair) (org-babel-js-var-to-js (cdr pair))))
 138    (org-babel--get-vars params)))
 139
 140 (defun org-babel-js-initiate-session (&optional session)
 141   "If there is not a current inferior-process-buffer in SESSION
 142 then create.  Return the initialized session."
 143   (unless (string= session "none")
 144     (cond
 145      ((string= "mozrepl" org-babel-js-cmd)
 146       (require 'moz)
 147       (let ((session-buffer (save-window-excursion
 148                               (run-mozilla nil)
 149                               (rename-buffer session)
 150                               (current-buffer))))
 151         (if (org-babel-comint-buffer-livep session-buffer)
 152             (progn (sit-for .25) session-buffer)
 153           (sit-for .5)
 154           (org-babel-js-initiate-session session))))
 155      ((string= "node" org-babel-js-cmd )
 156       (error "Session evaluation with node.js is not supported"))
 157      (t
 158       (error "Sessions are only supported with mozrepl add \":cmd mozrepl\"")))))
 159
 160 (provide 'ob-js)
 161
 162
 163
 164 ;;; ob-js.el ends here