lisp/ob-scheme.el

   1 ;;; ob-scheme.el --- org-babel functions for Scheme
   2
   3 ;; Copyright (C) 2010-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research, scheme
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Now working with SBCL for both session and external evaluation.
  27 ;;
  28 ;; This certainly isn't optimally robust, but it seems to be working
  29 ;; for the basic use cases.
  30
  31 ;;; Requirements:
  32
  33 ;; - a working scheme implementation
  34 ;;   (e.g. guile http://www.gnu.org/software/guile/guile.html)
  35 ;;
  36 ;; - for session based evaluation cmuscheme.el is required which is
  37 ;;   included in Emacs
  38
  39 ;;; Code:
  40 (require 'ob)
  41 (require 'ob-ref)
  42 (require 'ob-comint)
  43 (require 'ob-eval)
  44 (eval-when-compile (require 'cl))
  45
  46 (declare-function run-scheme "ext:cmuscheme" (cmd))
  47
  48 (defvar org-babel-default-header-args:scheme '()
  49   "Default header arguments for scheme code blocks.")
  50
  51 (defvar org-babel-scheme-eoe "org-babel-scheme-eoe"
  52   "String to indicate that evaluation has completed.")
  53
  54 (defcustom org-babel-scheme-cmd "guile"
  55   "Name of command used to evaluate scheme blocks."
  56   :group 'org-babel
  57   :type 'string)
  58
  59 (defun org-babel-expand-body:scheme (body params)
  60   "Expand BODY according to PARAMS, return the expanded body."
  61   (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
  62     (if (> (length vars) 0)
  63         (concat "(let ("
  64                 (mapconcat
  65                  (lambda (var) (format "%S" (print `(,(car var) ',(cdr var)))))
  66                  vars "\n      ")
  67                 ")\n" body ")")
  68       body)))
  69
  70 (defvar scheme-program-name)
  71 (defun org-babel-execute:scheme (body params)
  72   "Execute a block of Scheme code with org-babel.
  73 This function is called by `org-babel-execute-src-block'"
  74   (let* ((result-type (cdr (assoc :result-type params)))
  75          (org-babel-scheme-cmd (or (cdr (assoc :scheme params))
  76                                    org-babel-scheme-cmd))
  77          (full-body (org-babel-expand-body:scheme body params)))
  78     (read
  79      (if (not (string= (cdr (assoc :session params)) "none"))
  80          ;; session evaluation
  81          (let ((session (org-babel-prep-session:scheme
  82                          (cdr (assoc :session params)) params)))
  83            (org-babel-comint-with-output
  84                (session (format "%S" org-babel-scheme-eoe) t body)
  85              (mapc
  86               (lambda (line)
  87                 (insert (org-babel-chomp line)) (comint-send-input nil t))
  88               (list body (format "%S" org-babel-scheme-eoe)))))
  89        ;; external evaluation
  90        (let ((script-file (org-babel-temp-file "scheme-script-")))
  91          (with-temp-file script-file
  92            (insert
  93             ;; return the value or the output
  94             (if (string= result-type "value")
  95                 (format "(display %s)" full-body)
  96               full-body)))
  97          (org-babel-eval
  98           (format "%s %s" org-babel-scheme-cmd
  99                   (org-babel-process-file-name script-file)) ""))))))
 100
 101 (defun org-babel-prep-session:scheme (session params)
 102   "Prepare SESSION according to the header arguments specified in PARAMS."
 103   (let* ((session (org-babel-scheme-initiate-session session))
 104          (vars (mapcar #'cdr (org-babel-get-header params :var)))
 105          (var-lines
 106           (mapcar
 107            (lambda (var) (format "%S" (print `(define ,(car var) ',(cdr var)))))
 108            vars)))
 109     (when session
 110       (org-babel-comint-in-buffer session
 111         (sit-for .5) (goto-char (point-max))
 112         (mapc (lambda (var)
 113                 (insert var) (comint-send-input nil t)
 114                 (org-babel-comint-wait-for-output session)
 115                 (sit-for .1) (goto-char (point-max))) var-lines)))
 116     session))
 117
 118 (defun org-babel-scheme-initiate-session (&optional session)
 119   "If there is not a current inferior-process-buffer in SESSION
 120 then create.  Return the initialized session."
 121   (require 'cmuscheme)
 122   (unless (string= session "none")
 123     (let ((session-buffer (save-window-excursion
 124                             (run-scheme org-babel-scheme-cmd)
 125                             (rename-buffer session)
 126                             (current-buffer))))
 127       (if (org-babel-comint-buffer-livep session-buffer)
 128           (progn (sit-for .25) session-buffer)
 129         (sit-for .5)
 130         (org-babel-scheme-initiate-session session)))))
 131
 132 (provide 'ob-scheme)
 133
 134
 135
 136 ;;; ob-scheme.el ends here