lisp/org-inlinetask.el

   1 ;;; org-inlinetask.el --- Tasks independent of outline hierarchy
   2
   3 ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.35g
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29 ;;
  30 ;; This module implements inline tasks in Org-mode.  Inline tasks are
  31 ;; tasks that have all the properties of normal outline nodes, including
  32 ;; the ability to store meta data like scheduling dates, TODO state, tags
  33 ;; and properties.  However, these nodes are treated specially by the
  34 ;; visibility cycling and export commands.
  35 ;;
  36 ;; Visibility cycling exempts these nodes from cycling. So whenever their
  37 ;; parent is opened, so are these tasks.  This will only work with
  38 ;; `org-cycle', so if you are also using other commands to show/hide
  39 ;; entries, you will occasionally find these tasks to behave like
  40 ;; all other outline nodes, seemingly splitting the text of the parent
  41 ;; into children.
  42 ;;
  43 ;; Export commands do not treat these nodes as part of the sectioning
  44 ;; structure, but as a special inline text that is either removed, or
  45 ;; formatted in some special way.
  46 ;;
  47 ;; Special fontification of inline tasks, so that they can be immediately
  48 ;; recognized.  From the stars of the headline, only the first and the
  49 ;; last two will be visible, the others will be hidden using the
  50 ;; `org-hide' face.
  51 ;;
  52 ;; An inline task is identified solely by a minimum outline level, given
  53 ;; by the variable `org-inlinetask-min-level', default 15.
  54 ;;
  55 ;; Inline tasks are normally assumed to contain at most a time planning
  56 ;; line (DEADLINE etc) after it, and then any number of drawers, for
  57 ;; example LOGBOOK of PROPERTIES.  No empty lines are allowed.
  58 ;; If you need to have normal text as part of an inline task, you
  59 ;; can do so by adding an "END" headline with the same number of stars,
  60 ;; for example
  61 ;;
  62 ;;    **************** TODO some small task
  63 ;;                     DEADLINE: <2009-03-30 Mon>
  64 ;;                     :PROPERTIES:
  65 ;;                       :SOMETHING: or other
  66 ;;                     :END:
  67 ;;                     And here is some extra text
  68 ;;    **************** END
  69 ;;
  70 ;; Also, if you want to use refiling and archiving for inline tasks,
  71 ;; The END line must be present to make things work properly.
  72 ;;
  73 ;; This package installs one new command:
  74 ;;
  75 ;; C-c C-x t      Insert a new inline task with END line
  76
  77
  78 ;;; Code
  79
  80 (require 'org)
  81
  82 (defgroup org-inlinetask nil
  83   "Options concerning inline tasks in Org mode."
  84   :tag "Org Inline Tasks"
  85   :group 'org-structure)
  86
  87 (defcustom org-inlinetask-min-level 15
  88   "Minimum level a headline must have before it is treated as an inline task.
  89 It is strongly recommended that you set `org-cycle-max-level' not at all,
  90 or to a number smaller than this one.  In fact, when `org-cycle-max-level' is
  91 not set, it will be assumed to be one less than the value of smaller than
  92 the value of this variable."
  93   :group 'org-inlinetask
  94   :type 'boolean)
  95
  96 (defcustom org-inlinetask-export t
  97   "Non-nil means export inline tasks.
  98 When nil, they will not be exported."
  99   :group 'org-inlinetask
 100   :type 'boolean)
 101
 102 (defvar org-odd-levels-only)
 103 (defvar org-keyword-time-regexp)
 104 (defvar org-drawer-regexp)
 105 (defvar org-complex-heading-regexp)
 106 (defvar org-property-end-re)
 107
 108 (defun org-inlinetask-insert-task ()
 109   "Insert an inline task."
 110   (interactive)
 111   (or (bolp) (newline))
 112   (insert (make-string org-inlinetask-min-level ?*) " \n"
 113           (make-string org-inlinetask-min-level ?*) " END\n")
 114   (end-of-line -1))
 115 (define-key org-mode-map "\C-c\C-xt" 'org-inlinetask-insert-task)
 116
 117 (defvar htmlp)  ; dynamically scoped into the next function
 118 (defvar latexp) ; dynamically scoped into the next function
 119 (defun org-inlinetask-export-handler ()
 120   "Handle headlines with level larger or equal to `org-inlinetask-min-level'.
 121 Either remove headline and meta data, or do special formatting."
 122   (goto-char (point-min))
 123   (let* ((nstars (if org-odd-levels-only
 124                      (1- (* 2 (or org-inlinetask-min-level 200)))
 125                    (or org-inlinetask-min-level 200)))
 126          (re1 (format "^\\(\\*\\{%d,\\}\\) .*\n" nstars))
 127          (re2 (concat "^[ \t]*" org-keyword-time-regexp))
 128          headline beg end stars content indent)
 129     (while (re-search-forward re1 nil t)
 130       (setq headline (match-string 0)
 131             stars (match-string 1)
 132             content nil)
 133       (replace-match "")
 134       (while (looking-at re2)
 135         (delete-region (point) (1+ (point-at-eol))))
 136       (while (looking-at org-drawer-regexp)
 137         (setq beg (point))
 138         (if (re-search-forward org-property-end-re nil t)
 139             (delete-region beg (1+ (match-end 0)))))
 140       (setq beg (point))
 141       (when (and (re-search-forward "^\\(\\*+\\) " nil t)
 142                  (= (length (match-string 1)) (length stars))
 143                  (progn (goto-char (match-end 0))
 144                         (looking-at "END[ \t]*$")))
 145         (setq content (buffer-substring beg (1- (point-at-bol))))
 146         (delete-region beg (1+ (match-end 0))))
 147       (goto-char beg)
 148       (when org-inlinetask-export
 149         (when (string-match org-complex-heading-regexp headline)
 150           (setq headline (concat
 151                           (if (match-end 2)
 152                               (concat
 153                                (org-add-props
 154                                    (format
 155                                     "@<span class=\"%s %s\"> %s@</span>"
 156                                     (if (member (match-string 2 headline)
 157                                                 org-done-keywords)
 158                                         "done" "todo")
 159                                     (match-string 2 headline)
 160                                     (match-string 2 headline))
 161                                    nil 'org-protected t)
 162                                " ") "")
 163                           (match-string 4 headline)))
 164           (when content
 165             (if (not (string-match "\\S-" content))
 166                 (setq content nil)
 167               (if (string-match "[ \t\n]+\\'" content)
 168                   (setq content (substring content 0 (match-beginning 0))))
 169               (setq content (org-remove-indentation content))
 170               (if latexp (setq content (concat "\\quad \\\\\n" content)))))
 171           (insert (make-string (org-inlinetask-get-current-indentation) ?\ )
 172                   "- ")
 173           (setq indent (make-string (current-column) ?\ ))
 174           (insert headline " ::")
 175           (if content
 176               (insert (if htmlp " " (concat "\n" indent))
 177                       (mapconcat 'identity (org-split-string content "\n")
 178                                  (concat "\n" indent)) "\n")
 179             (insert "\n"))
 180           (insert indent)
 181           (backward-delete-char 2)
 182           (insert "THISISTHEINLINELISTTEMINATOR\n"))))))
 183
 184 (defun org-inlinetask-get-current-indentation ()
 185   "Get the indentation of the last non-while line above this one."
 186   (save-excursion
 187     (beginning-of-line 1)
 188     (skip-chars-backward " \t\n")
 189     (beginning-of-line 1)
 190     (or (org-at-item-p)
 191         (looking-at "[ \t]*"))
 192     (goto-char (match-end 0))
 193     (current-column)))
 194
 195 (defun org-inlinetask-fontify (limit)
 196   "Fontify the inline tasks."
 197   (let* ((nstars (if org-odd-levels-only
 198                      (1- (* 2 (or org-inlinetask-min-level 200)))
 199                    (or org-inlinetask-min-level 200)))
 200          (re (concat "^\\(\\*\\)\\(\\*\\{"
 201                     (format "%d" (- nstars 3))
 202                     ",\\}\\)\\(\\*\\* .*\\)")))
 203     (while (re-search-forward re limit t)
 204       (add-text-properties (match-beginning 1) (match-end 1)
 205                            '(face org-warning font-lock-fontified t))
 206       (add-text-properties (match-beginning 2) (match-end 2)
 207                            '(face org-hide font-lock-fontified t))
 208       (add-text-properties (match-beginning 3) (match-end 3)
 209                            '(face shadow font-lock-fontified t)))))
 210
 211 (defun org-inlinetask-remove-END-maybe ()
 212   "Remove an END line when present."
 213   (when (looking-at (format "\\([ \t]*\n\\)*\\*\\{%d,\\}[ \t]+END[ \t]*$"
 214                             org-inlinetask-min-level))
 215     (replace-match "")))
 216
 217 (defun org-inlinetask-remove-terminator ()
 218   (let (beg end)
 219     (save-excursion
 220       (goto-char (point-min))
 221       (while (re-search-forward "THISISTHEINLINELISTTEMINATOR\n" nil t)
 222         (setq beg (match-beginning 0) end (match-end 0))
 223         (save-excursion
 224           (beginning-of-line 1)
 225           (and (looking-at "<p\\(ara\\)?>THISISTHEINLINELISTTEMINATOR[ \t\n]*</p\\(ara\\)?>")
 226                (setq beg (point) end (match-end 0))))
 227         (delete-region beg end)))))
 228
 229 (eval-after-load "org-exp"
 230   '(add-hook 'org-export-preprocess-after-tree-selection-hook
 231              'org-inlinetask-export-handler))
 232 (eval-after-load "org"
 233   '(add-hook 'org-font-lock-hook 'org-inlinetask-fontify))
 234 (eval-after-load "org-html"
 235   '(add-hook 'org-export-html-final-hook 'org-inlinetask-remove-terminator))
 236 (eval-after-load "org-latex"
 237   '(add-hook 'org-export-latex-final-hook 'org-inlinetask-remove-terminator))
 238 (eval-after-load "org-ascii"
 239   '(add-hook 'org-export-ascii-final-hook 'org-inlinetask-remove-terminator))
 240 (eval-after-load "org-docbook"
 241   '(add-hook 'org-export-docbook-final-hook 'org-inlinetask-remove-terminator))
 242
 243 (provide 'org-inlinetask)
 244
 245 ;;; org-inlinetask.el ends here