lisp/org-duration.el

   1 ;;; org-duration.el --- Library handling durations   -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2017  Nicolas Goaziou
   4
   5 ;; Author: Nicolas Goaziou <mail@nicolasgoaziou.fr>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; This library provides tools to manipulate durations.  A duration
  24 ;; can have multiple formats:
  25 ;;
  26 ;;   - 3:12
  27 ;;   - 1:23:45
  28 ;;   - 1y 3d 3h 4min
  29 ;;   - 3d 13:35
  30 ;;   - 2.35h
  31 ;;
  32 ;; More accurately, it consists of numbers and units, as defined in
  33 ;; variable `org-duration-units', separated with white spaces, and
  34 ;; a "H:MM" or "H:MM:SS" part.  White spaces are tolerated between the
  35 ;; number and its relative unit.  Variable `org-duration-format'
  36 ;; controls durations default representation.
  37 ;;
  38 ;; The library provides functions allowing to convert a duration to,
  39 ;; and from, a number of minutes: `org-duration-to-minutes' and
  40 ;; `org-duration-from-minutes'.  It also provides two lesser tools:
  41 ;; `org-duration-p', and `org-duration-h:mm-only-p'.
  42 ;;
  43 ;; Users can set the number of minutes per unit, or define new units,
  44 ;; in `org-duration-units'.  The library also supports canonical
  45 ;; duration, i.e., a duration that doesn't depend on user's settings,
  46 ;; through optional arguments.
  47
  48 ;;; Code:
  49
  50 (require 'cl-lib)
  51 (require 'org-macs)
  52 (declare-function org-trim "org-trim" (s &optional keep-lead))
  53
  54 \f
  55 ;;; Public variables
  56
  57 (defconst org-duration-canonical-units
  58   `(("min" . 1)
  59     ("h" . 60)
  60     ("d" . ,(* 60 24)))
  61   "Canonical time duration units.
  62 See `org-duration-units' for details.")
  63
  64 (defcustom org-duration-units
  65   `(("min" . 1)
  66     ("h" . 60)
  67     ("d" . ,(* 60 24))
  68     ("w" . ,(* 60 24 7))
  69     ("m" . ,(* 60 24 30))
  70     ("y" . ,(* 60 24 365.25)))
  71   "Conversion factor to minutes for a duration.
  72
  73 Each entry has the form (UNIT . MODIFIER).
  74
  75 In a duration string, a number followed by UNIT is multiplied by
  76 the specified number of MODIFIER to obtain a duration in minutes.
  77
  78 For example, the following value
  79
  80   \\=`((\"min\" . 1)
  81     (\"h\" . 60)
  82     (\"d\" . ,(* 60 8))
  83     (\"w\" . ,(* 60 8 5))
  84     (\"m\" . ,(* 60 8 5 4))
  85     (\"y\" . ,(* 60 8 5 4 10)))
  86
  87 is meaningful if you work an average of 8 hours per day, 5 days
  88 a week, 4 weeks a month and 10 months a year.
  89
  90 When setting this variable outside the Customize interface, make
  91 sure to call the following command:
  92
  93   \\[org-duration-set-regexps]"
  94   :group 'org-agenda
  95   :version "26.1"
  96   :package-version '(Org . "9.1")
  97   :set (lambda (var val) (set-default var val) (org-duration-set-regexps))
  98   :initialize 'custom-initialize-changed
  99   :type '(choice
 100           (const :tag "H:MM" 'h:mm)
 101           (const :tag "H:MM:SS" 'h:mm:ss)
 102           (alist :key-type (string :tag "Unit")
 103                  :value-type (number :tag "Modifier"))))
 104
 105 (defcustom org-duration-format '(("d" . nil) (special . h:mm))
 106   "Format definition for a duration.
 107
 108 The value can be set to, respectively, the symbols `h:mm:ss' or
 109 `h:mm', which means a duration is expressed as, respectively,
 110 a \"H:MM:SS\" or \"H:MM\" string.
 111
 112 Alternatively, the value can be a list of entries following the
 113 pattern:
 114
 115   (UNIT . REQUIRED?)
 116
 117 UNIT is a unit string, as defined in `org-duration-units'.  The
 118 time duration is formatted using only the time components that
 119 are specified here.
 120
 121 Units with a zero value are skipped, unless REQUIRED? is non-nil.
 122 In that case, the unit is always used.
 123
 124 Eventually, the list can contain one of the following special
 125 entries:
 126
 127   (special . h:mm)
 128   (special . h:mm:ss)
 129
 130     Units shorter than an hour are ignored.  The hours and
 131     minutes part of the duration is expressed unconditionally
 132     with H:MM, or H:MM:SS, pattern.
 133
 134   (special . PRECISION)
 135
 136     A duration is expressed with a single unit, PRECISION being
 137     the number of decimal places to show.  The unit chosen is the
 138     first one required or with a non-zero integer part.  If there
 139     is no such unit, the smallest one is used.
 140
 141 For example,
 142
 143    ((\"d\" . nil) (\"h\" . t) (\"min\" . t))
 144
 145 means a duration longer than a day is expressed in days, hours
 146 and minutes, whereas a duration shorter than a day is always
 147 expressed in hours and minutes, even when shorter than an hour.
 148
 149 On the other hand, the value
 150
 151   ((\"d\" . nil) (\"min\" . nil))
 152
 153 means a duration longer than a day is expressed in days and
 154 minutes, whereas a duration shorter than a day is expressed
 155 entirely in minutes, even when longer than an hour.
 156
 157 The following format
 158
 159   ((\"d\" . nil) (special . h:mm))
 160
 161 means that any duration longer than a day is expressed with both
 162 a \"d\" unit and a \"H:MM\" part, whereas a duration shorter than
 163 a day is expressed only as a \"H:MM\" string.
 164
 165 Eventually,
 166
 167   ((\"d\" . nil) (\"h\" . nil) (special . 2))
 168
 169 expresses a duration longer than a day as a decimal number, with
 170 a 2-digits fractional part, of \"d\" unit.  A duration shorter
 171 than a day uses \"h\" unit instead."
 172   :group 'org-time
 173   :group 'org-clock
 174   :version "26.1"
 175   :package-version '(Org . "9.1")
 176   :type '(choice
 177           (const :tag "Use H:MM" h:mm)
 178           (const :tag "Use H:MM:SS" h:mm:ss)
 179           (repeat :tag "Use units"
 180                   (choice
 181                    (cons :tag "Use units"
 182                          (string :tag "Unit")
 183                          (choice (const :tag "Skip when zero" nil)
 184                                  (const :tag "Always used" t)))
 185                    (cons :tag "Use a single decimal unit"
 186                          (const special)
 187                          (integer :tag "Number of decimals"))
 188                    (cons :tag "Use both units and H:MM"
 189                          (const special)
 190                          (const h:mm))
 191                    (cons :tag "Use both units and H:MM:SS"
 192                          (const special)
 193                          (const h:mm:ss))))))
 194
 195 \f
 196 ;;; Internal variables and functions
 197
 198 (defconst org-duration--h:mm-re
 199   "\\`[ \t]*[0-9]+\\(?::[0-9]\\{2\\}\\)\\{1,2\\}[ \t]*\\'"
 200   "Regexp matching a duration expressed with H:MM or H:MM:SS format.
 201 See `org-duration--h:mm:ss-re' to only match the latter.  Hours
 202 can use any number of digits.")
 203
 204 (defconst org-duration--h:mm:ss-re
 205   "\\`[ \t]*[0-9]+\\(?::[0-9]\\{2\\}\\)\\{2\\}[ \t]*\\'"
 206   "Regexp matching a duration expressed H:MM:SS format.
 207 See `org-duration--h:mm-re' to also support H:MM format.  Hours
 208 can use any number of digits.")
 209
 210 (defvar org-duration--unit-re nil
 211   "Regexp matching a duration with an unit.
 212 Allowed units are defined in `org-duration-units'.  Match group
 213 1 contains the bare number.  Match group 2 contains the unit.")
 214
 215 (defvar org-duration--full-re nil
 216   "Regexp matching a duration expressed with units.
 217 Allowed units are defined in `org-duration-units'.")
 218
 219 (defvar org-duration--mixed-re nil
 220   "Regexp matching a duration expressed with units and H:MM or H:MM:SS format.
 221 Allowed units are defined in `org-duration-units'.  Match group
 222 1 contains units part.  Match group 2 contains H:MM or H:MM:SS
 223 part.")
 224
 225 (defun org-duration--modifier (unit &optional canonical)
 226   "Return modifier associated to string UNIT.
 227 When optional argument CANONICAL is non-nil, refer to
 228 `org-duration-canonical-units' instead of `org-duration-units'."
 229   (or (cdr (assoc unit (if canonical
 230                            org-duration-canonical-units
 231                          org-duration-units)))
 232       (error "Unknown unit: %S" unit)))
 233
 234 \f
 235 ;;; Public functions
 236
 237 ;;;###autoload
 238 (defun org-duration-set-regexps ()
 239   "Set duration related regexps."
 240   (interactive)
 241   (setq org-duration--unit-re
 242         (concat "\\([0-9]+\\(?:\\.[0-9]*\\)?\\)[ \t]*"
 243                 ;; Since user-defined units in `org-duration-units'
 244                 ;; can differ from canonical units in
 245                 ;; `org-duration-canonical-units', include both in
 246                 ;; regexp.
 247                 (regexp-opt (mapcar #'car (append org-duration-canonical-units
 248                                                   org-duration-units))
 249                             t)))
 250   (setq org-duration--full-re
 251         (format "\\`[ \t]*%s\\(?:[ \t]+%s\\)*[ \t]*\\'"
 252                 org-duration--unit-re
 253                 org-duration--unit-re))
 254   (setq org-duration--mixed-re
 255         (format "\\`[ \t]*\\(?1:%s\\(?:[ \t]+%s\\)*\\)[ \t]+\
 256 \\(?2:[0-9]+\\(?::[0-9][0-9]\\)\\{1,2\\}\\)[ \t]*\\'"
 257                 org-duration--unit-re
 258                 org-duration--unit-re)))
 259
 260 ;;;###autoload
 261 (defun org-duration-p (s)
 262   "Non-nil when string S is a time duration."
 263   (and (stringp s)
 264        (or (string-match-p org-duration--full-re s)
 265            (string-match-p org-duration--mixed-re s)
 266            (string-match-p org-duration--h:mm-re s))))
 267
 268 ;;;###autoload
 269 (defun org-duration-to-minutes (duration &optional canonical)
 270   "Return number of minutes of DURATION string.
 271
 272 When optional argument CANONICAL is non-nil, ignore
 273 `org-duration-units' and use standard time units value.
 274
 275 As a special case, a bare number represents minutes.
 276
 277 Return value as a float.  Raise an error if duration format is
 278 not recognized."
 279   (cond
 280    ((numberp duration) (float duration))
 281    ((string-match-p org-duration--h:mm-re duration)
 282     (pcase-let ((`(,hours ,minutes ,seconds)
 283                  (mapcar #'string-to-number (split-string duration ":"))))
 284       (+ (/ (or seconds 0) 60.0) minutes (* 60 hours))))
 285    ((string-match-p org-duration--full-re duration)
 286     (let ((minutes 0)
 287           (s 0))
 288       (while (string-match org-duration--unit-re duration s)
 289         (setq s (match-end 0))
 290         (let ((value (string-to-number (match-string 1 duration)))
 291               (unit (match-string 2 duration)))
 292           (cl-incf minutes (* value (org-duration--modifier unit canonical)))))
 293       (float minutes)))
 294    ((string-match org-duration--mixed-re duration)
 295     (let ((units-part (match-string 1 duration))
 296           (hms-part (match-string 2 duration)))
 297       (+ (org-duration-to-minutes units-part)
 298          (org-duration-to-minutes hms-part))))
 299    ((string-match-p "\\`[0-9]+\\(\\.[0-9]*\\)?\\'" duration)
 300     (float (string-to-number duration)))
 301    (t (error "Invalid duration format: %S" duration))))
 302
 303 ;;;###autoload
 304 (defun org-duration-from-minutes (minutes &optional fmt canonical)
 305   "Return duration string for a given number of MINUTES.
 306
 307 Format duration according to `org-duration-format' or FMT, when
 308 non-nil.
 309
 310 When optional argument CANONICAL is non-nil, ignore
 311 `org-duration-units' and use standard time units value.
 312
 313 Raise an error if expected format is unknown."
 314   (pcase (or fmt org-duration-format)
 315     (`h:mm
 316      (let ((minutes (floor minutes)))
 317        (format "%d:%02d" (/ minutes 60) (mod minutes 60))))
 318     (`h:mm:ss
 319      (let* ((whole-minutes (floor minutes))
 320             (seconds (floor (* 60 (- minutes whole-minutes)))))
 321        (format "%s:%02d"
 322                (org-duration-from-minutes whole-minutes 'h:mm)
 323                seconds)))
 324     ((pred atom) (error "Invalid duration format specification: %S" fmt))
 325     ;; Mixed format.  Call recursively the function on both parts.
 326     ((and duration-format
 327           (let `(special . ,(and mode (or `h:mm:ss `h:mm)))
 328             (assq 'special duration-format)))
 329      (let* ((truncated-format
 330              ;; Remove "special" mode from duration format in order to
 331              ;; recurse properly.  Also remove units smaller or equal
 332              ;; to an hour since H:MM part takes care of it.
 333              (cl-remove-if-not
 334               (lambda (pair)
 335                 (pcase pair
 336                   (`(,(and unit (pred stringp)) . ,_)
 337                    (> (org-duration--modifier unit canonical) 60))
 338                   (_ nil)))
 339               duration-format))
 340             (min-modifier               ;smallest modifier above hour
 341              (and truncated-format
 342                   (apply #'min
 343                          (mapcar (lambda (p)
 344                                    (org-duration--modifier (car p) canonical))
 345                                  truncated-format)))))
 346        (if (or (null min-modifier) (< minutes min-modifier))
 347            ;; There is not unit above the hour or the smallest unit
 348            ;; above the hour is too large for the number of minutes we
 349            ;; need to represent.  Use H:MM or H:MM:SS syntax.
 350            (org-duration-from-minutes minutes mode canonical)
 351          ;; Represent minutes above hour using provided units and H:MM
 352          ;; or H:MM:SS below.
 353          (let* ((units-part (* min-modifier (/ (floor minutes) min-modifier)))
 354                 (minutes-part (- minutes units-part)))
 355            (concat
 356             (org-duration-from-minutes units-part truncated-format canonical)
 357             " "
 358             (org-duration-from-minutes minutes-part mode))))))
 359     ;; Units format.
 360     (duration-format
 361      (let* ((fractional
 362              (let ((digits (cdr (assq 'special duration-format))))
 363                (and digits
 364                     (or (wholenump digits)
 365                         (error "Unknown formatting directive: %S" digits))
 366                     (format "%%.%df" digits))))
 367             (selected-units
 368              (sort (cl-remove-if
 369                     ;; Ignore special format cells.
 370                     (lambda (pair) (pcase pair (`(special . ,_) t) (_ nil)))
 371                     duration-format)
 372                    (lambda (a b)
 373                      (> (org-duration--modifier (car a) canonical)
 374                         (org-duration--modifier (car b) canonical))))))
 375        (cond
 376         ;; Fractional duration: use first unit that is either required
 377         ;; or smaller than MINUTES.
 378         (fractional
 379          (let* ((unit (car
 380                        (or (cl-find-if
 381                             (lambda (pair)
 382                               (pcase pair
 383                                 (`(,u . ,req?)
 384                                  (or req?
 385                                      (<= (org-duration--modifier u canonical)
 386                                          minutes)))))
 387                             selected-units)
 388                            ;; Fall back to smallest unit.
 389                            (org-last selected-units))))
 390                 (modifier (org-duration--modifier unit canonical)))
 391            (concat (format fractional (/ (float minutes) modifier)) unit)))
 392         ;; Otherwise build duration string according to available
 393         ;; units.
 394         ((org-string-nw-p
 395           (org-trim
 396            (mapconcat
 397             (lambda (units)
 398               (pcase-let* ((`(,unit . ,required?) units)
 399                            (modifier (org-duration--modifier unit canonical)))
 400                 (cond ((<= modifier minutes)
 401                        (let ((value (if (integerp modifier)
 402                                         (/ (floor minutes) modifier)
 403                                       (floor (/ minutes modifier)))))
 404                          (cl-decf minutes (* value modifier))
 405                          (format " %d%s" value unit)))
 406                       (required? (concat " 0" unit))
 407                       (t ""))))
 408             selected-units
 409             ""))))
 410         ;; No unit can properly represent MINUTES.  Use the smallest
 411         ;; one anyway.
 412         (t
 413          (pcase-let ((`((,unit . ,_)) (last selected-units)))
 414            (concat "0" unit))))))))
 415
 416 ;;;###autoload
 417 (defun org-duration-h:mm-only-p (times)
 418   "Non-nil when every duration in TIMES has \"H:MM\" or \"H:MM:SS\" format.
 419
 420 TIMES is a list of duration strings.
 421
 422 Return nil if any duration is expressed with units, as defined in
 423 `org-duration-units'.  Otherwise, if any duration is expressed
 424 with \"H:MM:SS\" format, return `h:mm:ss'.  Otherwise, return
 425 `h:mm'."
 426   (let (hms-flag)
 427     (catch :exit
 428       (dolist (time times)
 429         (cond ((string-match-p org-duration--full-re time)
 430                (throw :exit nil))
 431               ((string-match-p org-duration--mixed-re time)
 432                (throw :exit nil))
 433               (hms-flag nil)
 434               ((string-match-p org-duration--h:mm:ss-re time)
 435                (setq hms-flag 'h:mm:ss))))
 436       (or hms-flag 'h:mm))))
 437
 438 \f
 439 ;;; Initialization
 440
 441 (org-duration-set-regexps)
 442
 443 (provide 'org-duration)
 444 ;;; org-duration.el ends here