lisp/org-colview.el

   1 ;;; org-colview.el --- Column View in Org-mode
   2
   3 ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the column view for Org.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'org)
  33
  34 (declare-function org-agenda-redo "org-agenda" ())
  35 (declare-function org-agenda-do-context-action "org-agenda" ())
  36
  37 (when (featurep 'xemacs)
  38   (error "Do not load this file into XEmacs, use 'org-colview-xemacs.el'."))
  39
  40 ;;; Column View
  41
  42 (defvar org-columns-overlays nil
  43   "Holds the list of current column overlays.")
  44
  45 (defvar org-columns-current-fmt nil
  46   "Local variable, holds the currently active column format.")
  47 (make-variable-buffer-local 'org-columns-current-fmt)
  48 (defvar org-columns-current-fmt-compiled nil
  49   "Local variable, holds the currently active column format.
  50 This is the compiled version of the format.")
  51 (make-variable-buffer-local 'org-columns-current-fmt-compiled)
  52 (defvar org-columns-current-widths nil
  53   "Loval variable, holds the currently widths of fields.")
  54 (make-variable-buffer-local 'org-columns-current-widths)
  55 (defvar org-columns-current-maxwidths nil
  56   "Loval variable, holds the currently active maximum column widths.")
  57 (make-variable-buffer-local 'org-columns-current-maxwidths)
  58 (defvar org-columns-begin-marker (make-marker)
  59   "Points to the position where last a column creation command was called.")
  60 (defvar org-columns-top-level-marker (make-marker)
  61   "Points to the position where current columns region starts.")
  62
  63 (defvar org-columns-map (make-sparse-keymap)
  64   "The keymap valid in column display.")
  65
  66 (defun org-columns-content ()
  67   "Switch to contents view while in columns view."
  68   (interactive)
  69   (org-overview)
  70   (org-content))
  71
  72 (org-defkey org-columns-map "c" 'org-columns-content)
  73 (org-defkey org-columns-map "o" 'org-overview)
  74 (org-defkey org-columns-map "e" 'org-columns-edit-value)
  75 (org-defkey org-columns-map "\C-c\C-t" 'org-columns-todo)
  76 (org-defkey org-columns-map "\C-c\C-c" 'org-columns-set-tags-or-toggle)
  77 (org-defkey org-columns-map "\C-c\C-o" 'org-columns-open-link)
  78 (org-defkey org-columns-map "v" 'org-columns-show-value)
  79 (org-defkey org-columns-map "q" 'org-columns-quit)
  80 (org-defkey org-columns-map "r" 'org-columns-redo)
  81 (org-defkey org-columns-map "g" 'org-columns-redo)
  82 (org-defkey org-columns-map [left] 'backward-char)
  83 (org-defkey org-columns-map "\M-b" 'backward-char)
  84 (org-defkey org-columns-map "a" 'org-columns-edit-allowed)
  85 (org-defkey org-columns-map "s" 'org-columns-edit-attributes)
  86 (org-defkey org-columns-map "\M-f"
  87             (lambda () (interactive) (goto-char (1+ (point)))))
  88 (org-defkey org-columns-map [right]
  89             (lambda () (interactive) (goto-char (1+ (point)))))
  90 (org-defkey org-columns-map [down]
  91             (lambda () (interactive)
  92               (let ((col (current-column)))
  93                 (beginning-of-line 2)
  94                 (while (and (org-invisible-p2) (not (eobp)))
  95                   (beginning-of-line 2))
  96                 (move-to-column col)
  97                 (if (eq major-mode 'org-agenda-mode)
  98                     (org-agenda-do-context-action)))))
  99 (org-defkey org-columns-map [up]
 100             (lambda () (interactive)
 101               (let ((col (current-column)))
 102                 (beginning-of-line 0)
 103                 (while (and (org-invisible-p2) (not (bobp)))
 104                   (beginning-of-line 0))
 105                 (move-to-column col)
 106                 (if (eq major-mode 'org-agenda-mode)
 107                     (org-agenda-do-context-action)))))
 108 (org-defkey org-columns-map [(shift right)] 'org-columns-next-allowed-value)
 109 (org-defkey org-columns-map "n" 'org-columns-next-allowed-value)
 110 (org-defkey org-columns-map [(shift left)] 'org-columns-previous-allowed-value)
 111 (org-defkey org-columns-map "p" 'org-columns-previous-allowed-value)
 112 (org-defkey org-columns-map "<" 'org-columns-narrow)
 113 (org-defkey org-columns-map ">" 'org-columns-widen)
 114 (org-defkey org-columns-map [(meta right)] 'org-columns-move-right)
 115 (org-defkey org-columns-map [(meta left)] 'org-columns-move-left)
 116 (org-defkey org-columns-map [(shift meta right)] 'org-columns-new)
 117 (org-defkey org-columns-map [(shift meta left)] 'org-columns-delete)
 118 (dotimes (i 10)
 119   (org-defkey org-columns-map (number-to-string i)
 120               `(lambda () (interactive)
 121                  (org-columns-next-allowed-value nil ,i))))
 122
 123 (easy-menu-define org-columns-menu org-columns-map "Org Column Menu"
 124   '("Column"
 125     ["Edit property" org-columns-edit-value t]
 126     ["Next allowed value" org-columns-next-allowed-value t]
 127     ["Previous allowed value" org-columns-previous-allowed-value t]
 128     ["Show full value" org-columns-show-value t]
 129     ["Edit allowed values" org-columns-edit-allowed t]
 130     "--"
 131     ["Edit column attributes" org-columns-edit-attributes t]
 132     ["Increase column width" org-columns-widen t]
 133     ["Decrease column width" org-columns-narrow t]
 134     "--"
 135     ["Move column right" org-columns-move-right t]
 136     ["Move column left" org-columns-move-left t]
 137     ["Add column" org-columns-new t]
 138     ["Delete column" org-columns-delete t]
 139     "--"
 140     ["CONTENTS" org-columns-content t]
 141     ["OVERVIEW" org-overview t]
 142     ["Refresh columns display" org-columns-redo t]
 143     "--"
 144     ["Open link" org-columns-open-link t]
 145     "--"
 146     ["Quit" org-columns-quit t]))
 147
 148 (defun org-columns-new-overlay (beg end &optional string face)
 149   "Create a new column overlay and add it to the list."
 150   (let ((ov (make-overlay beg end)))
 151     (overlay-put ov 'face (or face 'secondary-selection))
 152     (org-overlay-display ov string face)
 153     (push ov org-columns-overlays)
 154     ov))
 155
 156 (defun org-columns-display-here (&optional props dateline)
 157   "Overlay the current line with column display."
 158   (interactive)
 159   (let* ((fmt org-columns-current-fmt-compiled)
 160          (beg (point-at-bol))
 161          (level-face (save-excursion
 162                        (beginning-of-line 1)
 163                        (and (looking-at "\\(\\**\\)\\(\\* \\)")
 164                             (org-get-level-face 2))))
 165          (ref-face (or level-face
 166                        (and (eq major-mode 'org-agenda-mode)
 167                             (get-text-property (point-at-bol) 'face))
 168                        'default))
 169          (color (list :foreground (face-attribute ref-face :foreground)))
 170          (face (list color 'org-column ref-face))
 171          (face1 (list color 'org-agenda-column-dateline ref-face))
 172          (cphr (get-text-property (point-at-bol) 'org-complex-heading-regexp))
 173          pom property ass width f string ov column val modval s2 title calc)
 174     ;; Check if the entry is in another buffer.
 175     (unless props
 176       (if (eq major-mode 'org-agenda-mode)
 177           (setq pom (or (org-get-at-bol 'org-hd-marker)
 178                         (org-get-at-bol 'org-marker))
 179                 props (if pom (org-entry-properties pom) nil))
 180         (setq props (org-entry-properties nil))))
 181     ;; Walk the format
 182     (while (setq column (pop fmt))
 183       (setq property (car column)
 184             title (nth 1 column)
 185             ass (if (equal property "ITEM")
 186                     (cons "ITEM"
 187                           ;; When in a buffer, get the whole line,
 188                           ;; we'll clean it later…
 189                           (if (eq major-mode 'org-mode)
 190                               (save-match-data
 191                                 (org-no-properties
 192                                  (org-remove-tabs
 193                                   (buffer-substring-no-properties
 194                                    (point-at-bol) (point-at-eol)))))
 195                             ;; In agenda, just get the `txt' property
 196                             (org-no-properties
 197                              (or (org-get-at-bol 'txt)
 198                                  (buffer-substring
 199                                   (point) (progn (end-of-line) (point)))))))
 200                   (assoc property props))
 201             width (or (cdr (assoc property org-columns-current-maxwidths))
 202                       (nth 2 column)
 203                       (length property))
 204             f (format "%%-%d.%ds | " width width)
 205             calc (nth 7 column)
 206             val (or (cdr ass) "")
 207             modval (cond ((and org-columns-modify-value-for-display-function
 208                                (functionp
 209                                 org-columns-modify-value-for-display-function))
 210                           (funcall org-columns-modify-value-for-display-function
 211                                    title val))
 212                          ((equal property "ITEM")
 213                           (org-columns-cleanup-item
 214                            val org-columns-current-fmt-compiled
 215                            (or org-complex-heading-regexp cphr)))
 216                          ((and calc (functionp calc)
 217                                (not (string= val ""))
 218                                (not (get-text-property 0 'org-computed val)))
 219                           (org-columns-number-to-string
 220                            (funcall calc (org-columns-string-to-number
 221                                           val (nth 4 column)))
 222                            (nth 4 column)))))
 223       (setq s2 (org-columns-add-ellipses (or modval val) width))
 224       (setq string (format f s2))
 225       ;; Create the overlay
 226       (org-unmodified
 227        (setq ov (org-columns-new-overlay
 228                  beg (setq beg (1+ beg)) string (if dateline face1 face)))
 229        (overlay-put ov 'keymap org-columns-map)
 230        (overlay-put ov 'org-columns-key property)
 231        (overlay-put ov 'org-columns-value (cdr ass))
 232        (overlay-put ov 'org-columns-value-modified modval)
 233        (overlay-put ov 'org-columns-pom pom)
 234        (overlay-put ov 'org-columns-format f)
 235        (overlay-put ov 'line-prefix "")
 236        (overlay-put ov 'wrap-prefix ""))
 237       (if (or (not (char-after beg))
 238               (equal (char-after beg) ?\n))
 239           (let ((inhibit-read-only t))
 240             (save-excursion
 241               (goto-char beg)
 242               (org-unmodified (insert " ")))))) ;; FIXME: add props and remove later?
 243       ;; Make the rest of the line disappear.
 244       (org-unmodified
 245        (setq ov (org-columns-new-overlay beg (point-at-eol)))
 246        (overlay-put ov 'invisible t)
 247        (overlay-put ov 'keymap org-columns-map)
 248        (overlay-put ov 'intangible t)
 249        (overlay-put ov 'line-prefix "")
 250        (overlay-put ov 'wrap-prefix "")
 251        (push ov org-columns-overlays)
 252        (setq ov (make-overlay (1- (point-at-eol)) (1+ (point-at-eol))))
 253        (overlay-put ov 'keymap org-columns-map)
 254        (push ov org-columns-overlays)
 255        (let ((inhibit-read-only t))
 256          (put-text-property (max (point-min) (1- (point-at-bol)))
 257                           (min (point-max) (1+ (point-at-eol)))
 258                           'read-only "Type `e' to edit property")))))
 259
 260 (defun org-columns-add-ellipses (string width)
 261   "Truncate STRING with WIDTH characters, with ellipses."
 262   (cond
 263    ((<= (length string) width) string)
 264    ((<= width (length org-columns-ellipses))
 265     (substring org-columns-ellipses 0 width))
 266    (t (concat (substring string 0 (- width (length org-columns-ellipses)))
 267               org-columns-ellipses))))
 268
 269 (defvar org-columns-full-header-line-format nil
 270   "The full header line format, will be shifted by horizontal scrolling." )
 271 (defvar org-previous-header-line-format nil
 272   "The header line format before column view was turned on.")
 273 (defvar org-columns-inhibit-recalculation nil
 274   "Inhibit recomputing of columns on column view startup.")
 275 (defvar org-columns-flyspell-was-active nil
 276   "Remember the state of `flyspell-mode' before column view.
 277 Flyspell-mode can cause problems in columns view, so it is turned off
 278 for the duration of the command.")
 279
 280 (defvar header-line-format)
 281 (defvar org-columns-previous-hscroll 0)
 282
 283 (defun org-columns-display-here-title ()
 284   "Overlay the newline before the current line with the table title."
 285   (interactive)
 286   (let ((fmt org-columns-current-fmt-compiled)
 287         string (title "")
 288         property width f column str widths)
 289     (while (setq column (pop fmt))
 290       (setq property (car column)
 291             str (or (nth 1 column) property)
 292             width (or (cdr (assoc property org-columns-current-maxwidths))
 293                       (nth 2 column)
 294                       (length str))
 295             widths (push width widths)
 296             f (format "%%-%d.%ds | " width width)
 297             string (format f str)
 298             title (concat title string)))
 299     (setq title (concat
 300                  (org-add-props " " nil 'display '(space :align-to 0))
 301                  ;;(org-add-props title nil 'face '(:weight bold :underline t :inherit default))))
 302                  (org-add-props title nil 'face 'org-column-title)))
 303     (org-set-local 'org-previous-header-line-format header-line-format)
 304     (org-set-local 'org-columns-current-widths (nreverse widths))
 305     (setq org-columns-full-header-line-format title)
 306     (setq org-columns-previous-hscroll -1)
 307 ;    (org-columns-hscoll-title)
 308     (org-add-hook 'post-command-hook 'org-columns-hscoll-title nil 'local)))
 309
 310 (defun org-columns-hscoll-title ()
 311   "Set the `header-line-format' so that it scrolls along with the table."
 312   (sit-for .0001) ; need to force a redisplay to update window-hscroll
 313   (when (not (= (window-hscroll) org-columns-previous-hscroll))
 314     (setq header-line-format
 315           (concat (substring org-columns-full-header-line-format 0 1)
 316                   (substring org-columns-full-header-line-format
 317                              (1+ (window-hscroll))))
 318           org-columns-previous-hscroll (window-hscroll))
 319     (force-mode-line-update)))
 320
 321 (defvar org-colview-initial-truncate-line-value nil
 322   "Remember the value of `truncate-lines' across colview.")
 323
 324 (defun org-columns-remove-overlays ()
 325   "Remove all currently active column overlays."
 326   (interactive)
 327   (when (marker-buffer org-columns-begin-marker)
 328     (with-current-buffer (marker-buffer org-columns-begin-marker)
 329       (when (local-variable-p 'org-previous-header-line-format)
 330         (setq header-line-format org-previous-header-line-format)
 331         (kill-local-variable 'org-previous-header-line-format)
 332         (remove-hook 'post-command-hook 'org-columns-hscoll-title 'local))
 333       (move-marker org-columns-begin-marker nil)
 334       (move-marker org-columns-top-level-marker nil)
 335       (org-unmodified
 336        (mapc 'delete-overlay org-columns-overlays)
 337        (setq org-columns-overlays nil)
 338        (let ((inhibit-read-only t))
 339          (remove-text-properties (point-min) (point-max) '(read-only t))))
 340       (when org-columns-flyspell-was-active
 341         (flyspell-mode 1))
 342       (when (local-variable-p 'org-colview-initial-truncate-line-value)
 343         (setq truncate-lines org-colview-initial-truncate-line-value)))))
 344
 345 (defun org-columns-cleanup-item (item fmt cphr)
 346   "Remove from ITEM what is a column in the format FMT.
 347 CPHR is the complex heading regexp to use for parsing ITEM."
 348   (let (fixitem)
 349     (if (not cphr)
 350         item
 351       (unless (string-match "^\*+ " item)
 352         (setq item (concat "* " item) fixitem t))
 353       (if (string-match cphr item)
 354           (setq item
 355                 (concat
 356                  (org-add-props (match-string 1 item) nil
 357                    'org-whitespace (* 2 (1- (org-reduced-level (- (match-end 1) (match-beginning 1))))))
 358                  (and (match-end 2) (not (assoc "TODO" fmt)) (concat " " (match-string 2 item)))
 359                  (and (match-end 3) (not (assoc "PRIORITY" fmt)) (concat " " (match-string 3 item)))
 360                  " " (save-match-data (org-columns-compact-links (match-string 4 item)))
 361                  (and (match-end 5) (not (assoc "TAGS" fmt)) (concat " " (match-string 5 item)))))
 362         (add-text-properties
 363          0 (1+ (match-end 1))
 364          (list 'org-whitespace (* 2 (1- (org-reduced-level (- (match-end 1) (match-beginning 1))))))
 365          item))
 366       (if fixitem (replace-regexp-in-string "^\*+ " "" item) item))))
 367
 368 (defun org-columns-compact-links (s)
 369   "Replace [[link][desc]] with [desc] or [link]."
 370   (while (string-match org-bracket-link-regexp s)
 371     (setq s (replace-match
 372              (concat "[" (match-string (if (match-end 3) 3 1) s) "]")
 373              t t s)))
 374   s)
 375
 376 (defun org-columns-show-value ()
 377   "Show the full value of the property."
 378   (interactive)
 379   (let ((value (get-char-property (point) 'org-columns-value)))
 380     (message "Value is: %s" (or value ""))))
 381
 382 (defvar org-agenda-columns-active) ;; defined in org-agenda.el
 383
 384 (defun org-columns-quit ()
 385   "Remove the column overlays and in this way exit column editing."
 386   (interactive)
 387   (org-unmodified
 388    (org-columns-remove-overlays)
 389    (let ((inhibit-read-only t))
 390      (remove-text-properties (point-min) (point-max) '(read-only t))))
 391   (when (eq major-mode 'org-agenda-mode)
 392     (setq org-agenda-columns-active nil)
 393     (message
 394      "Modification not yet reflected in Agenda buffer, use `r' to refresh")))
 395
 396 (defun org-columns-check-computed ()
 397   "Check if this column value is computed.
 398 If yes, throw an error indicating that changing it does not make sense."
 399   (let ((val (get-char-property (point) 'org-columns-value)))
 400     (when (and (stringp val)
 401                (get-char-property 0 'org-computed val))
 402       (error "This value is computed from the entry's children"))))
 403
 404 (defun org-columns-todo (&optional arg)
 405   "Change the TODO state during column view."
 406   (interactive "P")
 407   (org-columns-edit-value "TODO"))
 408
 409 (defun org-columns-set-tags-or-toggle (&optional arg)
 410   "Toggle checkbox at point, or set tags for current headline."
 411   (interactive "P")
 412   (if (string-match "\\`\\[[ xX-]\\]\\'"
 413                     (get-char-property (point) 'org-columns-value))
 414       (org-columns-next-allowed-value)
 415     (org-columns-edit-value "TAGS")))
 416
 417 (defun org-columns-edit-value (&optional key)
 418   "Edit the value of the property at point in column view.
 419 Where possible, use the standard interface for changing this line."
 420   (interactive)
 421   (org-columns-check-computed)
 422   (let* ((col (current-column))
 423          (key (or key (get-char-property (point) 'org-columns-key)))
 424          (value (get-char-property (point) 'org-columns-value))
 425          (bol (point-at-bol)) (eol (point-at-eol))
 426          (pom (or (get-text-property bol 'org-hd-marker)
 427                   (point))) ; keep despite of compiler waring
 428          (line-overlays
 429           (delq nil (mapcar (lambda (x)
 430                               (and (eq (overlay-buffer x) (current-buffer))
 431                                    (>= (overlay-start x) bol)
 432                                    (<= (overlay-start x) eol)
 433                                    x))
 434                             org-columns-overlays)))
 435          (org-columns-time (time-to-number-of-days (current-time)))
 436          nval eval allowed)
 437     (cond
 438      ((equal key "CLOCKSUM")
 439       (error "This special column cannot be edited"))
 440      ((equal key "ITEM")
 441       (setq eval '(org-with-point-at pom
 442                     (org-edit-headline))))
 443      ((equal key "TODO")
 444       (setq eval '(org-with-point-at
 445                    pom
 446                    (call-interactively 'org-todo))))
 447      ((equal key "PRIORITY")
 448       (setq eval '(org-with-point-at pom
 449                     (call-interactively 'org-priority))))
 450      ((equal key "TAGS")
 451       (setq eval '(org-with-point-at pom
 452                     (let ((org-fast-tag-selection-single-key
 453                            (if (eq org-fast-tag-selection-single-key 'expert)
 454                                t org-fast-tag-selection-single-key)))
 455                       (call-interactively 'org-set-tags)))))
 456      ((equal key "DEADLINE")
 457       (setq eval '(org-with-point-at pom
 458                     (call-interactively 'org-deadline))))
 459      ((equal key "SCHEDULED")
 460       (setq eval '(org-with-point-at pom
 461                     (call-interactively 'org-schedule))))
 462      ((equal key "BEAMER_env")
 463       (setq eval '(org-with-point-at pom
 464                     (call-interactively 'org-beamer-select-environment))))
 465      (t
 466       (setq allowed (org-property-get-allowed-values pom key 'table))
 467       (if allowed
 468           (setq nval (org-icompleting-read
 469                       "Value: " allowed nil
 470                       (not (get-text-property 0 'org-unrestricted
 471                                               (caar allowed)))))
 472         (setq nval (read-string "Edit: " value)))
 473       (setq nval (org-trim nval))
 474       (when (not (equal nval value))
 475         (setq eval '(org-entry-put pom key nval)))))
 476     (when eval
 477
 478       (cond
 479        ((equal major-mode 'org-agenda-mode)
 480         (org-columns-eval eval)
 481         ;; The following let preserves the current format, and makes sure
 482         ;; that in only a single file things need to be updated.
 483         (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 484                (buffer (marker-buffer pom))
 485                (org-agenda-contributing-files
 486                 (list (with-current-buffer buffer
 487                         (buffer-file-name (buffer-base-buffer))))))
 488           (org-agenda-columns)))
 489        (t
 490         (let ((inhibit-read-only t))
 491           (org-unmodified
 492            (remove-text-properties
 493             (max (point-min) (1- bol)) eol '(read-only t)))
 494           (unwind-protect
 495               (progn
 496                 (setq org-columns-overlays
 497                       (org-delete-all line-overlays org-columns-overlays))
 498                 (mapc 'delete-overlay line-overlays)
 499                 (org-columns-eval eval))
 500             (org-columns-display-here)))
 501         (org-move-to-column col)
 502         (if (and (eq major-mode 'org-mode)
 503                  (nth 3 (assoc key org-columns-current-fmt-compiled)))
 504             (org-columns-update key)))))))
 505
 506 (defun org-edit-headline () ; FIXME: this is not columns specific.  Make interactive?????  Use from agenda????
 507   "Edit the current headline, the part without TODO keyword, TAGS."
 508   (org-back-to-heading)
 509   (when (looking-at org-todo-line-regexp)
 510     (let ((pos (point))
 511           (pre (buffer-substring (match-beginning 0) (match-beginning 3)))
 512           (txt (match-string 3))
 513           (post "")
 514           txt2)
 515       (if (string-match (org-re "[ \t]+:[[:alnum:]:_@#%]+:[ \t]*$") txt)
 516           (setq post (match-string 0 txt)
 517                 txt (substring txt 0 (match-beginning 0))))
 518       (setq txt2 (read-string "Edit: " txt))
 519       (when (not (equal txt txt2))
 520         (goto-char pos)
 521         (insert pre txt2 post)
 522         (delete-region (point) (point-at-eol))
 523         (org-set-tags nil t)))))
 524
 525 (defun org-columns-edit-allowed ()
 526   "Edit the list of allowed values for the current property."
 527   (interactive)
 528   (let* ((pom (or (org-get-at-bol 'org-marker)
 529                   (org-get-at-bol 'org-hd-marker)
 530                   (point)))
 531          (key (get-char-property (point) 'org-columns-key))
 532          (key1 (concat key "_ALL"))
 533          (allowed (org-entry-get pom key1 t))
 534          nval)
 535     ;; FIXME: Cover editing TODO, TAGS etc in-buffer settings.????
 536     ;; FIXME: Write back to #+PROPERTY setting if that is needed.
 537     (setq nval (read-string "Allowed: " allowed))
 538     (org-entry-put
 539      (cond ((marker-position org-entry-property-inherited-from)
 540             org-entry-property-inherited-from)
 541            ((marker-position org-columns-top-level-marker)
 542             org-columns-top-level-marker)
 543            (t pom))
 544      key1 nval)))
 545
 546 (defun org-columns-eval (form)
 547   (let (hidep)
 548     (save-excursion
 549       (beginning-of-line 1)
 550       ;; `next-line' is needed here, because it skips invisible line.
 551       (condition-case nil (org-no-warnings (next-line 1)) (error nil))
 552       (setq hidep (org-at-heading-p 1)))
 553     (eval form)
 554     (and hidep (hide-entry))))
 555
 556 (defun org-columns-previous-allowed-value ()
 557   "Switch to the previous allowed value for this column."
 558   (interactive)
 559   (org-columns-next-allowed-value t))
 560
 561 (defun org-columns-next-allowed-value (&optional previous nth)
 562   "Switch to the next allowed value for this column.
 563 When PREVIOUS is set, go to the previous value.  When NTH is
 564 an integer, select that value."
 565   (interactive)
 566   (org-columns-check-computed)
 567   (let* ((col (current-column))
 568          (key (get-char-property (point) 'org-columns-key))
 569          (value (get-char-property (point) 'org-columns-value))
 570          (bol (point-at-bol)) (eol (point-at-eol))
 571          (pom (or (get-text-property bol 'org-hd-marker)
 572                   (point))) ; keep despite of compiler waring
 573          (line-overlays
 574           (delq nil (mapcar (lambda (x)
 575                               (and (eq (overlay-buffer x) (current-buffer))
 576                                    (>= (overlay-start x) bol)
 577                                    (<= (overlay-start x) eol)
 578                                    x))
 579                             org-columns-overlays)))
 580          (allowed (or (org-property-get-allowed-values pom key)
 581                       (and (memq
 582                             (nth 4 (assoc key org-columns-current-fmt-compiled))
 583                             '(checkbox checkbox-n-of-m checkbox-percent))
 584                            '("[ ]" "[X]"))
 585                       (org-colview-construct-allowed-dates value)))
 586          nval)
 587     (when (integerp nth)
 588       (setq nth (1- nth))
 589       (if (= nth -1) (setq nth 9)))
 590     (when (equal key "ITEM")
 591       (error "Cannot edit item headline from here"))
 592     (unless (or allowed (member key '("SCHEDULED" "DEADLINE")))
 593       (error "Allowed values for this property have not been defined"))
 594     (if (member key '("SCHEDULED" "DEADLINE"))
 595         (setq nval (if previous 'earlier 'later))
 596       (if previous (setq allowed (reverse allowed)))
 597       (cond
 598        (nth
 599         (setq nval (nth nth allowed))
 600         (if (not nval)
 601             (error "There are only %d allowed values for property `%s'"
 602                    (length allowed) key)))
 603        ((member value allowed)
 604         (setq nval (or (car (cdr (member value allowed)))
 605                        (car allowed)))
 606         (if (equal nval value)
 607             (error "Only one allowed value for this property")))
 608        (t (setq nval (car allowed)))))
 609     (cond
 610      ((equal major-mode 'org-agenda-mode)
 611       (org-columns-eval '(org-entry-put pom key nval))
 612       ;; The following let preserves the current format, and makes sure
 613       ;; that in only a single file things need to be updated.
 614       (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 615              (buffer (marker-buffer pom))
 616              (org-agenda-contributing-files
 617               (list (with-current-buffer buffer
 618                       (buffer-file-name (buffer-base-buffer))))))
 619         (org-agenda-columns)))
 620      (t
 621       (let ((inhibit-read-only t))
 622         (remove-text-properties (1- bol) eol '(read-only t))
 623         (unwind-protect
 624             (progn
 625               (setq org-columns-overlays
 626                     (org-delete-all line-overlays org-columns-overlays))
 627               (mapc 'delete-overlay line-overlays)
 628               (org-columns-eval '(org-entry-put pom key nval)))
 629           (org-columns-display-here)))
 630       (org-move-to-column col)
 631       (and (nth 3 (assoc key org-columns-current-fmt-compiled))
 632            (org-columns-update key))))))
 633
 634 (defun org-colview-construct-allowed-dates (s)
 635   "Construct a list of three dates around the date in S.
 636 This respects the format of the time stamp in S, active or non-active,
 637 and also including time or not.  S must be just a time stamp, no text
 638 around it."
 639   (when (and s (string-match (concat "^" org-ts-regexp3 "$") s))
 640     (let* ((time (org-parse-time-string s 'nodefaults))
 641            (active (equal (string-to-char s) ?<))
 642            (fmt (funcall (if (nth 1 time) 'cdr 'car) org-time-stamp-formats))
 643            time-before time-after)
 644       (unless active (setq fmt (concat "[" (substring fmt 1 -1) "]")))
 645       (setf (car time) (or (car time) 0))
 646       (setf (nth 1 time) (or (nth 1 time) 0))
 647       (setf (nth 2 time) (or (nth 2 time) 0))
 648       (setq time-before (copy-sequence time))
 649       (setq time-after (copy-sequence time))
 650       (setf (nth 3 time-before) (1- (nth 3 time)))
 651       (setf (nth 3 time-after) (1+ (nth 3 time)))
 652       (mapcar (lambda (x) (format-time-string fmt (apply 'encode-time x)))
 653               (list time-before time time-after)))))
 654
 655 (defun org-verify-version (task)
 656   (cond
 657    ((eq task 'columns)
 658     (if (or (featurep 'xemacs)
 659             (< emacs-major-version 22))
 660         (error "Emacs 22 is required for the columns feature")))))
 661
 662 (defun org-columns-open-link (&optional arg)
 663   (interactive "P")
 664   (let ((value (get-char-property (point) 'org-columns-value)))
 665     (org-open-link-from-string value arg)))
 666
 667 (defun org-columns-get-format-and-top-level ()
 668   (let (fmt)
 669     (when (condition-case nil (org-back-to-heading) (error nil))
 670       (setq fmt (org-entry-get nil "COLUMNS" t)))
 671     (setq fmt (or fmt org-columns-default-format))
 672     (org-set-local 'org-columns-current-fmt fmt)
 673     (org-columns-compile-format fmt)
 674     (if (marker-position org-entry-property-inherited-from)
 675         (move-marker org-columns-top-level-marker
 676                      org-entry-property-inherited-from)
 677       (move-marker org-columns-top-level-marker (point)))
 678     fmt))
 679
 680 (defun org-columns ()
 681   "Turn on column view on an org-mode file."
 682   (interactive)
 683   (org-verify-version 'columns)
 684   (org-columns-remove-overlays)
 685   (move-marker org-columns-begin-marker (point))
 686   (let ((org-columns-time (time-to-number-of-days (current-time)))
 687         beg end fmt cache maxwidths)
 688     (setq fmt (org-columns-get-format-and-top-level))
 689     (save-excursion
 690       (goto-char org-columns-top-level-marker)
 691       (setq beg (point))
 692       (unless org-columns-inhibit-recalculation
 693         (org-columns-compute-all))
 694       (setq end (or (condition-case nil (org-end-of-subtree t t) (error nil))
 695                     (point-max)))
 696       ;; Get and cache the properties
 697       (goto-char beg)
 698       (when (assoc "CLOCKSUM" org-columns-current-fmt-compiled)
 699         (save-excursion
 700           (save-restriction
 701             (narrow-to-region beg end)
 702             (org-clock-sum))))
 703       (while (re-search-forward org-outline-regexp-bol end t)
 704         (if (and org-columns-skip-archived-trees
 705                  (looking-at (concat ".*:" org-archive-tag ":")))
 706             (org-end-of-subtree t)
 707           (push (cons (org-current-line) (org-entry-properties)) cache)))
 708       (when cache
 709         (setq maxwidths (org-columns-get-autowidth-alist fmt cache))
 710         (org-set-local 'org-columns-current-maxwidths maxwidths)
 711         (org-columns-display-here-title)
 712         (when (org-set-local 'org-columns-flyspell-was-active
 713                              (org-bound-and-true-p flyspell-mode))
 714           (flyspell-mode 0))
 715         (unless (local-variable-p 'org-colview-initial-truncate-line-value)
 716           (org-set-local 'org-colview-initial-truncate-line-value
 717                          truncate-lines))
 718         (setq truncate-lines t)
 719         (mapc (lambda (x)
 720                 (org-goto-line (car x))
 721                 (org-columns-display-here (cdr x)))
 722               cache)))))
 723
 724 (eval-when-compile (defvar org-columns-time))
 725
 726 (defvar org-columns-compile-map
 727   '(("none" none +)
 728     (":" add_times +)
 729     ("+" add_numbers +)
 730     ("$" currency +)
 731     ("X" checkbox +)
 732     ("X/" checkbox-n-of-m +)
 733     ("X%" checkbox-percent +)
 734     ("max" max_numbers max)
 735     ("min" min_numbers min)
 736     ("mean" mean_numbers
 737      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 738     (":max" max_times max)
 739     (":min" min_times min)
 740     (":mean" mean_times
 741      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 742     ("@min" min_age min (lambda (x) (- org-columns-time x)))
 743     ("@max" max_age max (lambda (x) (- org-columns-time x)))
 744     ("@mean" mean_age
 745      (lambda (&rest x) (/ (apply '+ x) (float (length x))))
 746      (lambda (x) (- org-columns-time x)))
 747     ("est+" estimate org-estimate-combine))
 748   "Operator <-> format,function,calc  map.
 749 Used to compile/uncompile columns format and completing read in
 750 interactive function `org-columns-new'.
 751
 752 operator    string used in #+COLUMNS definition describing the
 753             summary type
 754 format      symbol describing summary type selected interactively in
 755             `org-columns-new' and internally in
 756             `org-columns-number-to-string' and
 757             `org-columns-string-to-number'
 758 function    called with a list of values as argument to calculate
 759             the summary value
 760 calc        function called on every element before summarizing.  This is
 761             optional and should only be specified if needed")
 762
 763 (defun org-columns-new (&optional prop title width op fmt fun &rest rest)
 764   "Insert a new column, to the left of the current column."
 765   (interactive)
 766   (let ((editp (and prop (assoc prop org-columns-current-fmt-compiled)))
 767         cell)
 768     (setq prop (org-icompleting-read
 769                 "Property: " (mapcar 'list (org-buffer-property-keys t nil t))
 770                 nil nil prop))
 771     (setq title (read-string (concat "Column title [" prop "]: ") (or title prop)))
 772     (setq width (read-string "Column width: " (if width (number-to-string width))))
 773     (if (string-match "\\S-" width)
 774         (setq width (string-to-number width))
 775       (setq width nil))
 776     (setq fmt (org-icompleting-read
 777                "Summary [none]: "
 778                (mapcar (lambda (x) (list (symbol-name (cadr x))))
 779                        org-columns-compile-map)
 780                nil t))
 781     (setq fmt (intern fmt)
 782           fun (cdr (assoc fmt (mapcar 'cdr org-columns-compile-map))))
 783     (if (eq fmt 'none) (setq fmt nil))
 784     (if editp
 785         (progn
 786           (setcar editp prop)
 787           (setcdr editp (list title width nil fmt nil fun)))
 788       (setq cell (nthcdr (1- (current-column))
 789                          org-columns-current-fmt-compiled))
 790       (setcdr cell (cons (list prop title width nil fmt nil
 791                                (car fun) (cadr fun))
 792                          (cdr cell))))
 793     (org-columns-store-format)
 794     (org-columns-redo)))
 795
 796 (defun org-columns-delete ()
 797   "Delete the column at point from columns view."
 798   (interactive)
 799   (let* ((n (current-column))
 800          (title (nth 1 (nth n org-columns-current-fmt-compiled))))
 801     (when (y-or-n-p
 802            (format "Are you sure you want to remove column \"%s\"? " title))
 803       (setq org-columns-current-fmt-compiled
 804             (delq (nth n org-columns-current-fmt-compiled)
 805                   org-columns-current-fmt-compiled))
 806       (org-columns-store-format)
 807       (org-columns-redo)
 808       (if (>= (current-column) (length org-columns-current-fmt-compiled))
 809           (backward-char 1)))))
 810
 811 (defun org-columns-edit-attributes ()
 812   "Edit the attributes of the current column."
 813   (interactive)
 814   (let* ((n (current-column))
 815          (info (nth n org-columns-current-fmt-compiled)))
 816     (apply 'org-columns-new info)))
 817
 818 (defun org-columns-widen (arg)
 819   "Make the column wider by ARG characters."
 820   (interactive "p")
 821   (let* ((n (current-column))
 822          (entry (nth n org-columns-current-fmt-compiled))
 823          (width (or (nth 2 entry)
 824                     (cdr (assoc (car entry) org-columns-current-maxwidths)))))
 825     (setq width (max 1 (+ width arg)))
 826     (setcar (nthcdr 2 entry) width)
 827     (org-columns-store-format)
 828     (org-columns-redo)))
 829
 830 (defun org-columns-narrow (arg)
 831   "Make the column narrower by ARG characters."
 832   (interactive "p")
 833   (org-columns-widen (- arg)))
 834
 835 (defun org-columns-move-right ()
 836   "Swap this column with the one to the right."
 837   (interactive)
 838   (let* ((n (current-column))
 839          (cell (nthcdr n org-columns-current-fmt-compiled))
 840          e)
 841     (when (>= n (1- (length org-columns-current-fmt-compiled)))
 842       (error "Cannot shift this column further to the right"))
 843     (setq e (car cell))
 844     (setcar cell (car (cdr cell)))
 845     (setcdr cell (cons e (cdr (cdr cell))))
 846     (org-columns-store-format)
 847     (org-columns-redo)
 848     (forward-char 1)))
 849
 850 (defun org-columns-move-left ()
 851   "Swap this column with the one to the left."
 852   (interactive)
 853   (let* ((n (current-column)))
 854     (when (= n 0)
 855       (error "Cannot shift this column further to the left"))
 856     (backward-char 1)
 857     (org-columns-move-right)
 858     (backward-char 1)))
 859
 860 (defun org-columns-store-format ()
 861   "Store the text version of the current columns format in appropriate place.
 862 This is either in the COLUMNS property of the node starting the current column
 863 display, or in the #+COLUMNS line of the current buffer."
 864   (let (fmt (cnt 0))
 865     (setq fmt (org-columns-uncompile-format org-columns-current-fmt-compiled))
 866     (org-set-local 'org-columns-current-fmt fmt)
 867     (if (marker-position org-columns-top-level-marker)
 868         (save-excursion
 869           (goto-char org-columns-top-level-marker)
 870           (if (and (org-at-heading-p)
 871                    (org-entry-get nil "COLUMNS"))
 872               (org-entry-put nil "COLUMNS" fmt)
 873             (goto-char (point-min))
 874             ;; Overwrite all #+COLUMNS lines....
 875             (while (re-search-forward "^#\\+COLUMNS:.*" nil t)
 876               (setq cnt (1+ cnt))
 877               (replace-match (concat "#+COLUMNS: " fmt) t t))
 878             (unless (> cnt 0)
 879               (goto-char (point-min))
 880               (or (org-at-heading-p t) (outline-next-heading))
 881               (let ((inhibit-read-only t))
 882                 (insert-before-markers "#+COLUMNS: " fmt "\n")))
 883             (org-set-local 'org-columns-default-format fmt))))))
 884
 885 (defvar org-agenda-overriding-columns-format nil
 886   "When set, overrides any other format definition for the agenda.
 887 Don't set this, this is meant for dynamic scoping.")
 888
 889 (defun org-columns-get-autowidth-alist (s cache)
 890   "Derive the maximum column widths from the format and the cache."
 891   (let ((start 0) rtn)
 892     (while (string-match (org-re "%\\([[:alpha:]][[:alnum:]_-]*\\)") s start)
 893       (push (cons (match-string 1 s) 1) rtn)
 894       (setq start (match-end 0)))
 895     (mapc (lambda (x)
 896             (setcdr x (apply 'max
 897                              (mapcar
 898                               (lambda (y)
 899                                 (length (or (cdr (assoc (car x) (cdr y))) " ")))
 900                               cache))))
 901           rtn)
 902     rtn))
 903
 904 (defun org-columns-compute-all ()
 905   "Compute all columns that have operators defined."
 906   (org-unmodified
 907    (remove-text-properties (point-min) (point-max) '(org-summaries t)))
 908   (let ((columns org-columns-current-fmt-compiled)
 909         (org-columns-time (time-to-number-of-days (current-time)))
 910         col)
 911     (while (setq col (pop columns))
 912       (when (nth 3 col)
 913         (save-excursion
 914           (org-columns-compute (car col)))))))
 915
 916 (defun org-columns-update (property)
 917   "Recompute PROPERTY, and update the columns display for it."
 918   (org-columns-compute property)
 919   (let (fmt val pos)
 920     (save-excursion
 921       (mapc (lambda (ov)
 922               (when (equal (overlay-get ov 'org-columns-key) property)
 923                 (setq pos (overlay-start ov))
 924                 (goto-char pos)
 925                 (when (setq val (cdr (assoc property
 926                                             (get-text-property
 927                                              (point-at-bol) 'org-summaries))))
 928                   (setq fmt (overlay-get ov 'org-columns-format))
 929                   (overlay-put ov 'org-columns-value val)
 930                   (overlay-put ov 'display (format fmt val)))))
 931             org-columns-overlays))))
 932
 933 (defun org-columns-compute (property)
 934   "Sum the values of property PROPERTY hierarchically, for the entire buffer."
 935   (interactive)
 936   (let* ((re org-outline-regexp-bol)
 937          (lmax 30) ; Does anyone use deeper levels???
 938          (lvals (make-vector lmax nil))
 939          (lflag (make-vector lmax nil))
 940          (level 0)
 941          (ass (assoc property org-columns-current-fmt-compiled))
 942          (format (nth 4 ass))
 943          (printf (nth 5 ass))
 944          (fun (nth 6 ass))
 945          (calc (or (nth 7 ass) 'identity))
 946          (beg org-columns-top-level-marker)
 947          last-level val valflag flag end sumpos sum-alist sum str str1 useval)
 948     (save-excursion
 949       ;; Find the region to compute
 950       (goto-char beg)
 951       (setq end (condition-case nil (org-end-of-subtree t) (error (point-max))))
 952       (goto-char end)
 953       ;; Walk the tree from the back and do the computations
 954       (while (re-search-backward re beg t)
 955         (setq sumpos (match-beginning 0)
 956               last-level level
 957               level (org-outline-level)
 958               val (org-entry-get nil property)
 959               valflag (and val (string-match "\\S-" val)))
 960         (cond
 961          ((< level last-level)
 962           ;; put the sum of lower levels here as a property
 963           (setq sum (when (aref lvals last-level)
 964                       (apply fun (aref lvals last-level)))
 965                 flag (aref lflag last-level) ; any valid entries from children?
 966                 str (org-columns-number-to-string sum format printf)
 967                 str1 (org-add-props (copy-sequence str) nil 'org-computed t 'face 'bold)
 968                 useval (if flag str1 (if valflag val ""))
 969                 sum-alist (get-text-property sumpos 'org-summaries))
 970           (if (assoc property sum-alist)
 971               (setcdr (assoc property sum-alist) useval)
 972             (push (cons property useval) sum-alist)
 973             (org-unmodified
 974              (add-text-properties sumpos (1+ sumpos)
 975                                   (list 'org-summaries sum-alist))))
 976           (when (and val (not (equal val (if flag str val))))
 977             (org-entry-put nil property (if flag str val)))
 978           ;; add current to current level accumulator
 979           (when (or flag valflag)
 980             (push (if flag
 981                       sum
 982                     (funcall calc (org-columns-string-to-number
 983                                    (if flag str val) format)))
 984                   (aref lvals level))
 985             (aset lflag level t))
 986           ;; clear accumulators for deeper levels
 987           (loop for l from (1+ level) to (1- lmax) do
 988                 (aset lvals l nil)
 989                 (aset lflag l nil)))
 990          ((>= level last-level)
 991           ;; add what we have here to the accumulator for this level
 992           (when valflag
 993             (push (funcall calc (org-columns-string-to-number val format))
 994                   (aref lvals level))
 995             (aset lflag level t)))
 996          (t (error "This should not happen")))))))
 997
 998 (defun org-columns-redo ()
 999   "Construct the column display again."
1000   (interactive)
1001   (message "Recomputing columns...")
1002   (let ((line (org-current-line))
1003         (col (current-column)))
1004     (save-excursion
1005       (if (marker-position org-columns-begin-marker)
1006           (goto-char org-columns-begin-marker))
1007       (org-columns-remove-overlays)
1008       (if (eq major-mode 'org-mode)
1009           (call-interactively 'org-columns)
1010         (org-agenda-redo)
1011         (call-interactively 'org-agenda-columns)))
1012     (org-goto-line line)
1013     (move-to-column col))
1014   (message "Recomputing columns...done"))
1015
1016 (defun org-columns-not-in-agenda ()
1017   (if (eq major-mode 'org-agenda-mode)
1018       (error "This command is only allowed in Org-mode buffers")))
1019
1020 (defun org-string-to-number (s)
1021   "Convert string to number, and interpret hh:mm:ss."
1022   (if (not (string-match ":" s))
1023       (string-to-number s)
1024     (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1025       (while l
1026         (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1027       sum)))
1028
1029 (defun org-columns-number-to-string (n fmt &optional printf)
1030   "Convert a computed column number to a string value, according to FMT."
1031   (cond
1032    ((memq fmt '(estimate)) (org-estimate-print n printf))
1033    ((not (numberp n)) "")
1034    ((memq fmt '(add_times max_times min_times mean_times))
1035     (let* ((h (floor n)) (m (floor (+ 0.5 (* 60 (- n h))))))
1036       (format org-time-clocksum-format h m)))
1037    ((eq fmt 'checkbox)
1038     (cond ((= n (floor n)) "[X]")
1039           ((> n 1.) "[-]")
1040           (t "[ ]")))
1041    ((memq fmt '(checkbox-n-of-m checkbox-percent))
1042     (let* ((n1 (floor n)) (n2 (floor (+ .5 (* 1000000 (- n n1))))))
1043       (org-nofm-to-completion n1 (+ n2 n1) (eq fmt 'checkbox-percent))))
1044    (printf (format printf n))
1045    ((eq fmt 'currency)
1046     (format "%.2f" n))
1047    ((memq fmt '(min_age max_age mean_age))
1048     (org-format-time-period n))
1049    (t (number-to-string n))))
1050
1051 (defun org-nofm-to-completion (n m &optional percent)
1052   (if (not percent)
1053       (format "[%d/%d]" n m)
1054     (format "[%d%%]"(floor (+ 0.5 (* 100. (/ (* 1.0 n) m)))))))
1055
1056
1057 (defun org-columns-string-to-number (s fmt)
1058   "Convert a column value to a number that can be used for column computing."
1059   (if s
1060       (cond
1061        ((memq fmt '(min_age max_age mean_age))
1062         (cond ((string= s "") org-columns-time)
1063               ((string-match
1064                 "\\([0-9]+\\)d \\([0-9]+\\)h \\([0-9]+\\)m \\([0-9]+\\)s"
1065                 s)
1066                (+ (* 60 (+ (* 60 (+ (* 24 (string-to-number (match-string 1 s)))
1067                                     (string-to-number (match-string 2 s))))
1068                            (string-to-number (match-string 3 s))))
1069                   (string-to-number (match-string 4 s))))
1070               (t (time-to-number-of-days (apply 'encode-time
1071                                                 (org-parse-time-string s t))))))
1072        ((string-match ":" s)
1073         (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1074           (while l
1075             (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1076           sum))
1077        ((memq fmt '(checkbox checkbox-n-of-m checkbox-percent))
1078         (if (equal s "[X]") 1. 0.000001))
1079        ((memq fmt '(estimate)) (org-string-to-estimate s))
1080        (t (string-to-number s)))))
1081
1082 (defun org-columns-uncompile-format (cfmt)
1083   "Turn the compiled columns format back into a string representation."
1084   (let ((rtn "") e s prop title op op-match width fmt printf fun calc)
1085     (while (setq e (pop cfmt))
1086       (setq prop (car e)
1087             title (nth 1 e)
1088             width (nth 2 e)
1089             op (nth 3 e)
1090             fmt (nth 4 e)
1091             printf (nth 5 e)
1092             fun (nth 6 e)
1093             calc (nth 7 e))
1094       (when (setq op-match (rassoc (list fmt fun calc) org-columns-compile-map))
1095         (setq op (car op-match)))
1096       (if (and op printf) (setq op (concat op ";" printf)))
1097       (if (equal title prop) (setq title nil))
1098       (setq s (concat "%" (if width (number-to-string width))
1099                       prop
1100                       (if title (concat "(" title ")"))
1101                       (if op (concat "{" op "}"))))
1102       (setq rtn (concat rtn " " s)))
1103     (org-trim rtn)))
1104
1105 (defun org-columns-compile-format (fmt)
1106   "Turn a column format string into an alist of specifications.
1107 The alist has one entry for each column in the format.  The elements of
1108 that list are:
1109 property     the property
1110 title        the title field for the columns
1111 width        the column width in characters, can be nil for automatic
1112 operator     the operator if any
1113 format       the output format for computed results, derived from operator
1114 printf       a printf format for computed values
1115 fun          the lisp function to compute summary values, derived from operator
1116 calc         function to get values from base elements"
1117   (let ((start 0) width prop title op op-match f printf fun calc)
1118     (setq org-columns-current-fmt-compiled nil)
1119     (while (string-match
1120             (org-re "%\\([0-9]+\\)?\\([[:alnum:]_-]+\\)\\(?:(\\([^)]+\\))\\)?\\(?:{\\([^}]+\\)}\\)?\\s-*")
1121             fmt start)
1122       (setq start (match-end 0)
1123             width (match-string 1 fmt)
1124             prop (match-string 2 fmt)
1125             title (or (match-string 3 fmt) prop)
1126             op (match-string 4 fmt)
1127             f nil
1128             printf nil
1129             fun '+
1130             calc nil)
1131       (if width (setq width (string-to-number width)))
1132       (when (and op (string-match ";" op))
1133         (setq printf (substring op (match-end 0))
1134               op (substring op 0 (match-beginning 0))))
1135       (when (setq op-match (assoc op org-columns-compile-map))
1136         (setq f (cadr op-match)
1137               fun (caddr op-match)
1138               calc (cadddr op-match)))
1139       (push (list prop title width op f printf fun calc)
1140             org-columns-current-fmt-compiled))
1141     (setq org-columns-current-fmt-compiled
1142           (nreverse org-columns-current-fmt-compiled))))
1143
1144
1145 ;;; Dynamic block for Column view
1146
1147 (defvar org-heading-regexp) ; defined in org.el
1148 (defvar org-heading-keyword-regexp-format) ; defined in org.el
1149 (defun org-columns-capture-view (&optional maxlevel skip-empty-rows)
1150   "Get the column view of the current buffer or subtree.
1151 The first optional argument MAXLEVEL sets the level limit.  A
1152 second optional argument SKIP-EMPTY-ROWS tells whether to skip
1153 empty rows, an empty row being one where all the column view
1154 specifiers except ITEM are empty.  This function returns a list
1155 containing the title row and all other rows.  Each row is a list
1156 of fields."
1157   (save-excursion
1158     (let* ((title (mapcar 'cadr org-columns-current-fmt-compiled))
1159            (re-comment (format org-heading-keyword-regexp-format
1160                                org-comment-string))
1161            (re-archive (concat ".*:" org-archive-tag ":"))
1162            (n (length title)) row tbl)
1163       (goto-char (point-min))
1164       (while (re-search-forward org-heading-regexp nil t)
1165         (catch 'next
1166           (when (and (or (null maxlevel)
1167                          (>= maxlevel
1168                              (if org-odd-levels-only
1169                                  (/ (1+ (length (match-string 1))) 2)
1170                                (length (match-string 1)))))
1171                      (get-char-property (match-beginning 0) 'org-columns-key))
1172             (when (save-excursion
1173                     (goto-char (point-at-bol))
1174                     (or (looking-at re-comment)
1175                         (looking-at re-archive)))
1176               (org-end-of-subtree t)
1177               (throw 'next t))
1178             (setq row nil)
1179             (loop for i from 0 to (1- n) do
1180                   (push
1181                    (org-quote-vert
1182                     (or (get-char-property (+ (match-beginning 0) i) 'org-columns-value-modified)
1183                         (get-char-property (+ (match-beginning 0) i) 'org-columns-value)
1184                         ""))
1185                    row))
1186             (setq row (nreverse row))
1187             (unless (and skip-empty-rows
1188                          (eq 1 (length (delete "" (delete-dups (copy-sequence row))))))
1189               (push row tbl)))))
1190       (append (list title 'hline) (nreverse tbl)))))
1191
1192 (defun org-dblock-write:columnview (params)
1193   "Write the column view table.
1194 PARAMS is a property list of parameters:
1195
1196 :width    enforce same column widths with <N> specifiers.
1197 :id       the :ID: property of the entry where the columns view
1198           should be built.  When the symbol `local', call locally.
1199           When `global' call column view with the cursor at the beginning
1200           of the buffer (usually this means that the whole buffer switches
1201           to column view).  When \"file:path/to/file.org\", invoke column
1202           view at the start of that file.  Otherwise, the ID is located
1203           using `org-id-find'.
1204 :hlines   When t, insert a hline before each item.  When a number, insert
1205           a hline before each level <= that number.
1206 :vlines   When t, make each column a colgroup to enforce vertical lines.
1207 :maxlevel When set to a number, don't capture headlines below this level.
1208 :skip-empty-rows
1209           When t, skip rows where all specifiers other than ITEM are empty."
1210   (let ((pos (move-marker (make-marker) (point)))
1211         (hlines (plist-get params :hlines))
1212         (vlines (plist-get params :vlines))
1213         (maxlevel (plist-get params :maxlevel))
1214         (content-lines (org-split-string (plist-get params :content) "\n"))
1215         (skip-empty-rows (plist-get params :skip-empty-rows))
1216         tbl id idpos nfields tmp recalc line
1217         id-as-string view-file view-pos)
1218     (when (setq id (plist-get params :id))
1219       (setq id-as-string (cond ((numberp id) (number-to-string id))
1220                                ((symbolp id) (symbol-name id))
1221                                ((stringp id) id)
1222                                (t "")))
1223       (cond ((not id) nil)
1224             ((eq id 'global) (setq view-pos (point-min)))
1225             ((eq id 'local))
1226             ((string-match "^file:\\(.*\\)" id-as-string)
1227              (setq view-file (match-string 1 id-as-string)
1228                    view-pos 1)
1229              (unless (file-exists-p view-file)
1230                (error "No such file: \"%s\"" id-as-string)))
1231             ((setq idpos (org-find-entry-with-id id))
1232              (setq view-pos idpos))
1233             ((setq idpos (org-id-find id))
1234              (setq view-file (car idpos))
1235              (setq view-pos (cdr idpos)))
1236             (t (error "Cannot find entry with :ID: %s" id))))
1237     (with-current-buffer (if view-file
1238                              (get-file-buffer view-file)
1239                            (current-buffer))
1240       (save-excursion
1241         (save-restriction
1242           (widen)
1243           (goto-char (or view-pos (point)))
1244           (org-columns)
1245           (setq tbl (org-columns-capture-view maxlevel skip-empty-rows))
1246           (setq nfields (length (car tbl)))
1247           (org-columns-quit))))
1248     (goto-char pos)
1249     (move-marker pos nil)
1250     (when tbl
1251       (when (plist-get params :hlines)
1252         (setq tmp nil)
1253         (while tbl
1254           (if (eq (car tbl) 'hline)
1255               (push (pop tbl) tmp)
1256             (if (string-match "\\` *\\(\\*+\\)" (caar tbl))
1257                 (if (and (not (eq (car tmp) 'hline))
1258                          (or (eq hlines t)
1259                              (and (numberp hlines)
1260                                   (<= (- (match-end 1) (match-beginning 1))
1261                                       hlines))))
1262                     (push 'hline tmp)))
1263             (push (pop tbl) tmp)))
1264         (setq tbl (nreverse tmp)))
1265       (when vlines
1266         (setq tbl (mapcar (lambda (x)
1267                             (if (eq 'hline x) x (cons "" x)))
1268                           tbl))
1269         (setq tbl (append tbl (list (cons "/" (make-list nfields "<>"))))))
1270       (setq pos (point))
1271       (when content-lines
1272         (while (string-match "^#" (car content-lines))
1273           (insert (pop content-lines) "\n")))
1274       (insert (org-listtable-to-string tbl))
1275       (when (plist-get params :width)
1276         (insert "\n|" (mapconcat (lambda (x) (format "<%d>" (max 3 x)))
1277                                  org-columns-current-widths "|")))
1278       (while (setq line (pop content-lines))
1279         (when (string-match "^#" line)
1280           (insert "\n" line)
1281           (when (string-match "^[ \t]*#\\+TBLFM" line)
1282             (setq recalc t))))
1283       (if recalc
1284           (progn (goto-char pos) (org-table-recalculate 'all))
1285         (goto-char pos)
1286         (org-table-align)))))
1287
1288 (defun org-listtable-to-string (tbl)
1289   "Convert a listtable TBL to a string that contains the Org-mode table.
1290 The table still need to be aligned.  The resulting string has no leading
1291 and tailing newline characters."
1292   (mapconcat
1293    (lambda (x)
1294      (cond
1295       ((listp x)
1296        (concat "|" (mapconcat 'identity x "|") "|"))
1297       ((eq x 'hline) "|-|")
1298       (t (error "Garbage in listtable: %s" x))))
1299    tbl "\n"))
1300
1301 (defun org-insert-columns-dblock ()
1302   "Create a dynamic block capturing a column view table."
1303   (interactive)
1304   (let ((defaults '(:name "columnview" :hlines 1))
1305         (id (org-icompleting-read
1306              "Capture columns (local, global, entry with :ID: property) [local]: "
1307              (append '(("global") ("local"))
1308                      (mapcar 'list (org-property-values "ID"))))))
1309     (if (equal id "") (setq id 'local))
1310     (if (equal id "global") (setq id 'global))
1311     (setq defaults (append defaults (list :id id)))
1312     (org-create-dblock defaults)
1313     (org-update-dblock)))
1314
1315 ;;; Column view in the agenda
1316
1317 (defvar org-agenda-view-columns-initially nil
1318   "When set, switch to columns view immediately after creating the agenda.")
1319
1320 (defvar org-agenda-columns-show-summaries) ; defined in org-agenda.el
1321 (defvar org-agenda-columns-compute-summary-properties); defined in org-agenda.el
1322 (defvar org-agenda-columns-add-appointments-to-effort-sum); as well
1323
1324 (defun org-agenda-columns ()
1325   "Turn on or update column view in the agenda."
1326   (interactive)
1327   (org-verify-version 'columns)
1328   (org-columns-remove-overlays)
1329   (move-marker org-columns-begin-marker (point))
1330   (let ((org-columns-time (time-to-number-of-days (current-time)))
1331          cache maxwidths m p a d fmt)
1332     (cond
1333      ((and (boundp 'org-agenda-overriding-columns-format)
1334            org-agenda-overriding-columns-format)
1335       (setq fmt org-agenda-overriding-columns-format)
1336       (org-set-local 'org-agenda-overriding-columns-format fmt))
1337      ((setq m (org-get-at-bol 'org-hd-marker))
1338       (setq fmt (or (org-entry-get m "COLUMNS" t)
1339                     (with-current-buffer (marker-buffer m)
1340                       org-columns-default-format))))
1341      ((and (boundp 'org-columns-current-fmt)
1342            (local-variable-p 'org-columns-current-fmt)
1343            org-columns-current-fmt)
1344       (setq fmt org-columns-current-fmt))
1345      ((setq m (next-single-property-change (point-min) 'org-hd-marker))
1346       (setq m (get-text-property m 'org-hd-marker))
1347       (setq fmt (or (org-entry-get m "COLUMNS" t)
1348                     (with-current-buffer (marker-buffer m)
1349                       org-columns-default-format)))))
1350     (setq fmt (or fmt org-columns-default-format))
1351     (org-set-local 'org-columns-current-fmt fmt)
1352     (org-columns-compile-format fmt)
1353     (when org-agenda-columns-compute-summary-properties
1354       (org-agenda-colview-compute org-columns-current-fmt-compiled))
1355     (save-excursion
1356       ;; Get and cache the properties
1357       (goto-char (point-min))
1358       (while (not (eobp))
1359         (when (setq m (or (org-get-at-bol 'org-hd-marker)
1360                           (org-get-at-bol 'org-marker)))
1361           (setq p (org-entry-properties m))
1362
1363           (when (or (not (setq a (assoc org-effort-property p)))
1364                          (not (string-match "\\S-" (or (cdr a) ""))))
1365             ;; OK, the property is not defined.  Use appointment duration?
1366             (when (and org-agenda-columns-add-appointments-to-effort-sum
1367                        (setq d (get-text-property (point) 'duration)))
1368               (setq d (org-minutes-to-hh:mm-string d))
1369               (put-text-property 0 (length d) 'face 'org-warning d)
1370               (push (cons org-effort-property d) p)))
1371           (push (cons (org-current-line) p) cache))
1372         (beginning-of-line 2))
1373       (when cache
1374         (setq maxwidths (org-columns-get-autowidth-alist fmt cache))
1375         (org-set-local 'org-columns-current-maxwidths maxwidths)
1376         (org-columns-display-here-title)
1377         (when (org-set-local 'org-columns-flyspell-was-active
1378                              (org-bound-and-true-p flyspell-mode))
1379           (flyspell-mode 0))
1380         (mapc (lambda (x)
1381                 (org-goto-line (car x))
1382                 (org-columns-display-here (cdr x)))
1383               cache)
1384         (when org-agenda-columns-show-summaries
1385           (org-agenda-colview-summarize cache))))))
1386
1387 (defun org-agenda-colview-summarize (cache)
1388   "Summarize the summarizable columns in column view in the agenda.
1389 This will add overlays to the date lines, to show the summary for each day."
1390   (let* ((fmt (mapcar (lambda (x)
1391                         (if (equal (car x) "CLOCKSUM")
1392                             (list "CLOCKSUM" (nth 1 x) (nth 2 x) ":" 'add_times
1393                                   nil '+ nil)
1394                           x))
1395                       org-columns-current-fmt-compiled))
1396          line c c1 stype calc sumfunc props lsum entries prop v title)
1397     (catch 'exit
1398       (when (delq nil (mapcar 'cadr fmt))
1399         ;; OK, at least one summation column, it makes sense to try this
1400         (goto-char (point-max))
1401         (while t
1402           (when (or (get-text-property (point) 'org-date-line)
1403                     (eq (get-text-property (point) 'face)
1404                         'org-agenda-structure))
1405             ;; OK, this is a date line that should be used
1406             (setq line (org-current-line))
1407             (setq entries nil c cache cache nil)
1408             (while (setq c1 (pop c))
1409               (if (> (car c1) line)
1410                   (push c1 entries)
1411                 (push c1 cache)))
1412             ;; now ENTRIES are the ones we want to use, CACHE is the rest
1413             ;; Compute the summaries for the properties we want,
1414             ;; set nil properties for the rest.
1415             (when (setq entries (mapcar 'cdr entries))
1416               (setq props
1417                     (mapcar
1418                      (lambda (f)
1419                        (setq prop (car f)
1420                              title (nth 1 f)
1421                              stype (nth 4 f)
1422                              sumfunc (nth 6 f)
1423                              calc (or (nth 7 f) 'identity))
1424                        (cond
1425                         ((equal prop "ITEM")
1426                          (cons prop (buffer-substring (point-at-bol)
1427                                                       (point-at-eol))))
1428                         ((not stype) (cons prop ""))
1429                         (t ;; do the summary
1430                          (setq lsum nil)
1431                          (dolist (x entries)
1432                            (setq v (cdr (assoc prop x)))
1433                            (if v
1434                                (push
1435                                 (funcall
1436                                  (if (not (get-text-property 0 'org-computed v))
1437                                      calc
1438                                    'identity)
1439                                  (org-columns-string-to-number
1440                                   v stype))
1441                                 lsum)))
1442                          (setq lsum (remove nil lsum))
1443                          (setq lsum
1444                                (cond ((> (length lsum) 1)
1445                                       (org-columns-number-to-string
1446                                        (apply sumfunc lsum) stype))
1447                                      ((eq (length lsum) 1)
1448                                       (org-columns-number-to-string
1449                                        (car lsum) stype))
1450                                      (t "")))
1451                          (put-text-property 0 (length lsum) 'face 'bold lsum)
1452                          (unless (eq calc 'identity)
1453                            (put-text-property 0 (length lsum) 'org-computed t lsum))
1454                          (cons prop lsum))))
1455                      fmt))
1456               (org-columns-display-here props 'dateline)
1457               (org-set-local 'org-agenda-columns-active t)))
1458           (if (bobp) (throw 'exit t))
1459           (beginning-of-line 0))))))
1460
1461 (defun org-agenda-colview-compute (fmt)
1462   "Compute the relevant columns in the contributing source buffers."
1463   (let ((files org-agenda-contributing-files)
1464         (org-columns-begin-marker (make-marker))
1465         (org-columns-top-level-marker (make-marker))
1466         f fm a b)
1467     (while (setq f (pop files))
1468       (setq b (find-buffer-visiting f))
1469       (with-current-buffer (or (buffer-base-buffer b) b)
1470         (save-excursion
1471           (save-restriction
1472             (widen)
1473             (org-unmodified
1474              (remove-text-properties (point-min) (point-max)
1475                                      '(org-summaries t)))
1476             (goto-char (point-min))
1477             (org-columns-get-format-and-top-level)
1478             (while (setq fm (pop fmt))
1479               (if (equal (car fm) "CLOCKSUM")
1480                   (org-clock-sum)
1481                 (when (and (nth 4 fm)
1482                            (setq a (assoc (car fm)
1483                                           org-columns-current-fmt-compiled))
1484                            (equal (nth 4 a) (nth 4 fm)))
1485                   (org-columns-compute (car fm)))))))))))
1486
1487 (defun org-format-time-period (interval)
1488   "Convert time in fractional days to days/hours/minutes/seconds."
1489   (if (numberp interval)
1490     (let* ((days (floor interval))
1491            (frac-hours (* 24 (- interval days)))
1492            (hours (floor frac-hours))
1493            (minutes (floor (* 60 (- frac-hours hours))))
1494            (seconds (floor (* 60 (- (* 60 (- frac-hours hours)) minutes)))))
1495       (format "%dd %02dh %02dm %02ds" days hours minutes seconds))
1496     ""))
1497
1498 (defun org-estimate-mean-and-var (v)
1499   "Return the mean and variance of an estimate."
1500   (let* ((low (float (car v)))
1501          (high (float (cadr v)))
1502          (mean (/ (+ low high) 2.0))
1503          (var (/ (+ (expt (- mean low) 2.0) (expt (- high mean) 2.0)) 2.0)))
1504     (list  mean var)))
1505
1506 (defun org-estimate-combine (&rest el)
1507   "Combine a list of estimates, using mean and variance.
1508 The mean and variance of the result will be the sum of the means
1509 and variances (respectively) of the individual estimates."
1510   (let ((mean 0)
1511         (var 0))
1512     (mapc (lambda (e)
1513               (let ((stats (org-estimate-mean-and-var e)))
1514                 (setq mean (+ mean (car stats)))
1515                 (setq var (+ var (cadr stats)))))
1516             el)
1517     (let ((stdev (sqrt var)))
1518       (list (- mean stdev) (+ mean stdev)))))
1519
1520 (defun org-estimate-print (e &optional fmt)
1521   "Prepare a string representation of an estimate.
1522 This formats these numbers as two numbers with a \"-\" between them."
1523   (if (null fmt) (set 'fmt "%.0f"))
1524   (format "%s" (mapconcat (lambda (n) (format fmt n))  e "-")))
1525
1526 (defun org-string-to-estimate (s)
1527   "Convert a string to an estimate.
1528 The string should be two numbers joined with a \"-\"."
1529   (if (string-match "\\(.*\\)-\\(.*\\)" s)
1530       (list (string-to-number (match-string 1 s))
1531             (string-to-number(match-string 2 s)))
1532     (list (string-to-number s) (string-to-number s))))
1533
1534 (provide 'org-colview)
1535
1536 ;;; org-colview.el ends here