lisp/ob-emacs-lisp.el

   1 ;;; ob-emacs-lisp.el --- org-babel functions for emacs-lisp code evaluation
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating emacs-lisp code
  27
  28 ;;; Code:
  29 (require 'ob)
  30
  31 (defvar org-babel-default-header-args:emacs-lisp nil
  32   "Default arguments for evaluating an emacs-lisp source block.")
  33
  34 (declare-function orgtbl-to-generic "org-table" (table params))
  35
  36 (defun org-babel-expand-body:emacs-lisp (body params)
  37   "Expand BODY according to PARAMS, return the expanded body."
  38   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  39          (result-params (cdr (assoc :result-params params)))
  40          (print-level nil) (print-length nil)
  41          (body (if (> (length vars) 0)
  42                    (concat "(let ("
  43                            (mapconcat
  44                             (lambda (var)
  45                               (format "%S" (print `(,(car var) ',(cdr var)))))
  46                             vars "\n      ")
  47                            ")\n" body "\n)")
  48                  (concat body "\n"))))
  49     (if (or (member "code" result-params)
  50             (member "pp" result-params))
  51         (concat "(pp " body ")") body)))
  52
  53 (defun org-babel-execute:emacs-lisp (body params)
  54   "Execute a block of emacs-lisp code with Babel."
  55   (save-window-excursion
  56     (let ((result
  57            (eval (read (format (if (member "output"
  58                                            (cdr (assoc :result-params params)))
  59                                    "(with-output-to-string %s)"
  60                                  "(progn %s)")
  61                                (org-babel-expand-body:emacs-lisp
  62                                 body params))))))
  63       (org-babel-result-cond (cdr (assoc :result-params params))
  64         (let ((print-level nil)
  65               (print-length nil))
  66           (if (or (member "scalar" (cdr (assoc :result-params params)))
  67                   (member "verbatim" (cdr (assoc :result-params params))))
  68               (format "%S" result)
  69             (format "%s" result)))
  70         (org-babel-reassemble-table
  71          result
  72          (org-babel-pick-name (cdr (assoc :colname-names params))
  73                               (cdr (assoc :colnames params)))
  74          (org-babel-pick-name (cdr (assoc :rowname-names params))
  75                               (cdr (assoc :rownames params))))))))
  76
  77 (provide 'ob-emacs-lisp)
  78
  79
  80
  81 ;;; ob-emacs-lisp.el ends here