lisp/ob-R.el

   1 ;;; ob-R.el --- org-babel functions for R code evaluation
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research, R, statistics
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating R code
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function orgtbl-to-tsv "org-table" (table params))
  34 (declare-function R "ext:essd-r" (&optional start-args))
  35 (declare-function inferior-ess-send-input "ext:ess-inf" ())
  36 (declare-function ess-make-buffer-current "ext:ess-inf" ())
  37 (declare-function ess-eval-buffer "ext:ess-inf" (vis))
  38 (declare-function ess-wait-for-process "ext:ess-inf"
  39                   (&optional proc sec-prompt wait force-redisplay))
  40 (declare-function org-number-sequence "org-compat" (from &optional to inc))
  41 (declare-function org-remove-if-not "org" (predicate seq))
  42 (declare-function org-every "org" (pred seq))
  43
  44 (defconst org-babel-header-args:R
  45   '((width               . :any)
  46     (height              . :any)
  47     (bg                  . :any)
  48     (units               . :any)
  49     (pointsize           . :any)
  50     (antialias           . :any)
  51     (quality             . :any)
  52     (compression         . :any)
  53     (res                 . :any)
  54     (type                . :any)
  55     (family              . :any)
  56     (title               . :any)
  57     (fonts               . :any)
  58     (version             . :any)
  59     (paper               . :any)
  60     (encoding            . :any)
  61     (pagecentre          . :any)
  62     (colormodel          . :any)
  63     (useDingbats         . :any)
  64     (horizontal          . :any)
  65     (results             . ((file list vector table scalar verbatim)
  66                             (raw org html latex code pp wrap)
  67                             (replace silent append prepend)
  68                             (output value graphics))))
  69   "R-specific header arguments.")
  70
  71 (defconst ob-R-safe-header-args
  72   (append org-babel-safe-header-args
  73           '(:width :height :bg :units :pointsize :antialias :quality
  74                    :compression :res :type :family :title :fonts
  75                    :version :paper :encoding :pagecentre :colormodel
  76                    :useDingbats :horizontal))
  77   "Header args which are safe for R babel blocks.
  78
  79 See `org-babel-safe-header-args' for documentation of the format of
  80 this variable.")
  81
  82 (defvar org-babel-default-header-args:R '())
  83 (put 'org-babel-default-header-args:R 'safe-local-variable
  84      (org-babel-header-args-safe-fn ob-R-safe-header-args))
  85
  86 (defcustom org-babel-R-command "R --slave --no-save"
  87   "Name of command to use for executing R code."
  88   :group 'org-babel
  89   :version "24.1"
  90   :type 'string)
  91
  92 (defvar ess-local-process-name) ; dynamically scoped
  93 (defun org-babel-edit-prep:R (info)
  94   (let ((session (cdr (assoc :session (nth 2 info)))))
  95     (when (and session (string-match "^\\*\\(.+?\\)\\*$" session))
  96       (save-match-data (org-babel-R-initiate-session session nil)))))
  97
  98 (defconst ob-R-transfer-variable-table-with-header
  99   "%s <- local({
 100      con <- textConnection(
 101        %S
 102      )
 103      res <- read.table(
 104        con,
 105        header    = %s,
 106        row.names = %s,
 107        sep       = \"\\t\",
 108        as.is     = TRUE
 109      )
 110      close(con)
 111      res
 112    })"
 113   "R code used to transfer a table defined as a variable from org to R.
 114 This function is used when the table contains a header.")
 115
 116 (defconst ob-R-transfer-variable-table-without-header
 117   "%s <- local({
 118      con <- textConnection(
 119        %S
 120      )
 121      res <- read.table(
 122        con,
 123        header    = %s,
 124        row.names = %s,
 125        sep       = \"\\t\",
 126        as.is     = TRUE,
 127        fill      = TRUE,
 128        col.names = paste(\"V\", seq_len(%d), sep =\"\")
 129      )
 130      close(con)
 131      res
 132    })"
 133   "R code used to transfer a table defined as a variable from org to R.
 134 This function is used when the table does not contain a header.")
 135
 136 (defun org-babel-expand-body:R (body params &optional graphics-file)
 137   "Expand BODY according to PARAMS, return the expanded body."
 138   (mapconcat 'identity
 139              (append
 140               (when (cdr (assoc :prologue params))
 141                 (list (cdr (assoc :prologue params))))
 142               (org-babel-variable-assignments:R params)
 143               (list body)
 144               (when (cdr (assoc :epilogue params))
 145                 (list (cdr (assoc :epilogue params)))))
 146              "\n"))
 147
 148 (defun org-babel-execute:R (body params)
 149   "Execute a block of R code.
 150 This function is called by `org-babel-execute-src-block'."
 151   (save-excursion
 152     (let* ((result-params (cdr (assoc :result-params params)))
 153            (result-type (cdr (assoc :result-type params)))
 154            (session (org-babel-R-initiate-session
 155                      (cdr (assoc :session params)) params))
 156            (colnames-p (cdr (assoc :colnames params)))
 157            (rownames-p (cdr (assoc :rownames params)))
 158            (graphics-file (and (member "graphics" (assq :result-params params))
 159                                (org-babel-graphical-output-file params)))
 160            (full-body
 161             (let ((inside
 162                    (list (org-babel-expand-body:R body params graphics-file))))
 163               (mapconcat 'identity
 164                          (if graphics-file
 165                              (append
 166                               (list (org-babel-R-construct-graphics-device-call
 167                                      graphics-file params))
 168                               inside
 169                               (list "},error=function(e){plot(x=-1:1, y=-1:1, type='n', xlab='', ylab='', axes=FALSE); text(x=0, y=0, labels=e$message, col='red'); paste('ERROR', e$message, sep=' : ')}); dev.off()"))
 170                            inside)
 171                          "\n")))
 172            (result
 173             (org-babel-R-evaluate
 174              session full-body result-type result-params
 175              (or (equal "yes" colnames-p)
 176                  (org-babel-pick-name
 177                   (cdr (assoc :colname-names params)) colnames-p))
 178              (or (equal "yes" rownames-p)
 179                  (org-babel-pick-name
 180                   (cdr (assoc :rowname-names params)) rownames-p)))))
 181       (if graphics-file nil result))))
 182
 183 (defun org-babel-prep-session:R (session params)
 184   "Prepare SESSION according to the header arguments specified in PARAMS."
 185   (let* ((session (org-babel-R-initiate-session session params))
 186          (var-lines (org-babel-variable-assignments:R params)))
 187     (org-babel-comint-in-buffer session
 188       (mapc (lambda (var)
 189               (end-of-line 1) (insert var) (comint-send-input nil t)
 190               (org-babel-comint-wait-for-output session)) var-lines))
 191     session))
 192
 193 (defun org-babel-load-session:R (session body params)
 194   "Load BODY into SESSION."
 195   (save-window-excursion
 196     (let ((buffer (org-babel-prep-session:R session params)))
 197       (with-current-buffer buffer
 198         (goto-char (process-mark (get-buffer-process (current-buffer))))
 199         (insert (org-babel-chomp body)))
 200       buffer)))
 201
 202 ;; helper functions
 203
 204 (defun org-babel-variable-assignments:R (params)
 205   "Return list of R statements assigning the block's variables."
 206   (let ((vars (mapcar 'cdr (org-babel-get-header params :var))))
 207     (mapcar
 208      (lambda (pair)
 209        (org-babel-R-assign-elisp
 210         (car pair) (cdr pair)
 211         (equal "yes" (cdr (assoc :colnames params)))
 212         (equal "yes" (cdr (assoc :rownames params)))))
 213      (mapcar
 214       (lambda (i)
 215         (cons (car (nth i vars))
 216               (org-babel-reassemble-table
 217                (cdr (nth i vars))
 218                (cdr (nth i (cdr (assoc :colname-names params))))
 219                (cdr (nth i (cdr (assoc :rowname-names params)))))))
 220       (org-number-sequence 0 (1- (length vars)))))))
 221
 222 (defun org-babel-R-quote-tsv-field (s)
 223   "Quote field S for export to R."
 224   (if (stringp s)
 225       (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\"")
 226     (format "%S" s)))
 227
 228 (defun org-babel-R-assign-elisp (name value colnames-p rownames-p)
 229   "Construct R code assigning the elisp VALUE to a variable named NAME."
 230   (if (listp value)
 231       (let* ((lengths (mapcar 'length (org-remove-if-not 'sequencep value)))
 232              (max (if lengths (apply 'max lengths) 0))
 233              (min (if lengths (apply 'min lengths) 0)))
 234         ;; Ensure VALUE has an orgtbl structure (depth of at least 2).
 235         (unless (listp (car value)) (setq value (list value)))
 236         (let ((file (orgtbl-to-tsv value '(:fmt org-babel-R-quote-tsv-field)))
 237               (header (if (or (eq (nth 1 value) 'hline) colnames-p)
 238                           "TRUE" "FALSE"))
 239               (row-names (if rownames-p "1" "NULL")))
 240           (if (= max min)
 241               (format ob-R-transfer-variable-table-with-header
 242                       name file header row-names)
 243             (format ob-R-transfer-variable-table-without-header
 244                     name file header row-names max))))
 245     (cond ((integerp value) (format "%s <- %s" name (concat (number-to-string value) "L")))
 246           ((floatp   value) (format "%s <- %s" name value))
 247           ((stringp  value) (format "%s <- %S" name (org-no-properties value)))
 248           (t                (format "%s <- %S" name (prin1-to-string value))))))
 249
 250
 251 (defvar ess-ask-for-ess-directory) ; dynamically scoped
 252 (defun org-babel-R-initiate-session (session params)
 253   "If there is not a current R process then create one."
 254   (unless (string= session "none")
 255     (let ((session (or session "*R*"))
 256           (ess-ask-for-ess-directory
 257            (and (boundp 'ess-ask-for-ess-directory)
 258                 ess-ask-for-ess-directory
 259                 (not (cdr (assoc :dir params))))))
 260       (if (org-babel-comint-buffer-livep session)
 261           session
 262         (save-window-excursion
 263           (when (get-buffer session)
 264             ;; Session buffer exists, but with dead process
 265             (set-buffer session))
 266           (require 'ess) (R)
 267           (ess-wait-for-process)
 268           (rename-buffer
 269            (if (bufferp session)
 270                (buffer-name session)
 271              (if (stringp session)
 272                  session
 273                (buffer-name))))
 274           (current-buffer))))))
 275
 276 (defun org-babel-R-associate-session (session)
 277   "Associate R code buffer with an R session.
 278 Make SESSION be the inferior ESS process associated with the
 279 current code buffer."
 280   (setq ess-local-process-name
 281         (process-name (get-buffer-process session)))
 282   (ess-make-buffer-current))
 283
 284 (defvar org-babel-R-graphics-devices
 285   '((:bmp "bmp" "filename")
 286     (:jpg "jpeg" "filename")
 287     (:jpeg "jpeg" "filename")
 288     (:tikz "tikz" "file")
 289     (:tiff "tiff" "filename")
 290     (:png "png" "filename")
 291     (:svg "svg" "file")
 292     (:pdf "pdf" "file")
 293     (:ps "postscript" "file")
 294     (:postscript "postscript" "file"))
 295   "An alist mapping graphics file types to R functions.
 296
 297 Each member of this list is a list with three members:
 298 1. the file extension of the graphics file, as an elisp :keyword
 299 2. the R graphics device function to call to generate such a file
 300 3. the name of the argument to this function which specifies the
 301    file to write to (typically \"file\" or \"filename\")")
 302
 303 (defun org-babel-R-construct-graphics-device-call (out-file params)
 304   "Construct the call to the graphics device."
 305   (let* ((allowed-args '(:width :height :bg :units :pointsize
 306                                 :antialias :quality :compression :res
 307                                 :type :family :title :fonts :version
 308                                 :paper :encoding :pagecentre :colormodel
 309                                 :useDingbats :horizontal))
 310          (device (and (string-match ".+\\.\\([^.]+\\)" out-file)
 311                       (match-string 1 out-file)))
 312          (device-info (or (assq (intern (concat ":" device))
 313                                 org-babel-R-graphics-devices)
 314                           (assq :png org-babel-R-graphics-devices)))
 315         (extra-args (cdr (assq :R-dev-args params))) filearg args)
 316     (setq device (nth 1 device-info))
 317     (setq filearg (nth 2 device-info))
 318     (setq args (mapconcat
 319                 (lambda (pair)
 320                   (if (member (car pair) allowed-args)
 321                       (format ",%s=%S"
 322                               (substring (symbol-name (car pair)) 1)
 323                               (cdr pair)) ""))
 324                 params ""))
 325     (format "%s(%s=\"%s\"%s%s%s); tryCatch({"
 326             device filearg out-file args
 327             (if extra-args "," "") (or extra-args ""))))
 328
 329 (defvar org-babel-R-eoe-indicator "'org_babel_R_eoe'")
 330 (defvar org-babel-R-eoe-output "[1] \"org_babel_R_eoe\"")
 331
 332 (defvar org-babel-R-write-object-command "{function(object,transfer.file){object;invisible(if(inherits(try({tfile<-tempfile();write.table(object,file=tfile,sep=\"\\t\",na=\"nil\",row.names=%s,col.names=%s,quote=FALSE);file.rename(tfile,transfer.file)},silent=TRUE),\"try-error\")){if(!file.exists(transfer.file))file.create(transfer.file)})}}(object=%s,transfer.file=\"%s\")")
 333
 334 (defun org-babel-R-evaluate
 335   (session body result-type result-params column-names-p row-names-p)
 336   "Evaluate R code in BODY."
 337   (if session
 338       (org-babel-R-evaluate-session
 339        session body result-type result-params column-names-p row-names-p)
 340     (org-babel-R-evaluate-external-process
 341      body result-type result-params column-names-p row-names-p)))
 342
 343 (defun org-babel-R-evaluate-external-process
 344   (body result-type result-params column-names-p row-names-p)
 345   "Evaluate BODY in external R process.
 346 If RESULT-TYPE equals 'output then return standard output as a
 347 string.  If RESULT-TYPE equals 'value then return the value of the
 348 last statement in BODY, as elisp."
 349   (case result-type
 350     (value
 351      (let ((tmp-file (org-babel-temp-file "R-")))
 352        (org-babel-eval org-babel-R-command
 353                        (format org-babel-R-write-object-command
 354                                (if row-names-p "TRUE" "FALSE")
 355                                (if column-names-p
 356                                    (if row-names-p "NA" "TRUE")
 357                                  "FALSE")
 358                                (format "{function ()\n{\n%s\n}}()" body)
 359                                (org-babel-process-file-name tmp-file 'noquote)))
 360        (org-babel-R-process-value-result
 361         (org-babel-result-cond result-params
 362           (with-temp-buffer
 363             (insert-file-contents tmp-file)
 364             (buffer-string))
 365           (org-babel-import-elisp-from-file tmp-file '(16)))
 366         column-names-p)))
 367     (output (org-babel-eval org-babel-R-command body))))
 368
 369 (defvar ess-eval-visibly-p)
 370
 371 (defun org-babel-R-evaluate-session
 372   (session body result-type result-params column-names-p row-names-p)
 373   "Evaluate BODY in SESSION.
 374 If RESULT-TYPE equals 'output then return standard output as a
 375 string.  If RESULT-TYPE equals 'value then return the value of the
 376 last statement in BODY, as elisp."
 377   (case result-type
 378     (value
 379      (with-temp-buffer
 380        (insert (org-babel-chomp body))
 381        (let ((ess-local-process-name
 382               (process-name (get-buffer-process session)))
 383              (ess-eval-visibly-p nil))
 384          (ess-eval-buffer nil)))
 385      (let ((tmp-file (org-babel-temp-file "R-")))
 386        (org-babel-comint-eval-invisibly-and-wait-for-file
 387         session tmp-file
 388         (format org-babel-R-write-object-command
 389                 (if row-names-p "TRUE" "FALSE")
 390                 (if column-names-p
 391                     (if row-names-p "NA" "TRUE")
 392                   "FALSE")
 393                 ".Last.value" (org-babel-process-file-name tmp-file 'noquote)))
 394        (org-babel-R-process-value-result
 395         (org-babel-result-cond result-params
 396           (with-temp-buffer
 397             (insert-file-contents tmp-file)
 398             (buffer-string))
 399           (org-babel-import-elisp-from-file tmp-file '(16)))
 400         column-names-p)))
 401     (output
 402      (mapconcat
 403       'org-babel-chomp
 404       (butlast
 405        (delq nil
 406              (mapcar
 407               (lambda (line) (when (> (length line) 0) line))
 408               (mapcar
 409                (lambda (line) ;; cleanup extra prompts left in output
 410                  (if (string-match
 411                       "^\\([ ]*[>+\\.][ ]?\\)+\\([[0-9]+\\|[ ]\\)" line)
 412                      (substring line (match-end 1))
 413                    line))
 414                (org-babel-comint-with-output (session org-babel-R-eoe-output)
 415                  (insert (mapconcat 'org-babel-chomp
 416                                     (list body org-babel-R-eoe-indicator)
 417                                     "\n"))
 418                  (inferior-ess-send-input)))))) "\n"))))
 419
 420 (defun org-babel-R-process-value-result (result column-names-p)
 421   "R-specific processing of return value.
 422 Insert hline if column names in output have been requested."
 423   (if column-names-p
 424       (cons (car result) (cons 'hline (cdr result)))
 425     result))
 426
 427 (provide 'ob-R)
 428
 429
 430
 431 ;;; ob-R.el ends here