lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function org-remove-indentation "org" )
  37 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  38 (declare-function py-toggle-shells "ext:python-mode" (arg))
  39 (declare-function run-python "ext:python" (&optional cmd noshow new))
  40
  41 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  42
  43 (defvar org-babel-default-header-args:python '())
  44
  45 (defvar org-babel-python-command "python"
  46   "Name of command for executing python code.")
  47
  48 (defvar org-babel-python-mode (if (featurep 'xemacs) 'python-mode 'python)
  49   "Preferred python mode for use in running python interactively.")
  50
  51 (defvar org-src-preserve-indentation)
  52
  53 (defun org-babel-execute:python (body params)
  54   "Execute a block of Python code with Babel.
  55 This function is called by `org-babel-execute-src-block'."
  56   (let* ((session (org-babel-python-initiate-session
  57                    (cdr (assoc :session params))))
  58          (result-params (cdr (assoc :result-params params)))
  59          (result-type (cdr (assoc :result-type params)))
  60          (return-val (when (and (eq result-type 'value) (not session))
  61                        (cdr (assoc :return params))))
  62          (preamble (cdr (assoc :preamble params)))
  63          (full-body
  64           (org-babel-expand-body:generic
  65            (concat body (if return-val (format "return %s" return-val) ""))
  66            params (org-babel-variable-assignments:python params)))
  67          (result (org-babel-python-evaluate
  68                   session full-body result-type result-params preamble)))
  69     (org-babel-reassemble-table
  70      result
  71      (org-babel-pick-name (cdr (assoc :colname-names params))
  72                           (cdr (assoc :colnames params)))
  73      (org-babel-pick-name (cdr (assoc :rowname-names params))
  74                           (cdr (assoc :rownames params))))))
  75
  76 (defun org-babel-prep-session:python (session params)
  77   "Prepare SESSION according to the header arguments in PARAMS.
  78 VARS contains resolved variable references"
  79   (let* ((session (org-babel-python-initiate-session session))
  80          (var-lines
  81           (org-babel-variable-assignments:python params)))
  82     (org-babel-comint-in-buffer session
  83       (mapc (lambda (var)
  84               (end-of-line 1) (insert var) (comint-send-input)
  85               (org-babel-comint-wait-for-output session)) var-lines))
  86     session))
  87
  88 (defun org-babel-load-session:python (session body params)
  89   "Load BODY into SESSION."
  90   (save-window-excursion
  91     (let ((buffer (org-babel-prep-session:python session params)))
  92       (with-current-buffer buffer
  93         (goto-char (process-mark (get-buffer-process (current-buffer))))
  94         (insert (org-babel-chomp body)))
  95       buffer)))
  96
  97 ;; helper functions
  98
  99 (defun org-babel-variable-assignments:python (params)
 100   "Return list of python statements assigning the block's variables"
 101   (mapcar
 102    (lambda (pair)
 103      (format "%s=%s"
 104              (car pair)
 105              (org-babel-python-var-to-python (cdr pair))))
 106    (mapcar #'cdr (org-babel-get-header params :var))))
 107
 108 (defun org-babel-python-var-to-python (var)
 109   "Convert an elisp value to a python variable.
 110 Convert an elisp value, VAR, into a string of python source code
 111 specifying a variable of the same value."
 112   (if (listp var)
 113       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 114     (if (equal var 'hline)
 115         "None"
 116       (format
 117        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 118        var))))
 119
 120 (defun org-babel-python-table-or-string (results)
 121   "Convert RESULTS into an appropriate elisp value.
 122 If the results look like a list or tuple, then convert them into an
 123 Emacs-lisp table, otherwise return the results as a string."
 124   (org-babel-script-escape results))
 125
 126 (defvar org-babel-python-buffers '((:default . nil)))
 127
 128 (defun org-babel-python-session-buffer (session)
 129   "Return the buffer associated with SESSION."
 130   (cdr (assoc session org-babel-python-buffers)))
 131
 132 (defun org-babel-python-initiate-session-by-key (&optional session)
 133   "Initiate a python session.
 134 If there is not a current inferior-process-buffer in SESSION
 135 then create.  Return the initialized session."
 136   (require org-babel-python-mode)
 137   (save-window-excursion
 138     (let* ((session (if session (intern session) :default))
 139            (python-buffer (org-babel-python-session-buffer session)))
 140       (cond
 141        ((and (eq 'python org-babel-python-mode)
 142              (fboundp 'run-python)) ; python.el
 143         (run-python))
 144        ((and (eq 'python-mode org-babel-python-mode)
 145              (fboundp 'py-shell)) ; python-mode.el
 146         ;; Make sure that py-which-bufname is initialized, as otherwise
 147         ;; it will be overwritten the first time a Python buffer is
 148         ;; created.
 149         (when (fboundp 'py-shell)
 150            (py-toggle-shells py-default-interpreter))
 151         ;; `py-shell' creates a buffer whose name is the value of
 152         ;; `py-which-bufname' with '*'s at the beginning and end
 153         (let* ((bufname (if python-buffer
 154                             (replace-regexp-in-string ;; zap surrounding *
 155                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 156                           (concat "Python-" (symbol-name session))))
 157                (py-which-bufname bufname))
 158           (py-shell)
 159           (setq python-buffer (concat "*" bufname "*"))))
 160        (t
 161         (error "No function available for running an inferior python.")))
 162       (setq org-babel-python-buffers
 163             (cons (cons session python-buffer)
 164                   (assq-delete-all session org-babel-python-buffers)))
 165       session)))
 166
 167 (defun org-babel-python-initiate-session (&optional session params)
 168   "Create a session named SESSION according to PARAMS."
 169   (unless (string= session "none")
 170     (org-babel-python-session-buffer
 171      (org-babel-python-initiate-session-by-key session))))
 172
 173 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 174   "A string to indicate that evaluation has completed.")
 175 (defvar org-babel-python-wrapper-method
 176   "
 177 def main():
 178 %s
 179
 180 open('%s', 'w').write( str(main()) )")
 181 (defvar org-babel-python-pp-wrapper-method
 182   "
 183 import pprint
 184 def main():
 185 %s
 186
 187 open('%s', 'w').write( pprint.pformat(main()) )")
 188
 189 (defun org-babel-python-evaluate
 190   (session body &optional result-type result-params preamble)
 191   "Evaluate BODY as python code."
 192   (if session
 193       (org-babel-python-evaluate-session
 194        session body result-type result-params)
 195     (org-babel-python-evaluate-external-process
 196      body result-type result-params preamble)))
 197
 198 (defun org-babel-python-evaluate-external-process
 199   (body &optional result-type result-params preamble)
 200   "Evaluate BODY in external python process.
 201 If RESULT-TYPE equals 'output then return standard output as a
 202 string. If RESULT-TYPE equals 'value then return the value of the
 203 last statement in BODY, as elisp."
 204   (case result-type
 205     (output (org-babel-eval org-babel-python-command
 206                             (concat (if preamble (concat preamble "\n") "") body)))
 207     (value (let ((tmp-file (org-babel-temp-file "python-")))
 208              (org-babel-eval org-babel-python-command
 209                              (concat
 210                               (if preamble (concat preamble "\n") "")
 211                               (format
 212                                (if (member "pp" result-params)
 213                                    org-babel-python-pp-wrapper-method
 214                                  org-babel-python-wrapper-method)
 215                                (mapconcat
 216                                 (lambda (line) (format "\t%s" line))
 217                                 (split-string
 218                                  (org-remove-indentation
 219                                   (org-babel-trim body))
 220                                  "[\r\n]") "\n")
 221                                (org-babel-process-file-name tmp-file 'noquote))))
 222              ((lambda (raw)
 223                 (if (or (member "code" result-params)
 224                         (member "pp" result-params))
 225                     raw
 226                   (org-babel-python-table-or-string raw)))
 227               (org-babel-eval-read-file tmp-file))))))
 228
 229 (defun org-babel-python-evaluate-session
 230   (session body &optional result-type result-params)
 231   "Pass BODY to the Python process in SESSION.
 232 If RESULT-TYPE equals 'output then return standard output as a
 233 string. If RESULT-TYPE equals 'value then return the value of the
 234 last statement in BODY, as elisp."
 235   (flet ((dump-last-value
 236           (tmp-file pp)
 237           (mapc
 238            (lambda (statement) (insert statement) (comint-send-input))
 239            (if pp
 240                (list
 241                 "import pprint"
 242                 (format "open('%s', 'w').write(pprint.pformat(_))"
 243                         (org-babel-process-file-name tmp-file 'noquote)))
 244              (list (format "open('%s', 'w').write(str(_))"
 245                            (org-babel-process-file-name tmp-file 'noquote))))))
 246          (input-body (body)
 247                      (mapc (lambda (statement) (insert statement) (comint-send-input))
 248                            (split-string (org-babel-trim body) "[\r\n]+"))
 249                      (comint-send-input) (comint-send-input)))
 250     (case result-type
 251       (output
 252        (mapconcat
 253         #'org-babel-trim
 254         (butlast
 255          (org-babel-comint-with-output
 256              (session org-babel-python-eoe-indicator t body)
 257            (let ((comint-process-echoes nil))
 258              (input-body body)
 259              (insert org-babel-python-eoe-indicator)
 260              (comint-send-input))) 2) "\n"))
 261       (value
 262        ((lambda (results)
 263           (if (or (member "code" result-params) (member "pp" result-params))
 264               results
 265             (org-babel-python-table-or-string results)))
 266         (let ((tmp-file (org-babel-temp-file "python-")))
 267           (org-babel-comint-with-output
 268               (session org-babel-python-eoe-indicator t body)
 269             (let ((comint-process-echoes nil))
 270               (input-body body)
 271               (dump-last-value tmp-file (member "pp" result-params))
 272               (comint-send-input) (comint-send-input)
 273               (insert org-babel-python-eoe-indicator)
 274               (comint-send-input)))
 275           (org-babel-eval-read-file tmp-file)))))))
 276
 277 (defun org-babel-python-read-string (string)
 278   "Strip 's from around python string"
 279   (if (string-match "^'\\([^\000]+\\)'$" string)
 280       (match-string 1 string)
 281     string))
 282
 283 (provide 'ob-python)
 284
 285 ;; arch-tag: f19b6c3d-dfcb-4a1a-9ce0-45ade1ebc212
 286
 287 ;;; ob-python.el ends here