lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>,
   6 ;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112           (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115
 116 (declare-function calendar-leap-year-p "calendar" (year))
 117 (declare-function diary-ordinal-suffix "diary-lib" (n))
 118
 119 (defvar date)   ;; dynamically scoped from Org
 120
 121 ;; Support for version 2.35
 122 (defvar org-bbdb-old (fboundp 'bbdb-record-get-field-internal))
 123
 124 ;; Customization
 125
 126 (defgroup org-bbdb-anniversaries nil
 127   "Customizations for including anniversaries from BBDB into Agenda."
 128   :group 'org-bbdb)
 129
 130 (defcustom org-bbdb-default-anniversary-format "birthday"
 131   "Default anniversary class."
 132   :type  'string
 133   :group 'org-bbdb-anniversaries
 134   :require 'bbdb)
 135
 136 (defcustom org-bbdb-anniversary-format-alist
 137   '(("birthday" lambda
 138      (name years suffix)
 139      (concat "Birthday: [[bbdb:" name "][" name " ("
 140              (format "%s" years)        ; handles numbers as well as strings
 141              suffix ")]]"))
 142     ("wedding" lambda
 143      (name years suffix)
 144      (concat "[[bbdb:" name "][" name "'s "
 145              (format "%s" years)
 146              suffix " wedding anniversary]]")))
 147   "How different types of anniversaries should be formatted.
 148 An alist of elements (STRING . FORMAT) where STRING is the name of an
 149 anniversary class and format is either:
 150 1) A format string with the following substitutions (in order):
 151     * the name of the record containing this anniversary
 152     * the number of years
 153     * an ordinal suffix (st, nd, rd, th) for the year
 154
 155 2) A function to be called with three arguments: NAME YEARS SUFFIX
 156    (string int string) returning a string for the diary or nil.
 157
 158 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 159    scope of variables NAME, YEARS and SUFFIX (among others)."
 160   :type 'sexp
 161   :group 'org-bbdb-anniversaries
 162   :require 'bbdb)
 163
 164 (defcustom org-bbdb-anniversary-field 'anniversary
 165   "The BBDB field which contains anniversaries.
 166 The anniversaries are stored in the following format
 167
 168 YYYY-MM-DD Class-or-Format-String
 169
 170 where class is one of the customized classes for anniversaries;
 171 birthday and wedding are predefined.  Format-String can take three
 172 substitutions 1) the name of the record containing this
 173 anniversary, 2) the number of years, and 3) an ordinal suffix for
 174 the year.
 175
 176 Multiple anniversaries can be separated by \\n."
 177   :type    'symbol
 178   :group   'org-bbdb-anniversaries
 179   :require 'bbdb)
 180
 181 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 182   "How to retrieve `month date year' from the anniversary field.
 183
 184 Customize if you have already filled your BBDB with dates
 185 different from YYYY-MM-DD.  The function must return a list (month
 186 date year)."
 187   :type 'function
 188   :group 'org-bbdb-anniversaries
 189   :require 'bbdb)
 190
 191
 192 ;; Install the link type
 193 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 194 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 195
 196 ;; Implementation
 197 (defun org-bbdb-store-link ()
 198   "Store a link to a BBDB database entry."
 199   (when (eq major-mode 'bbdb-mode)
 200     ;; This is BBDB, we make this link!
 201     (let* ((rec (bbdb-current-record))
 202            (name (bbdb-record-name rec))
 203            (company (if org-bbdb-old
 204                         (bbdb-record-getprop rec 'company)
 205                       (car (bbdb-record-get-field rec 'organization))))
 206            (link (org-make-link "bbdb:" name)))
 207       (org-store-link-props :type "bbdb" :name name :company company
 208                             :link link :description name)
 209       link)))
 210
 211 (defun org-bbdb-export (path desc format)
 212   "Create the export version of a BBDB link specified by PATH or DESC.
 213 If exporting to either HTML or LaTeX FORMAT the link will be
 214 italicized, in all other cases it is left unchanged."
 215   (when (string= desc (format "bbdb:%s" path))
 216     (setq desc path))
 217   (cond
 218    ((eq format 'html) (format "<i>%s</i>" desc))
 219    ((eq format 'latex) (format "\\textit{%s}" desc))
 220    (t desc)))
 221
 222 (defun org-bbdb-open (name)
 223   "Follow a BBDB link to NAME."
 224   (require 'bbdb)
 225   (let ((inhibit-redisplay (not debug-on-error))
 226         (bbdb-electric-p nil))
 227     (if org-bbdb-old
 228         (org-bbdb-open-old)
 229       (org-bbdb-open-new))))
 230
 231 (defun org-bbdb-open-old ()
 232   (catch 'exit
 233     ;; Exact match on name
 234     (bbdb-name (concat "\\`" name "\\'") nil)
 235     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 236     ;; Exact match on name
 237     (bbdb-company (concat "\\`" name "\\'") nil)
 238     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 239     ;; Partial match on name
 240     (bbdb-name name nil)
 241     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 242     ;; Partial match on company
 243     (bbdb-company name nil)
 244     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 245     ;; General match including network address and notes
 246     (bbdb name nil)
 247     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 248       (delete-window (get-buffer-window "*BBDB*"))
 249       (error "No matching BBDB record"))))
 250
 251 (defun org-bbdb-open-new ()
 252   (catch 'exit
 253     ;; Exact match on name
 254     (bbdb-search-name (concat "\\`" name "\\'") nil)
 255     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 256     ;; Exact match on name
 257     (bbdb-search-organization (concat "\\`" name "\\'") nil)
 258     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 259     ;; Partial match on name
 260     (bbdb-search-name name nil)
 261     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 262     ;; Partial match on company
 263     (bbdb-search-organization name nil)
 264     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 265     ;; General match including network address and notes
 266     (bbdb name nil)
 267     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 268       (delete-window (get-buffer-window "*BBDB*"))
 269       (error "No matching BBDB record"))))
 270
 271 (defun org-bbdb-anniv-extract-date (time-str)
 272   "Convert YYYY-MM-DD to (month date year).
 273 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 274 it will be considered unknown."
 275   (multiple-value-bind (a b c) (values-list (bbdb-split time-str "-"))
 276     (if (eq c nil)
 277         (list (string-to-number a)
 278               (string-to-number b)
 279               nil)
 280       (list (string-to-number b)
 281             (string-to-number c)
 282             (string-to-number a)))))
 283
 284 (defun org-bbdb-anniv-split (str)
 285   "Split multiple entries in the BBDB anniversary field.
 286 Argument STR is the anniversary field in BBDB."
 287   (let ((pos (string-match "[ \t]" str)))
 288     (if pos (list (substring str 0 pos)
 289                   (bbdb-string-trim (substring str pos)))
 290       (list str nil))))
 291
 292 (defvar org-bbdb-anniv-hash nil
 293   "A hash holding anniversaries extracted from BBDB.
 294 The hash table is created on first use.")
 295
 296 (defvar org-bbdb-updated-p t
 297   "This is non-nil if BBDB has been updated since we last built the hash.")
 298
 299 (defun org-bbdb-make-anniv-hash ()
 300   "Create a hash with anniversaries extracted from BBDB, for fast access.
 301 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 302
 303   (let (split tmp annivs)
 304     (clrhash org-bbdb-anniv-hash)
 305     (dolist (rec (bbdb-records))
 306       (when (setq annivs (bbdb-record-getprop
 307                           rec org-bbdb-anniversary-field))
 308         (setq annivs (bbdb-split annivs "\n"))
 309         (while annivs
 310           (setq split (org-bbdb-anniv-split (pop annivs)))
 311           (multiple-value-bind (m d y)
 312               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 313             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 314             (puthash (list m d) (cons (list y
 315                                             (bbdb-record-name rec)
 316                                             (cadr split))
 317                                       tmp)
 318                      org-bbdb-anniv-hash))))))
 319   (setq org-bbdb-updated-p nil))
 320
 321 (defun org-bbdb-updated (rec)
 322   "Record the fact that BBDB has been updated.
 323 This is used by Org to re-create the anniversary hash table."
 324   (setq org-bbdb-updated-p t))
 325
 326 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 327
 328 ;;;###autoload
 329 (defun org-bbdb-anniversaries()
 330   "Extract anniversaries from BBDB for display in the agenda."
 331   (require 'bbdb)
 332   (require 'diary-lib)
 333   (unless (hash-table-p org-bbdb-anniv-hash)
 334     (setq org-bbdb-anniv-hash
 335           (make-hash-table :test 'equal :size 366)))
 336
 337   (when (or org-bbdb-updated-p
 338             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 339     (org-bbdb-make-anniv-hash))
 340
 341   (let* ((m (car date))    ; month
 342          (d (nth 1 date))  ; day
 343          (y (nth 2 date))  ; year
 344          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 345          (text ())
 346          rec recs)
 347
 348     ;; we don't want to miss people born on Feb. 29th
 349     (when (and (= m 3) (= d 1)
 350                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 351                (not (calendar-leap-year-p y)))
 352       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 353       (while (setq rec (pop recs))
 354         (push rec annivs)))
 355
 356     (when annivs
 357       (while (setq rec (pop annivs))
 358         (when rec
 359           (let* ((class (or (nth 2 rec)
 360                             org-bbdb-default-anniversary-format))
 361                  (form (or (cdr (assoc-string
 362                                  class org-bbdb-anniversary-format-alist t))
 363                            class))      ; (as format string)
 364                  (name (nth 1 rec))
 365                  (years (if (eq (car rec) nil)
 366                             "unknown"
 367                           (- y (car rec))))
 368                  (suffix (if (eq (car rec) nil)
 369                              ""
 370                            (diary-ordinal-suffix years)))
 371                  (tmp (cond
 372                        ((functionp form)
 373                         (funcall form name years suffix))
 374                        ((listp form) (eval form))
 375                        (t (format form name years suffix)))))
 376             (org-add-props tmp nil 'org-bbdb-name name)
 377             (if text
 378                 (setq text (append text (list tmp)))
 379               (setq text (list tmp)))))
 380         ))
 381     text))
 382
 383 (defun org-bbdb-complete-link ()
 384   "Read a bbdb link with name completion."
 385   (require 'bbdb-com)
 386   (concat "bbdb:"
 387           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 388
 389 (defun org-bbdb-anniv-export-ical ()
 390   "Extract anniversaries from BBDB and convert them to icalendar format."
 391   (require 'bbdb)
 392   (require 'diary-lib)
 393   (unless (hash-table-p org-bbdb-anniv-hash)
 394     (setq org-bbdb-anniv-hash
 395           (make-hash-table :test 'equal :size 366)))
 396   (when (or org-bbdb-updated-p
 397             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 398     (org-bbdb-make-anniv-hash))
 399   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 400
 401 (defun org-bbdb-format-vevent (key recs)
 402   (let (rec categ)
 403     (while (setq rec (pop recs))
 404       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 405       (princ (format "BEGIN:VEVENT
 406 UID: ANNIV-%4i%02i%02i-%s
 407 DTSTART:%4i%02i%02i
 408 SUMMARY:%s
 409 DESCRIPTION:%s
 410 CATEGORIES:%s
 411 RRULE:FREQ=YEARLY
 412 END:VEVENT\n"
 413                      (nth 0 rec) (nth 0 key) (nth 1 key)
 414                      (mapconcat 'identity
 415                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 416                                 "-")
 417                      (nth 0 rec) (nth 0 key) (nth 1 key)
 418                      (nth 1 rec)
 419                      (concat (capitalize categ) " " (nth 1 rec))
 420                      categ)))))
 421
 422 (provide 'org-bbdb)
 423
 424 ;;; org-bbdb.el ends here