lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004-2011 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg AT gnu DOT org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile
  38   (require 'cl))
  39
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-at-table.el-p "org" ())
  42 (declare-function org-get-indentation "org" (&optional line))
  43 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  44 (declare-function org-pop-to-buffer-same-window
  45                   "org-compat" (&optional buffer-or-name norecord label))
  46
  47 (defcustom org-edit-src-region-extra nil
  48   "Additional regexps to identify regions for editing with `org-edit-src-code'.
  49 For examples see the function `org-edit-src-find-region-and-lang'.
  50 The regular expression identifying the begin marker should end with a newline,
  51 and the regexp marking the end line should start with a newline, to make sure
  52 there are kept outside the narrowed region."
  53   :group 'org-edit-structure
  54   :type '(repeat
  55           (list
  56            (regexp :tag "begin regexp")
  57            (regexp :tag "end regexp")
  58            (choice :tag "language"
  59                    (string :tag "specify")
  60                    (integer :tag "from match group")
  61                    (const :tag "from `lang' element")
  62                    (const :tag "from `style' element")))))
  63
  64 (defcustom org-coderef-label-format "(ref:%s)"
  65   "The default coderef format.
  66 This format string will be used to search for coderef labels in literal
  67 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  68 an individual literal example with the -l option, like
  69
  70 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  71 ...
  72 #+END_SRC
  73
  74 If you want to use this for HTML export, make sure that the format does
  75 not introduce special font-locking, and avoid the HTML special
  76 characters `<', `>', and `&'.  The reason for this restriction is that
  77 the labels are searched for only after htmlize has done its job."
  78   :group 'org-edit-structure ; FIXME this is not in the right group
  79   :type 'string)
  80
  81 (defcustom org-edit-fixed-width-region-mode 'artist-mode
  82   "The mode that should be used to edit fixed-width regions.
  83 These are the regions where each line starts with a colon."
  84   :group 'org-edit-structure
  85   :type '(choice
  86           (const artist-mode)
  87           (const picture-mode)
  88           (const fundamental-mode)
  89           (function :tag "Other (specify)")))
  90
  91 (defcustom org-src-preserve-indentation nil
  92   "If non-nil preserve leading whitespace characters on export.
  93 If non-nil leading whitespace characters in source code blocks
  94 are preserved on export, and when switching between the org
  95 buffer and the language mode edit buffer.  If this variable is nil
  96 then, after editing with \\[org-edit-src-code], the
  97 minimum (across-lines) number of leading whitespace characters
  98 are removed from all lines, and the code block is uniformly
  99 indented according to the value of `org-edit-src-content-indentation'."
 100   :group 'org-edit-structure
 101   :type 'boolean)
 102
 103 (defcustom org-edit-src-content-indentation 2
 104   "Indentation for the content of a source code block.
 105 This should be the number of spaces added to the indentation of the #+begin
 106 line in order to compute the indentation of the block content after
 107 editing it with \\[org-edit-src-code].  Has no effect if
 108 `org-src-preserve-indentation' is non-nil."
 109   :group 'org-edit-structure
 110   :type 'integer)
 111
 112 (defvar org-src-strip-leading-and-trailing-blank-lines nil
 113   "If non-nil, blank lines are removed when exiting the code edit
 114 buffer.")
 115
 116 (defcustom org-edit-src-persistent-message t
 117   "Non-nil means show persistent exit help message while editing src examples.
 118 The message is shown in the header-line, which will be created in the
 119 first line of the window showing the editing buffer."
 120   :group 'org-edit-structure
 121   :type 'boolean)
 122
 123 (defcustom org-src-window-setup 'reorganize-frame
 124   "How the source code edit buffer should be displayed.
 125 Possible values for this option are:
 126
 127 current-window    Show edit buffer in the current window, keeping all other
 128                   windows.
 129 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 130 reorganize-frame  Show only two windows on the current frame, the current
 131                   window and the edit buffer. When exiting the edit buffer,
 132                   return to one window.
 133 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 134                   Also, when exiting the edit buffer, kill that frame."
 135   :group 'org-edit-structure
 136   :type '(choice
 137           (const current-window)
 138           (const other-frame)
 139           (const other-window)
 140           (const reorganize-frame)))
 141
 142 (defvar org-src-mode-hook nil
 143   "Hook  run after Org switched a source code snippet to its Emacs mode.
 144 This hook will run
 145
 146 - when editing a source code snippet with \"C-c '\".
 147 - When formatting a source code snippet for export with htmlize.
 148
 149 You may want to use this hook for example to turn off `outline-minor-mode'
 150 or similar things which you want to have when editing a source code file,
 151 but which mess up the display of a snippet in Org exported files.")
 152
 153 (defcustom org-src-lang-modes
 154   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 155     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 156     ("calc" . fundamental) ("C" . c) ("cpp" . c++)
 157     ("screen" . shell-script))
 158   "Alist mapping languages to their major mode.
 159 The key is the language name, the value is the string that should
 160 be inserted as the name of the major mode.  For many languages this is
 161 simple, but for language where this is not the case, this variable
 162 provides a way to simplify things on the user side.
 163 For example, there is no ocaml-mode in Emacs, but the mode to use is
 164 `tuareg-mode'."
 165   :group 'org-edit-structure
 166   :type '(repeat
 167           (cons
 168            (string "Language name")
 169            (symbol "Major mode"))))
 170
 171 ;;; Editing source examples
 172
 173 (defvar org-src-mode-map (make-sparse-keymap))
 174 (define-key org-src-mode-map "\C-c'" 'org-edit-src-exit)
 175
 176 (defvar org-edit-src-force-single-line nil)
 177 (defvar org-edit-src-from-org-mode nil)
 178 (defvar org-edit-src-allow-write-back-p t)
 179 (defvar org-edit-src-picture nil)
 180 (defvar org-edit-src-beg-marker nil)
 181 (defvar org-edit-src-end-marker nil)
 182 (defvar org-edit-src-overlay nil)
 183 (defvar org-edit-src-block-indentation nil)
 184 (defvar org-edit-src-saved-temp-window-config nil)
 185
 186 (defvar org-src-ask-before-returning-to-edit-buffer t
 187   "If nil, when org-edit-src code is used on a block that already
 188   has an active edit buffer, it will switch to that edit buffer
 189   immediately; otherwise it will ask whether you want to return
 190   to the existing edit buffer.")
 191
 192 (defvar org-src-babel-info nil)
 193
 194 (define-minor-mode org-src-mode
 195   "Minor mode for language major mode buffers generated by org.
 196 This minor mode is turned on in two situations:
 197 - when editing a source code snippet with \"C-c '\".
 198 - When formatting a source code snippet for export with htmlize.
 199 There is a mode hook, and keybindings for `org-edit-src-exit' and
 200 `org-edit-src-save'")
 201
 202 (defun org-edit-src-code (&optional context code edit-buffer-name)
 203   "Edit the source code example at point.
 204 The example is copied to a separate buffer, and that buffer is
 205 switched to the correct language mode.  When done, exit with
 206 \\[org-edit-src-exit].  This will remove the original code in the
 207 Org buffer, and replace it with the edited version. Optional
 208 argument CONTEXT is used by \\[org-edit-src-save] when calling
 209 this function. See \\[org-src-window-setup] to configure the
 210 display of windows containing the Org buffer and the code
 211 buffer."
 212   (interactive)
 213   (unless (eq context 'save)
 214     (setq org-edit-src-saved-temp-window-config (current-window-configuration)))
 215   (let ((mark (and (org-region-active-p) (mark)))
 216         (case-fold-search t)
 217         (info (org-edit-src-find-region-and-lang))
 218         (full-info (org-babel-get-src-block-info 'light))
 219         (org-mode-p (derived-mode-p 'org-mode)) ;; derived-mode-p is reflexive
 220         (beg (make-marker))
 221         (end (make-marker))
 222         (allow-write-back-p (null code))
 223         block-nindent total-nindent ovl lang lang-f single lfmt buffer msg
 224         begline markline markcol line col transmitted-variables)
 225     (if (not info)
 226         nil
 227       (setq beg (move-marker beg (nth 0 info))
 228             end (move-marker end (nth 1 info))
 229             msg (if allow-write-back-p
 230                     (substitute-command-keys
 231                      "Edit, then exit with C-c ' (C-c and single quote)")
 232                   "Exit with C-c ' (C-c and single quote)")
 233             code (or code (buffer-substring-no-properties beg end))
 234             lang (or (cdr (assoc (nth 2 info) org-src-lang-modes))
 235                      (nth 2 info))
 236             lang (if (symbolp lang) (symbol-name lang) lang)
 237             single (nth 3 info)
 238             block-nindent (nth 5 info)
 239             lang-f (intern (concat lang "-mode"))
 240             begline (save-excursion (goto-char beg) (org-current-line))
 241             transmitted-variables
 242             `((org-edit-src-content-indentation
 243                ,org-edit-src-content-indentation)
 244               (org-edit-src-force-single-line ,single)
 245               (org-edit-src-from-org-mode ,org-mode-p)
 246               (org-edit-src-allow-write-back-p ,allow-write-back-p)
 247               (org-src-preserve-indentation ,org-src-preserve-indentation)
 248               (org-src-babel-info ,(org-babel-get-src-block-info 'light))
 249               (org-coderef-label-format
 250                ,(or (nth 4 info) org-coderef-label-format))
 251               (org-edit-src-beg-marker ,beg)
 252               (org-edit-src-end-marker ,end)
 253               (org-edit-src-block-indentation ,block-nindent)))
 254       (if (and mark (>= mark beg) (<= mark (1+ end)))
 255           (save-excursion (goto-char (min mark end))
 256                           (setq markline (org-current-line)
 257                                 markcol (current-column))))
 258       (if (equal lang-f 'table.el-mode)
 259           (setq lang-f (lambda ()
 260                          (text-mode)
 261                          (if (org-bound-and-true-p flyspell-mode)
 262                              (flyspell-mode -1))
 263                          (table-recognize)
 264                          (org-set-local 'org-edit-src-content-indentation 0))))
 265       (unless (functionp lang-f)
 266         (error "No such language mode: %s" lang-f))
 267       (save-excursion
 268         (if (> (point) end) (goto-char end))
 269         (setq line (org-current-line)
 270               col (current-column)))
 271       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 272                (if org-src-ask-before-returning-to-edit-buffer
 273                    (y-or-n-p "Return to existing edit buffer? [n] will revert changes: ") t))
 274           (org-src-switch-to-buffer buffer 'return)
 275         (when buffer
 276           (with-current-buffer buffer
 277             (if (boundp 'org-edit-src-overlay)
 278                 (delete-overlay org-edit-src-overlay)))
 279           (kill-buffer buffer))
 280         (setq buffer (generate-new-buffer
 281                       (or edit-buffer-name
 282                           (org-src-construct-edit-buffer-name (buffer-name) lang))))
 283         (setq ovl (make-overlay beg end))
 284         (overlay-put ovl 'edit-buffer buffer)
 285         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 286         (overlay-put ovl 'face 'secondary-selection)
 287         (overlay-put ovl
 288                      'keymap
 289                      (let ((map (make-sparse-keymap)))
 290                        (define-key map [mouse-1] 'org-edit-src-continue)
 291                        map))
 292         (overlay-put ovl :read-only "Leave me alone")
 293         (setq transmitted-variables
 294               (append transmitted-variables `((org-edit-src-overlay ,ovl))))
 295         (org-src-switch-to-buffer buffer 'edit)
 296         (if (eq single 'macro-definition)
 297             (setq code (replace-regexp-in-string "\\\\n" "\n" code t t)))
 298         (insert code)
 299         (remove-text-properties (point-min) (point-max)
 300                                 '(display nil invisible nil intangible nil))
 301         (unless (cadr (assq 'org-src-preserve-indentation transmitted-variables))
 302           (setq total-nindent (or (org-do-remove-indentation) 0)))
 303         (let ((org-inhibit-startup t))
 304           (condition-case e
 305               (funcall lang-f)
 306             (error
 307              (error "Language mode `%s' fails with: %S" lang-f (nth 1 e)))))
 308         (dolist (pair transmitted-variables)
 309           (org-set-local (car pair) (cadr pair)))
 310         (if (eq major-mode 'org-mode)
 311             (progn
 312               (goto-char (point-min))
 313               (while (re-search-forward "^," nil t)
 314                 (if (eq (org-current-line) line) (setq total-nindent (1+ total-nindent)))
 315                 (replace-match "")))
 316           (org-strip-protective-commas (point-min) (point-max)))
 317         (when markline
 318           (org-goto-line (1+ (- markline begline)))
 319           (org-move-to-column
 320            (if org-src-preserve-indentation markcol
 321              (max 0 (- markcol total-nindent))))
 322           (push-mark (point) 'no-message t)
 323           (setq deactivate-mark nil))
 324         (org-goto-line (1+ (- line begline)))
 325         (org-move-to-column
 326          (if org-src-preserve-indentation col (max 0 (- col total-nindent))))
 327         (org-src-mode)
 328         (set-buffer-modified-p nil)
 329         (and org-edit-src-persistent-message
 330              (org-set-local 'header-line-format msg))
 331         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 332           (when (fboundp edit-prep-func)
 333             (funcall edit-prep-func full-info))))
 334       t)))
 335
 336 (defun org-edit-src-continue (e)
 337   (interactive "e")
 338   (mouse-set-point e)
 339   (let ((buf (get-char-property (point) 'edit-buffer)))
 340     (if buf (org-src-switch-to-buffer buf 'continue)
 341       (error "Something is wrong here"))))
 342
 343 (defun org-src-switch-to-buffer (buffer context)
 344   (case org-src-window-setup
 345     ('current-window
 346      (org-pop-to-buffer-same-window buffer))
 347     ('other-window
 348      (switch-to-buffer-other-window buffer))
 349     ('other-frame
 350      (case context
 351        ('exit
 352         (let ((frame (selected-frame)))
 353           (switch-to-buffer-other-frame buffer)
 354           (delete-frame frame)))
 355        ('save
 356         (kill-buffer (current-buffer))
 357         (org-pop-to-buffer-same-window buffer))
 358        (t
 359         (switch-to-buffer-other-frame buffer))))
 360     ('reorganize-frame
 361      (if (eq context 'edit) (delete-other-windows))
 362      (org-switch-to-buffer-other-window buffer)
 363      (if (eq context 'exit) (delete-other-windows)))
 364     ('switch-invisibly
 365      (set-buffer buffer))
 366     (t
 367      (message "Invalid value %s for org-src-window-setup"
 368               (symbol-name org-src-window-setup))
 369      (org-pop-to-buffer-same-window buffer))))
 370
 371 (defun org-src-construct-edit-buffer-name (org-buffer-name lang)
 372   "Construct the buffer name for a source editing buffer."
 373   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 374
 375 (defun org-edit-src-find-buffer (beg end)
 376   "Find a source editing buffer that is already editing the region BEG to END."
 377   (catch 'exit
 378     (mapc
 379      (lambda (b)
 380        (with-current-buffer b
 381          (if (and (string-match "\\`*Org Src " (buffer-name))
 382                   (local-variable-p 'org-edit-src-beg-marker (current-buffer))
 383                   (local-variable-p 'org-edit-src-end-marker (current-buffer))
 384                   (equal beg org-edit-src-beg-marker)
 385                   (equal end org-edit-src-end-marker))
 386              (throw 'exit (current-buffer)))))
 387      (buffer-list))
 388     nil))
 389
 390 (defun org-edit-fixed-width-region ()
 391   "Edit the fixed-width ascii drawing at point.
 392 This must be a region where each line starts with a colon followed by
 393 a space character.
 394 An new buffer is created and the fixed-width region is copied into it,
 395 and the buffer is switched into `artist-mode' for editing.  When done,
 396 exit with \\[org-edit-src-exit].  The edited text will then replace
 397 the fragment in the Org-mode buffer."
 398   (interactive)
 399   (let ((line (org-current-line))
 400         (col (current-column))
 401         (case-fold-search t)
 402         (msg (substitute-command-keys
 403               "Edit, then exit with C-c ' (C-c and single quote)"))
 404         (org-mode-p (eq major-mode 'org-mode))
 405         (beg (make-marker))
 406         (end (make-marker))
 407         (preserve-indentation org-src-preserve-indentation)
 408         block-nindent ovl beg1 end1 code begline buffer)
 409     (beginning-of-line 1)
 410     (if (looking-at "[ \t]*[^:\n \t]")
 411         nil
 412       (if (looking-at "[ \t]*\\(\n\\|\\'\\)")
 413           (setq beg1 (point) end1 beg1)
 414         (save-excursion
 415           (if (re-search-backward "^[ \t]*[^: \t]" nil 'move)
 416               (setq beg1 (point-at-bol 2))
 417             (setq beg1 (point))))
 418         (save-excursion
 419           (if (re-search-forward "^[ \t]*[^: \t]" nil 'move)
 420               (setq end1 (1- (match-beginning 0)))
 421             (setq end1 (point))))
 422         (org-goto-line line))
 423       (setq beg (move-marker beg beg1)
 424             end (move-marker end end1)
 425             code (buffer-substring-no-properties beg end)
 426             begline (save-excursion (goto-char beg) (org-current-line)))
 427       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 428                (y-or-n-p "Return to existing edit buffer? [n] will revert changes: "))
 429           (org-pop-to-buffer-same-window buffer)
 430         (when buffer
 431           (with-current-buffer buffer
 432             (if (boundp 'org-edit-src-overlay)
 433                 (delete-overlay org-edit-src-overlay)))
 434           (kill-buffer buffer))
 435         (setq buffer (generate-new-buffer
 436                       (org-src-construct-edit-buffer-name
 437                        (buffer-name) "Fixed Width")))
 438         (setq ovl (make-overlay beg end))
 439         (overlay-put ovl 'face 'secondary-selection)
 440         (overlay-put ovl 'edit-buffer buffer)
 441         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 442         (overlay-put ovl 'face 'secondary-selection)
 443         (overlay-put ovl
 444                          'keymap
 445                          (let ((map (make-sparse-keymap)))
 446                            (define-key map [mouse-1] 'org-edit-src-continue)
 447                            map))
 448         (overlay-put ovl :read-only "Leave me alone")
 449         (org-pop-to-buffer-same-window buffer)
 450         (insert code)
 451         (remove-text-properties (point-min) (point-max)
 452                                 '(display nil invisible nil intangible nil))
 453         (setq block-nindent (or (org-do-remove-indentation) 0))
 454         (cond
 455          ((eq org-edit-fixed-width-region-mode 'artist-mode)
 456           (fundamental-mode)
 457           (artist-mode 1))
 458          (t (funcall org-edit-fixed-width-region-mode)))
 459         (set (make-local-variable 'org-edit-src-force-single-line) nil)
 460         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 461         (set (make-local-variable 'org-edit-src-picture) t)
 462         (goto-char (point-min))
 463         (while (re-search-forward "^[ \t]*: ?" nil t)
 464           (replace-match ""))
 465         (org-goto-line (1+ (- line begline)))
 466         (org-move-to-column (max 0 (- col block-nindent 2)))
 467         (org-set-local 'org-edit-src-beg-marker beg)
 468         (org-set-local 'org-edit-src-end-marker end)
 469         (org-set-local 'org-edit-src-overlay ovl)
 470         (org-set-local 'org-edit-src-block-indentation block-nindent)
 471         (org-set-local 'org-edit-src-content-indentation 0)
 472         (org-set-local 'org-src-preserve-indentation nil)
 473         (org-src-mode)
 474         (set-buffer-modified-p nil)
 475         (and org-edit-src-persistent-message
 476              (org-set-local 'header-line-format msg)))
 477       (message "%s" msg)
 478       t)))
 479
 480 (defun org-edit-src-find-region-and-lang ()
 481   "Find the region and language for a local edit.
 482 Return a list with beginning and end of the region, a string representing
 483 the language, a switch telling if the content should be in a single line."
 484   (let ((re-list
 485          (append
 486           org-edit-src-region-extra
 487           '(
 488             ("<src\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</src>" lang)
 489             ("<literal\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</literal>" style)
 490             ("<example>[ \t]*\n?" "\n?[ \t]*</example>" "fundamental")
 491             ("<lisp>[ \t]*\n?" "\n?[ \t]*</lisp>" "emacs-lisp")
 492             ("<perl>[ \t]*\n?" "\n?[ \t]*</perl>" "perl")
 493             ("<python>[ \t]*\n?" "\n?[ \t]*</python>" "python")
 494             ("<ruby>[ \t]*\n?" "\n?[ \t]*</ruby>" "ruby")
 495             ("^[ \t]*#\\+begin_src\\( \\([^ \t\n]+\\)\\)?.*\n" "\n[ \t]*#\\+end_src" 2)
 496             ("^[ \t]*#\\+begin_example.*\n" "\n[ \t]*#\\+end_example" "fundamental")
 497             ("^[ \t]*#\\+html:" "\n" "html" single-line)
 498             ("^[ \t]*#\\+begin_html.*\n" "\n[ \t]*#\\+end_html" "html")
 499             ("^[ \t]*#\\+latex:" "\n" "latex" single-line)
 500             ("^[ \t]*#\\+begin_latex.*\n" "\n[ \t]*#\\+end_latex" "latex")
 501             ("^[ \t]*#\\+ascii:" "\n" "fundamental" single-line)
 502             ("^[ \t]*#\\+begin_ascii.*\n" "\n[ \t]*#\\+end_ascii" "fundamental")
 503             ("^[ \t]*#\\+docbook:" "\n" "xml" single-line)
 504             ("^[ \t]*#\\+macro:[ \t]+\\S-+\\( \\|$\\)"
 505              "\n" "fundamental" macro-definition)
 506             ("^[ \t]*#\\+begin_docbook.*\n" "\n[ \t]*#\\+end_docbook" "xml")
 507             )))
 508         (pos (point))
 509         re1 re2 single beg end lang lfmt match-re1 ind entry)
 510     (catch 'exit
 511       (while (setq entry (pop re-list))
 512         (setq re1 (car entry) re2 (nth 1 entry) lang (nth 2 entry)
 513               single (nth 3 entry))
 514         (save-excursion
 515           (if (or (looking-at re1)
 516                   (re-search-backward re1 nil t))
 517               (progn
 518                 (setq match-re1 (match-string 0))
 519                 (setq beg (match-end 0)
 520                       lang (org-edit-src-get-lang lang)
 521                       lfmt (org-edit-src-get-label-format match-re1)
 522                       ind (org-edit-src-get-indentation (match-beginning 0)))
 523                 (if (and (re-search-forward re2 nil t)
 524                          (>= (match-end 0) pos))
 525                     (throw 'exit (list beg (match-beginning 0)
 526                                        lang single lfmt ind))))
 527             (if (or (looking-at re2)
 528                     (re-search-forward re2 nil t))
 529                 (progn
 530                   (setq end (match-beginning 0))
 531                   (if (and (re-search-backward re1 nil t)
 532                            (<= (match-beginning 0) pos))
 533                       (progn
 534                         (setq lfmt (org-edit-src-get-label-format
 535                                     (match-string 0))
 536                               ind (org-edit-src-get-indentation
 537                                    (match-beginning 0)))
 538                         (throw 'exit
 539                                (list (match-end 0) end
 540                                      (org-edit-src-get-lang lang)
 541                                      single lfmt ind)))))))))
 542       (when (org-at-table.el-p)
 543         (re-search-backward "^[\t]*[^ \t|\\+]" nil t)
 544         (setq beg (1+ (point-at-eol)))
 545         (goto-char beg)
 546         (or (re-search-forward "^[\t]*[^ \t|\\+]" nil t)
 547             (progn (goto-char (point-max)) (newline)))
 548         (setq end (point-at-bol))
 549         (setq ind (org-edit-src-get-indentation beg))
 550         (throw 'exit (list beg end 'table.el nil nil ind))))))
 551
 552 (defun org-edit-src-get-lang (lang)
 553   "Extract the src language."
 554   (let ((m (match-string 0)))
 555     (cond
 556      ((stringp lang) lang)
 557      ((integerp lang) (match-string lang))
 558      ((and (eq lang 'lang)
 559            (string-match "\\<lang=\"\\([^ \t\n\"]+\\)\"" m))
 560       (match-string 1 m))
 561      ((and (eq lang 'style)
 562            (string-match "\\<style=\"\\([^ \t\n\"]+\\)\"" m))
 563       (match-string 1 m))
 564      (t "fundamental"))))
 565
 566 (defun org-edit-src-get-label-format (s)
 567   "Extract the label format."
 568   (save-match-data
 569     (if (string-match "-l[ \t]+\\\\?\"\\([^\t\r\n\"]+\\)\\\\?\"" s)
 570         (match-string 1 s))))
 571
 572 (defun org-edit-src-get-indentation (pos)
 573   "Count leading whitespace characters on line."
 574   (save-match-data
 575     (goto-char pos)
 576     (org-get-indentation)))
 577
 578 (defun org-edit-src-exit (&optional context)
 579   "Exit special edit and protect problematic lines."
 580   (interactive)
 581   (unless (org-bound-and-true-p org-edit-src-from-org-mode)
 582     (error "This is not a sub-editing buffer, something is wrong"))
 583   (widen)
 584   (let* ((beg org-edit-src-beg-marker)
 585          (end org-edit-src-end-marker)
 586          (ovl org-edit-src-overlay)
 587          (buffer (current-buffer))
 588          (single (org-bound-and-true-p org-edit-src-force-single-line))
 589          (macro (eq single 'macro-definition))
 590          (total-nindent (+ (or org-edit-src-block-indentation 0)
 591                            org-edit-src-content-indentation))
 592          (preserve-indentation org-src-preserve-indentation)
 593          (allow-write-back-p (org-bound-and-true-p org-edit-src-allow-write-back-p))
 594          (delta 0) code line col indent)
 595     (when allow-write-back-p
 596       (unless preserve-indentation (untabify (point-min) (point-max)))
 597       (if org-src-strip-leading-and-trailing-blank-lines
 598           (save-excursion
 599             (goto-char (point-min))
 600             (if (looking-at "[ \t\n]*\n") (replace-match ""))
 601             (unless macro
 602               (if (re-search-forward "\n[ \t\n]*\\'" nil t) (replace-match ""))))))
 603     (setq line (if (org-bound-and-true-p org-edit-src-force-single-line)
 604                    1
 605                  (org-current-line))
 606           col (current-column))
 607     (when allow-write-back-p
 608       (when single
 609         (goto-char (point-min))
 610         (if (re-search-forward "\\s-+\\'" nil t) (replace-match ""))
 611         (goto-char (point-min))
 612         (let ((cnt 0))
 613           (while (re-search-forward "\n" nil t)
 614             (setq cnt (1+ cnt))
 615             (replace-match (if macro "\\n" " ") t t))
 616           (when (and macro (> cnt 0))
 617             (goto-char (point-max)) (insert "\\n")))
 618         (goto-char (point-min))
 619         (if (looking-at "\\s-*") (replace-match " ")))
 620       (when (org-bound-and-true-p org-edit-src-from-org-mode)
 621         (goto-char (point-min))
 622         (while (re-search-forward
 623                 (if (eq major-mode 'org-mode) "^\\(.\\)" "^\\([*]\\|[ \t]*#\\+\\)") nil t)
 624           (if (eq (org-current-line) line) (setq delta (1+ delta)))
 625           (replace-match ",\\1")))
 626       (when (org-bound-and-true-p org-edit-src-picture)
 627         (setq preserve-indentation nil)
 628         (untabify (point-min) (point-max))
 629         (goto-char (point-min))
 630         (while (re-search-forward "^" nil t)
 631           (replace-match ": ")))
 632       (unless (or single preserve-indentation (= total-nindent 0))
 633         (setq indent (make-string total-nindent ?\ ))
 634         (goto-char (point-min))
 635         (while (re-search-forward "^" nil t)
 636           (replace-match indent)))
 637       (if (org-bound-and-true-p org-edit-src-picture)
 638           (setq total-nindent (+ total-nindent 2)))
 639       (setq code (buffer-string))
 640       (set-buffer-modified-p nil))
 641     (org-src-switch-to-buffer (marker-buffer beg) (or context 'exit))
 642     (kill-buffer buffer)
 643     (goto-char beg)
 644     (when allow-write-back-p
 645       (delete-region beg end)
 646       (insert code)
 647       (goto-char beg)
 648       (if single (just-one-space)))
 649     (if (memq t (mapcar (lambda (overlay)
 650                           (eq (overlay-get overlay 'invisible)
 651                               'org-hide-block))
 652                         (overlays-at (point))))
 653         ;; Block is hidden; put point at start of block
 654         (beginning-of-line 0)
 655       ;; Block is visible, put point where it was in the code buffer
 656       (org-goto-line (1- (+ (org-current-line) line)))
 657       (org-move-to-column (if preserve-indentation col (+ col total-nindent delta))))
 658     (move-marker beg nil)
 659     (move-marker end nil))
 660   (unless (eq context 'save)
 661     (when org-edit-src-saved-temp-window-config
 662       (set-window-configuration org-edit-src-saved-temp-window-config)
 663       (setq org-edit-src-saved-temp-window-config nil))))
 664
 665 (defun org-edit-src-save ()
 666   "Save parent buffer with current state source-code buffer."
 667   (interactive)
 668   (let ((p (point)) (m (mark)) msg)
 669     (save-window-excursion
 670       (org-edit-src-exit 'save)
 671       (save-buffer)
 672       (setq msg (current-message))
 673       (if (eq org-src-window-setup 'other-frame)
 674           (let ((org-src-window-setup 'current-window))
 675             (org-edit-src-code 'save))
 676         (org-edit-src-code 'save)))
 677     (push-mark m 'nomessage)
 678     (goto-char (min p (point-max)))
 679     (message (or msg ""))))
 680
 681 (defun org-src-mode-configure-edit-buffer ()
 682   (when (org-bound-and-true-p org-edit-src-from-org-mode)
 683     (org-add-hook 'kill-buffer-hook
 684                   #'(lambda () (delete-overlay org-edit-src-overlay)) nil 'local)
 685     (if (org-bound-and-true-p org-edit-src-allow-write-back-p)
 686         (progn
 687           (setq buffer-offer-save t)
 688           (setq buffer-file-name
 689                 (concat (buffer-file-name (marker-buffer org-edit-src-beg-marker))
 690                         "[" (buffer-name) "]"))
 691           (if (featurep 'xemacs)
 692               (progn
 693                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 694                 (setq write-contents-hooks '(org-edit-src-save)))
 695             (setq write-contents-functions '(org-edit-src-save))))
 696       (setq buffer-read-only t))))
 697
 698 (org-add-hook 'org-src-mode-hook 'org-src-mode-configure-edit-buffer)
 699
 700
 701 (defun org-src-associate-babel-session (info)
 702   "Associate edit buffer with comint session."
 703   (interactive)
 704   (let ((session (cdr (assoc :session (nth 2 info)))))
 705     (and session (not (string= session "none"))
 706          (org-babel-comint-buffer-livep session)
 707          ((lambda (f) (and (fboundp f) (funcall f session)))
 708           (intern (format "org-babel-%s-associate-session" (nth 0 info)))))))
 709
 710 (defun org-src-babel-configure-edit-buffer ()
 711   (when org-src-babel-info
 712     (org-src-associate-babel-session org-src-babel-info)))
 713
 714 (org-add-hook 'org-src-mode-hook 'org-src-babel-configure-edit-buffer)
 715 (defmacro org-src-do-at-code-block (&rest body)
 716   "Execute a command from an edit buffer in the Org-mode buffer."
 717   `(let ((beg-marker org-edit-src-beg-marker))
 718      (if beg-marker
 719          (with-current-buffer (marker-buffer beg-marker)
 720            (goto-char (marker-position beg-marker))
 721            ,@body))))
 722 (def-edebug-spec org-src-do-at-code-block (body))
 723
 724 (defun org-src-do-key-sequence-at-code-block (&optional key)
 725   "Execute key sequence at code block in the source Org buffer.
 726 The command bound to KEY in the Org-babel key map is executed
 727 remotely with point temporarily at the start of the code block in
 728 the Org buffer.
 729
 730 This command is not bound to a key by default, to avoid conflicts
 731 with language major mode bindings. To bind it to C-c @ in all
 732 language major modes, you could use
 733
 734   (add-hook 'org-src-mode-hook
 735             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 736                     'org-src-do-key-sequence-at-code-block)))
 737
 738 In that case, for example, C-c @ t issued in code edit buffers
 739 would tangle the current Org code block, C-c @ e would execute
 740 the block and C-c @ h would display the other available
 741 Org-babel commands."
 742   (interactive "kOrg-babel key: ")
 743   (if (equal key (kbd "C-g")) (keyboard-quit)
 744     (org-edit-src-save)
 745     (org-src-do-at-code-block
 746      (call-interactively
 747       (lookup-key org-babel-map key)))))
 748
 749 (defcustom org-src-tab-acts-natively nil
 750   "If non-nil, the effect of TAB in a code block is as if it were
 751 issued in the language major mode buffer."
 752   :type 'boolean
 753   :group 'org-babel)
 754
 755 (defun org-src-native-tab-command-maybe ()
 756   "Perform language-specific TAB action.
 757 Alter code block according to effect of TAB in the language major
 758 mode."
 759   (and org-src-tab-acts-natively
 760        (let ((org-src-strip-leading-and-trailing-blank-lines nil))
 761          (org-babel-do-key-sequence-in-edit-buffer (kbd "TAB")))))
 762
 763 (add-hook 'org-tab-first-hook 'org-src-native-tab-command-maybe)
 764
 765 (defun org-src-font-lock-fontify-block (lang start end)
 766   "Fontify code block.
 767 This function is called by emacs automatic fontification, as long
 768 as `org-src-fontify-natively' is non-nil. For manual
 769 fontification of code blocks see `org-src-fontify-block' and
 770 `org-src-fontify-buffer'"
 771   (let ((lang-mode (org-src-get-lang-mode lang)))
 772     (if (fboundp lang-mode)
 773         (let ((string (buffer-substring-no-properties start end))
 774               (modified (buffer-modified-p))
 775               (org-buffer (current-buffer)) pos next)
 776           (remove-text-properties start end '(face nil))
 777           (with-current-buffer
 778               (get-buffer-create
 779                (concat " org-src-fontification:" (symbol-name lang-mode)))
 780             (delete-region (point-min) (point-max))
 781             (insert (concat string " ")) ;; so there's a final property change
 782             (unless (eq major-mode lang-mode) (funcall lang-mode))
 783             (font-lock-fontify-buffer)
 784             (setq pos (point-min))
 785             (while (setq next (next-single-property-change pos 'face))
 786               (put-text-property
 787                (+ start (1- pos)) (+ start next) 'face
 788                (get-text-property pos 'face) org-buffer)
 789               (setq pos next)))
 790           (add-text-properties
 791            start end
 792            '(font-lock-fontified t fontified t font-lock-multiline t))
 793           (set-buffer-modified-p modified)))))
 794
 795 (defun org-src-fontify-block ()
 796   "Fontify code block at point."
 797   (interactive)
 798   (save-excursion
 799     (let ((org-src-fontify-natively t)
 800           (info (org-edit-src-find-region-and-lang)))
 801       (font-lock-fontify-region (nth 0 info) (nth 1 info)))))
 802
 803 (defun org-src-fontify-buffer ()
 804   "Fontify all code blocks in the current buffer"
 805   (interactive)
 806   (org-babel-map-src-blocks nil
 807     (org-src-fontify-block)))
 808
 809 (defun org-src-get-lang-mode (lang)
 810   "Return major mode that should be used for LANG.
 811 LANG is a string, and the returned major mode is a symbol."
 812   (intern
 813    (concat
 814     ((lambda (l) (if (symbolp l) (symbol-name l) l))
 815      (or (cdr (assoc lang org-src-lang-modes)) lang)) "-mode")))
 816
 817 (provide 'org-src)
 818
 819 ;;; org-src.el ends here