lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements globally unique identifiers for Org-mode entries.
  28 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  29 ;; are provided that create and retrieve such identifiers, and that find
  30 ;; entries based on the identifier.
  31
  32 ;; Identifiers consist of a prefix (default "Org" given by the variable
  33 ;; `org-id-prefix') and a unique part that can be created by a number
  34 ;; of different methods, see the variable `org-id-method'.
  35 ;; Org has a builtin method that uses a compact encoding of the creation
  36 ;; time of the ID, with microsecond accuracy.  This virtually
  37 ;; guarantees globally unique identifiers, even if several people are
  38 ;; creating IDs at the same time in files that will eventually be used
  39 ;; together.
  40 ;;
  41 ;; By default Org uses UUIDs as global unique identifiers.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 ;;; Code:
  72
  73 (require 'org)
  74
  75 (declare-function message-make-fqdn "message" ())
  76 (declare-function org-pop-to-buffer-same-window
  77                   "org-compat" (&optional buffer-or-name norecord label))
  78
  79 ;;; Customization
  80
  81 (defgroup org-id nil
  82   "Options concerning global entry identifiers in Org-mode."
  83   :tag "Org ID"
  84   :group 'org)
  85
  86 (defcustom org-id-uuid-program "uuidgen"
  87   "The uuidgen program."
  88   :group 'org-id
  89   :type 'string)
  90
  91 (defcustom org-id-method 'uuid
  92   "The method that should be used to create new IDs.
  93
  94 An ID will consist of the optional prefix specified in `org-id-prefix',
  95 and a unique part created by the method this variable specifies.
  96
  97 Allowed values are:
  98
  99 org        Org's own internal method, using an encoding of the current time to
 100            microsecond accuracy, and optionally the current domain of the
 101            computer.  See the variable `org-id-include-domain'.
 102
 103 uuid       Create random (version 4) UUIDs.  If the program defined in
 104            `org-id-uuid-program' is available it is used to create the ID.
 105            Otherwise an internal functions is used."
 106   :group 'org-id
 107   :type '(choice
 108           (const :tag "Org's internal method" org)
 109           (const :tag "external: uuidgen" uuid)))
 110
 111 (defcustom org-id-prefix nil
 112   "The prefix for IDs.
 113
 114 This may be a string, or it can be nil to indicate that no prefix is required.
 115 When a string, the string should have no space characters as IDs are expected
 116 to have no space characters in them."
 117   :group 'org-id
 118   :type '(choice
 119           (const :tag "No prefix")
 120           (string :tag "Prefix")))
 121
 122 (defcustom org-id-include-domain nil
 123   "Non-nil means add the domain name to new IDs.
 124 This ensures global uniqueness of IDs, and is also suggested by
 125 RFC 2445 in combination with RFC 822.  This is only relevant if
 126 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 127 be added.
 128 The default is to not use this because we have no really good way to get
 129 the true domain, and Org entries will normally not be shared with enough
 130 people to make this necessary."
 131   :group 'org-id
 132   :type 'boolean)
 133
 134 (defcustom org-id-track-globally t
 135   "Non-nil means track IDs through files, so that links work globally.
 136 This work by maintaining a hash table for IDs and writing this table
 137 to disk when exiting Emacs.  Because of this, it works best if you use
 138 a single Emacs process, not many.
 139
 140 When nil, IDs are not tracked.  Links to IDs will still work within
 141 a buffer, but not if the entry is located in another file.
 142 IDs can still be used if the entry with the id is in the same file as
 143 the link."
 144   :group 'org-id
 145   :type 'boolean)
 146
 147 (defcustom org-id-locations-file (convert-standard-filename
 148                                   "~/.emacs.d/.org-id-locations")
 149   "The file for remembering in which file an ID was defined.
 150 This variable is only relevant when `org-id-track-globally' is set."
 151   :group 'org-id
 152   :type 'file)
 153
 154 (defvar org-id-locations nil
 155   "List of files with IDs in those files.")
 156
 157 (defvar org-id-files nil
 158   "List of files that contain IDs.")
 159
 160 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 161   "Files to be searched for IDs, besides the agenda files.
 162 When Org reparses files to remake the list of files and IDs it is tracking,
 163 it will normally scan the agenda files, the archives related to agenda files,
 164 any files that are listed as ID containing in the current register, and
 165 any Org-mode files currently visited by Emacs.
 166 You can list additional files here.
 167 This variable is only relevant when `org-id-track-globally' is set."
 168   :group 'org-id
 169   :type
 170   '(choice
 171     (symbol :tag "Variable")
 172     (repeat :tag "List of files"
 173             (file))))
 174
 175 (defcustom org-id-search-archives t
 176   "Non-nil means search also the archive files of agenda files for entries.
 177 This is a possibility to reduce overhead, but it means that entries moved
 178 to the archives can no longer be found by ID.
 179 This variable is only relevant when `org-id-track-globally' is set."
 180   :group 'org-id
 181   :type 'boolean)
 182
 183 ;;; The API functions
 184
 185 ;;;###autoload
 186 (defun org-id-get-create (&optional force)
 187   "Create an ID for the current entry and return it.
 188 If the entry already has an ID, just return it.
 189 With optional argument FORCE, force the creation of a new ID."
 190   (interactive "P")
 191   (when force
 192     (org-entry-put (point) "ID" nil))
 193   (org-id-get (point) 'create))
 194
 195 ;;;###autoload
 196 (defun org-id-copy ()
 197   "Copy the ID of the entry at point to the kill ring.
 198 Create an ID if necessary."
 199   (interactive)
 200   (org-kill-new (org-id-get nil 'create)))
 201
 202 ;;;###autoload
 203 (defun org-id-get (&optional pom create prefix)
 204   "Get the ID property of the entry at point-or-marker POM.
 205 If POM is nil, refer to the entry at point.
 206 If the entry does not have an ID, the function returns nil.
 207 However, when CREATE is non nil, create an ID if none is present already.
 208 PREFIX will be passed through to `org-id-new'.
 209 In any case, the ID of the entry is returned."
 210   (org-with-point-at pom
 211     (let ((id (org-entry-get nil "ID")))
 212       (cond
 213        ((and id (stringp id) (string-match "\\S-" id))
 214         id)
 215        (create
 216         (setq id (org-id-new prefix))
 217         (org-entry-put pom "ID" id)
 218         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 219         id)
 220        (t nil)))))
 221
 222 ;;;###autoload
 223 (defun org-id-get-with-outline-path-completion (&optional targets)
 224   "Use outline-path-completion to retrieve the ID of an entry.
 225 TARGETS may be a setting for `org-refile-targets' to define the eligible
 226 headlines.  When omitted, all headlines in all agenda files are
 227 eligible.
 228 It returns the ID of the entry.  If necessary, the ID is created."
 229   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 230          (org-refile-use-outline-path
 231           (if (caar org-refile-targets) 'file t))
 232          (org-refile-target-verify-function nil)
 233          (spos (org-refile-get-location "Entry"))
 234          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 235                                      (get-file-buffer (nth 1 spos))))))
 236     (prog1 (org-id-get pom 'create)
 237       (move-marker pom nil))))
 238
 239 ;;;###autoload
 240 (defun org-id-get-with-outline-drilling (&optional targets)
 241   "Use an outline-cycling interface to retrieve the ID of an entry.
 242 This only finds entries in the current buffer, using `org-get-location'.
 243 It returns the ID of the entry.  If necessary, the ID is created."
 244   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 245          (pom (and spos (move-marker (make-marker) (car spos)))))
 246     (prog1 (org-id-get pom 'create)
 247       (move-marker pom nil))))
 248
 249 ;;;###autoload
 250 (defun org-id-goto (id)
 251   "Switch to the buffer containing the entry with id ID.
 252 Move the cursor to that entry in that buffer."
 253   (interactive "sID: ")
 254   (let ((m (org-id-find id 'marker)))
 255     (unless m
 256       (error "Cannot find entry with ID \"%s\"" id))
 257     (org-pop-to-buffer-same-window (marker-buffer m))
 258     (goto-char m)
 259     (move-marker m nil)
 260     (org-show-context)))
 261
 262 ;;;###autoload
 263 (defun org-id-find (id &optional markerp)
 264   "Return the location of the entry with the id ID.
 265 The return value is a cons cell (file-name . position), or nil
 266 if there is no entry with that ID.
 267 With optional argument MARKERP, return the position as a new marker."
 268   (cond
 269    ((symbolp id) (setq id (symbol-name id)))
 270    ((numberp id) (setq id (number-to-string id))))
 271   (let ((file (org-id-find-id-file id))
 272         org-agenda-new-buffers where)
 273     (when file
 274       (setq where (org-id-find-id-in-file id file markerp)))
 275     (unless where
 276       (org-id-update-id-locations nil t)
 277       (setq file (org-id-find-id-file id))
 278       (when file
 279         (setq where (org-id-find-id-in-file id file markerp))))
 280     where))
 281
 282 ;;; Internal functions
 283
 284 ;; Creating new IDs
 285
 286 (defun org-id-new (&optional prefix)
 287   "Create a new globally unique ID.
 288
 289 An ID consists of two parts separated by a colon:
 290 - a prefix
 291 - a unique part that will be created according to `org-id-method'.
 292
 293 PREFIX can specify the prefix, the default is given by the variable
 294 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 295 prefix even if `org-id-prefix' specifies one.
 296
 297 So a typical ID could look like \"Org:4nd91V40HI\"."
 298   (let* ((prefix (if (eq prefix 'none)
 299                      ""
 300                    (concat (or prefix org-id-prefix) ":")))
 301          unique)
 302     (if (equal prefix ":") (setq prefix ""))
 303     (cond
 304      ((memq org-id-method '(uuidgen uuid))
 305       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 306       (unless (org-uuidgen-p unique)
 307         (setq unique (org-id-uuid))))
 308      ((eq org-id-method 'org)
 309       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 310              (postfix (if org-id-include-domain
 311                           (progn
 312                             (require 'message)
 313                             (concat "@" (message-make-fqdn))))))
 314         (setq unique (concat etime postfix))))
 315      (t (error "Invalid `org-id-method'")))
 316     (concat prefix unique)))
 317
 318 (defun org-id-uuid ()
 319   "Return string with random (version 4) UUID."
 320   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 321                           (random t)
 322                           (current-time)
 323                           (user-uid)
 324                           (emacs-pid)
 325                           (user-full-name)
 326                           user-mail-address
 327                           (recent-keys)))))
 328     (format "%s-%s-4%s-%s%s-%s"
 329             (substring rnd 0 8)
 330             (substring rnd 8 12)
 331             (substring rnd 13 16)
 332             (format "%x"
 333                     (logior
 334                      #b10000000
 335                      (logand
 336                       #b10111111
 337                       (string-to-number
 338                        (substring rnd 16 18) 16))))
 339             (substring rnd 18 20)
 340             (substring rnd 20 32))))
 341
 342 (defun org-id-reverse-string (s)
 343   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 344
 345 (defun org-id-int-to-b36-one-digit (i)
 346   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 347   (cond
 348    ((< i 10) (+ ?0 i))
 349    ((< i 36) (+ ?a i -10))
 350    (t (error "Larger that 35"))))
 351
 352 (defun org-id-b36-to-int-one-digit (i)
 353   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 354 The input I may be a character, or a single-letter string."
 355   (and (stringp i) (setq i (string-to-char i)))
 356   (cond
 357    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 358    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 359    (t (error "Invalid b36 letter"))))
 360
 361 (defun org-id-int-to-b36 (i &optional length)
 362   "Convert an integer to a base-36 number represented as a string."
 363   (let ((s ""))
 364     (while (> i 0)
 365       (setq s (concat (char-to-string
 366                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 367             i (/ i 36)))
 368     (setq length (max 1 (or length 1)))
 369     (if (< (length s) length)
 370         (setq s (concat (make-string (- length (length s)) ?0) s)))
 371     s))
 372
 373 (defun org-id-b36-to-int (s)
 374   "Convert a base-36 string into the corresponding integer."
 375   (let ((r 0))
 376     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 377           s)
 378     r))
 379
 380 (defun org-id-time-to-b36 (&optional time)
 381   "Encode TIME as a 10-digit string.
 382 This string holds the time to micro-second accuracy, and can be decoded
 383 using `org-id-decode'."
 384   (setq time (or time (current-time)))
 385   (concat (org-id-int-to-b36 (nth 0 time) 4)
 386           (org-id-int-to-b36 (nth 1 time) 4)
 387           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 388
 389 (defun org-id-decode (id)
 390   "Split ID into the prefix and the time value that was used to create it.
 391 The return value is (prefix . time) where PREFIX is nil or a string,
 392 and time is the usual three-integer representation of time."
 393   (let (prefix time parts)
 394     (setq parts (org-split-string id ":"))
 395     (if (= 2 (length parts))
 396         (setq prefix (car parts) time (nth 1 parts))
 397       (setq prefix nil time (nth 0 parts)))
 398     (setq time (org-id-reverse-string time))
 399     (setq time (list (org-id-b36-to-int (substring time 0 4))
 400                      (org-id-b36-to-int (substring time 4 8))
 401                      (org-id-b36-to-int (substring time 8 12))))
 402     (cons prefix time)))
 403
 404 ;; Storing ID locations (files)
 405
 406 (defun org-id-update-id-locations (&optional files silent)
 407   "Scan relevant files for IDs.
 408 Store the relation between files and corresponding IDs.
 409 This will scan all agenda files, all associated archives, and all
 410 files currently mentioned in `org-id-locations'.
 411 When FILES is given, scan these files instead.
 412 When CHECK is given, prepare detailed information about duplicate IDs."
 413   (interactive)
 414   (if (not org-id-track-globally)
 415       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 416     (let* ((org-id-search-archives
 417             (or org-id-search-archives
 418                 (and (symbolp org-id-extra-files)
 419                      (symbol-value org-id-extra-files)
 420                      (member 'agenda-archives org-id-extra-files))))
 421            (files
 422             (or files
 423                 (append
 424                  ;; Agenda files and all associated archives
 425                  (org-agenda-files t org-id-search-archives)
 426                  ;; Explicit extra files
 427                  (if (symbolp org-id-extra-files)
 428                      (symbol-value org-id-extra-files)
 429                    org-id-extra-files)
 430               ;; Files associated with live org-mode buffers
 431                  (delq nil
 432                        (mapcar (lambda (b)
 433                                  (with-current-buffer b
 434                                    (and (derived-mode-p 'org-mode) (buffer-file-name))))
 435                                (buffer-list)))
 436                  ;; All files known to have IDs
 437                  org-id-files)))
 438            org-agenda-new-buffers
 439            file nfiles tfile ids reg found id seen (ndup 0))
 440       (when (member 'agenda-archives files)
 441         (setq files (delq 'agenda-archives (copy-sequence files))))
 442       (setq nfiles (length files))
 443       (while (setq file (pop files))
 444         (unless silent
 445           (message "Finding ID locations (%d/%d files): %s"
 446                    (- nfiles (length files)) nfiles file))
 447         (setq tfile (file-truename file))
 448         (when (and (file-exists-p file) (not (member tfile seen)))
 449           (push tfile seen)
 450           (setq ids nil)
 451           (with-current-buffer (org-get-agenda-file-buffer file)
 452             (save-excursion
 453               (save-restriction
 454                 (widen)
 455                 (goto-char (point-min))
 456                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 457                                           nil t)
 458                   (setq id (org-match-string-no-properties 1))
 459                   (if (member id found)
 460                       (progn
 461                         (message "Duplicate ID \"%s\", also in file %s"
 462                                  id (or (car (delq
 463                                               nil
 464                                               (mapcar
 465                                                (lambda (x)
 466                                                  (if (member id (cdr x))
 467                                                      (car x)))
 468                                                reg)))
 469                                         (buffer-file-name)))
 470                         (when (= ndup 0)
 471                           (ding)
 472                           (sit-for 2))
 473                         (setq ndup (1+ ndup)))
 474                     (push id found)
 475                     (push id ids)))
 476                 (push (cons (abbreviate-file-name file) ids) reg))))))
 477       (org-release-buffers org-agenda-new-buffers)
 478       (setq org-agenda-new-buffers nil)
 479       (setq org-id-locations reg)
 480       (setq org-id-files (mapcar 'car org-id-locations))
 481       (org-id-locations-save) ;; this function can also handle the alist form
 482       ;; now convert to a hash
 483       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 484       (if (> ndup 0)
 485           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 486         (message "%d unique files scanned for IDs" (length org-id-files)))
 487       org-id-locations)))
 488
 489 (defun org-id-locations-save ()
 490   "Save `org-id-locations' in `org-id-locations-file'."
 491   (when (and org-id-track-globally org-id-locations)
 492     (let ((out (if (hash-table-p org-id-locations)
 493                    (org-id-hash-to-alist org-id-locations)
 494                  org-id-locations)))
 495       (with-temp-file org-id-locations-file
 496         (print out (current-buffer))))))
 497
 498 (defun org-id-locations-load ()
 499   "Read the data from `org-id-locations-file'."
 500   (setq org-id-locations nil)
 501   (when org-id-track-globally
 502     (with-temp-buffer
 503       (condition-case nil
 504           (progn
 505             (insert-file-contents-literally org-id-locations-file)
 506             (goto-char (point-min))
 507             (setq org-id-locations (read (current-buffer))))
 508         (error
 509          (message "Could not read org-id-values from %s. Setting it to nil."
 510                   org-id-locations-file))))
 511     (setq org-id-files (mapcar 'car org-id-locations))
 512     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 513
 514 (defun org-id-add-location (id file)
 515   "Add the ID with location FILE to the database of ID locations."
 516   ;; Only if global tracking is on, and when the buffer has a file
 517   (when (and org-id-track-globally id file)
 518     (unless org-id-locations (org-id-locations-load))
 519     (puthash id (abbreviate-file-name file) org-id-locations)
 520     (add-to-list 'org-id-files (abbreviate-file-name file))))
 521
 522 (unless noninteractive
 523   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 524
 525 (defun org-id-hash-to-alist (hash)
 526   "Turn an org-id hash into an alist, so that it can be written to a file."
 527   (let (res x)
 528     (maphash
 529      (lambda (k v)
 530        (if (setq x (member v res))
 531            (setcdr x (cons k (cdr x)))
 532          (push (list v k) res)))
 533      hash)
 534     res))
 535
 536 (defun org-id-alist-to-hash (list)
 537   "Turn an org-id location list into a hash table."
 538   (let ((res (make-hash-table
 539               :test 'equal
 540               :size (apply '+ (mapcar 'length list))))
 541         f)
 542     (mapc
 543      (lambda (x)
 544        (setq f (car x))
 545        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 546      list)
 547     res))
 548
 549 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 550   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 551   (when org-id-track-globally
 552     (save-match-data
 553       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 554       (when (bufferp buffer-or-file)
 555         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 556                                  buffer-or-file))
 557         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 558       (when buffer-or-file
 559         (let ((fname (abbreviate-file-name buffer-or-file))
 560               (s 0))
 561           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 562             (setq s (match-end 0))
 563             (org-id-add-location (match-string 1 txt) fname)))))))
 564
 565 ;; Finding entries with specified id
 566
 567 ;;;###autoload
 568 (defun org-id-find-id-file (id)
 569   "Query the id database for the file in which this ID is located."
 570   (unless org-id-locations (org-id-locations-load))
 571   (or (and org-id-locations
 572            (hash-table-p org-id-locations)
 573            (gethash id org-id-locations))
 574       ;; ball back on current buffer
 575       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 576                             (current-buffer)))))
 577
 578 (defun org-id-find-id-in-file (id file &optional markerp)
 579   "Return the position of the entry ID in FILE.
 580 If that files does not exist, or if it does not contain this ID,
 581 return nil.
 582 The position is returned as a cons cell (file-name . position).  With
 583 optional argument MARKERP, return the position as a new marker."
 584   (let (org-agenda-new-buffers buf pos)
 585     (cond
 586      ((not file) nil)
 587      ((not (file-exists-p file)) nil)
 588      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 589           (setq pos (org-find-entry-with-id id))
 590           (when pos
 591             (if markerp
 592                 (move-marker (make-marker) pos buf)
 593               (cons file pos))))))))
 594
 595 ;; id link type
 596
 597 ;; Calling the following function is hard-coded into `org-store-link',
 598 ;; so we do have to add it to `org-store-link-functions'.
 599
 600 ;;;###autoload
 601 (defun org-id-store-link ()
 602   "Store a link to the current entry, using its ID."
 603   (interactive)
 604   (when (and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
 605     (let* ((link (org-make-link "id:" (org-id-get-create)))
 606            (case-fold-search nil)
 607            (desc (save-excursion
 608                    (org-back-to-heading t)
 609                    (or (and (looking-at org-complex-heading-regexp)
 610                             (if (match-end 4)
 611                                 (match-string 4)
 612                               (match-string 0)))
 613                        link))))
 614       (org-store-link-props :link link :description desc :type "id")
 615       link)))
 616
 617 (defun org-id-open (id)
 618   "Go to the entry with id ID."
 619   (org-mark-ring-push)
 620   (let ((m (org-id-find id 'marker))
 621         cmd)
 622     (unless m
 623       (error "Cannot find entry with ID \"%s\"" id))
 624     ;; Use a buffer-switching command in analogy to finding files
 625     (setq cmd
 626           (or
 627            (cdr
 628             (assq
 629              (cdr (assq 'file org-link-frame-setup))
 630              '((find-file . switch-to-buffer)
 631                (find-file-other-window . switch-to-buffer-other-window)
 632                (find-file-other-frame . switch-to-buffer-other-frame))))
 633            'switch-to-buffer-other-window))
 634     (if (not (equal (current-buffer) (marker-buffer m)))
 635         (funcall cmd (marker-buffer m)))
 636     (goto-char m)
 637     (move-marker m nil)
 638     (org-show-context)))
 639
 640 (org-add-link-type "id" 'org-id-open)
 641
 642 (provide 'org-id)
 643
 644 ;;; org-id.el ends here