lisp/ob-C.el

   1 ;;; ob-C.el --- org-babel functions for C and similar languages
   2
   3 ;; Copyright (C) 2010-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating C code.
  27 ;;
  28 ;; very limited implementation:
  29 ;; - currently only support :results output
  30 ;; - not much in the way of error feedback
  31
  32 ;;; Code:
  33 (require 'ob)
  34 (require 'ob-eval)
  35 (require 'cc-mode)
  36
  37 (declare-function org-entry-get "org"
  38                   (pom property &optional inherit literal-nil))
  39
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("C++" . "cpp"))
  43
  44 (defvar org-babel-default-header-args:C '())
  45
  46 (defvar org-babel-C-compiler "gcc"
  47   "Command used to compile a C source code file into an
  48   executable.")
  49
  50 (defvar org-babel-C++-compiler "g++"
  51   "Command used to compile a C++ source code file into an
  52   executable.")
  53
  54 (defvar org-babel-c-variant nil
  55   "Internal variable used to hold which type of C (e.g. C or C++)
  56 is currently being evaluated.")
  57
  58 (defun org-babel-execute:cpp (body params)
  59   "Execute BODY according to PARAMS.  This function calls
  60 `org-babel-execute:C++'."
  61   (org-babel-execute:C++ body params))
  62
  63 (defun org-babel-execute:C++ (body params)
  64     "Execute a block of C++ code with org-babel.  This function is
  65 called by `org-babel-execute-src-block'."
  66   (let ((org-babel-c-variant 'cpp)) (org-babel-C-execute body params)))
  67
  68 (defun org-babel-expand-body:C++ (body params)
  69   "Expand a block of C++ code with org-babel according to it's
  70 header arguments (calls `org-babel-C-expand')."
  71   (let ((org-babel-c-variant 'cpp)) (org-babel-C-expand body params)))
  72
  73 (defun org-babel-execute:C (body params)
  74   "Execute a block of C code with org-babel.  This function is
  75 called by `org-babel-execute-src-block'."
  76   (let ((org-babel-c-variant 'c)) (org-babel-C-execute body params)))
  77
  78 (defun org-babel-expand-body:c (body params)
  79   "Expand a block of C code with org-babel according to it's
  80 header arguments (calls `org-babel-C-expand')."
  81   (let ((org-babel-c-variant 'c)) (org-babel-C-expand body params)))
  82
  83 (defun org-babel-C-execute (body params)
  84   "This function should only be called by `org-babel-execute:C'
  85 or `org-babel-execute:C++'."
  86   (let* ((tmp-src-file (org-babel-temp-file
  87                         "C-src-"
  88                         (cond
  89                          ((equal org-babel-c-variant 'c) ".c")
  90                          ((equal org-babel-c-variant 'cpp) ".cpp"))))
  91          (tmp-bin-file (org-babel-temp-file "C-bin-"))
  92          (cmdline (cdr (assoc :cmdline params)))
  93          (flags (cdr (assoc :flags params)))
  94          (full-body (org-babel-C-expand body params))
  95          (compile
  96           (progn
  97             (with-temp-file tmp-src-file (insert full-body))
  98             (org-babel-eval
  99              (format "%s -o %s %s %s -I \"%s\""
 100                      (cond
 101                       ((equal org-babel-c-variant 'c) org-babel-C-compiler)
 102                       ((equal org-babel-c-variant 'cpp) org-babel-C++-compiler))
 103                      (org-babel-process-file-name tmp-bin-file)
 104                      (mapconcat 'identity
 105                                 (if (listp flags) flags (list flags)) " ")
 106                      (org-babel-process-file-name tmp-src-file)
 107                      (file-name-directory (buffer-file-name))) ""))))
 108     ((lambda (results)
 109        (org-babel-reassemble-table
 110         (if (member "vector" (cdr (assoc :result-params params)))
 111             (let ((tmp-file (org-babel-temp-file "c-")))
 112               (with-temp-file tmp-file (insert results))
 113               (org-babel-import-elisp-from-file tmp-file))
 114           (org-babel-read results))
 115         (org-babel-pick-name
 116          (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
 117         (org-babel-pick-name
 118          (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params)))))
 119      (org-babel-trim
 120        (org-babel-eval
 121         (concat tmp-bin-file (if cmdline (concat " " cmdline) "")) "")))))
 122
 123 (defun org-babel-C-expand (body params)
 124   "Expand a block of C or C++ code with org-babel according to
 125 it's header arguments."
 126   (let ((vars (mapcar #'cdr (org-babel-get-header params :var)))
 127         (main-p (not (string= (cdr (assoc :main params)) "no")))
 128         (includes (or (cdr (assoc :includes params))
 129                       (org-babel-read (org-entry-get nil "includes" t))))
 130         (defines (org-babel-read
 131                   (or (cdr (assoc :defines params))
 132                       (org-babel-read (org-entry-get nil "defines" t))))))
 133      (mapconcat 'identity
 134                 (list
 135                  ;; includes
 136                  (mapconcat
 137                   (lambda (inc) (format "#include %s" inc))
 138                   (if (listp includes) includes (list includes)) "\n")
 139                  ;; defines
 140                  (mapconcat
 141                   (lambda (inc) (format "#define %s" inc))
 142                   (if (listp defines) defines (list defines)) "\n")
 143                  ;; variables
 144                  (mapconcat 'org-babel-C-var-to-C vars "\n")
 145                  ;; body
 146                  (if main-p
 147                      (org-babel-C-ensure-main-wrap body)
 148                    body) "\n") "\n")))
 149
 150 (defun org-babel-C-ensure-main-wrap (body)
 151   "Wrap body in a \"main\" function call if none exists."
 152   (if (string-match "^[ \t]*[intvod]+[ \t\n\r]*main[ \t]*(.*)" body)
 153       body
 154     (format "int main() {\n%s\n}\n" body)))
 155
 156 (defun org-babel-prep-session:C (session params)
 157   "This function does nothing as C is a compiled language with no
 158 support for sessions"
 159   (error "C is a compiled languages -- no support for sessions"))
 160
 161 (defun org-babel-load-session:C (session body params)
 162   "This function does nothing as C is a compiled language with no
 163 support for sessions"
 164   (error "C is a compiled languages -- no support for sessions"))
 165
 166 ;; helper functions
 167
 168 (defun org-babel-C-var-to-C (pair)
 169   "Convert an elisp val into a string of C code specifying a var
 170 of the same value."
 171   ;; TODO list support
 172   (let ((var (car pair))
 173         (val (cdr pair)))
 174     (when (symbolp val)
 175       (setq val (symbol-name val))
 176       (when (= (length val) 1)
 177         (setq val (string-to-char val))))
 178     (cond
 179      ((integerp val)
 180       (format "int %S = %S;" var val))
 181      ((floatp val)
 182       (format "double %S = %S;" var val))
 183      ((or (integerp val))
 184       (format "char %S = '%S';" var val))
 185      ((stringp val)
 186       (format "char %S[%d] = \"%s\";"
 187               var (+ 1 (length val)) val))
 188      (t
 189       (format "u32 %S = %S;" var val)))))
 190
 191
 192 (provide 'ob-C)
 193
 194
 195
 196 ;;; ob-C.el ends here