lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements globally unique identifiers for Org-mode entries.
  29 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  30 ;; are provided that create and retrieve such identifiers, and that find
  31 ;; entries based on the identifier.
  32
  33 ;; Identifiers consist of a prefix (default "Org" given by the variable
  34 ;; `org-id-prefix') and a unique part that can be created by a number
  35 ;; of different methods, see the variable `org-id-method'.
  36 ;; Org has a builtin method that uses a compact encoding of the creation
  37 ;; time of the ID, with microsecond accuracy.  This virtually
  38 ;; guarantees globally unique identifiers, even if several people are
  39 ;; creating IDs at the same time in files that will eventually be used
  40 ;; together.
  41 ;;
  42 ;; By default Org uses UUIDs as global unique identifiers.
  43 ;;
  44 ;; This file defines the following API:
  45 ;;
  46 ;; org-id-get-create
  47 ;;        Create an ID for the entry at point if it does not yet have one.
  48 ;;        Returns the ID (old or new).  This function can be used
  49 ;;        interactively, with prefix argument the creation of a new ID is
  50 ;;        forced, even if there was an old one.
  51 ;;
  52 ;; org-id-get
  53 ;;        Get the ID property of an entry.  Using appropriate arguments
  54 ;;        to the function, it can also create the ID for this entry.
  55 ;;
  56 ;; org-id-goto
  57 ;;        Command to go to a specific ID, this command can be used
  58 ;;        interactively.
  59 ;;
  60 ;; org-id-get-with-outline-path-completion
  61 ;;        Retrieve the ID of an entry, using outline path completion.
  62 ;;        This function can work for multiple files.
  63 ;;
  64 ;; org-id-get-with-outline-drilling
  65 ;;        Retrieve the ID of an entry, using outline path completion.
  66 ;;        This function only works for the current file.
  67 ;;
  68 ;; org-id-find
  69 ;;        Find the location of an entry with specific id.
  70 ;;
  71
  72 ;;; Code:
  73
  74 (require 'org)
  75
  76 (declare-function message-make-fqdn "message" ())
  77
  78 ;;; Customization
  79
  80 (defgroup org-id nil
  81   "Options concerning global entry identifiers in Org-mode."
  82   :tag "Org ID"
  83   :group 'org)
  84
  85 (defcustom org-id-uuid-program "uuidgen"
  86   "The uuidgen program."
  87   :group 'org-id
  88   :type 'string)
  89
  90 (defcustom org-id-method 'uuid
  91   "The method that should be used to create new IDs.
  92
  93 An ID will consist of the optional prefix specified in `org-id-prefix',
  94 and a unique part created by the method this variable specifies.
  95
  96 Allowed values are:
  97
  98 org        Org's own internal method, using an encoding of the current time to
  99            microsecond accuracy, and optionally the current domain of the
 100            computer.  See the variable `org-id-include-domain'.
 101
 102 uuid       Create random (version 4) UUIDs.  If the program defined in
 103            `org-id-uuid-program' is available it is used to create the ID.
 104            Otherwise an internal functions is used."
 105   :group 'org-id
 106   :type '(choice
 107           (const :tag "Org's internal method" org)
 108           (const :tag "external: uuidgen" uuid)))
 109
 110 (defcustom org-id-prefix nil
 111   "The prefix for IDs.
 112
 113 This may be a string, or it can be nil to indicate that no prefix is required.
 114 When a string, the string should have no space characters as IDs are expected
 115 to have no space characters in them."
 116   :group 'org-id
 117   :type '(choice
 118           (const :tag "No prefix")
 119           (string :tag "Prefix")))
 120
 121 (defcustom org-id-include-domain nil
 122   "Non-nil means add the domain name to new IDs.
 123 This ensures global uniqueness of IDs, and is also suggested by
 124 RFC 2445 in combination with RFC 822.  This is only relevant if
 125 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 126 be added.
 127 The default is to not use this because we have no really good way to get
 128 the true domain, and Org entries will normally not be shared with enough
 129 people to make this necessary."
 130   :group 'org-id
 131   :type 'boolean)
 132
 133 (defcustom org-id-track-globally t
 134   "Non-nil means track IDs through files, so that links work globally.
 135 This work by maintaining a hash table for IDs and writing this table
 136 to disk when exiting Emacs.  Because of this, it works best if you use
 137 a single Emacs process, not many.
 138
 139 When nil, IDs are not tracked.  Links to IDs will still work within
 140 a buffer, but not if the entry is located in another file.
 141 IDs can still be used if the entry with the id is in the same file as
 142 the link."
 143   :group 'org-id
 144   :type 'boolean)
 145
 146 (defcustom org-id-locations-file (convert-standard-filename
 147                                   "~/.emacs.d/.org-id-locations")
 148   "The file for remembering in which file an ID was defined.
 149 This variable is only relevant when `org-id-track-globally' is set."
 150   :group 'org-id
 151   :type 'file)
 152
 153 (defvar org-id-locations nil
 154   "List of files with IDs in those files.")
 155
 156 (defvar org-id-files nil
 157   "List of files that contain IDs.")
 158
 159 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 160   "Files to be searched for IDs, besides the agenda files.
 161 When Org reparses files to remake the list of files and IDs it is tracking,
 162 it will normally scan the agenda files, the archives related to agenda files,
 163 any files that are listed as ID containing in the current register, and
 164 any Org-mode files currently visited by Emacs.
 165 You can list additional files here.
 166 This variable is only relevant when `org-id-track-globally' is set."
 167   :group 'org-id
 168   :type
 169   '(choice
 170     (symbol :tag "Variable")
 171     (repeat :tag "List of files"
 172             (file))))
 173
 174 (defcustom org-id-search-archives t
 175   "Non-nil means search also the archive files of agenda files for entries.
 176 This is a possibility to reduce overhead, but it means that entries moved
 177 to the archives can no longer be found by ID.
 178 This variable is only relevant when `org-id-track-globally' is set."
 179   :group 'org-id
 180   :type 'boolean)
 181
 182 ;;; The API functions
 183
 184 ;;;###autoload
 185 (defun org-id-get-create (&optional force)
 186   "Create an ID for the current entry and return it.
 187 If the entry already has an ID, just return it.
 188 With optional argument FORCE, force the creation of a new ID."
 189   (interactive "P")
 190   (when force
 191     (org-entry-put (point) "ID" nil))
 192   (org-id-get (point) 'create))
 193
 194 ;;;###autoload
 195 (defun org-id-copy ()
 196   "Copy the ID of the entry at point to the kill ring.
 197 Create an ID if necessary."
 198   (interactive)
 199   (org-kill-new (org-id-get nil 'create)))
 200
 201 ;;;###autoload
 202 (defun org-id-get (&optional pom create prefix)
 203   "Get the ID property of the entry at point-or-marker POM.
 204 If POM is nil, refer to the entry at point.
 205 If the entry does not have an ID, the function returns nil.
 206 However, when CREATE is non nil, create an ID if none is present already.
 207 PREFIX will be passed through to `org-id-new'.
 208 In any case, the ID of the entry is returned."
 209   (org-with-point-at pom
 210     (let ((id (org-entry-get nil "ID")))
 211       (cond
 212        ((and id (stringp id) (string-match "\\S-" id))
 213         id)
 214        (create
 215         (setq id (org-id-new prefix))
 216         (org-entry-put pom "ID" id)
 217         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 218         id)
 219        (t nil)))))
 220
 221 ;;;###autoload
 222 (defun org-id-get-with-outline-path-completion (&optional targets)
 223   "Use outline-path-completion to retrieve the ID of an entry.
 224 TARGETS may be a setting for `org-refile-targets' to define the eligible
 225 headlines.  When omitted, all headlines in all agenda files are
 226 eligible.
 227 It returns the ID of the entry.  If necessary, the ID is created."
 228   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 229          (org-refile-use-outline-path
 230           (if (caar org-refile-targets) 'file t))
 231          (org-refile-target-verify-function nil)
 232          (spos (org-refile-get-location "Entry"))
 233          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 234                                      (get-file-buffer (nth 1 spos))))))
 235     (prog1 (org-id-get pom 'create)
 236       (move-marker pom nil))))
 237
 238 ;;;###autoload
 239 (defun org-id-get-with-outline-drilling (&optional targets)
 240   "Use an outline-cycling interface to retrieve the ID of an entry.
 241 This only finds entries in the current buffer, using `org-get-location'.
 242 It returns the ID of the entry.  If necessary, the ID is created."
 243   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 244          (pom (and spos (move-marker (make-marker) (car spos)))))
 245     (prog1 (org-id-get pom 'create)
 246       (move-marker pom nil))))
 247
 248 ;;;###autoload
 249 (defun org-id-goto (id)
 250   "Switch to the buffer containing the entry with id ID.
 251 Move the cursor to that entry in that buffer."
 252   (interactive "sID: ")
 253   (let ((m (org-id-find id 'marker)))
 254     (unless m
 255       (error "Cannot find entry with ID \"%s\"" id))
 256     (switch-to-buffer (marker-buffer m))
 257     (goto-char m)
 258     (move-marker m nil)
 259     (org-show-context)))
 260
 261 ;;;###autoload
 262 (defun org-id-find (id &optional markerp)
 263   "Return the location of the entry with the id ID.
 264 The return value is a cons cell (file-name . position), or nil
 265 if there is no entry with that ID.
 266 With optional argument MARKERP, return the position as a new marker."
 267   (cond
 268    ((symbolp id) (setq id (symbol-name id)))
 269    ((numberp id) (setq id (number-to-string id))))
 270   (let ((file (org-id-find-id-file id))
 271         org-agenda-new-buffers where)
 272     (when file
 273       (setq where (org-id-find-id-in-file id file markerp)))
 274     (unless where
 275       (org-id-update-id-locations)
 276       (setq file (org-id-find-id-file id))
 277       (when file
 278         (setq where (org-id-find-id-in-file id file markerp))))
 279     where))
 280
 281 ;;; Internal functions
 282
 283 ;; Creating new IDs
 284
 285 (defun org-id-new (&optional prefix)
 286   "Create a new globally unique ID.
 287
 288 An ID consists of two parts separated by a colon:
 289 - a prefix
 290 - a unique part that will be created according to `org-id-method'.
 291
 292 PREFIX can specify the prefix, the default is given by the variable
 293 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 294 prefix even if `org-id-prefix' specifies one.
 295
 296 So a typical ID could look like \"Org:4nd91V40HI\"."
 297   (let* ((prefix (if (eq prefix 'none)
 298                      ""
 299                    (concat (or prefix org-id-prefix) ":")))
 300          unique)
 301     (if (equal prefix ":") (setq prefix ""))
 302     (cond
 303      ((memq org-id-method '(uuidgen uuid))
 304       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 305       (unless (org-uuidgen-p unique)
 306         (setq unique (org-id-uuid))))
 307      ((eq org-id-method 'org)
 308       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 309              (postfix (if org-id-include-domain
 310                           (progn
 311                             (require 'message)
 312                             (concat "@" (message-make-fqdn))))))
 313         (setq unique (concat etime postfix))))
 314      (t (error "Invalid `org-id-method'")))
 315     (concat prefix unique)))
 316
 317 (defun org-id-uuid ()
 318   "Return string with random (version 4) UUID."
 319   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 320                           (random t)
 321                           (current-time)
 322                           (user-uid)
 323                           (emacs-pid)
 324                           (user-full-name)
 325                           user-mail-address
 326                           (recent-keys)))))
 327     (format "%s-%s-4%s-%s%s-%s"
 328             (substring rnd 0 8)
 329             (substring rnd 8 12)
 330             (substring rnd 13 16)
 331             (format "%x"
 332                     (logior
 333                      #b10000000
 334                      (logand
 335                       #b10111111
 336                       (string-to-number
 337                        (substring rnd 16 18) 16))))
 338             (substring rnd 18 20)
 339             (substring rnd 20 32))))
 340
 341 (defun org-id-reverse-string (s)
 342   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 343
 344 (defun org-id-int-to-b36-one-digit (i)
 345   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 346   (cond
 347    ((< i 10) (+ ?0 i))
 348    ((< i 36) (+ ?a i -10))
 349    (t (error "Larger that 35"))))
 350
 351 (defun org-id-b36-to-int-one-digit (i)
 352   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 353 The input I may be a character, or a single-letter string."
 354   (and (stringp i) (setq i (string-to-char i)))
 355   (cond
 356    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 357    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 358    (t (error "Invalid b36 letter"))))
 359
 360 (defun org-id-int-to-b36 (i &optional length)
 361   "Convert an integer to a base-36 number represented as a string."
 362   (let ((s ""))
 363     (while (> i 0)
 364       (setq s (concat (char-to-string
 365                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 366             i (/ i 36)))
 367     (setq length (max 1 (or length 1)))
 368     (if (< (length s) length)
 369         (setq s (concat (make-string (- length (length s)) ?0) s)))
 370     s))
 371
 372 (defun org-id-b36-to-int (s)
 373   "Convert a base-36 string into the corresponding integer."
 374   (let ((r 0))
 375     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 376           s)
 377     r))
 378
 379 (defun org-id-time-to-b36 (&optional time)
 380   "Encode TIME as a 10-digit string.
 381 This string holds the time to micro-second accuracy, and can be decoded
 382 using `org-id-decode'."
 383   (setq time (or time (current-time)))
 384   (concat (org-id-int-to-b36 (nth 0 time) 4)
 385           (org-id-int-to-b36 (nth 1 time) 4)
 386           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 387
 388 (defun org-id-decode (id)
 389   "Split ID into the prefix and the time value that was used to create it.
 390 The return value is (prefix . time) where PREFIX is nil or a string,
 391 and time is the usual three-integer representation of time."
 392   (let (prefix time parts)
 393     (setq parts (org-split-string id ":"))
 394     (if (= 2 (length parts))
 395         (setq prefix (car parts) time (nth 1 parts))
 396       (setq prefix nil time (nth 0 parts)))
 397     (setq time (org-id-reverse-string time))
 398     (setq time (list (org-id-b36-to-int (substring time 0 4))
 399                      (org-id-b36-to-int (substring time 4 8))
 400                      (org-id-b36-to-int (substring time 8 12))))
 401     (cons prefix time)))
 402
 403 ;; Storing ID locations (files)
 404
 405 (defun org-id-update-id-locations (&optional files)
 406   "Scan relevant files for IDs.
 407 Store the relation between files and corresponding IDs.
 408 This will scan all agenda files, all associated archives, and all
 409 files currently mentioned in `org-id-locations'.
 410 When FILES is given, scan these files instead.
 411 When CHECK is given, prepare detailed information about duplicate IDs."
 412   (interactive)
 413   (if (not org-id-track-globally)
 414       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 415     (let* ((org-id-search-archives
 416             (or org-id-search-archives
 417                 (and (symbolp org-id-extra-files)
 418                      (symbol-value org-id-extra-files)
 419                      (member 'agenda-archives org-id-extra-files))))
 420            (files
 421             (or files
 422                 (append
 423                  ;; Agenda files and all associated archives
 424                  (org-agenda-files t org-id-search-archives)
 425                  ;; Explicit extra files
 426                  (if (symbolp org-id-extra-files)
 427                      (symbol-value org-id-extra-files)
 428                    org-id-extra-files)
 429               ;; Files associated with live org-mode buffers
 430                  (delq nil
 431                        (mapcar (lambda (b)
 432                                  (with-current-buffer b
 433                                    (and (org-mode-p) (buffer-file-name))))
 434                                (buffer-list)))
 435                  ;; All files known to have IDs
 436                  org-id-files)))
 437            org-agenda-new-buffers
 438            file nfiles tfile ids reg found id seen (ndup 0))
 439       (when (member 'agenda-archives files)
 440         (setq files (delq 'agenda-archives (copy-sequence files))))
 441       (setq nfiles (length files))
 442       (while (setq file (pop files))
 443         (message "Finding ID locations (%d/%d files): %s"
 444                  (- nfiles (length files)) nfiles file)
 445         (setq tfile (file-truename file))
 446         (when (and (file-exists-p file) (not (member tfile seen)))
 447           (push tfile seen)
 448           (setq ids nil)
 449           (with-current-buffer (org-get-agenda-file-buffer file)
 450             (save-excursion
 451               (save-restriction
 452                 (widen)
 453                 (goto-char (point-min))
 454                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 455                                           nil t)
 456                   (setq id (org-match-string-no-properties 1))
 457                   (if (member id found)
 458                       (progn
 459                         (message "Duplicate ID \"%s\", also in file %s"
 460                                  id (or (car (delq
 461                                               nil
 462                                               (mapcar
 463                                                (lambda (x)
 464                                                  (if (member id (cdr x))
 465                                                      (car x)))
 466                                                reg)))
 467                                         (buffer-file-name)))
 468                         (when (= ndup 0)
 469                           (ding)
 470                           (sit-for 2))
 471                         (setq ndup (1+ ndup)))
 472                     (push id found)
 473                     (push id ids)))
 474                 (push (cons (abbreviate-file-name file) ids) reg))))))
 475       (org-release-buffers org-agenda-new-buffers)
 476       (setq org-agenda-new-buffers nil)
 477       (setq org-id-locations reg)
 478       (setq org-id-files (mapcar 'car org-id-locations))
 479       (org-id-locations-save) ;; this function can also handle the alist form
 480       ;; now convert to a hash
 481       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 482       (if (> ndup 0)
 483           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 484         (message "%d unique files scanned for IDs" (length org-id-files)))
 485       org-id-locations)))
 486
 487 (defun org-id-locations-save ()
 488   "Save `org-id-locations' in `org-id-locations-file'."
 489   (when (and org-id-track-globally org-id-locations)
 490     (let ((out (if (hash-table-p org-id-locations)
 491                    (org-id-hash-to-alist org-id-locations)
 492                  org-id-locations)))
 493       (with-temp-file org-id-locations-file
 494         (print out (current-buffer))))))
 495
 496 (defun org-id-locations-load ()
 497   "Read the data from `org-id-locations-file'."
 498   (setq org-id-locations nil)
 499   (when org-id-track-globally
 500     (with-temp-buffer
 501       (condition-case nil
 502           (progn
 503             (insert-file-contents-literally org-id-locations-file)
 504             (goto-char (point-min))
 505             (setq org-id-locations (read (current-buffer))))
 506         (error
 507          (message "Could not read org-id-values from %s. Setting it to nil."
 508                   org-id-locations-file))))
 509     (setq org-id-files (mapcar 'car org-id-locations))
 510     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 511
 512 (defun org-id-add-location (id file)
 513   "Add the ID with location FILE to the database of ID locations."
 514   ;; Only if global tracking is on, and when the buffer has a file
 515   (when (and org-id-track-globally id file)
 516     (unless org-id-locations (org-id-locations-load))
 517     (puthash id (abbreviate-file-name file) org-id-locations)
 518     (add-to-list 'org-id-files (abbreviate-file-name file))))
 519
 520 (unless noninteractive
 521   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 522
 523 (defun org-id-hash-to-alist (hash)
 524   "Turn an org-id hash into an alist, so that it can be written to a file."
 525   (let (res x)
 526     (maphash
 527      (lambda (k v)
 528        (if (setq x (member v res))
 529            (setcdr x (cons k (cdr x)))
 530          (push (list v k) res)))
 531      hash)
 532     res))
 533
 534 (defun org-id-alist-to-hash (list)
 535   "Turn an org-id location list into a hash table."
 536   (let ((res (make-hash-table
 537               :test 'equal
 538               :size (apply '+ (mapcar 'length list))))
 539         f)
 540     (mapc
 541      (lambda (x)
 542        (setq f (car x))
 543        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 544      list)
 545     res))
 546
 547 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 548   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 549   (when org-id-track-globally
 550     (save-match-data
 551       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 552       (when (bufferp buffer-or-file)
 553         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 554                                  buffer-or-file))
 555         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 556       (when buffer-or-file
 557         (let ((fname (abbreviate-file-name buffer-or-file))
 558               (s 0))
 559           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 560             (setq s (match-end 0))
 561             (org-id-add-location (match-string 1 txt) fname)))))))
 562
 563 ;; Finding entries with specified id
 564
 565 ;;;###autoload
 566 (defun org-id-find-id-file (id)
 567   "Query the id database for the file in which this ID is located."
 568   (unless org-id-locations (org-id-locations-load))
 569   (or (and org-id-locations
 570            (hash-table-p org-id-locations)
 571            (gethash id org-id-locations))
 572       ;; ball back on current buffer
 573       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 574                             (current-buffer)))))
 575
 576 (defun org-id-find-id-in-file (id file &optional markerp)
 577   "Return the position of the entry ID in FILE.
 578 If that files does not exist, or if it does not contain this ID,
 579 return nil.
 580 The position is returned as a cons cell (file-name . position).  With
 581 optional argument MARKERP, return the position as a new marker."
 582   (let (org-agenda-new-buffers buf pos)
 583     (cond
 584      ((not file) nil)
 585      ((not (file-exists-p file)) nil)
 586      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 587           (setq pos (org-find-entry-with-id id))
 588           (when pos
 589             (if markerp
 590                 (move-marker (make-marker) pos buf)
 591               (cons file pos))))))))
 592
 593 ;; id link type
 594
 595 ;; Calling the following function is hard-coded into `org-store-link',
 596 ;; so we do have to add it to `org-store-link-functions'.
 597
 598 ;;;###autoload
 599 (defun org-id-store-link ()
 600   "Store a link to the current entry, using its ID."
 601   (interactive)
 602   (when (and (buffer-file-name (buffer-base-buffer)) (org-mode-p))
 603     (let* ((link (org-make-link "id:" (org-id-get-create)))
 604            (case-fold-search nil)
 605            (desc (save-excursion
 606                    (org-back-to-heading t)
 607                    (or (and (looking-at org-complex-heading-regexp)
 608                             (if (match-end 4)
 609                                 (match-string 4)
 610                               (match-string 0)))
 611                        link))))
 612       (org-store-link-props :link link :description desc :type "id")
 613       link)))
 614
 615 (defun org-id-open (id)
 616   "Go to the entry with id ID."
 617   (org-mark-ring-push)
 618   (let ((m (org-id-find id 'marker))
 619         cmd)
 620     (unless m
 621       (error "Cannot find entry with ID \"%s\"" id))
 622     ;; Use a buffer-switching command in analogy to finding files
 623     (setq cmd
 624           (or
 625            (cdr
 626             (assq
 627              (cdr (assq 'file org-link-frame-setup))
 628              '((find-file . switch-to-buffer)
 629                (find-file-other-window . switch-to-buffer-other-window)
 630                (find-file-other-frame . switch-to-buffer-other-frame))))
 631            'switch-to-buffer-other-window))
 632     (if (not (equal (current-buffer) (marker-buffer m)))
 633         (funcall cmd (marker-buffer m)))
 634     (goto-char m)
 635     (move-marker m nil)
 636     (org-show-context)))
 637
 638 (org-add-link-type "id" 'org-id-open)
 639
 640 (provide 'org-id)
 641
 642 ;;; org-id.el ends here
 643
 644 ;; arch-tag: e5abaca4-e16f-4b25-832a-540cfb63a712
 645
 646