testing/org-test.el

   1 ;;;; org-test.el --- Tests for Org-mode
   2
   3 ;; Copyright (c) 2010 Sebastian Rose, Eric Schulte
   4 ;; Authors:
   5 ;;     Sebastian Rose, Hannover, Germany, sebastian_rose gmx de
   6 ;;     Eric Schulte, Santa Fe, New Mexico, USA, schulte.eric gmail com
   7 ;;     David Maus, Brunswick, Germany, dmaus ictsoc de
   8
   9 ;; Released under the GNU General Public License version 3
  10 ;; see: http://www.gnu.org/licenses/gpl-3.0.html
  11
  12 ;; Definition of `special-mode' copied from Emacs23's simple.el to be
  13 ;; provide a testing environment for Emacs22.
  14
  15 ;;;; Comments:
  16
  17 ;; Interactive testing for Org mode.
  18
  19 ;; The heart of all this is the commands `org-test-current-defun'.  If
  20 ;; called while in a `defun' all ert tests with names matching the
  21 ;; name of the function are run.
  22
  23 ;;; Test Development
  24 ;; For test development purposes a number of navigation and test
  25 ;; function construction routines are available as a git submodule
  26 ;; (jump.el)
  27 ;; Install with...
  28 ;; $ git submodule init
  29 ;; $ git submodule update
  30
  31 \f
  32 ;;;; Code:
  33 (let* ((org-test-dir (expand-file-name
  34                       (file-name-directory
  35                        (or load-file-name buffer-file-name))))
  36        (org-lisp-dir (expand-file-name
  37                       (concat org-test-dir "../lisp"))))
  38
  39   (unless (featurep 'org)
  40     (setq load-path (cons org-lisp-dir load-path))
  41     (require 'org)
  42     (require 'org-id)
  43      (org-babel-do-load-languages
  44      'org-babel-load-languages '((sh . t) (org . t))))
  45
  46   (let* ((load-path (cons
  47                      org-test-dir
  48                      (cons
  49                       (expand-file-name "jump" org-test-dir)
  50                       load-path))))
  51     (require 'cl)
  52     (when (= emacs-major-version 22)
  53       (defvar special-mode-map
  54         (let ((map (make-sparse-keymap)))
  55           (suppress-keymap map)
  56           (define-key map "q" 'quit-window)
  57           (define-key map " " 'scroll-up)
  58           (define-key map "\C-?" 'scroll-down)
  59           (define-key map "?" 'describe-mode)
  60           (define-key map "h" 'describe-mode)
  61           (define-key map ">" 'end-of-buffer)
  62           (define-key map "<" 'beginning-of-buffer)
  63           (define-key map "g" 'revert-buffer)
  64           (define-key map "z" 'kill-this-buffer)
  65           map))
  66
  67       (put 'special-mode 'mode-class 'special)
  68       (define-derived-mode special-mode nil "Special"
  69         "Parent major mode from which special major modes should inherit."
  70         (setq buffer-read-only t)))
  71     (require 'ert)
  72     (require 'ert-x)
  73     (when (file-exists-p
  74            (expand-file-name "jump/jump.el" org-test-dir))
  75       (require 'jump)
  76       (require 'which-func))))
  77
  78 (defconst org-test-default-test-file-name "tests.el"
  79   "For each defun a separate file with tests may be defined.
  80 tests.el is the fallback or default if you like.")
  81
  82 (defconst org-test-default-directory-name "testing"
  83   "Basename or the directory where the tests live.
  84 org-test searches this directory up the directory tree.")
  85
  86 (defconst org-test-dir
  87   (expand-file-name (file-name-directory (or load-file-name buffer-file-name))))
  88
  89 (defconst org-base-dir
  90   (expand-file-name ".." org-test-dir))
  91
  92 (defconst org-test-example-dir
  93   (expand-file-name "examples" org-test-dir))
  94
  95 (defconst org-test-file
  96   (expand-file-name "normal.org" org-test-example-dir))
  97
  98 (defconst org-test-no-heading-file
  99   (expand-file-name "no-heading.org" org-test-example-dir))
 100
 101 (defconst org-test-link-in-heading-file
 102   (expand-file-name "link-in-heading.org" org-test-dir))
 103
 104 \f
 105 ;;; Functions for writing tests
 106 (put 'missing-test-dependency
 107      'error-conditions
 108      '(error missing-test-dependency))
 109
 110 (defun org-test-for-executable (exe)
 111   "Throw an error if EXE is not available.
 112 This can be used at the top of code-block-language specific test
 113 files to avoid loading the file on systems without the
 114 executable."
 115   (unless (reduce
 116            (lambda (acc dir)
 117              (or acc (file-exists-p (expand-file-name exe dir))))
 118            exec-path :initial-value nil)
 119     (signal 'missing-test-dependency (list exe))))
 120
 121 (defun org-test-buffer (&optional file)
 122   "TODO:  Setup and return a buffer to work with.
 123 If file is non-nil insert it's contents in there.")
 124
 125 (defun org-test-compare-with-file (&optional file)
 126   "TODO:  Compare the contents of the test buffer with FILE.
 127 If file is not given, search for a file named after the test
 128 currently executed.")
 129
 130 (defmacro org-test-at-id (id &rest body)
 131   "Run body after placing the point in the headline identified by ID."
 132   (declare (indent 1))
 133   `(let* ((id-location (org-id-find ,id))
 134           (id-file (car id-location))
 135           (visited-p (get-file-buffer id-file))
 136           to-be-removed)
 137      (save-window-excursion
 138        (save-match-data
 139          (org-id-goto ,id)
 140          (setq to-be-removed (current-buffer))
 141          (condition-case nil
 142              (progn
 143                (org-show-subtree)
 144                (org-show-block-all))
 145            (error nil))
 146          (save-restriction ,@body)))
 147      (unless visited-p
 148        (kill-buffer to-be-removed))))
 149 (def-edebug-spec org-test-at-id (form body))
 150
 151 (defmacro org-test-in-example-file (file &rest body)
 152   "Execute body in the Org-mode example file."
 153   (declare (indent 1))
 154   `(let* ((my-file (or ,file org-test-file))
 155           (visited-p (get-file-buffer my-file))
 156           to-be-removed)
 157      (save-window-excursion
 158        (save-match-data
 159          (find-file my-file)
 160          (unless (eq major-mode 'org-mode)
 161            (org-mode))
 162          (setq to-be-removed (current-buffer))
 163          (goto-char (point-min))
 164          (condition-case nil
 165              (progn
 166                (outline-next-visible-heading 1)
 167                (org-show-subtree)
 168                (org-show-block-all))
 169            (error nil))
 170          (save-restriction ,@body)))
 171      (unless visited-p
 172        (kill-buffer to-be-removed))))
 173
 174 (defmacro org-test-at-marker (file marker &rest body)
 175   "Run body after placing the point at MARKER in FILE.
 176 Note the uuidgen command-line command can be useful for
 177 generating unique markers for insertion as anchors into org
 178 files."
 179   (declare (indent 2))
 180   `(org-test-in-example-file ,file
 181      (goto-char (point-min))
 182      (re-search-forward (regexp-quote ,marker))
 183      ,@body))
 184 (def-edebug-spec org-test-at-marker (form form body))
 185
 186 (defmacro org-test-with-temp-text (text &rest body)
 187   "Run body in a temporary buffer with Org-mode as the active
 188 mode holding TEXT.  If the string \"<point>\" appears in TEXT
 189 then remove it and place the point there before running BODY,
 190 otherwise place the point at the beginning of the inserted text."
 191   (declare (indent 1))
 192   (let ((inside-text (if (stringp text) text (eval text))))
 193     `(with-temp-buffer
 194        (org-mode)
 195        ,(let ((point (string-match (regexp-quote "<point>") inside-text)))
 196           (if point
 197               `(progn (insert `(replace-match "" nil nil inside-text))
 198                       (goto-char ,(match-beginning 0)))
 199             `(progn (insert ,inside-text)
 200                     (goto-char (point-min)))))
 201        ,@body)))
 202 (def-edebug-spec org-test-with-temp-text (form body))
 203
 204 (defmacro org-test-with-temp-text-in-file (text &rest body)
 205   "Run body in a temporary file buffer with Org-mode as the active mode."
 206   (declare (indent 1))
 207   (let ((file (make-temp-file "org-test"))
 208         (inside-text (if (stringp text) text (eval text)))
 209         (results (gensym)))
 210     `(let ((kill-buffer-query-functions nil) ,results)
 211        (with-temp-file ,file (insert ,inside-text))
 212        (find-file ,file)
 213        (org-mode)
 214        (setq ,results ,@body)
 215        (save-buffer) (kill-buffer (current-buffer))
 216        (delete-file ,file)
 217        ,results)))
 218 (def-edebug-spec org-test-with-temp-text-in-file (form body))
 219
 220 \f
 221 ;;; Navigation Functions
 222 (when (featurep 'jump)
 223   (defjump org-test-jump
 224     (("lisp/\\1.el" . "testing/lisp/test-\\1.el")
 225      ("lisp/\\1.el" . "testing/lisp/\\1.el/test.*.el")
 226      ("contrib/lisp/\\1.el" . "testing/contrib/lisp/test-\\1.el")
 227      ("contrib/lisp/\\1.el" . "testing/contrib/lisp/\\1.el/test.*.el")
 228      ("testing/lisp/test-\\1.el" . "lisp/\\1.el")
 229      ("testing/lisp/\\1.el" . "lisp/\\1.el/test.*.el")
 230      ("testing/contrib/lisp/test-\\1.el" . "contrib/lisp/\\1.el")
 231      ("testing/contrib/lisp/test-\\1.el" . "contrib/lisp/\\1.el/test.*.el"))
 232     (concat org-base-dir "/")
 233     "Jump between org-mode files and their tests."
 234     (lambda (path)
 235       (let* ((full-path (expand-file-name path org-base-dir))
 236              (file-name (file-name-nondirectory path))
 237              (name (file-name-sans-extension file-name)))
 238         (find-file full-path)
 239         (insert
 240          ";;; " file-name "\n\n"
 241          ";; Copyright (c) " (nth 5 (decode-time (current-time)))
 242          " " user-full-name "\n"
 243          ";; Authors: " user-full-name "\n\n"
 244          ";; Released under the GNU General Public License version 3\n"
 245          ";; see: http://www.gnu.org/licenses/gpl-3.0.html\n\n"
 246          ";;;; Comments:\n\n"
 247          ";; Template test file for Org-mode tests\n\n"
 248          "\f\n"
 249          ";;; Code:\n"
 250          "(let ((load-path (cons (expand-file-name\n"
 251          "                      \"..\" (file-name-directory\n"
 252          "                            (or load-file-name buffer-file-name)))\n"
 253          "                     load-path)))\n"
 254          "  (require 'org-test)\n"
 255          "  (require 'org-test-ob-consts))\n\n"
 256          "\f\n"
 257          ";;; Tests\n"
 258          "(ert-deftest " name "/example-test ()\n"
 259          "  \"Just an example to get you started.\"\n"
 260          "  (should t)\n"
 261          "  (should-not nil)\n"
 262          "  (should-error (error \"errr...\")))\n\n\n"
 263          "(provide '" name ")\n\n"
 264          ";;; " file-name " ends here\n") full-path))
 265     (lambda () ((lambda (res) (if (listp res) (car res) res)) (which-function)))))
 266
 267 (define-key emacs-lisp-mode-map "\M-\C-j" 'org-test-jump)
 268
 269 \f
 270 ;;; Miscellaneous helper functions
 271 (defun org-test-strip-text-props (s)
 272   "Return S without any text properties."
 273   (let ((noprop (copy-sequence s)))
 274     (set-text-properties 0 (length noprop) nil noprop)
 275     noprop))
 276 \f
 277
 278 (defun org-test-string-exact-match (regex string &optional start)
 279   "case sensative string-match"
 280   (let ((case-fold-search nil)
 281         (case-replace nil))
 282     (if(and (equal regex "")
 283             (not(equal string "")))
 284         nil
 285       (if (equal 0 (string-match regex string start))
 286           t
 287         nil))))
 288
 289 ;;; Load and Run tests
 290 (defun org-test-load ()
 291   "Load up the org-mode test suite."
 292   (interactive)
 293   (flet ((rld (base)
 294               ;; Recursively load all files, if files throw errors
 295               ;; then silently ignore the error and continue to the
 296               ;; next file.  This allows files to error out if
 297               ;; required executables aren't available.
 298               (mapc
 299                (lambda (path)
 300                  (if (file-directory-p path)
 301                      (rld path)
 302                    (condition-case err
 303                        (when (string-match "^[A-Za-z].*\\.el$"
 304                                          (file-name-nondirectory path))
 305                          (load-file path))
 306                      (missing-test-dependency
 307                       (let ((name (intern
 308                                    (concat "org-missing-dependency/"
 309                                            (file-name-nondirectory
 310                                             (file-name-sans-extension path))))))
 311                         (eval `(ert-deftest ,name ()
 312                                  :expected-result :failed (should nil))))))))
 313                (directory-files base 'full
 314                                 "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*\\.el$"))))
 315     (rld (expand-file-name "lisp" org-test-dir))
 316     (rld (expand-file-name "lisp" (expand-file-name "contrib" org-test-dir)))))
 317
 318 (defun org-test-current-defun ()
 319   "Test the current function."
 320   (interactive)
 321   (ert (which-function)))
 322
 323 (defun org-test-current-file ()
 324   "Run all tests for current file."
 325   (interactive)
 326   (ert (concat "test-"
 327                (file-name-sans-extension
 328                 (file-name-nondirectory (buffer-file-name)))
 329                "/")))
 330
 331 (defun org-test-touch-all-examples ()
 332   (dolist (file (directory-files
 333                  org-test-example-dir 'full
 334                  "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*\\.org$"))
 335     (find-file file)))
 336
 337 (defun org-test-update-id-locations ()
 338   (org-id-update-id-locations
 339    (directory-files
 340     org-test-example-dir 'full
 341     "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*\\.org$")))
 342
 343 (defun org-test-run-batch-tests ()
 344   "Run all defined tests matching \"\\(org\\|ob\\)\".
 345 Load all test files first."
 346   (interactive)
 347   (let ((org-id-track-globally t)
 348         (org-id-locations-file
 349          (convert-standard-filename
 350           (expand-file-name
 351            "testing/.test-org-id-locations"
 352            org-base-dir))))
 353     (org-test-touch-all-examples)
 354     (org-test-update-id-locations)
 355     (org-test-load)
 356     (ert-run-tests-batch-and-exit "\\(org\\|ob\\)")))
 357
 358 (defun org-test-run-all-tests ()
 359   "Run all defined tests matching \"\\(org\\|ob\\)\".
 360 Load all test files first."
 361   (interactive)
 362   (org-test-touch-all-examples)
 363   (org-test-load)
 364   (ert "\\(org\\|ob\\)"))
 365
 366 (provide 'org-test)
 367
 368 ;;; org-test.el ends here