lisp/ob-comint.el

   1 ;;; ob-comint.el --- Babel Functions for Interaction with Comint Buffers -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research, comint
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; These functions build on comint to ease the sending and receiving
  27 ;; of commands and results from comint buffers.
  28
  29 ;; Note that the buffers in this file are analogous to sessions in
  30 ;; org-babel at large.
  31
  32 ;;; Code:
  33 (require 'ob-core)
  34 (require 'org-compat)
  35 (require 'comint)
  36 (require 'tramp)
  37
  38 (defun org-babel-comint-buffer-livep (buffer)
  39   "Check if BUFFER is a comint buffer with a live process."
  40   (let ((buffer (if buffer (get-buffer buffer))))
  41     (and buffer (buffer-live-p buffer) (get-buffer-process buffer) buffer)))
  42
  43 (defmacro org-babel-comint-in-buffer (buffer &rest body)
  44   "Check BUFFER and execute BODY.
  45 BUFFER is checked with `org-babel-comint-buffer-livep'.  BODY is
  46 executed inside the protection of `save-excursion' and
  47 `save-match-data'."
  48   (declare (indent 1))
  49   `(progn
  50      (unless (org-babel-comint-buffer-livep ,buffer)
  51        (error "Buffer %s does not exist or has no process" ,buffer))
  52      (save-match-data
  53        (with-current-buffer ,buffer
  54          (save-excursion
  55            (let ((comint-input-filter (lambda (_input) nil)))
  56              ,@body))))))
  57 (def-edebug-spec org-babel-comint-in-buffer (form body))
  58
  59 (defmacro org-babel-comint-with-output (meta &rest body)
  60   "Evaluate BODY in BUFFER and return process output.
  61 Will wait until EOE-INDICATOR appears in the output, then return
  62 all process output.  If REMOVE-ECHO and FULL-BODY are present and
  63 non-nil, then strip echo'd body from the returned output.  META
  64 should be a list containing the following where the last two
  65 elements are optional.
  66
  67  (BUFFER EOE-INDICATOR REMOVE-ECHO FULL-BODY)
  68
  69 This macro ensures that the filter is removed in case of an error
  70 or user `keyboard-quit' during execution of body."
  71   (declare (indent 1))
  72   (let ((buffer (nth 0 meta))
  73         (eoe-indicator (nth 1 meta))
  74         (remove-echo (nth 2 meta))
  75         (full-body (nth 3 meta)))
  76     `(org-babel-comint-in-buffer ,buffer
  77        (let* ((string-buffer "")
  78               (comint-output-filter-functions
  79                (cons (lambda (text) (setq string-buffer (concat string-buffer text)))
  80                      comint-output-filter-functions))
  81               dangling-text)
  82          ;; got located, and save dangling text
  83          (goto-char (process-mark (get-buffer-process (current-buffer))))
  84          (let ((start (point))
  85                (end (point-max)))
  86            (setq dangling-text (buffer-substring start end))
  87            (delete-region start end))
  88          ;; pass FULL-BODY to process
  89          ,@body
  90          ;; wait for end-of-evaluation indicator
  91          (while (progn
  92                   (goto-char comint-last-input-end)
  93                   (not (save-excursion
  94                          (and (re-search-forward
  95                                (regexp-quote ,eoe-indicator) nil t)
  96                               (re-search-forward
  97                                comint-prompt-regexp nil t)))))
  98            (accept-process-output (get-buffer-process (current-buffer)))
  99            ;; thought the following this would allow async
 100            ;; background running, but I was wrong...
 101            ;; (run-with-timer .5 .5 'accept-process-output
 102            ;;            (get-buffer-process (current-buffer)))
 103            )
 104          ;; replace cut dangling text
 105          (goto-char (process-mark (get-buffer-process (current-buffer))))
 106          (insert dangling-text)
 107
 108          ;; remove echo'd FULL-BODY from input
 109          (when (and ,remove-echo ,full-body
 110                     (string-match
 111                      (replace-regexp-in-string
 112                       "\n" "[\r\n]+" (regexp-quote (or ,full-body "")))
 113                      string-buffer))
 114            (setq string-buffer (substring string-buffer (match-end 0))))
 115          (split-string string-buffer comint-prompt-regexp)))))
 116 (def-edebug-spec org-babel-comint-with-output (sexp body))
 117
 118 (defun org-babel-comint-input-command (buffer cmd)
 119   "Pass CMD to BUFFER.
 120 The input will not be echoed."
 121   (org-babel-comint-in-buffer buffer
 122     (goto-char (process-mark (get-buffer-process buffer)))
 123     (insert cmd)
 124     (comint-send-input)
 125     (org-babel-comint-wait-for-output buffer)))
 126
 127 (defun org-babel-comint-wait-for-output (buffer)
 128   "Wait until output arrives from BUFFER.
 129 Note: this is only safe when waiting for the result of a single
 130 statement (not large blocks of code)."
 131   (org-babel-comint-in-buffer buffer
 132     (while (progn
 133              (goto-char comint-last-input-end)
 134              (not (and (re-search-forward comint-prompt-regexp nil t)
 135                        (goto-char (match-beginning 0))
 136                        (string= (face-name (face-at-point))
 137                                 "comint-highlight-prompt"))))
 138       (accept-process-output (get-buffer-process buffer)))))
 139
 140 (defun org-babel-comint-eval-invisibly-and-wait-for-file
 141   (buffer file string &optional period)
 142   "Evaluate STRING in BUFFER invisibly.
 143 Don't return until FILE exists.  Code in STRING must ensure that
 144 FILE exists at end of evaluation."
 145   (unless (org-babel-comint-buffer-livep buffer)
 146     (error "Buffer %s does not exist or has no process" buffer))
 147   (when (file-exists-p file) (delete-file file))
 148   (process-send-string
 149    (get-buffer-process buffer)
 150    (if (= (aref string (1- (length string))) ?\n) string (concat string "\n")))
 151   ;; From Tramp 2.1.19 the following cache flush is not necessary
 152   (when (file-remote-p default-directory)
 153     (with-parsed-tramp-file-name default-directory nil
 154       (tramp-flush-directory-property v "")))
 155   (while (not (file-exists-p file)) (sit-for (or period 0.25))))
 156
 157 (provide 'ob-comint)
 158
 159
 160
 161 ;;; ob-comint.el ends here