lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Extract the code from source blocks out into raw source-code files.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'org-src)
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (declare-function org-link-escape "org" (text &optional table))
  36 (declare-function org-heading-components "org" ())
  37 (declare-function org-back-to-heading "org" (invisible-ok))
  38 (declare-function org-fill-template "org" (template alist))
  39 (declare-function org-babel-update-block-body "org" (new-body))
  40 (declare-function make-directory "files" (dir &optional parents))
  41
  42 ;;;###autoload
  43 (defcustom org-babel-tangle-lang-exts
  44   '(("emacs-lisp" . "el"))
  45   "Alist mapping languages to their file extensions.
  46 The key is the language name, the value is the string that should
  47 be inserted as the extension commonly used to identify files
  48 written in this language.  If no entry is found in this list,
  49 then the name of the language is used."
  50   :group 'org-babel-tangle
  51   :type '(repeat
  52           (cons
  53            (string "Language name")
  54            (string "File Extension"))))
  55
  56 (defcustom org-babel-post-tangle-hook nil
  57   "Hook run in code files tangled by `org-babel-tangle'."
  58   :group 'org-babel
  59   :type 'hook)
  60
  61 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  62   "Hook run at the beginning of `org-babel-tangle'."
  63   :group 'org-babel
  64   :type 'hook)
  65
  66 (defcustom org-babel-tangle-body-hook nil
  67   "Hook run over the contents of each code block body."
  68   :group 'org-babel
  69   :type 'hook)
  70
  71 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  72   "Format of inserted comments in tangled code files.
  73 The following format strings can be used to insert special
  74 information into the output using `org-fill-template'.
  75 %start-line --- the line number at the start of the code block
  76 %file --------- the file from which the code block was tangled
  77 %link --------- Org-mode style link to the code block
  78 %source-name -- name of the code block
  79
  80 Whether or not comments are inserted during tangling is
  81 controlled by the :comments header argument."
  82   :group 'org-babel
  83   :type 'string)
  84
  85 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  86   "Format of inserted comments in tangled code files.
  87 The following format strings can be used to insert special
  88 information into the output using `org-fill-template'.
  89 %start-line --- the line number at the start of the code block
  90 %file --------- the file from which the code block was tangled
  91 %link --------- Org-mode style link to the code block
  92 %source-name -- name of the code block
  93
  94 Whether or not comments are inserted during tangling is
  95 controlled by the :comments header argument."
  96   :group 'org-babel
  97   :type 'string)
  98
  99 (defun org-babel-find-file-noselect-refresh (file)
 100   "Find file ensuring that the latest changes on disk are
 101 represented in the file."
 102   (find-file-noselect file)
 103   (with-current-buffer (get-file-buffer file)
 104     (revert-buffer t t t)))
 105
 106 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 107   "Open FILE into a temporary buffer execute BODY there like
 108 `progn', then kill the FILE buffer returning the result of
 109 evaluating BODY."
 110   (declare (indent 1))
 111   (let ((temp-result (make-symbol "temp-result"))
 112         (temp-file (make-symbol "temp-file"))
 113         (visited-p (make-symbol "visited-p")))
 114     `(let (,temp-result ,temp-file
 115            (,visited-p (get-file-buffer ,file)))
 116        (org-babel-find-file-noselect-refresh ,file)
 117        (setf ,temp-file (get-file-buffer ,file))
 118        (with-current-buffer ,temp-file
 119          (setf ,temp-result (progn ,@body)))
 120        (unless ,visited-p (kill-buffer ,temp-file))
 121        ,temp-result)))
 122
 123 ;;;###autoload
 124 (defun org-babel-load-file (file)
 125   "Load Emacs Lisp source code blocks in the Org-mode FILE.
 126 This function exports the source code using
 127 `org-babel-tangle' and then loads the resulting file using
 128 `load-file'."
 129   (interactive "fFile to load: ")
 130   (flet ((age (file)
 131               (float-time
 132                (time-subtract (current-time)
 133                               (nth 5 (or (file-attributes (file-truename file))
 134                                          (file-attributes file)))))))
 135     (let* ((base-name (file-name-sans-extension file))
 136            (exported-file (concat base-name ".el")))
 137       ;; tangle if the org-mode file is newer than the elisp file
 138       (unless (and (file-exists-p exported-file)
 139                    (> (age file) (age exported-file)))
 140         (org-babel-tangle-file file exported-file "emacs-lisp"))
 141       (load-file exported-file)
 142       (message "loaded %s" exported-file))))
 143
 144 ;;;###autoload
 145 (defun org-babel-tangle-file (file &optional target-file lang)
 146   "Extract the bodies of source code blocks in FILE.
 147 Source code blocks are extracted with `org-babel-tangle'.
 148 Optional argument TARGET-FILE can be used to specify a default
 149 export file for all source blocks.  Optional argument LANG can be
 150 used to limit the exported source code blocks by language."
 151   (interactive "fFile to tangle: \nP")
 152   (let ((visited-p (get-file-buffer (expand-file-name file)))
 153         to-be-removed)
 154     (save-window-excursion
 155       (find-file file)
 156       (setq to-be-removed (current-buffer))
 157       (org-babel-tangle target-file lang))
 158     (unless visited-p
 159       (kill-buffer to-be-removed))))
 160
 161 (defun org-babel-tangle-publish (_ filename pub-dir)
 162   "Tangle FILENAME and place the results in PUB-DIR."
 163   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 164
 165 ;;;###autoload
 166 (defun org-babel-tangle (&optional target-file lang)
 167   "Write code blocks to source-specific files.
 168 Extract the bodies of all source code blocks from the current
 169 file into their own source-specific files.  Optional argument
 170 TARGET-FILE can be used to specify a default export file for all
 171 source blocks.  Optional argument LANG can be used to limit the
 172 exported source code blocks by language."
 173   (interactive)
 174   (run-hooks 'org-babel-pre-tangle-hook)
 175   (save-excursion
 176     (let ((block-counter 0)
 177           (org-babel-default-header-args
 178            (if target-file
 179                (org-babel-merge-params org-babel-default-header-args
 180                                        (list (cons :tangle target-file)))
 181              org-babel-default-header-args))
 182           path-collector)
 183       (mapc ;; map over all languages
 184        (lambda (by-lang)
 185          (let* ((lang (car by-lang))
 186                 (specs (cdr by-lang))
 187                 (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 188                 (lang-f (intern
 189                          (concat
 190                           (or (and (cdr (assoc lang org-src-lang-modes))
 191                                    (symbol-name
 192                                     (cdr (assoc lang org-src-lang-modes))))
 193                               lang)
 194                           "-mode")))
 195                 she-banged)
 196            (mapc
 197             (lambda (spec)
 198               (flet ((get-spec (name)
 199                                (cdr (assoc name (nth 4 spec)))))
 200                 (let* ((tangle (get-spec :tangle))
 201                        (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 202                                   (get-spec :shebang)))
 203                        (base-name (cond
 204                                    ((string= "yes" tangle)
 205                                     (file-name-sans-extension
 206                                      (buffer-file-name)))
 207                                    ((string= "no" tangle) nil)
 208                                    ((> (length tangle) 0) tangle)))
 209                        (file-name (when base-name
 210                                     ;; decide if we want to add ext to base-name
 211                                     (if (and ext (string= "yes" tangle))
 212                                         (concat base-name "." ext) base-name))))
 213                   (when file-name
 214                     ;; possibly create the parent directories for file
 215                     (when ((lambda (m) (and m (not (string= m "no"))))
 216                            (get-spec :mkdirp))
 217                       (make-directory (file-name-directory file-name) 'parents))
 218                     ;; delete any old versions of file
 219                     (when (and (file-exists-p file-name)
 220                                (not (member file-name path-collector)))
 221                       (delete-file file-name))
 222                     ;; drop source-block to file
 223                     (with-temp-buffer
 224                       (when (fboundp lang-f) (funcall lang-f))
 225                       (when (and she-bang (not (member file-name she-banged)))
 226                         (insert (concat she-bang "\n"))
 227                         (setq she-banged (cons file-name she-banged)))
 228                       (org-babel-spec-to-string spec)
 229                       ;; We avoid append-to-file as it does not work with tramp.
 230                       (let ((content (buffer-string)))
 231                         (with-temp-buffer
 232                           (if (file-exists-p file-name)
 233                               (insert-file-contents file-name))
 234                           (goto-char (point-max))
 235                           (insert content)
 236                           (write-region nil nil file-name))))
 237                     ;; if files contain she-bangs, then make the executable
 238                     (when she-bang (set-file-modes file-name #o755))
 239                     ;; update counter
 240                     (setq block-counter (+ 1 block-counter))
 241                     (add-to-list 'path-collector file-name)))))
 242             specs)))
 243        (org-babel-tangle-collect-blocks lang))
 244       (message "tangled %d code block%s from %s" block-counter
 245                (if (= block-counter 1) "" "s")
 246                (file-name-nondirectory
 247                 (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
 248       ;; run `org-babel-post-tangle-hook' in all tangled files
 249       (when org-babel-post-tangle-hook
 250         (mapc
 251          (lambda (file)
 252            (org-babel-with-temp-filebuffer file
 253              (run-hooks 'org-babel-post-tangle-hook)))
 254          path-collector))
 255       path-collector)))
 256
 257 (defun org-babel-tangle-clean ()
 258   "Remove comments inserted by `org-babel-tangle'.
 259 Call this function inside of a source-code file generated by
 260 `org-babel-tangle' to remove all comments inserted automatically
 261 by `org-babel-tangle'.  Warning, this comment removes any lines
 262 containing constructs which resemble org-mode file links or noweb
 263 references."
 264   (interactive)
 265   (goto-char (point-min))
 266   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 267              (re-search-forward "<<[^[:space:]]*>>" nil t))
 268     (delete-region (save-excursion (beginning-of-line 1) (point))
 269                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 270
 271 (defvar org-stored-links)
 272 (defun org-babel-tangle-collect-blocks (&optional language)
 273   "Collect source blocks in the current Org-mode file.
 274 Return an association list of source-code block specifications of
 275 the form used by `org-babel-spec-to-string' grouped by language.
 276 Optional argument LANG can be used to limit the collected source
 277 code blocks by language."
 278   (let ((block-counter 1) (current-heading "") blocks)
 279     (org-babel-map-src-blocks (buffer-file-name)
 280       ((lambda (new-heading)
 281          (if (not (string= new-heading current-heading))
 282              (progn
 283                (setq block-counter 1)
 284                (setq current-heading new-heading))
 285            (setq block-counter (+ 1 block-counter))))
 286        (replace-regexp-in-string "[ \t]" "-"
 287                                  (condition-case nil
 288                                      (nth 4 (org-heading-components))
 289                                    (error (buffer-file-name)))))
 290       (let* ((start-line (save-restriction (widen)
 291                                            (+ 1 (line-number-at-pos (point)))))
 292              (file (buffer-file-name))
 293              (info (org-babel-get-src-block-info 'light))
 294              (src-lang (nth 0 info)))
 295         (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
 296           (unless (and language (not (string= language src-lang)))
 297             (let* ((info (org-babel-get-src-block-info))
 298                    (params (nth 2 info))
 299                    (link ((lambda (link)
 300                             (and (string-match org-bracket-link-regexp link)
 301                                  (match-string 1 link)))
 302                           (org-babel-clean-text-properties
 303                            (org-store-link nil))))
 304                    (source-name
 305                     (intern (or (nth 4 info)
 306                                 (format "%s:%d"
 307                                         current-heading block-counter))))
 308                    (expand-cmd
 309                     (intern (concat "org-babel-expand-body:" src-lang)))
 310                    (assignments-cmd
 311                     (intern (concat "org-babel-variable-assignments:" src-lang)))
 312                    (body
 313                     ((lambda (body) ;; run the tangle-body-hook
 314                        (with-temp-buffer
 315                          (insert body)
 316                          (run-hooks 'org-babel-tangle-body-hook)
 317                          (buffer-string)))
 318                      ((lambda (body) ;; expand the body in language specific manner
 319                         (if (assoc :no-expand params)
 320                             body
 321                           (if (fboundp expand-cmd)
 322                               (funcall expand-cmd body params)
 323                             (org-babel-expand-body:generic
 324                              body params
 325                              (and (fboundp assignments-cmd)
 326                                   (funcall assignments-cmd params))))))
 327                       (if (and (cdr (assoc :noweb params)) ;; expand noweb refs
 328                                (let ((nowebs (split-string
 329                                               (cdr (assoc :noweb params)))))
 330                                  (or (member "yes" nowebs)
 331                                      (member "tangle" nowebs))))
 332                           (org-babel-expand-noweb-references info)
 333                         (nth 1 info)))))
 334                    (comment
 335                     (when (or (string= "both" (cdr (assoc :comments params)))
 336                               (string= "org" (cdr (assoc :comments params))))
 337                       ;; from the previous heading or code-block end
 338                       (buffer-substring
 339                        (max (condition-case nil
 340                                 (save-excursion
 341                                   (org-back-to-heading t) (point))
 342                               (error 0))
 343                             (save-excursion
 344                               (re-search-backward
 345                                org-babel-src-block-regexp nil t)
 346                               (match-end 0)))
 347                        (point))))
 348                    by-lang)
 349               ;; add the spec for this block to blocks under it's language
 350               (setq by-lang (cdr (assoc src-lang blocks)))
 351               (setq blocks (delq (assoc src-lang blocks) blocks))
 352               (setq blocks (cons
 353                             (cons src-lang
 354                                   (cons (list start-line file link
 355                                               source-name params body comment)
 356                                         by-lang)) blocks)))))))
 357     ;; ensure blocks in the correct order
 358     (setq blocks
 359           (mapcar
 360            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 361            blocks))
 362     blocks))
 363
 364 (defun org-babel-spec-to-string (spec)
 365   "Insert SPEC into the current file.
 366 Insert the source-code specified by SPEC into the current
 367 source code file.  This function uses `comment-region' which
 368 assumes that the appropriate major-mode is set.  SPEC has the
 369 form
 370
 371   (start-line file link source-name params body comment)"
 372   (let* ((start-line (nth 0 spec))
 373          (file (nth 1 spec))
 374          (link (org-link-escape (nth 2 spec)))
 375          (source-name (nth 3 spec))
 376          (body (nth 5 spec))
 377          (comment (nth 6 spec))
 378          (comments (cdr (assoc :comments (nth 4 spec))))
 379          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 380          (link-p (or (string= comments "both") (string= comments "link")
 381                      (string= comments "yes") (string= comments "noweb")))
 382          (link-data (mapcar (lambda (el)
 383                               (cons (symbol-name el)
 384                                     ((lambda (le)
 385                                        (if (stringp le) le (format "%S" le)))
 386                                      (eval el))))
 387                             '(start-line file link source-name))))
 388     (flet ((insert-comment (text)
 389             (let ((text (org-babel-trim text)))
 390               (when (and comments (not (string= comments "no"))
 391                          (> (length text) 0))
 392                 (when padline (insert "\n"))
 393                 (comment-region (point) (progn (insert text) (point)))
 394                 (end-of-line nil) (insert "\n")))))
 395       (when comment (insert-comment comment))
 396       (when link-p
 397         (insert-comment
 398          (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 399       (when padline (insert "\n"))
 400       (insert
 401        (format
 402         "%s\n"
 403         (replace-regexp-in-string
 404          "^," ""
 405          (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 406       (when link-p
 407         (insert-comment
 408          (org-fill-template org-babel-tangle-comment-format-end link-data))))))
 409
 410 (defun org-babel-tangle-comment-links ( &optional info)
 411   "Return a list of begin and end link comments for the code block at point."
 412   (let* ((start-line (org-babel-where-is-src-block-head))
 413          (file (buffer-file-name))
 414          (link (org-link-escape (progn (call-interactively 'org-store-link)
 415                                        (org-babel-clean-text-properties
 416                                         (car (pop org-stored-links))))))
 417          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 418          (link-data (mapcar (lambda (el)
 419                               (cons (symbol-name el)
 420                                     ((lambda (le)
 421                                        (if (stringp le) le (format "%S" le)))
 422                                      (eval el))))
 423                             '(start-line file link source-name))))
 424     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 425           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 426
 427 ;; de-tangling functions
 428 (defvar org-bracket-link-analytic-regexp)
 429 (defun org-babel-detangle (&optional source-code-file)
 430   "Propagate changes in source file back original to Org-mode file.
 431 This requires that code blocks were tangled with link comments
 432 which enable the original code blocks to be found."
 433   (interactive)
 434   (save-excursion
 435     (when source-code-file (find-file source-code-file))
 436     (goto-char (point-min))
 437     (let ((counter 0) new-body end)
 438       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 439         (when (re-search-forward
 440                (concat " " (regexp-quote (match-string 5)) " ends here"))
 441           (setq end (match-end 0))
 442           (forward-line -1)
 443           (save-excursion
 444             (when (setq new-body (org-babel-tangle-jump-to-org))
 445               (org-babel-update-block-body new-body)))
 446           (setq counter (+ 1 counter)))
 447         (goto-char end))
 448       (prog1 counter (message "detangled %d code blocks" counter)))))
 449
 450 (defun org-babel-tangle-jump-to-org ()
 451   "Jump from a tangled code file to the related Org-mode file."
 452   (interactive)
 453   (let ((mid (point))
 454         start end done
 455         target-buffer target-char link path block-name body)
 456     (save-window-excursion
 457       (save-excursion
 458         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 459                     (not ; ever wider searches until matching block comments
 460                      (and (setq start (point-at-eol))
 461                           (setq link (match-string 0))
 462                           (setq path (match-string 3))
 463                           (setq block-name (match-string 5))
 464                           (save-excursion
 465                             (save-match-data
 466                               (re-search-forward
 467                                (concat " " (regexp-quote block-name)
 468                                        " ends here") nil t)
 469                               (setq end (point-at-bol))))))))
 470         (unless (and start (< start mid) (< mid end))
 471           (error "not in tangled code"))
 472         (setq body (org-babel-trim (buffer-substring start end))))
 473       (when (string-match "::" path)
 474         (setq path (substring path 0 (match-beginning 0))))
 475       (find-file path) (setq target-buffer (current-buffer))
 476       (goto-char start) (org-open-link-from-string link)
 477       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 478           (org-babel-next-src-block
 479            (string-to-number (match-string 1 block-name)))
 480         (org-babel-goto-named-src-block block-name))
 481       (setq target-char (point)))
 482     (pop-to-buffer target-buffer)
 483     (prog1 body (goto-char target-char))))
 484
 485 (provide 'ob-tangle)
 486
 487 ;; arch-tag: 413ced93-48f5-4216-86e4-3fc5df8c8f24
 488
 489 ;;; ob-tangle.el ends here