lisp/org-publish.el

   1 ;;; org-publish.el --- publish related org-mode files as a website
   2 ;; Copyright (C) 2006, 2007, 2008  Free Software Foundation, Inc.
   3
   4 ;; Author: David O'Toole <dto@gnu.org>
   5 ;; Maintainer: Bastien Guerry <bzg AT altern DOT org>
   6 ;; Keywords: hypermedia, outlines, wp
   7 ;; Version: 6.08
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This program allow configurable publishing of related sets of
  27 ;; Org-mode files as a complete website.
  28 ;;
  29 ;; org-publish.el can do the following:
  30 ;;
  31 ;; + Publish all one's org-files to HTML or LaTeX
  32 ;; + Upload HTML, images, attachments and other files to a web server
  33 ;; + Exclude selected private pages from publishing
  34 ;; + Publish a clickable index of pages
  35 ;; + Manage local timestamps for publishing only changed files
  36 ;; + Accept plugin functions to extend range of publishable content
  37 ;;
  38 ;; Special thanks to the org-mode maintainer Carsten Dominik for his
  39 ;; ideas, enthusiasm, and cooperation.
  40
  41 ;;; Installation:
  42
  43 ;; Put org-publish.el in your load path, byte-compile it, and then add
  44 ;; the following lines to your emacs initialization file:
  45
  46 ;; (autoload 'org-publish "org-publish" nil t)
  47 ;; (autoload 'org-publish "org-publish-all" nil t)
  48 ;; (autoload 'org-publish "org-publish-current-file" nil t)
  49 ;; (autoload 'org-publish "org-publish-current-project" nil t)
  50
  51 ;; NOTE: When org-publish.el is included with org.el, those forms are
  52 ;; already in the file org-install.el, and hence don't need to be put
  53 ;; in your emacs initialization file in this case.
  54
  55 ;;; Usage:
  56 ;;
  57 ;; The program's main configuration variable is
  58 ;; `org-publish-project-alist'. See below for example configurations
  59 ;; with commentary.
  60
  61 ;; The main interactive functions are:
  62 ;;
  63 ;; M-x org-publish
  64 ;; M-x org-publish-all
  65 ;; M-x org-publish-current-file
  66 ;; M-x org-publish-current-project
  67
  68 ;;;; Simple example configuration:
  69
  70 ;; (setq org-publish-project-alist
  71 ;;       (list
  72 ;;        '("org" . (:base-directory "~/org/"
  73 ;;                   :base-extension "org"
  74 ;;                   :publishing-directory "~/public_html"
  75 ;;                   :with-section-numbers nil
  76 ;;                   :table-of-contents nil
  77 ;;                   :recursive t
  78 ;;                   :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">")))
  79
  80 ;;;; More complex example configuration:
  81
  82 ;; Imagine your *.org files are kept in ~/org, your images in
  83 ;; ~/images, and stylesheets in ~/other. Now imagine you want to
  84 ;; publish the files through an ssh connection to a remote host, via
  85 ;; Tramp-mode. To maintain relative links from *.org files to /images
  86 ;; and /other, we should replicate the same directory structure in
  87 ;; your web server account's designated html root (in this case,
  88 ;; assumed to be ~/html)
  89
  90 ;; Once you've done created the proper directories, you can adapt the
  91 ;; following example configuration to your specific paths, run M-x
  92 ;; org-publish-all, and it should publish the files to the correct
  93 ;; directories on the web server, transforming the *.org files into
  94 ;; HTML, and leaving other files alone.
  95
  96 ;; (setq org-publish-project-alist
  97 ;;       (list
  98 ;;        '("orgfiles" :base-directory "~/org/"
  99 ;;                     :base-extension "org"
 100 ;;                     :publishing-directory "/ssh:user@host:~/html/notebook/"
 101 ;;                     :publishing-function org-publish-org-to-html
 102 ;;                     :exclude "PrivatePage.org"   ;; regexp
 103 ;;                     :headline-levels 3
 104 ;;                     :with-section-numbers nil
 105 ;;                     :table-of-contents nil
 106 ;;                     :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">"
 107 ;;                     :auto-preamble t
 108 ;;                     :auto-postamble nil)
 109 ;;         ("images" :base-directory "~/images/"
 110 ;;                   :base-extension "jpg\\|gif\\|png"
 111 ;;                   :publishing-directory "/ssh:user@host:~/html/images/"
 112 ;;                   :publishing-function org-publish-attachment)
 113 ;;         ("other"  :base-directory "~/other/"
 114 ;;                   :base-extension "css"
 115 ;;                   :publishing-directory "/ssh:user@host:~/html/other/"
 116 ;;                   :publishing-function org-publish-attachment)
 117 ;;         ("website" :components ("orgfiles" "images" "other"))))
 118
 119 ;; For more information, see the documentation for the variable
 120 ;; `org-publish-project-alist'.
 121
 122 ;; Of course, you don't have to publish to remote directories from
 123 ;; within emacs. You can always just publish to local folders, and
 124 ;; then use the synchronization/upload tool of your choice.
 125
 126 ;;; List of user-visible changes since version 1.27
 127
 128 ;; 1.78: Allow list-valued :publishing-function
 129 ;; 1.77: Added :preparation-function, this allows you to use GNU Make etc.
 130 ;; 1.65: Remove old "composite projects". They're redundant.
 131 ;; 1.64: Allow meta-projects with :components
 132 ;; 1.57: Timestamps flag is now called "org-publish-use-timestamps-flag"
 133 ;; 1.52: Properly set default for :index-filename
 134 ;; 1.48: Composite projects allowed.
 135 ;;       :include keyword allowed.
 136 ;; 1.43: Index no longer includes itself in the index.
 137 ;; 1.42: Fix "function definition is void" error
 138 ;;       when :publishing-function not set in org-publish-current-file.
 139 ;; 1.41: Fixed bug where index isn't published on first try.
 140 ;; 1.37: Added interactive function "org-publish". Prompts for particular
 141 ;;       project name to publish.
 142 ;; 1.34: Added force-publish option to all interactive functions.
 143 ;; 1.32: Fixed "index.org has changed on disk" error during index publishing.
 144 ;; 1.30: Fixed startup error caused by (require 'em-unix)
 145
 146 ;;; Code:
 147
 148 (eval-when-compile
 149   (require 'cl))
 150 (require 'org)
 151 (require 'org-exp)
 152
 153 (eval-and-compile
 154   (unless (fboundp 'declare-function)
 155     (defmacro declare-function (fn file &optional arglist fileonly))))
 156
 157 (defgroup org-publish nil
 158   "Options for publishing a set of Org-mode and related files."
 159   :tag "Org Publishing"
 160   :group 'org)
 161
 162 (defcustom org-publish-project-alist nil
 163   "Association list to control publishing behavior.
 164 Each element of the alist is a publishing 'project.'  The CAR of
 165 each element is a string, uniquely identifying the project.  The
 166 CDR of each element is in one of the following forms:
 167
 168   (:property value :property value ... )
 169
 170 OR,
 171
 172   (:components (\"project-1\" \"project-2\" ...))
 173
 174 When the CDR of an element of org-publish-project-alist is in
 175 this second form, the elements of the list after :components are
 176 taken to be components of the project, which group together files
 177 requiring different publishing options.  When you publish such a
 178 project with \\[org-publish], the components all publish.
 179
 180 When a property is given a value in org-publish-project-alist, its
 181 setting overrides the value of the corresponding user variable
 182 \(if any) during publishing.  However, options set within a file
 183 override everything.
 184
 185 Most properties are optional, but some should always be set:
 186
 187   :base-directory        Directory containing publishing source files
 188   :base-extension        Extension (without the dot!) of source files.
 189                          This can be a regular expression.
 190   :publishing-directory  Directory (possibly remote) where output
 191                          files will be published
 192
 193 The :exclude property may be used to prevent certain files from
 194 being published.  Its value may be a string or regexp matching
 195 file names you don't want to be published.
 196
 197 The :include property may be used to include extra files.  Its
 198 value may be a list of filenames to include. The filenames are
 199 considered relative to the base directory.
 200
 201 When both :include and :exclude properties are given values, the
 202 exclusion step happens first.
 203
 204 One special property controls which back-end function to use for
 205 publishing files in the project.  This can be used to extend the
 206 set of file types publishable by org-publish, as well as the set
 207 of output formats.
 208
 209   :publishing-function     Function to publish file.  The default is
 210                            `org-publish-org-to-html', but other
 211                            values are possible.  May also be a
 212                            list of functions, in which case
 213                            each function in the list is invoked
 214                            in turn.
 215
 216 Another property allows you to insert code that prepares a
 217 project for publishing.  For example, you could call GNU Make on a
 218 certain makefile, to ensure published files are built up to date.
 219
 220   :preparation-function   Function to be called before publishing
 221                           this project.
 222   :completion-function    Function to be called after publishing
 223                           this project.
 224
 225 Some properties control details of the Org publishing process,
 226 and are equivalent to the corresponding user variables listed in
 227 the right column.  See the documentation for those variables to
 228 learn more about their use and default values.
 229
 230   :language              `org-export-default-language'
 231   :headline-levels       `org-export-headline-levels'
 232   :section-numbers       `org-export-with-section-numbers'
 233   :table-of-contents     `org-export-with-toc'
 234   :emphasize             `org-export-with-emphasize'
 235   :sub-superscript       `org-export-with-sub-superscripts'
 236   :TeX-macros            `org-export-with-TeX-macros'
 237   :fixed-width           `org-export-with-fixed-width'
 238   :tables                `org-export-with-tables'
 239   :table-auto-headline   `org-export-highlight-first-table-line'
 240   :style                 `org-export-html-style'
 241   :convert-org-links     `org-export-html-link-org-files-as-html'
 242   :inline-images         `org-export-html-inline-images'
 243   :expand-quoted-html    `org-export-html-expand'
 244   :timestamp             `org-export-html-with-timestamp'
 245   :publishing-directory  `org-export-publishing-directory'
 246   :preamble              `org-export-html-preamble'
 247   :postamble             `org-export-html-postamble'
 248   :auto-preamble         `org-export-html-auto-preamble'
 249   :auto-postamble        `org-export-html-auto-postamble'
 250   :author                `user-full-name'
 251   :email                 `user-mail-address'
 252
 253 The following properties may be used to control publishing of an
 254 index of files or summary page for a given project.
 255
 256   :auto-index            Whether to publish an index during
 257                          `org-publish-current-project' or `org-publish-all'.
 258   :index-filename        Filename for output of index.  Defaults
 259                          to 'index.org' (which becomes 'index.html').
 260   :index-title           Title of index page.  Defaults to name of file.
 261   :index-function        Plugin function to use for generation of index.
 262                          Defaults to `org-publish-org-index', which
 263                          generates a plain list of links to all files
 264                          in the project.
 265   :index-style           Can be `list' (index is just an itemized list
 266                          of the titles of the files involved) or
 267                          `tree' (the directory structure of the source
 268                          files is reflected in the index).  Defaults to
 269                          `tree'."
 270   :group 'org-publish
 271   :type 'alist)
 272
 273 (defcustom org-publish-use-timestamps-flag t
 274   "When non-nil, use timestamp checking to publish only changed files.
 275 When nil, do no timestamp checking and always publish all files."
 276   :group 'org-publish
 277   :type 'boolean)
 278
 279 (defcustom org-publish-timestamp-directory "~/.org-timestamps/"
 280   "Name of directory in which to store publishing timestamps."
 281   :group 'org-publish
 282   :type 'directory)
 283
 284 (defcustom org-publish-before-export-hook nil
 285   "Hook run before export on the Org file.
 286 If the functions in this hook modify the original Org buffer, the
 287 modified buffer will be used for export, but the buffer will be
 288 restored and saved back to its initial state after export."
 289   :group 'org-publish
 290   :type 'hook)
 291
 292 (defcustom org-publish-after-export-hook nil
 293   "Hook run after export on the exported buffer.
 294 If functions in this hook modify the buffer, it will be saved."
 295   :group 'org-publish
 296   :type 'hook)
 297
 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 299 ;;; Timestamp-related functions
 300
 301 (defun org-publish-timestamp-filename (filename)
 302   "Return path to timestamp file for filename FILENAME."
 303   (concat (file-name-as-directory org-publish-timestamp-directory)
 304          "X" (if (fboundp 'sha1) (sha1 filename) (md5 filename))))
 305
 306 (defun org-publish-needed-p (filename)
 307   "Return `t' if FILENAME should be published."
 308   (let ((rtn
 309          (if org-publish-use-timestamps-flag
 310              (if (file-exists-p org-publish-timestamp-directory)
 311                  ;; first handle possible wrong timestamp directory
 312                  (if (not (file-directory-p org-publish-timestamp-directory))
 313                      (error "Org publish timestamp: %s is not a directory"
 314                             org-publish-timestamp-directory)
 315                    ;; there is a timestamp, check if FILENAME is newer
 316                    (file-newer-than-file-p
 317                     filename (org-publish-timestamp-filename filename)))
 318                (make-directory org-publish-timestamp-directory)
 319                t)
 320            ;; don't use timestamps, always return t
 321            t)))
 322     (if rtn
 323         (message "Publishing file %s" filename)
 324       (message   "Skipping unmodified file %s" filename))
 325     rtn))
 326
 327 (defun org-publish-update-timestamp (filename)
 328   "Update publishing timestamp for file FILENAME.
 329 If there is no timestamp, create one."
 330   (let ((timestamp-file (org-publish-timestamp-filename filename))
 331         newly-created-timestamp)
 332     (if (not (file-exists-p timestamp-file))
 333         ;; create timestamp file if needed
 334         (with-temp-buffer
 335           (make-directory (file-name-directory timestamp-file) t)
 336           (write-file timestamp-file)
 337           (setq newly-created-timestamp t)))
 338     ;; Emacs 21 doesn't have `set-file-times'
 339     (if (and (fboundp 'set-file-times)
 340              (not newly-created-timestamp))
 341         (set-file-times timestamp-file)
 342       (call-process "touch" nil 0 nil timestamp-file))))
 343
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345 ;;; Mapping files to project names
 346
 347 (defvar org-publish-files-alist nil
 348   "Alist of files and their parent projects.
 349 Each element of this alist is of the form:
 350
 351   (file-name . project-name)")
 352
 353 (defvar org-publish-initial-buffer nil
 354   "The buffer `org-publish' has been called from.")
 355 (defvar org-publish-temp-files nil
 356   "Temporary list of files to be published.")
 357
 358 (defun org-publish-initialize-files-alist (&optional refresh)
 359   "Set `org-publish-files-alist' if it is not set.
 360 Also set it if the optional argument REFRESH is non-nil."
 361   (interactive "P")
 362   (when (or refresh (not org-publish-files-alist))
 363     (setq org-publish-files-alist
 364           (org-publish-get-files org-publish-project-alist))))
 365
 366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 367 ;;; Compatibility aliases
 368
 369 ;; Delete-dups is not in Emacs <22
 370 (if (fboundp 'delete-dups)
 371     (defalias 'org-publish-delete-dups 'delete-dups)
 372   (defun org-publish-delete-dups (list)
 373     "Destructively remove `equal' duplicates from LIST.
 374 Store the result in LIST and return it.  LIST must be a proper list.
 375 Of several `equal' occurrences of an element in LIST, the first
 376 one is kept.
 377
 378 This is a compatibility function for Emacsen without `delete-dups'."
 379     ;; Code from `subr.el' in Emacs 22:
 380     (let ((tail list))
 381       (while tail
 382         (setcdr tail (delete (car tail) (cdr tail)))
 383         (setq tail (cdr tail))))
 384     list))
 385
 386 (declare-function org-publish-delete-dups "org-publish" (list))
 387
 388 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 389 ;;; Getting project information out of org-publish-project-alist
 390
 391 (defun org-publish-get-files (projects-alist &optional no-exclusion)
 392   "Return the list of all publishable files for PROJECTS-ALIST.
 393 If NO-EXCLUSION is non-nil, don't exclude files."
 394   (let (all-files)
 395     ;; add all projects
 396     (mapc
 397      (lambda(p)
 398        (let* ((exclude (plist-get (cdr p) :exclude))
 399               (files (and p (org-publish-get-base-files p exclude))))
 400          ;; add all files from this project
 401          (mapc (lambda(f)
 402                  (add-to-list 'all-files
 403                               (cons (expand-file-name f) (car p))))
 404                files)))
 405      (org-publish-expand-projects projects-alist))
 406     all-files))
 407
 408 (defun org-publish-expand-projects (projects-alist)
 409   "Expand projects in PROJECTS-ALIST.
 410 This splices all the components into the list."
 411   (let ((rest projects-alist) rtn p components)
 412     (while (setq p (pop rest))
 413       (if (setq components (plist-get (cdr p) :components))
 414           (setq rest (append
 415                       (mapcar (lambda (x) (assoc x org-publish-project-alist))
 416                               components)
 417                       rest))
 418         (push p rtn)))
 419     (nreverse (org-publish-delete-dups (delq nil rtn)))))
 420
 421 (defun org-publish-get-base-files-1 (base-dir &optional recurse match skip-file skip-dir)
 422   "Set `org-publish-temp-files' with files from BASE-DIR directory.
 423 If RECURSE is non-nil, check BASE-DIR recursively.  If MATCH is
 424 non-nil, restrict this list to the files matching the regexp
 425 MATCH.  If SKIP-FILE is non-nil, skip file matching the regexp
 426 SKIP-FILE.  If SKIP-DIR is non-nil, don't check directories
 427 matching the regexp SKIP-DIR when recursiing through BASE-DIR."
 428   (mapc (lambda (f)
 429           (let ((fd-p (car (file-attributes f)))
 430                 (fnd (file-name-nondirectory f)))
 431             (if (and fd-p recurse
 432                      (not (string-match "^\\.+$" fnd))
 433                      (if skip-dir (not (string-match skip-dir fnd)) t))
 434                 (org-publish-get-base-files-1 f recurse match skip-file skip-dir)
 435               (unless (or fd-p ;; this is a directory
 436                           (and skip-file (string-match skip-file fnd))
 437                           (not (string-match match fnd)))
 438                 (pushnew f org-publish-temp-files)))))
 439         (directory-files base-dir t (unless recurse match))))
 440
 441 (defun org-publish-get-base-files (project &optional exclude-regexp)
 442   "Return a list of all files in PROJECT.
 443 If EXCLUDE-REGEXP is set, this will be used to filter out
 444 matching filenames."
 445   (let* ((project-plist (cdr project))
 446          (base-dir (file-name-as-directory
 447                     (plist-get project-plist :base-directory)))
 448          (include-list (plist-get project-plist :include))
 449          (recurse (plist-get project-plist :recursive))
 450          (extension (or (plist-get project-plist :base-extension) "org"))
 451          (match (concat "^[^\\.].*\\.\\(" extension "\\)$")))
 452     (setq org-publish-temp-files nil)
 453     (org-publish-get-base-files-1 base-dir recurse match
 454                                   ;; FIXME distinguish exclude regexp
 455                                   ;; for skip-file and skip-dir?
 456                                   exclude-regexp exclude-regexp)
 457     (mapc (lambda (f)
 458             (pushnew
 459              (expand-file-name (concat base-dir f))
 460              org-publish-temp-files))
 461           include-list)
 462     org-publish-temp-files))
 463
 464 (defun org-publish-get-project-from-filename (filename)
 465   "Return the project FILENAME belongs."
 466   (let* ((project-name (cdr (assoc (expand-file-name filename)
 467                                    org-publish-files-alist))))
 468     (assoc project-name org-publish-project-alist)))
 469
 470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 471 ;;; Pluggable publishing back-end functions
 472
 473 (defun org-publish-org-to (format plist filename pub-dir)
 474   "Publish an org file to FORMAT.
 475 PLIST is the property list for the given project.
 476 FILENAME is the filename of the org file to be published.
 477 PUB-DIR is the publishing directory."
 478   (require 'org)
 479   (unless (file-exists-p pub-dir)
 480     (make-directory pub-dir t))
 481   (let* ((visiting (find-buffer-visiting filename))
 482          (plist (cons :buffer-will-be-killed (cons t plist)))
 483          (init-buf (or visiting (find-file filename)))
 484          (init-point (point))
 485          (init-buf-string (buffer-string)) export-buf)
 486     ;; run hooks before exporting
 487     (run-hooks 'org-publish-before-export-hook)
 488     ;; export the possibly modified buffer
 489     (setq export-buf
 490           (funcall (intern (concat "org-export-as-" format))
 491                    (plist-get plist :headline-levels)
 492                    nil plist nil nil pub-dir))
 493     (set-buffer export-buf)
 494     ;; run hooks after export and save export
 495     (and (run-hooks 'org-publish-after-export-hook)
 496          (if (buffer-modified-p) (save-buffer)))
 497     (kill-buffer export-buf)
 498     ;; maybe restore buffer's content
 499     (set-buffer init-buf)
 500     (when (buffer-modified-p init-buf)
 501       (erase-buffer)
 502       (insert init-buf-string)
 503       (save-buffer)
 504       (goto-char init-point))
 505     (unless visiting
 506       (kill-buffer init-buf))))
 507
 508 (defun org-publish-org-to-latex (plist filename pub-dir)
 509   "Publish an org file to LaTeX.
 510 See `org-publish-org-to' to the list of arguments."
 511   (org-publish-org-to "latex" plist filename pub-dir))
 512
 513 (defun org-publish-org-to-html (plist filename pub-dir)
 514   "Publish an org file to HTML.
 515 See `org-publish-org-to' to the list of arguments."
 516   (org-publish-org-to "html" plist filename pub-dir))
 517
 518 (defun org-publish-attachment (plist filename pub-dir)
 519   "Publish a file with no transformation of any kind.
 520 See `org-publish-org-to' to the list of arguments."
 521   ;; make sure eshell/cp code is loaded
 522   (eval-and-compile
 523     (require 'eshell)
 524     (require 'esh-maint)
 525     (require 'em-unix))
 526   (unless (file-directory-p pub-dir)
 527     (make-directory pub-dir t))
 528   (eshell/cp filename pub-dir))
 529
 530 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 531 ;;; Publishing files, sets of files, and indices
 532
 533 (defun org-publish-file (filename &optional project)
 534   "Publish file FILENAME from PROJECT."
 535   (when (org-publish-needed-p filename)
 536     (let* ((project
 537             (or project
 538                 (or (org-publish-get-project-from-filename filename)
 539                     (if (y-or-n-p
 540                          (format "%s is not in a project.  Re-read the list of projects files? "
 541                                  (abbreviate-file-name filename)))
 542                         ;; If requested, re-initialize the list of projects files
 543                         (progn (org-publish-initialize-files-alist t)
 544                                (or (org-publish-get-project-from-filename filename)
 545                                    (error "File %s not part of any known project"
 546                                           (abbreviate-file-name filename))))
 547                       (error "Can't publish file outside of a project")))))
 548            (project-plist (cdr project))
 549            (ftname (file-truename filename))
 550            (publishing-function
 551             (or (plist-get project-plist :publishing-function)
 552                 'org-publish-org-to-html))
 553            (base-dir (file-name-as-directory
 554                       (file-truename (plist-get project-plist :base-directory))))
 555            (pub-dir (file-name-as-directory
 556                      (file-truename (plist-get project-plist :publishing-directory))))
 557            tmp-pub-dir)
 558       (setq tmp-pub-dir
 559             (file-name-directory
 560              (concat pub-dir
 561                      (and (string-match (regexp-quote base-dir) ftname)
 562                           (substring ftname (match-end 0))))))
 563       (if (listp publishing-function)
 564           ;; allow chain of publishing functions
 565           (mapc (lambda (f)
 566                   (funcall f project-plist filename tmp-pub-dir))
 567                 publishing-function)
 568         (funcall publishing-function project-plist filename tmp-pub-dir)))
 569     (org-publish-update-timestamp filename)))
 570
 571 (defun org-publish-projects (projects)
 572   "Publish all files belonging to the PROJECTS alist.
 573 If :auto-index is set, publish the index too."
 574   (mapc
 575    (lambda (project)
 576      (let*
 577          ((project-plist (cdr project))
 578           (exclude-regexp (plist-get project-plist :exclude))
 579           (index-p (plist-get project-plist :auto-index))
 580           (index-filename (or (plist-get project-plist :index-filename)
 581                               "index.org"))
 582           (index-function (or (plist-get project-plist :index-function)
 583                               'org-publish-org-index))
 584           (preparation-function (plist-get project-plist :preparation-function))
 585           (completion-function (plist-get project-plist :completion-function))
 586           (files (org-publish-get-base-files project exclude-regexp)) file)
 587        (when preparation-function (funcall preparation-function))
 588        (if index-p (funcall index-function project index-filename))
 589        (while (setq file (pop files))
 590          (org-publish-file file project))
 591        (when completion-function (funcall completion-function))))
 592    (org-publish-expand-projects projects)))
 593
 594 (defun org-publish-org-index (project &optional index-filename)
 595   "Create an index of pages in set defined by PROJECT.
 596 Optionally set the filename of the index with INDEX-FILENAME.
 597 Default for INDEX-FILENAME is 'index.org'."
 598   (let* ((project-plist (cdr project))
 599          (dir (file-name-as-directory
 600                (plist-get project-plist :base-directory)))
 601          (localdir (file-name-directory dir))
 602          (indent-str (make-string 2 ?\ ))
 603          (exclude-regexp (plist-get project-plist :exclude))
 604          (files (nreverse (org-publish-get-base-files project exclude-regexp)))
 605          (index-filename (concat dir (or index-filename "index.org")))
 606          (index-title (or (plist-get project-plist :index-title)
 607                           (concat "Index for project " (car project))))
 608          (index-style (or (plist-get project-plist :index-style)
 609                           'tree))
 610          (index-buffer (find-buffer-visiting index-filename))
 611          (ifn (file-name-nondirectory index-filename))
 612          file)
 613     ;; if buffer is already open, kill it to prevent error message
 614     (if index-buffer
 615         (kill-buffer index-buffer))
 616     (with-temp-buffer
 617       (insert (concat index-title "\n\n"))
 618       (while (setq file (pop files))
 619         (let ((fn (file-name-nondirectory file))
 620               (link (file-relative-name file dir))
 621               (oldlocal localdir))
 622           ;; index shouldn't index itself
 623           (unless (string= fn ifn)
 624             (if (eq index-style 'list)
 625                 (message "Generating list-style index for %s" index-title)
 626               (message "Generating tree-style index for %s" index-title)
 627               (setq localdir (concat (file-name-as-directory dir)
 628                                      (file-name-directory link)))
 629               (unless (string= localdir oldlocal)
 630                 (if (string= localdir dir)
 631                     (setq indent-str (make-string 2 ?\ ))
 632                   (let ((subdirs
 633                          (split-string
 634                           (directory-file-name
 635                            (file-name-directory
 636                             (file-relative-name localdir dir))) "/"))
 637                         (subdir ""))
 638                     (setq indent-str (make-string 2 ?\ ))
 639                     (dolist (d subdirs)
 640                       (setq subdir (concat subdir d "/"))
 641                       (insert (concat indent-str " + [[file:"
 642                                       subdir "][" d "/]]\n"))
 643                       (setq indent-str (make-string
 644                                         (+ (length indent-str) 2) ?\ )))))))
 645             ;; This is common to 'flat and 'tree
 646             (insert (concat indent-str " + [[file:" link "]["
 647                             (org-publish-find-title file)
 648                             "]]\n"))
 649             )))
 650       (write-file index-filename)
 651       (kill-buffer (current-buffer)))))
 652
 653 (defun org-publish-find-title (file)
 654   "Find the title of file in project."
 655   (save-excursion
 656     (set-buffer (find-file-noselect file))
 657     (let* ((opt-plist (org-combine-plists (org-default-export-plist)
 658                                           (org-infile-export-plist))))
 659       (or (plist-get opt-plist :title)
 660           (and (not
 661                 (plist-get opt-plist :skip-before-1st-heading))
 662                (org-export-grab-title-from-buffer))
 663           (file-name-nondirectory (file-name-sans-extension file))))))
 664
 665
 666 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 667 ;;; Interactive publishing functions
 668
 669 (defalias 'org-publish-project 'org-publish)
 670
 671 ;;;###autoload
 672 (defun org-publish (project &optional force)
 673   "Publish PROJECT."
 674   (interactive "P")
 675   (setq org-publish-initial-buffer (current-buffer))
 676   (save-window-excursion
 677     (let* ((force current-prefix-arg)
 678            (org-publish-use-timestamps-flag
 679             (if force nil org-publish-use-timestamps-flag)))
 680       (org-publish-projects
 681        (list (or project
 682                  (assoc (completing-read
 683                          "Publish project: "
 684                          org-publish-project-alist nil t)
 685                         org-publish-project-alist)))))))
 686
 687 ;;;###autoload
 688 (defun org-publish-all (&optional force)
 689   "Publish all projects.
 690 With prefix argument, force publish all files."
 691   (interactive "P")
 692   (org-publish-initialize-files-alist)
 693   (save-window-excursion
 694     (let ((org-publish-use-timestamps-flag
 695            (if force nil org-publish-use-timestamps-flag)))
 696       (org-publish-projects org-publish-project-alist))))
 697
 698 ;;;###autoload
 699 (defun org-publish-current-file (&optional force)
 700   "Publish the current file.
 701 With prefix argument, force publish the file."
 702   (interactive "P")
 703   (org-publish-initialize-files-alist)
 704   (save-window-excursion
 705     (let ((org-publish-use-timestamps-flag
 706            (if force nil org-publish-use-timestamps-flag)))
 707       (org-publish-file (buffer-file-name)))))
 708
 709 ;;;###autoload
 710 (defun org-publish-current-project (&optional force)
 711   "Publish the project associated with the current file.
 712 With a prefix argument, force publishing of all files in
 713 the project."
 714   (interactive "P")
 715   (org-publish-initialize-files-alist)
 716   (save-window-excursion
 717     (let ((project (org-publish-get-project-from-filename (buffer-file-name)))
 718           (org-publish-use-timestamps-flag
 719            (if force nil org-publish-use-timestamps-flag)))
 720       (if (not project)
 721           (error "File %s is not part of any known project" (buffer-file-name)))
 722       (org-publish project))))
 723
 724 (provide 'org-publish)
 725
 726
 727 ;; arch-tag: 72807f3c-8af0-4a6b-8dca-c3376eb25adb
 728
 729 ;;; org-publish.el ends here