lisp/org-colview.el

   1 ;;; org-colview.el --- Column View in Org-mode
   2
   3 ;; Copyright (C) 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the column view for Org.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'org)
  33
  34 (declare-function org-agenda-redo "org-agenda" ())
  35 (declare-function org-agenda-do-context-action "org-agenda" ())
  36 (declare-function org-clock-sum-today "org-clock" (&optional headline-filter))
  37
  38 (when (featurep 'xemacs)
  39   (error "Do not load this file into XEmacs, use `org-colview-xemacs.el' from the contrib/ directory"))
  40
  41 ;;; Column View
  42
  43 (defvar org-columns-overlays nil
  44   "Holds the list of current column overlays.")
  45
  46 (defvar org-columns-current-fmt nil
  47   "Local variable, holds the currently active column format.")
  48 (make-variable-buffer-local 'org-columns-current-fmt)
  49 (defvar org-columns-current-fmt-compiled nil
  50   "Local variable, holds the currently active column format.
  51 This is the compiled version of the format.")
  52 (make-variable-buffer-local 'org-columns-current-fmt-compiled)
  53 (defvar org-columns-current-widths nil
  54   "Loval variable, holds the currently widths of fields.")
  55 (make-variable-buffer-local 'org-columns-current-widths)
  56 (defvar org-columns-current-maxwidths nil
  57   "Loval variable, holds the currently active maximum column widths.")
  58 (make-variable-buffer-local 'org-columns-current-maxwidths)
  59 (defvar org-columns-begin-marker (make-marker)
  60   "Points to the position where last a column creation command was called.")
  61 (defvar org-columns-top-level-marker (make-marker)
  62   "Points to the position where current columns region starts.")
  63
  64 (defvar org-columns-map (make-sparse-keymap)
  65   "The keymap valid in column display.")
  66
  67 (defun org-columns-content ()
  68   "Switch to contents view while in columns view."
  69   (interactive)
  70   (org-overview)
  71   (org-content))
  72
  73 (org-defkey org-columns-map "c" 'org-columns-content)
  74 (org-defkey org-columns-map "o" 'org-overview)
  75 (org-defkey org-columns-map "e" 'org-columns-edit-value)
  76 (org-defkey org-columns-map "\C-c\C-t" 'org-columns-todo)
  77 (org-defkey org-columns-map "\C-c\C-c" 'org-columns-set-tags-or-toggle)
  78 (org-defkey org-columns-map "\C-c\C-o" 'org-columns-open-link)
  79 (org-defkey org-columns-map "v" 'org-columns-show-value)
  80 (org-defkey org-columns-map "q" 'org-columns-quit)
  81 (org-defkey org-columns-map "r" 'org-columns-redo)
  82 (org-defkey org-columns-map "g" 'org-columns-redo)
  83 (org-defkey org-columns-map [left] 'backward-char)
  84 (org-defkey org-columns-map "\M-b" 'backward-char)
  85 (org-defkey org-columns-map "a" 'org-columns-edit-allowed)
  86 (org-defkey org-columns-map "s" 'org-columns-edit-attributes)
  87 (org-defkey org-columns-map "\M-f"
  88             (lambda () (interactive) (goto-char (1+ (point)))))
  89 (org-defkey org-columns-map [right]
  90             (lambda () (interactive) (goto-char (1+ (point)))))
  91 (org-defkey org-columns-map [down]
  92             (lambda () (interactive)
  93               (let ((col (current-column)))
  94                 (beginning-of-line 2)
  95                 (while (and (org-invisible-p2) (not (eobp)))
  96                   (beginning-of-line 2))
  97                 (move-to-column col)
  98                 (if (eq major-mode 'org-agenda-mode)
  99                     (org-agenda-do-context-action)))))
 100 (org-defkey org-columns-map [up]
 101             (lambda () (interactive)
 102               (let ((col (current-column)))
 103                 (beginning-of-line 0)
 104                 (while (and (org-invisible-p2) (not (bobp)))
 105                   (beginning-of-line 0))
 106                 (move-to-column col)
 107                 (if (eq major-mode 'org-agenda-mode)
 108                     (org-agenda-do-context-action)))))
 109 (org-defkey org-columns-map [(shift right)] 'org-columns-next-allowed-value)
 110 (org-defkey org-columns-map "n" 'org-columns-next-allowed-value)
 111 (org-defkey org-columns-map [(shift left)] 'org-columns-previous-allowed-value)
 112 (org-defkey org-columns-map "p" 'org-columns-previous-allowed-value)
 113 (org-defkey org-columns-map "<" 'org-columns-narrow)
 114 (org-defkey org-columns-map ">" 'org-columns-widen)
 115 (org-defkey org-columns-map [(meta right)] 'org-columns-move-right)
 116 (org-defkey org-columns-map [(meta left)] 'org-columns-move-left)
 117 (org-defkey org-columns-map [(shift meta right)] 'org-columns-new)
 118 (org-defkey org-columns-map [(shift meta left)] 'org-columns-delete)
 119 (dotimes (i 10)
 120   (org-defkey org-columns-map (number-to-string i)
 121               `(lambda () (interactive)
 122                  (org-columns-next-allowed-value nil ,i))))
 123
 124 (easy-menu-define org-columns-menu org-columns-map "Org Column Menu"
 125   '("Column"
 126     ["Edit property" org-columns-edit-value t]
 127     ["Next allowed value" org-columns-next-allowed-value t]
 128     ["Previous allowed value" org-columns-previous-allowed-value t]
 129     ["Show full value" org-columns-show-value t]
 130     ["Edit allowed values" org-columns-edit-allowed t]
 131     "--"
 132     ["Edit column attributes" org-columns-edit-attributes t]
 133     ["Increase column width" org-columns-widen t]
 134     ["Decrease column width" org-columns-narrow t]
 135     "--"
 136     ["Move column right" org-columns-move-right t]
 137     ["Move column left" org-columns-move-left t]
 138     ["Add column" org-columns-new t]
 139     ["Delete column" org-columns-delete t]
 140     "--"
 141     ["CONTENTS" org-columns-content t]
 142     ["OVERVIEW" org-overview t]
 143     ["Refresh columns display" org-columns-redo t]
 144     "--"
 145     ["Open link" org-columns-open-link t]
 146     "--"
 147     ["Quit" org-columns-quit t]))
 148
 149 (defun org-columns-new-overlay (beg end &optional string face)
 150   "Create a new column overlay and add it to the list."
 151   (let ((ov (make-overlay beg end)))
 152     (overlay-put ov 'face (or face 'secondary-selection))
 153     (remove-text-properties 0 (length string) '(face nil) string)
 154     (org-overlay-display ov string face)
 155     (push ov org-columns-overlays)
 156     ov))
 157
 158 (defun org-columns-display-here (&optional props dateline)
 159   "Overlay the current line with column display."
 160   (interactive)
 161   (let* ((fmt org-columns-current-fmt-compiled)
 162          (beg (point-at-bol))
 163          (level-face (save-excursion
 164                        (beginning-of-line 1)
 165                        (and (looking-at "\\(\\**\\)\\(\\* \\)")
 166                             (org-get-level-face 2))))
 167          (ref-face (or level-face
 168                        (and (eq major-mode 'org-agenda-mode)
 169                             (get-text-property (point-at-bol) 'face))
 170                        'default))
 171          (color (list :foreground (face-attribute ref-face :foreground)))
 172          (font (list :height (face-attribute 'default :height)
 173                      :family (face-attribute 'default :family)))
 174          (face (list color font 'org-column ref-face))
 175          (face1 (list color font 'org-agenda-column-dateline ref-face))
 176          (cphr (get-text-property (point-at-bol) 'org-complex-heading-regexp))
 177          pom property ass width f fc string fm ov column val modval s2 title calc)
 178     ;; Check if the entry is in another buffer.
 179     (unless props
 180       (if (eq major-mode 'org-agenda-mode)
 181           (setq pom (or (org-get-at-bol 'org-hd-marker)
 182                         (org-get-at-bol 'org-marker))
 183                 props (if pom (org-entry-properties pom) nil))
 184         (setq props (org-entry-properties nil))))
 185     ;; Walk the format
 186     (while (setq column (pop fmt))
 187       (setq property (car column)
 188             title (nth 1 column)
 189             ass (assoc property props)
 190             width (or (cdr (assoc property org-columns-current-maxwidths))
 191                       (nth 2 column)
 192                       (length property))
 193             f (format "%%-%d.%ds | " width width)
 194             fm (nth 4 column)
 195             fc (nth 5 column)
 196             calc (nth 7 column)
 197             val (or (cdr ass) "")
 198             modval (cond ((and org-columns-modify-value-for-display-function
 199                                (functionp
 200                                 org-columns-modify-value-for-display-function))
 201                           (funcall org-columns-modify-value-for-display-function
 202                                    title val))
 203                          ((equal property "ITEM")
 204                           (org-columns-compact-links val))
 205                          (fc (org-columns-number-to-string
 206                               (org-columns-string-to-number val fm) fm fc))
 207                          ((and calc (functionp calc)
 208                                (not (string= val ""))
 209                                (not (get-text-property 0 'org-computed val)))
 210                           (org-columns-number-to-string
 211                            (funcall calc (org-columns-string-to-number
 212                                           val fm)) fm))))
 213       (setq s2 (org-columns-add-ellipses (or modval val) width))
 214       (setq string (format f s2))
 215       ;; Create the overlay
 216       (org-with-silent-modifications
 217        (setq ov (org-columns-new-overlay
 218                  beg (setq beg (1+ beg)) string (if dateline face1 face)))
 219        (overlay-put ov 'keymap org-columns-map)
 220        (overlay-put ov 'org-columns-key property)
 221        (overlay-put ov 'org-columns-value (cdr ass))
 222        (overlay-put ov 'org-columns-value-modified modval)
 223        (overlay-put ov 'org-columns-pom pom)
 224        (overlay-put ov 'org-columns-format f)
 225        (overlay-put ov 'line-prefix "")
 226        (overlay-put ov 'wrap-prefix ""))
 227       (if (or (not (char-after beg))
 228               (equal (char-after beg) ?\n))
 229           (let ((inhibit-read-only t))
 230             (save-excursion
 231               (goto-char beg)
 232               (org-unmodified (insert " ")))))) ;; FIXME: add props and remove later?
 233     ;; Make the rest of the line disappear.
 234     (org-unmodified
 235      (setq ov (org-columns-new-overlay beg (point-at-eol)))
 236      (overlay-put ov 'invisible t)
 237      (overlay-put ov 'keymap org-columns-map)
 238      (overlay-put ov 'intangible t)
 239      (overlay-put ov 'line-prefix "")
 240      (overlay-put ov 'wrap-prefix "")
 241      (push ov org-columns-overlays)
 242      (setq ov (make-overlay (1- (point-at-eol)) (1+ (point-at-eol))))
 243      (overlay-put ov 'keymap org-columns-map)
 244      (push ov org-columns-overlays)
 245      (let ((inhibit-read-only t))
 246        (put-text-property (max (point-min) (1- (point-at-bol)))
 247                           (min (point-max) (1+ (point-at-eol)))
 248                           'read-only "Type `e' to edit property")))))
 249
 250 (defun org-columns-add-ellipses (string width)
 251   "Truncate STRING with WIDTH characters, with ellipses."
 252   (cond
 253    ((<= (length string) width) string)
 254    ((<= width (length org-columns-ellipses))
 255     (substring org-columns-ellipses 0 width))
 256    (t (concat (substring string 0 (- width (length org-columns-ellipses)))
 257               org-columns-ellipses))))
 258
 259 (defvar org-columns-full-header-line-format nil
 260   "The full header line format, will be shifted by horizontal scrolling." )
 261 (defvar org-previous-header-line-format nil
 262   "The header line format before column view was turned on.")
 263 (defvar org-columns-inhibit-recalculation nil
 264   "Inhibit recomputing of columns on column view startup.")
 265 (defvar org-columns-flyspell-was-active nil
 266   "Remember the state of `flyspell-mode' before column view.
 267 Flyspell-mode can cause problems in columns view, so it is turned off
 268 for the duration of the command.")
 269
 270 (defvar header-line-format)
 271 (defvar org-columns-previous-hscroll 0)
 272
 273 (defun org-columns-display-here-title ()
 274   "Overlay the newline before the current line with the table title."
 275   (interactive)
 276   (let ((fmt org-columns-current-fmt-compiled)
 277         string (title "")
 278         property width f column str widths)
 279     (while (setq column (pop fmt))
 280       (setq property (car column)
 281             str (or (nth 1 column) property)
 282             width (or (cdr (assoc property org-columns-current-maxwidths))
 283                       (nth 2 column)
 284                       (length str))
 285             widths (push width widths)
 286             f (format "%%-%d.%ds | " width width)
 287             string (format f str)
 288             title (concat title string)))
 289     (setq title (concat
 290                  (org-add-props " " nil 'display '(space :align-to 0))
 291                  ;;(org-add-props title nil 'face '(:weight bold :underline t :inherit default))))
 292                  (org-add-props title nil 'face 'org-column-title)))
 293     (org-set-local 'org-previous-header-line-format header-line-format)
 294     (org-set-local 'org-columns-current-widths (nreverse widths))
 295     (setq org-columns-full-header-line-format title)
 296     (setq org-columns-previous-hscroll -1)
 297                                         ;    (org-columns-hscoll-title)
 298     (org-add-hook 'post-command-hook 'org-columns-hscoll-title nil 'local)))
 299
 300 (defun org-columns-hscoll-title ()
 301   "Set the `header-line-format' so that it scrolls along with the table."
 302   (sit-for .0001) ; need to force a redisplay to update window-hscroll
 303   (when (not (= (window-hscroll) org-columns-previous-hscroll))
 304     (setq header-line-format
 305           (concat (substring org-columns-full-header-line-format 0 1)
 306                   (substring org-columns-full-header-line-format
 307                              (1+ (window-hscroll))))
 308           org-columns-previous-hscroll (window-hscroll))
 309     (force-mode-line-update)))
 310
 311 (defvar org-colview-initial-truncate-line-value nil
 312   "Remember the value of `truncate-lines' across colview.")
 313
 314 ;;;###autoload
 315 (defun org-columns-remove-overlays ()
 316   "Remove all currently active column overlays."
 317   (interactive)
 318   (when (marker-buffer org-columns-begin-marker)
 319     (with-current-buffer (marker-buffer org-columns-begin-marker)
 320       (when (local-variable-p 'org-previous-header-line-format)
 321         (setq header-line-format org-previous-header-line-format)
 322         (kill-local-variable 'org-previous-header-line-format)
 323         (remove-hook 'post-command-hook 'org-columns-hscoll-title 'local))
 324       (move-marker org-columns-begin-marker nil)
 325       (move-marker org-columns-top-level-marker nil)
 326       (org-with-silent-modifications
 327        (mapc 'delete-overlay org-columns-overlays)
 328        (setq org-columns-overlays nil)
 329        (let ((inhibit-read-only t))
 330          (remove-text-properties (point-min) (point-max) '(read-only t))))
 331       (when org-columns-flyspell-was-active
 332         (flyspell-mode 1))
 333       (when (local-variable-p 'org-colview-initial-truncate-line-value)
 334         (setq truncate-lines org-colview-initial-truncate-line-value)))))
 335
 336 (defun org-columns-compact-links (s)
 337   "Replace [[link][desc]] with [desc] or [link]."
 338   (while (string-match org-bracket-link-regexp s)
 339     (setq s (replace-match
 340              (concat "[" (match-string (if (match-end 3) 3 1) s) "]")
 341              t t s)))
 342   s)
 343
 344 (defun org-columns-show-value ()
 345   "Show the full value of the property."
 346   (interactive)
 347   (let ((value (get-char-property (point) 'org-columns-value)))
 348     (message "Value is: %s" (or value ""))))
 349
 350 (defvar org-agenda-columns-active) ;; defined in org-agenda.el
 351
 352 (defun org-columns-quit ()
 353   "Remove the column overlays and in this way exit column editing."
 354   (interactive)
 355   (org-with-silent-modifications
 356    (org-columns-remove-overlays)
 357    (let ((inhibit-read-only t))
 358      (remove-text-properties (point-min) (point-max) '(read-only t))))
 359   (when (eq major-mode 'org-agenda-mode)
 360     (setq org-agenda-columns-active nil)
 361     (message
 362      "Modification not yet reflected in Agenda buffer, use `r' to refresh")))
 363
 364 (defun org-columns-check-computed ()
 365   "Check if this column value is computed.
 366 If yes, throw an error indicating that changing it does not make sense."
 367   (let ((val (get-char-property (point) 'org-columns-value)))
 368     (when (and (stringp val)
 369                (get-char-property 0 'org-computed val))
 370       (error "This value is computed from the entry's children"))))
 371
 372 (defun org-columns-todo (&optional arg)
 373   "Change the TODO state during column view."
 374   (interactive "P")
 375   (org-columns-edit-value "TODO"))
 376
 377 (defun org-columns-set-tags-or-toggle (&optional arg)
 378   "Toggle checkbox at point, or set tags for current headline."
 379   (interactive "P")
 380   (if (string-match "\\`\\[[ xX-]\\]\\'"
 381                     (get-char-property (point) 'org-columns-value))
 382       (org-columns-next-allowed-value)
 383     (org-columns-edit-value "TAGS")))
 384
 385 (defvar org-agenda-overriding-columns-format nil
 386   "When set, overrides any other format definition for the agenda.
 387 Don't set this, this is meant for dynamic scoping.")
 388
 389 (defun org-columns-edit-value (&optional key)
 390   "Edit the value of the property at point in column view.
 391 Where possible, use the standard interface for changing this line."
 392   (interactive)
 393   (org-columns-check-computed)
 394   (let* ((col (current-column))
 395          (key (or key (get-char-property (point) 'org-columns-key)))
 396          (value (get-char-property (point) 'org-columns-value))
 397          (bol (point-at-bol)) (eol (point-at-eol))
 398          (pom (or (get-text-property bol 'org-hd-marker)
 399                   (point))) ; keep despite of compiler waring
 400          (line-overlays
 401           (delq nil (mapcar (lambda (x)
 402                               (and (eq (overlay-buffer x) (current-buffer))
 403                                    (>= (overlay-start x) bol)
 404                                    (<= (overlay-start x) eol)
 405                                    x))
 406                             org-columns-overlays)))
 407          (org-columns-time (time-to-number-of-days (current-time)))
 408          nval eval allowed)
 409     (cond
 410      ((equal key "CLOCKSUM")
 411       (error "This special column cannot be edited"))
 412      ((equal key "ITEM")
 413       (setq eval '(org-with-point-at pom
 414                     (org-edit-headline))))
 415      ((equal key "TODO")
 416       (setq eval '(org-with-point-at
 417                       pom
 418                     (call-interactively 'org-todo))))
 419      ((equal key "PRIORITY")
 420       (setq eval '(org-with-point-at pom
 421                     (call-interactively 'org-priority))))
 422      ((equal key "TAGS")
 423       (setq eval '(org-with-point-at pom
 424                     (let ((org-fast-tag-selection-single-key
 425                            (if (eq org-fast-tag-selection-single-key 'expert)
 426                                t org-fast-tag-selection-single-key)))
 427                       (call-interactively 'org-set-tags)))))
 428      ((equal key "DEADLINE")
 429       (setq eval '(org-with-point-at pom
 430                     (call-interactively 'org-deadline))))
 431      ((equal key "SCHEDULED")
 432       (setq eval '(org-with-point-at pom
 433                     (call-interactively 'org-schedule))))
 434      ((equal key "BEAMER_env")
 435       (setq eval '(org-with-point-at pom
 436                     (call-interactively 'org-beamer-select-environment))))
 437      (t
 438       (setq allowed (org-property-get-allowed-values pom key 'table))
 439       (if allowed
 440           (setq nval (org-icompleting-read
 441                       "Value: " allowed nil
 442                       (not (get-text-property 0 'org-unrestricted
 443                                               (caar allowed)))))
 444         (setq nval (read-string "Edit: " value)))
 445       (setq nval (org-trim nval))
 446       (when (not (equal nval value))
 447         (setq eval '(org-entry-put pom key nval)))))
 448     (when eval
 449
 450       (cond
 451        ((equal major-mode 'org-agenda-mode)
 452         (org-columns-eval eval)
 453         ;; The following let preserves the current format, and makes sure
 454         ;; that in only a single file things need to be updated.
 455         (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 456                (buffer (marker-buffer pom))
 457                (org-agenda-contributing-files
 458                 (list (with-current-buffer buffer
 459                         (buffer-file-name (buffer-base-buffer))))))
 460           (org-agenda-columns)))
 461        (t
 462         (let ((inhibit-read-only t))
 463           (org-with-silent-modifications
 464            (remove-text-properties
 465             (max (point-min) (1- bol)) eol '(read-only t)))
 466           (unwind-protect
 467               (progn
 468                 (setq org-columns-overlays
 469                       (org-delete-all line-overlays org-columns-overlays))
 470                 (mapc 'delete-overlay line-overlays)
 471                 (org-columns-eval eval))
 472             (org-columns-display-here)))
 473         (org-move-to-column col)
 474         (if (and (derived-mode-p 'org-mode)
 475                  (nth 3 (assoc key org-columns-current-fmt-compiled)))
 476             (org-columns-update key)))))))
 477
 478 (defun org-edit-headline () ; FIXME: this is not columns specific.  Make interactive?????  Use from agenda????
 479   "Edit the current headline, the part without TODO keyword, TAGS."
 480   (org-back-to-heading)
 481   (when (looking-at org-todo-line-regexp)
 482     (let ((pos (point))
 483           (pre (buffer-substring (match-beginning 0) (match-beginning 3)))
 484           (txt (match-string 3))
 485           (post "")
 486           txt2)
 487       (if (string-match (org-re "[ \t]+:[[:alnum:]:_@#%]+:[ \t]*$") txt)
 488           (setq post (match-string 0 txt)
 489                 txt (substring txt 0 (match-beginning 0))))
 490       (setq txt2 (read-string "Edit: " txt))
 491       (when (not (equal txt txt2))
 492         (goto-char pos)
 493         (insert pre txt2 post)
 494         (delete-region (point) (point-at-eol))
 495         (org-set-tags nil t)))))
 496
 497 (defun org-columns-edit-allowed ()
 498   "Edit the list of allowed values for the current property."
 499   (interactive)
 500   (let* ((pom (or (org-get-at-bol 'org-marker)
 501                   (org-get-at-bol 'org-hd-marker)
 502                   (point)))
 503          (key (get-char-property (point) 'org-columns-key))
 504          (key1 (concat key "_ALL"))
 505          (allowed (org-entry-get pom key1 t))
 506          nval)
 507     ;; FIXME: Cover editing TODO, TAGS etc in-buffer settings.????
 508     ;; FIXME: Write back to #+PROPERTY setting if that is needed.
 509     (setq nval (read-string "Allowed: " allowed))
 510     (org-entry-put
 511      (cond ((marker-position org-entry-property-inherited-from)
 512             org-entry-property-inherited-from)
 513            ((marker-position org-columns-top-level-marker)
 514             org-columns-top-level-marker)
 515            (t pom))
 516      key1 nval)))
 517
 518 (defun org-columns-eval (form)
 519   (let (hidep)
 520     (save-excursion
 521       (beginning-of-line 1)
 522       ;; `next-line' is needed here, because it skips invisible line.
 523       (condition-case nil (org-no-warnings (next-line 1)) (error nil))
 524       (setq hidep (org-at-heading-p 1)))
 525     (eval form)
 526     (and hidep (hide-entry))))
 527
 528 (defun org-columns-previous-allowed-value ()
 529   "Switch to the previous allowed value for this column."
 530   (interactive)
 531   (org-columns-next-allowed-value t))
 532
 533 (defun org-columns-next-allowed-value (&optional previous nth)
 534   "Switch to the next allowed value for this column.
 535 When PREVIOUS is set, go to the previous value.  When NTH is
 536 an integer, select that value."
 537   (interactive)
 538   (org-columns-check-computed)
 539   (let* ((col (current-column))
 540          (key (get-char-property (point) 'org-columns-key))
 541          (value (get-char-property (point) 'org-columns-value))
 542          (bol (point-at-bol)) (eol (point-at-eol))
 543          (pom (or (get-text-property bol 'org-hd-marker)
 544                   (point))) ; keep despite of compiler waring
 545          (line-overlays
 546           (delq nil (mapcar (lambda (x)
 547                               (and (eq (overlay-buffer x) (current-buffer))
 548                                    (>= (overlay-start x) bol)
 549                                    (<= (overlay-start x) eol)
 550                                    x))
 551                             org-columns-overlays)))
 552          (allowed (or (org-property-get-allowed-values pom key)
 553                       (and (memq
 554                             (nth 4 (assoc key org-columns-current-fmt-compiled))
 555                             '(checkbox checkbox-n-of-m checkbox-percent))
 556                            '("[ ]" "[X]"))
 557                       (org-colview-construct-allowed-dates value)))
 558          nval)
 559     (when (integerp nth)
 560       (setq nth (1- nth))
 561       (if (= nth -1) (setq nth 9)))
 562     (when (equal key "ITEM")
 563       (error "Cannot edit item headline from here"))
 564     (unless (or allowed (member key '("SCHEDULED" "DEADLINE" "CLOCKSUM")))
 565       (error "Allowed values for this property have not been defined"))
 566     (if (member key '("SCHEDULED" "DEADLINE" "CLOCKSUM"))
 567         (setq nval (if previous 'earlier 'later))
 568       (if previous (setq allowed (reverse allowed)))
 569       (cond
 570        (nth
 571         (setq nval (nth nth allowed))
 572         (if (not nval)
 573             (error "There are only %d allowed values for property `%s'"
 574                    (length allowed) key)))
 575        ((member value allowed)
 576         (setq nval (or (car (cdr (member value allowed)))
 577                        (car allowed)))
 578         (if (equal nval value)
 579             (error "Only one allowed value for this property")))
 580        (t (setq nval (car allowed)))))
 581     (cond
 582      ((equal major-mode 'org-agenda-mode)
 583       (org-columns-eval '(org-entry-put pom key nval))
 584       ;; The following let preserves the current format, and makes sure
 585       ;; that in only a single file things need to be updated.
 586       (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 587              (buffer (marker-buffer pom))
 588              (org-agenda-contributing-files
 589               (list (with-current-buffer buffer
 590                       (buffer-file-name (buffer-base-buffer))))))
 591         (org-agenda-columns)))
 592      (t
 593       (let ((inhibit-read-only t))
 594         (remove-text-properties (1- bol) eol '(read-only t))
 595         (unwind-protect
 596             (progn
 597               (setq org-columns-overlays
 598                     (org-delete-all line-overlays org-columns-overlays))
 599               (mapc 'delete-overlay line-overlays)
 600               (org-columns-eval '(org-entry-put pom key nval)))
 601           (org-columns-display-here)))
 602       (org-move-to-column col)
 603       (and (nth 3 (assoc key org-columns-current-fmt-compiled))
 604            (org-columns-update key))))))
 605
 606 (defun org-colview-construct-allowed-dates (s)
 607   "Construct a list of three dates around the date in S.
 608 This respects the format of the time stamp in S, active or non-active,
 609 and also including time or not.  S must be just a time stamp, no text
 610 around it."
 611   (when (and s (string-match (concat "^" org-ts-regexp3 "$") s))
 612     (let* ((time (org-parse-time-string s 'nodefaults))
 613            (active (equal (string-to-char s) ?<))
 614            (fmt (funcall (if (nth 1 time) 'cdr 'car) org-time-stamp-formats))
 615            time-before time-after)
 616       (unless active (setq fmt (concat "[" (substring fmt 1 -1) "]")))
 617       (setf (car time) (or (car time) 0))
 618       (setf (nth 1 time) (or (nth 1 time) 0))
 619       (setf (nth 2 time) (or (nth 2 time) 0))
 620       (setq time-before (copy-sequence time))
 621       (setq time-after (copy-sequence time))
 622       (setf (nth 3 time-before) (1- (nth 3 time)))
 623       (setf (nth 3 time-after) (1+ (nth 3 time)))
 624       (mapcar (lambda (x) (format-time-string fmt (apply 'encode-time x)))
 625               (list time-before time time-after)))))
 626
 627 (defun org-verify-version (task)
 628   (cond
 629    ((eq task 'columns)
 630     (if (or (featurep 'xemacs)
 631             (< emacs-major-version 22))
 632         (error "Emacs 22 is required for the columns feature")))))
 633
 634 (defun org-columns-open-link (&optional arg)
 635   (interactive "P")
 636   (let ((value (get-char-property (point) 'org-columns-value)))
 637     (org-open-link-from-string value arg)))
 638
 639 ;;;###autoload
 640 (defun org-columns-get-format-and-top-level ()
 641   (let ((fmt (org-columns-get-format)))
 642     (org-columns-goto-top-level)
 643     fmt))
 644
 645 (defun org-columns-get-format (&optional fmt-string)
 646   (interactive)
 647   (let (fmt-as-property fmt)
 648     (when (condition-case nil (org-back-to-heading) (error nil))
 649       (setq fmt-as-property (org-entry-get nil "COLUMNS" t)))
 650     (setq fmt (or fmt-string fmt-as-property org-columns-default-format))
 651     (org-set-local 'org-columns-current-fmt fmt)
 652     (org-columns-compile-format fmt)
 653     fmt))
 654
 655 (defun org-columns-goto-top-level ()
 656   (when (condition-case nil (org-back-to-heading) (error nil))
 657     (org-entry-get nil "COLUMNS" t))
 658   (if (marker-position org-entry-property-inherited-from)
 659       (move-marker org-columns-top-level-marker org-entry-property-inherited-from)
 660     (move-marker org-columns-top-level-marker (point))))
 661
 662 ;;;###autoload
 663 (defun org-columns (&optional columns-fmt-string)
 664   "Turn on column view on an org-mode file.
 665 When COLUMNS-FMT-STRING is non-nil, use it as the column format."
 666   (interactive)
 667   (org-verify-version 'columns)
 668   (org-columns-remove-overlays)
 669   (move-marker org-columns-begin-marker (point))
 670   (let ((org-columns-time (time-to-number-of-days (current-time)))
 671         beg end fmt cache maxwidths)
 672     (org-columns-goto-top-level)
 673     (setq fmt (org-columns-get-format columns-fmt-string))
 674     (save-excursion
 675       (goto-char org-columns-top-level-marker)
 676       (setq beg (point))
 677       (unless org-columns-inhibit-recalculation
 678         (org-columns-compute-all))
 679       (setq end (or (condition-case nil (org-end-of-subtree t t) (error nil))
 680                     (point-max)))
 681       ;; Get and cache the properties
 682       (goto-char beg)
 683       (when (assoc "CLOCKSUM" org-columns-current-fmt-compiled)
 684         (save-excursion
 685           (save-restriction
 686             (narrow-to-region beg end)
 687             (org-clock-sum))))
 688       (when (assoc "CLOCKSUM_T" org-columns-current-fmt-compiled)
 689         (save-excursion
 690           (save-restriction
 691             (narrow-to-region beg end)
 692             (org-clock-sum-today))))
 693       (while (re-search-forward org-outline-regexp-bol end t)
 694         (if (and org-columns-skip-archived-trees
 695                  (looking-at (concat ".*:" org-archive-tag ":")))
 696             (org-end-of-subtree t)
 697           (push (cons (org-current-line) (org-entry-properties)) cache)))
 698       (when cache
 699         (setq maxwidths (org-columns-get-autowidth-alist fmt cache))
 700         (org-set-local 'org-columns-current-maxwidths maxwidths)
 701         (org-columns-display-here-title)
 702         (when (org-set-local 'org-columns-flyspell-was-active
 703                              (org-bound-and-true-p flyspell-mode))
 704           (flyspell-mode 0))
 705         (unless (local-variable-p 'org-colview-initial-truncate-line-value)
 706           (org-set-local 'org-colview-initial-truncate-line-value
 707                          truncate-lines))
 708         (setq truncate-lines t)
 709         (mapc (lambda (x)
 710                 (org-goto-line (car x))
 711                 (org-columns-display-here (cdr x)))
 712               cache)))))
 713
 714 (eval-when-compile (defvar org-columns-time))
 715
 716 (defvar org-columns-compile-map
 717   '(("none" none +)
 718     (":" add_times +)
 719     ("+" add_numbers +)
 720     ("$" currency +)
 721     ("X" checkbox +)
 722     ("X/" checkbox-n-of-m +)
 723     ("X%" checkbox-percent +)
 724     ("max" max_numbers max)
 725     ("min" min_numbers min)
 726     ("mean" mean_numbers
 727      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 728     (":max" max_times max)
 729     (":min" min_times min)
 730     (":mean" mean_times
 731      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 732     ("@min" min_age min (lambda (x) (- org-columns-time x)))
 733     ("@max" max_age max (lambda (x) (- org-columns-time x)))
 734     ("@mean" mean_age
 735      (lambda (&rest x) (/ (apply '+ x) (float (length x))))
 736      (lambda (x) (- org-columns-time x)))
 737     ("est+" estimate org-estimate-combine))
 738   "Operator <-> format,function,calc  map.
 739 Used to compile/uncompile columns format and completing read in
 740 interactive function `org-columns-new'.
 741
 742 operator    string used in #+COLUMNS definition describing the
 743             summary type
 744 format      symbol describing summary type selected interactively in
 745             `org-columns-new' and internally in
 746             `org-columns-number-to-string' and
 747             `org-columns-string-to-number'
 748 function    called with a list of values as argument to calculate
 749             the summary value
 750 calc        function called on every element before summarizing.  This is
 751             optional and should only be specified if needed")
 752
 753 (defun org-columns-new (&optional prop title width op fmt fun &rest rest)
 754   "Insert a new column, to the left of the current column."
 755   (interactive)
 756   (let ((editp (and prop (assoc prop org-columns-current-fmt-compiled)))
 757         cell)
 758     (setq prop (org-icompleting-read
 759                 "Property: " (mapcar 'list (org-buffer-property-keys t nil t))
 760                 nil nil prop))
 761     (setq title (read-string (concat "Column title [" prop "]: ") (or title prop)))
 762     (setq width (read-string "Column width: " (if width (number-to-string width))))
 763     (if (string-match "\\S-" width)
 764         (setq width (string-to-number width))
 765       (setq width nil))
 766     (setq fmt (org-icompleting-read
 767                "Summary [none]: "
 768                (mapcar (lambda (x) (list (symbol-name (cadr x))))
 769                        org-columns-compile-map)
 770                nil t))
 771     (setq fmt (intern fmt)
 772           fun (cdr (assoc fmt (mapcar 'cdr org-columns-compile-map))))
 773     (if (eq fmt 'none) (setq fmt nil))
 774     (if editp
 775         (progn
 776           (setcar editp prop)
 777           (setcdr editp (list title width nil fmt nil fun)))
 778       (setq cell (nthcdr (1- (current-column))
 779                          org-columns-current-fmt-compiled))
 780       (setcdr cell (cons (list prop title width nil fmt nil
 781                                (car fun) (cadr fun))
 782                          (cdr cell))))
 783     (org-columns-store-format)
 784     (org-columns-redo)))
 785
 786 (defun org-columns-delete ()
 787   "Delete the column at point from columns view."
 788   (interactive)
 789   (let* ((n (current-column))
 790          (title (nth 1 (nth n org-columns-current-fmt-compiled))))
 791     (when (y-or-n-p
 792            (format "Are you sure you want to remove column \"%s\"? " title))
 793       (setq org-columns-current-fmt-compiled
 794             (delq (nth n org-columns-current-fmt-compiled)
 795                   org-columns-current-fmt-compiled))
 796       (org-columns-store-format)
 797       (org-columns-redo)
 798       (if (>= (current-column) (length org-columns-current-fmt-compiled))
 799           (backward-char 1)))))
 800
 801 (defun org-columns-edit-attributes ()
 802   "Edit the attributes of the current column."
 803   (interactive)
 804   (let* ((n (current-column))
 805          (info (nth n org-columns-current-fmt-compiled)))
 806     (apply 'org-columns-new info)))
 807
 808 (defun org-columns-widen (arg)
 809   "Make the column wider by ARG characters."
 810   (interactive "p")
 811   (let* ((n (current-column))
 812          (entry (nth n org-columns-current-fmt-compiled))
 813          (width (or (nth 2 entry)
 814                     (cdr (assoc (car entry) org-columns-current-maxwidths)))))
 815     (setq width (max 1 (+ width arg)))
 816     (setcar (nthcdr 2 entry) width)
 817     (org-columns-store-format)
 818     (org-columns-redo)))
 819
 820 (defun org-columns-narrow (arg)
 821   "Make the column narrower by ARG characters."
 822   (interactive "p")
 823   (org-columns-widen (- arg)))
 824
 825 (defun org-columns-move-right ()
 826   "Swap this column with the one to the right."
 827   (interactive)
 828   (let* ((n (current-column))
 829          (cell (nthcdr n org-columns-current-fmt-compiled))
 830          e)
 831     (when (>= n (1- (length org-columns-current-fmt-compiled)))
 832       (error "Cannot shift this column further to the right"))
 833     (setq e (car cell))
 834     (setcar cell (car (cdr cell)))
 835     (setcdr cell (cons e (cdr (cdr cell))))
 836     (org-columns-store-format)
 837     (org-columns-redo)
 838     (forward-char 1)))
 839
 840 (defun org-columns-move-left ()
 841   "Swap this column with the one to the left."
 842   (interactive)
 843   (let* ((n (current-column)))
 844     (when (= n 0)
 845       (error "Cannot shift this column further to the left"))
 846     (backward-char 1)
 847     (org-columns-move-right)
 848     (backward-char 1)))
 849
 850 (defun org-columns-store-format ()
 851   "Store the text version of the current columns format in appropriate place.
 852 This is either in the COLUMNS property of the node starting the current column
 853 display, or in the #+COLUMNS line of the current buffer."
 854   (let (fmt (cnt 0))
 855     (setq fmt (org-columns-uncompile-format org-columns-current-fmt-compiled))
 856     (org-set-local 'org-columns-current-fmt fmt)
 857     (if (marker-position org-columns-top-level-marker)
 858         (save-excursion
 859           (goto-char org-columns-top-level-marker)
 860           (if (and (org-at-heading-p)
 861                    (org-entry-get nil "COLUMNS"))
 862               (org-entry-put nil "COLUMNS" fmt)
 863             (goto-char (point-min))
 864             ;; Overwrite all #+COLUMNS lines....
 865             (while (re-search-forward "^[ \t]*#\\+COLUMNS:.*" nil t)
 866               (setq cnt (1+ cnt))
 867               (replace-match (concat "#+COLUMNS: " fmt) t t))
 868             (unless (> cnt 0)
 869               (goto-char (point-min))
 870               (or (org-at-heading-p t) (outline-next-heading))
 871               (let ((inhibit-read-only t))
 872                 (insert-before-markers "#+COLUMNS: " fmt "\n")))
 873             (org-set-local 'org-columns-default-format fmt))))))
 874
 875 (defun org-columns-get-autowidth-alist (s cache)
 876   "Derive the maximum column widths from the format and the cache."
 877   (let ((start 0) rtn)
 878     (while (string-match (org-re "%\\([[:alpha:]][[:alnum:]_-]*\\)") s start)
 879       (push (cons (match-string 1 s) 1) rtn)
 880       (setq start (match-end 0)))
 881     (mapc (lambda (x)
 882             (setcdr x (apply 'max
 883                              (mapcar
 884                               (lambda (y)
 885                                 (length (or (cdr (assoc (car x) (cdr y))) " ")))
 886                               cache))))
 887           rtn)
 888     rtn))
 889
 890 (defun org-columns-compute-all ()
 891   "Compute all columns that have operators defined."
 892   (org-with-silent-modifications
 893    (remove-text-properties (point-min) (point-max) '(org-summaries t)))
 894   (let ((columns org-columns-current-fmt-compiled)
 895         (org-columns-time (time-to-number-of-days (current-time)))
 896         col)
 897     (while (setq col (pop columns))
 898       (when (nth 3 col)
 899         (save-excursion
 900           (org-columns-compute (car col)))))))
 901
 902 (defun org-columns-update (property)
 903   "Recompute PROPERTY, and update the columns display for it."
 904   (org-columns-compute property)
 905   (let (fmt val pos)
 906     (save-excursion
 907       (mapc (lambda (ov)
 908               (when (equal (overlay-get ov 'org-columns-key) property)
 909                 (setq pos (overlay-start ov))
 910                 (goto-char pos)
 911                 (when (setq val (cdr (assoc property
 912                                             (get-text-property
 913                                              (point-at-bol) 'org-summaries))))
 914                   (setq fmt (overlay-get ov 'org-columns-format))
 915                   (overlay-put ov 'org-columns-value val)
 916                   (overlay-put ov 'display (format fmt val)))))
 917             org-columns-overlays))))
 918
 919 (defvar org-inlinetask-min-level
 920   (if (featurep 'org-inlinetask) org-inlinetask-min-level 15))
 921
 922 ;;;###autoload
 923 (defun org-columns-compute (property)
 924   "Sum the values of property PROPERTY hierarchically, for the entire buffer."
 925   (interactive)
 926   (let* ((re org-outline-regexp-bol)
 927          (lmax 30) ; Does anyone use deeper levels???
 928          (lvals (make-vector lmax nil))
 929          (lflag (make-vector lmax nil))
 930          (level 0)
 931          (ass (assoc property org-columns-current-fmt-compiled))
 932          (format (nth 4 ass))
 933          (printf (nth 5 ass))
 934          (fun (nth 6 ass))
 935          (calc (or (nth 7 ass) 'identity))
 936          (beg org-columns-top-level-marker)
 937          (inminlevel org-inlinetask-min-level)
 938          (last-level org-inlinetask-min-level)
 939          val valflag flag end sumpos sum-alist sum str str1 useval)
 940     (save-excursion
 941       ;; Find the region to compute
 942       (goto-char beg)
 943       (setq end (condition-case nil (org-end-of-subtree t) (error (point-max))))
 944       (goto-char end)
 945       ;; Walk the tree from the back and do the computations
 946       (while (re-search-backward re beg t)
 947         (setq sumpos (match-beginning 0)
 948               last-level (if (not (or (zerop level) (eq level inminlevel)))
 949                              level last-level)
 950               level (org-outline-level)
 951               val (org-entry-get nil property)
 952               valflag (and val (string-match "\\S-" val)))
 953         (cond
 954          ((< level last-level)
 955           ;; put the sum of lower levels here as a property
 956           (setq sum (+ (if (and (/= last-level inminlevel)
 957                                 (aref lvals last-level))
 958                            (apply fun (aref lvals last-level)) 0)
 959                        (if (aref lvals inminlevel)
 960                            (apply fun (aref lvals inminlevel)) 0))
 961                 flag (or (aref lflag last-level) ; any valid entries from children?
 962                          (aref lflag inminlevel)) ; or inline tasks?
 963                 str (org-columns-number-to-string sum format printf)
 964                 str1 (org-add-props (copy-sequence str) nil 'org-computed t 'face 'bold)
 965                 useval (if flag str1 (if valflag val ""))
 966                 sum-alist (get-text-property sumpos 'org-summaries))
 967           (if (assoc property sum-alist)
 968               (setcdr (assoc property sum-alist) useval)
 969             (push (cons property useval) sum-alist)
 970             (org-with-silent-modifications
 971              (add-text-properties sumpos (1+ sumpos)
 972                                   (list 'org-summaries sum-alist))))
 973           (when (and val (not (equal val (if flag str val))))
 974             (org-entry-put nil property (if flag str val)))
 975           ;; add current to current level accumulator
 976           (when (or flag valflag)
 977             (push (if flag
 978                       sum
 979                     (funcall calc (org-columns-string-to-number
 980                                    (if flag str val) format)))
 981                   (aref lvals level))
 982             (aset lflag level t))
 983           ;; clear accumulators for deeper levels
 984           (loop for l from (1+ level) to (1- lmax) do
 985                 (aset lvals l nil)
 986                 (aset lflag l nil)))
 987          ((>= level last-level)
 988           ;; add what we have here to the accumulator for this level
 989           (when valflag
 990             (push (funcall calc (org-columns-string-to-number val format))
 991                   (aref lvals level))
 992             (aset lflag level t)))
 993          (t (error "This should not happen")))))))
 994
 995 (defun org-columns-redo ()
 996   "Construct the column display again."
 997   (interactive)
 998   (message "Recomputing columns...")
 999   (let ((line (org-current-line))
1000         (col (current-column)))
1001     (save-excursion
1002       (if (marker-position org-columns-begin-marker)
1003           (goto-char org-columns-begin-marker))
1004       (org-columns-remove-overlays)
1005       (if (derived-mode-p 'org-mode)
1006           (call-interactively 'org-columns)
1007         (org-agenda-redo)
1008         (call-interactively 'org-agenda-columns)))
1009     (org-goto-line line)
1010     (move-to-column col))
1011   (message "Recomputing columns...done"))
1012
1013 (defun org-columns-not-in-agenda ()
1014   (if (eq major-mode 'org-agenda-mode)
1015       (error "This command is only allowed in Org-mode buffers")))
1016
1017 (defun org-string-to-number (s)
1018   "Convert string to number, and interpret hh:mm:ss."
1019   (if (not (string-match ":" s))
1020       (string-to-number s)
1021     (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1022       (while l
1023         (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1024       sum)))
1025
1026 ;;;###autoload
1027 (defun org-columns-number-to-string (n fmt &optional printf)
1028   "Convert a computed column number to a string value, according to FMT."
1029   (cond
1030    ((memq fmt '(estimate)) (org-estimate-print n printf))
1031    ((not (numberp n)) "")
1032    ((memq fmt '(add_times max_times min_times mean_times))
1033     (org-hours-to-clocksum-string n))
1034    ((eq fmt 'checkbox)
1035     (cond ((= n (floor n)) "[X]")
1036           ((> n 1.) "[-]")
1037           (t "[ ]")))
1038    ((memq fmt '(checkbox-n-of-m checkbox-percent))
1039     (let* ((n1 (floor n)) (n2 (floor (+ .5 (* 1000000 (- n n1))))))
1040       (org-nofm-to-completion n1 (+ n2 n1) (eq fmt 'checkbox-percent))))
1041    (printf (format printf n))
1042    ((eq fmt 'currency)
1043     (format "%.2f" n))
1044    ((memq fmt '(min_age max_age mean_age))
1045     (org-format-time-period n))
1046    (t (number-to-string n))))
1047
1048 (defun org-nofm-to-completion (n m &optional percent)
1049   (if (not percent)
1050       (format "[%d/%d]" n m)
1051     (format "[%d%%]"(floor (+ 0.5 (* 100. (/ (* 1.0 n) m)))))))
1052
1053
1054 (defun org-columns-string-to-number (s fmt)
1055   "Convert a column value to a number that can be used for column computing."
1056   (if s
1057       (cond
1058        ((memq fmt '(min_age max_age mean_age))
1059         (cond ((string= s "") org-columns-time)
1060               ((string-match
1061                 "\\([0-9]+\\)d \\([0-9]+\\)h \\([0-9]+\\)m \\([0-9]+\\)s"
1062                 s)
1063                (+ (* 60 (+ (* 60 (+ (* 24 (string-to-number (match-string 1 s)))
1064                                     (string-to-number (match-string 2 s))))
1065                            (string-to-number (match-string 3 s))))
1066                   (string-to-number (match-string 4 s))))
1067               (t (time-to-number-of-days (apply 'encode-time
1068                                                 (org-parse-time-string s t))))))
1069        ((string-match ":" s)
1070         (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1071           (while l
1072             (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1073           sum))
1074        ((string-match (concat "\\([0-9.]+\\) *\\("
1075                               (regexp-opt (mapcar 'car org-effort-durations))
1076                               "\\)") s)
1077         (setq s (concat "0:" (org-duration-string-to-minutes s t)))
1078         (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1079           (while l
1080             (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1081           sum))
1082        ((memq fmt '(checkbox checkbox-n-of-m checkbox-percent))
1083         (if (equal s "[X]") 1. 0.000001))
1084        ((memq fmt '(estimate)) (org-string-to-estimate s))
1085        (t (string-to-number s)))))
1086
1087 (defun org-columns-uncompile-format (cfmt)
1088   "Turn the compiled columns format back into a string representation."
1089   (let ((rtn "") e s prop title op op-match width fmt printf fun calc ee map)
1090     (while (setq e (pop cfmt))
1091       (setq prop (car e)
1092             title (nth 1 e)
1093             width (nth 2 e)
1094             op (nth 3 e)
1095             fmt (nth 4 e)
1096             printf (nth 5 e)
1097             fun (nth 6 e)
1098             calc (nth 7 e))
1099       (setq map (copy-sequence org-columns-compile-map))
1100       (while (setq ee (pop map))
1101         (if (equal fmt (nth 1 ee))
1102             (setq op (car ee) map nil)))
1103       (if (and op printf) (setq op (concat op ";" printf)))
1104       (if (equal title prop) (setq title nil))
1105       (setq s (concat "%" (if width (number-to-string width))
1106                       prop
1107                       (if title (concat "(" title ")"))
1108                       (if op (concat "{" op "}"))))
1109       (setq rtn (concat rtn " " s)))
1110     (org-trim rtn)))
1111
1112 (defun org-columns-compile-format (fmt)
1113   "Turn a column format string into an alist of specifications.
1114 The alist has one entry for each column in the format.  The elements of
1115 that list are:
1116 property     the property
1117 title        the title field for the columns
1118 width        the column width in characters, can be nil for automatic
1119 operator     the operator if any
1120 format       the output format for computed results, derived from operator
1121 printf       a printf format for computed values
1122 fun          the lisp function to compute summary values, derived from operator
1123 calc         function to get values from base elements"
1124   (let ((start 0) width prop title op op-match f printf fun calc)
1125     (setq org-columns-current-fmt-compiled nil)
1126     (while (string-match
1127             (org-re "%\\([0-9]+\\)?\\([[:alnum:]_-]+\\)\\(?:(\\([^)]+\\))\\)?\\(?:{\\([^}]+\\)}\\)?\\s-*")
1128             fmt start)
1129       (setq start (match-end 0)
1130             width (match-string 1 fmt)
1131             prop (match-string 2 fmt)
1132             title (or (match-string 3 fmt) prop)
1133             op (match-string 4 fmt)
1134             f nil
1135             printf nil
1136             fun '+
1137             calc nil)
1138       (if width (setq width (string-to-number width)))
1139       (when (and op (string-match ";" op))
1140         (setq printf (substring op (match-end 0))
1141               op (substring op 0 (match-beginning 0))))
1142       (when (setq op-match (assoc op org-columns-compile-map))
1143         (setq f (cadr op-match)
1144               fun (caddr op-match)
1145               calc (cadddr op-match)))
1146       (push (list prop title width op f printf fun calc)
1147             org-columns-current-fmt-compiled))
1148     (setq org-columns-current-fmt-compiled
1149           (nreverse org-columns-current-fmt-compiled))))
1150
1151
1152 ;;; Dynamic block for Column view
1153
1154 (defvar org-heading-regexp) ; defined in org.el
1155 (defvar org-heading-keyword-regexp-format) ; defined in org.el
1156 (defun org-columns-capture-view (&optional maxlevel skip-empty-rows)
1157   "Get the column view of the current buffer or subtree.
1158 The first optional argument MAXLEVEL sets the level limit.  A
1159 second optional argument SKIP-EMPTY-ROWS tells whether to skip
1160 empty rows, an empty row being one where all the column view
1161 specifiers except ITEM are empty.  This function returns a list
1162 containing the title row and all other rows.  Each row is a list
1163 of fields."
1164   (save-excursion
1165     (let* ((title (mapcar 'cadr org-columns-current-fmt-compiled))
1166            (re-archive (concat ".*:" org-archive-tag ":"))
1167            (n (length title)) row tbl)
1168       (goto-char (point-min))
1169       (while (re-search-forward org-heading-regexp nil t)
1170         (catch 'next
1171           (when (and (or (null maxlevel)
1172                          (>= maxlevel
1173                              (if org-odd-levels-only
1174                                  (/ (1+ (length (match-string 1))) 2)
1175                                (length (match-string 1)))))
1176                      (get-char-property (match-beginning 0) 'org-columns-key))
1177             (when (or (org-in-commented-heading-p t)
1178                       (save-excursion
1179                         (beginning-of-line)
1180                         (looking-at re-archive)))
1181               (org-end-of-subtree t)
1182               (throw 'next t))
1183             (setq row nil)
1184             (loop for i from 0 to (1- n) do
1185                   (push
1186                    (org-quote-vert
1187                     (or (get-char-property (+ (match-beginning 0) i) 'org-columns-value-modified)
1188                         (get-char-property (+ (match-beginning 0) i) 'org-columns-value)
1189                         ""))
1190                    row))
1191             (setq row (nreverse row))
1192             (unless (and skip-empty-rows
1193                          (eq 1 (length (delete "" (delete-dups (copy-sequence row))))))
1194               (push row tbl)))))
1195       (append (list title 'hline) (nreverse tbl)))))
1196
1197 ;;;###autoload
1198 (defun org-dblock-write:columnview (params)
1199   "Write the column view table.
1200 PARAMS is a property list of parameters:
1201
1202 :width    enforce same column widths with <N> specifiers.
1203 :id       the :ID: property of the entry where the columns view
1204           should be built.  When the symbol `local', call locally.
1205           When `global' call column view with the cursor at the beginning
1206           of the buffer (usually this means that the whole buffer switches
1207           to column view).  When \"file:path/to/file.org\", invoke column
1208           view at the start of that file.  Otherwise, the ID is located
1209           using `org-id-find'.
1210 :hlines   When t, insert a hline before each item.  When a number, insert
1211           a hline before each level <= that number.
1212 :vlines   When t, make each column a colgroup to enforce vertical lines.
1213 :maxlevel When set to a number, don't capture headlines below this level.
1214 :skip-empty-rows
1215           When t, skip rows where all specifiers other than ITEM are empty.
1216 :format   When non-nil, specify the column view format to use."
1217   (let ((pos (point-marker))
1218         (hlines (plist-get params :hlines))
1219         (vlines (plist-get params :vlines))
1220         (maxlevel (plist-get params :maxlevel))
1221         (content-lines (org-split-string (plist-get params :content) "\n"))
1222         (skip-empty-rows (plist-get params :skip-empty-rows))
1223         (columns-fmt (plist-get params :format))
1224         (case-fold-search t)
1225         tbl id idpos nfields tmp recalc line
1226         id-as-string view-file view-pos)
1227     (when (setq id (plist-get params :id))
1228       (setq id-as-string (cond ((numberp id) (number-to-string id))
1229                                ((symbolp id) (symbol-name id))
1230                                ((stringp id) id)
1231                                (t "")))
1232       (cond ((not id) nil)
1233             ((eq id 'global) (setq view-pos (point-min)))
1234             ((eq id 'local))
1235             ((string-match "^file:\\(.*\\)" id-as-string)
1236              (setq view-file (match-string 1 id-as-string)
1237                    view-pos 1)
1238              (unless (file-exists-p view-file)
1239                (error "No such file: \"%s\"" id-as-string)))
1240             ((setq idpos (org-find-entry-with-id id))
1241              (setq view-pos idpos))
1242             ((setq idpos (org-id-find id))
1243              (setq view-file (car idpos))
1244              (setq view-pos (cdr idpos)))
1245             (t (error "Cannot find entry with :ID: %s" id))))
1246     (with-current-buffer (if view-file
1247                              (get-file-buffer view-file)
1248                            (current-buffer))
1249       (save-excursion
1250         (save-restriction
1251           (widen)
1252           (goto-char (or view-pos (point)))
1253           (org-columns columns-fmt)
1254           (setq tbl (org-columns-capture-view maxlevel skip-empty-rows))
1255           (setq nfields (length (car tbl)))
1256           (org-columns-quit))))
1257     (goto-char pos)
1258     (move-marker pos nil)
1259     (when tbl
1260       (when (plist-get params :hlines)
1261         (setq tmp nil)
1262         (while tbl
1263           (if (eq (car tbl) 'hline)
1264               (push (pop tbl) tmp)
1265             (if (string-match "\\` *\\(\\*+\\)" (caar tbl))
1266                 (if (and (not (eq (car tmp) 'hline))
1267                          (or (eq hlines t)
1268                              (and (numberp hlines)
1269                                   (<= (- (match-end 1) (match-beginning 1))
1270                                       hlines))))
1271                     (push 'hline tmp)))
1272             (push (pop tbl) tmp)))
1273         (setq tbl (nreverse tmp)))
1274       (when vlines
1275         (setq tbl (mapcar (lambda (x)
1276                             (if (eq 'hline x) x (cons "" x)))
1277                           tbl))
1278         (setq tbl (append tbl (list (cons "/" (make-list nfields "<>"))))))
1279       (when content-lines
1280         (while (string-match "^#" (car content-lines))
1281           (insert (pop content-lines) "\n")))
1282       (setq pos (point))
1283       (insert (org-listtable-to-string tbl))
1284       (when (plist-get params :width)
1285         (insert "\n|" (mapconcat (lambda (x) (format "<%d>" (max 3 x)))
1286                                  org-columns-current-widths "|")))
1287       (while (setq line (pop content-lines))
1288         (when (string-match "^#" line)
1289           (insert "\n" line)
1290           (when (string-match "^[ \t]*#\\+tblfm" line)
1291             (setq recalc t))))
1292       (if recalc
1293           (progn (goto-char pos) (org-table-recalculate 'all))
1294         (goto-char pos)
1295         (org-table-align)))))
1296
1297 (defun org-listtable-to-string (tbl)
1298   "Convert a listtable TBL to a string that contains the Org-mode table.
1299 The table still need to be aligned.  The resulting string has no leading
1300 and tailing newline characters."
1301   (mapconcat
1302    (lambda (x)
1303      (cond
1304       ((listp x)
1305        (concat "|" (mapconcat 'identity x "|") "|"))
1306       ((eq x 'hline) "|-|")
1307       (t (error "Garbage in listtable: %s" x))))
1308    tbl "\n"))
1309
1310 ;;;###autoload
1311 (defun org-insert-columns-dblock ()
1312   "Create a dynamic block capturing a column view table."
1313   (interactive)
1314   (let ((defaults '(:name "columnview" :hlines 1))
1315         (id (org-icompleting-read
1316              "Capture columns (local, global, entry with :ID: property) [local]: "
1317              (append '(("global") ("local"))
1318                      (mapcar 'list (org-property-values "ID"))))))
1319     (if (equal id "") (setq id 'local))
1320     (if (equal id "global") (setq id 'global))
1321     (setq defaults (append defaults (list :id id)))
1322     (org-create-dblock defaults)
1323     (org-update-dblock)))
1324
1325 ;;; Column view in the agenda
1326
1327 (defvar org-agenda-view-columns-initially nil
1328   "When set, switch to columns view immediately after creating the agenda.")
1329
1330 (defvar org-agenda-columns-show-summaries) ; defined in org-agenda.el
1331 (defvar org-agenda-columns-compute-summary-properties); defined in org-agenda.el
1332 (defvar org-agenda-columns-add-appointments-to-effort-sum); as well
1333
1334 ;;;###autoload
1335 (defun org-agenda-columns ()
1336   "Turn on or update column view in the agenda."
1337   (interactive)
1338   (org-verify-version 'columns)
1339   (org-columns-remove-overlays)
1340   (move-marker org-columns-begin-marker (point))
1341   (let ((org-columns-time (time-to-number-of-days (current-time)))
1342         cache maxwidths m p a d fmt)
1343     (cond
1344      ((and (boundp 'org-agenda-overriding-columns-format)
1345            org-agenda-overriding-columns-format)
1346       (setq fmt org-agenda-overriding-columns-format))
1347      ((setq m (org-get-at-bol 'org-hd-marker))
1348       (setq fmt (or (org-entry-get m "COLUMNS" t)
1349                     (with-current-buffer (marker-buffer m)
1350                       org-columns-default-format))))
1351      ((and (boundp 'org-columns-current-fmt)
1352            (local-variable-p 'org-columns-current-fmt)
1353            org-columns-current-fmt)
1354       (setq fmt org-columns-current-fmt))
1355      ((setq m (next-single-property-change (point-min) 'org-hd-marker))
1356       (setq m (get-text-property m 'org-hd-marker))
1357       (setq fmt (or (org-entry-get m "COLUMNS" t)
1358                     (with-current-buffer (marker-buffer m)
1359                       org-columns-default-format)))))
1360     (setq fmt (or fmt org-columns-default-format))
1361     (org-set-local 'org-columns-current-fmt fmt)
1362     (org-columns-compile-format fmt)
1363     (when org-agenda-columns-compute-summary-properties
1364       (org-agenda-colview-compute org-columns-current-fmt-compiled))
1365     (save-excursion
1366       ;; Get and cache the properties
1367       (goto-char (point-min))
1368       (while (not (eobp))
1369         (when (setq m (or (org-get-at-bol 'org-hd-marker)
1370                           (org-get-at-bol 'org-marker)))
1371           (setq p (org-entry-properties m))
1372
1373           (when (or (not (setq a (assoc org-effort-property p)))
1374                     (not (string-match "\\S-" (or (cdr a) ""))))
1375             ;; OK, the property is not defined.  Use appointment duration?
1376             (when (and org-agenda-columns-add-appointments-to-effort-sum
1377                        (setq d (get-text-property (point) 'duration)))
1378               (setq d (org-minutes-to-clocksum-string d))
1379               (put-text-property 0 (length d) 'face 'org-warning d)
1380               (push (cons org-effort-property d) p)))
1381           (push (cons (org-current-line) p) cache))
1382         (beginning-of-line 2))
1383       (when cache
1384         (setq maxwidths (org-columns-get-autowidth-alist fmt cache))
1385         (org-set-local 'org-columns-current-maxwidths maxwidths)
1386         (org-columns-display-here-title)
1387         (when (org-set-local 'org-columns-flyspell-was-active
1388                              (org-bound-and-true-p flyspell-mode))
1389           (flyspell-mode 0))
1390         (mapc (lambda (x)
1391                 (org-goto-line (car x))
1392                 (org-columns-display-here (cdr x)))
1393               cache)
1394         (when org-agenda-columns-show-summaries
1395           (org-agenda-colview-summarize cache))))))
1396
1397 (defun org-agenda-colview-summarize (cache)
1398   "Summarize the summarizable columns in column view in the agenda.
1399 This will add overlays to the date lines, to show the summary for each day."
1400   (let* ((fmt (mapcar (lambda (x)
1401                         (if (string-match "CLOCKSUM.*" (car x))
1402                             (list (match-string 0 (car x))
1403                                   (nth 1 x) (nth 2 x) ":" 'add_times
1404                                   nil '+ nil)
1405                           x))
1406                       org-columns-current-fmt-compiled))
1407          line c c1 stype calc sumfunc props lsum entries prop v title)
1408     (catch 'exit
1409       (when (delq nil (mapcar 'cadr fmt))
1410         ;; OK, at least one summation column, it makes sense to try this
1411         (goto-char (point-max))
1412         (while t
1413           (when (or (get-text-property (point) 'org-date-line)
1414                     (eq (get-text-property (point) 'face)
1415                         'org-agenda-structure))
1416             ;; OK, this is a date line that should be used
1417             (setq line (org-current-line))
1418             (setq entries nil c cache cache nil)
1419             (while (setq c1 (pop c))
1420               (if (> (car c1) line)
1421                   (push c1 entries)
1422                 (push c1 cache)))
1423             ;; now ENTRIES are the ones we want to use, CACHE is the rest
1424             ;; Compute the summaries for the properties we want,
1425             ;; set nil properties for the rest.
1426             (when (setq entries (mapcar 'cdr entries))
1427               (setq props
1428                     (mapcar
1429                      (lambda (f)
1430                        (setq prop (car f)
1431                              title (nth 1 f)
1432                              stype (nth 4 f)
1433                              sumfunc (nth 6 f)
1434                              calc (or (nth 7 f) 'identity))
1435                        (cond
1436                         ((equal prop "ITEM")
1437                          (cons prop (buffer-substring (point-at-bol)
1438                                                       (point-at-eol))))
1439                         ((not stype) (cons prop ""))
1440                         (t ;; do the summary
1441                          (setq lsum nil)
1442                          (dolist (x entries)
1443                            (setq v (cdr (assoc prop x)))
1444                            (if v
1445                                (push
1446                                 (funcall
1447                                  (if (not (get-text-property 0 'org-computed v))
1448                                      calc
1449                                    'identity)
1450                                  (org-columns-string-to-number
1451                                   v stype))
1452                                 lsum)))
1453                          (setq lsum (remove nil lsum))
1454                          (setq lsum
1455                                (cond ((> (length lsum) 1)
1456                                       (org-columns-number-to-string
1457                                        (apply sumfunc lsum) stype))
1458                                      ((eq (length lsum) 1)
1459                                       (org-columns-number-to-string
1460                                        (car lsum) stype))
1461                                      (t "")))
1462                          (put-text-property 0 (length lsum) 'face 'bold lsum)
1463                          (unless (eq calc 'identity)
1464                            (put-text-property 0 (length lsum) 'org-computed t lsum))
1465                          (cons prop lsum))))
1466                      fmt))
1467               (org-columns-display-here props 'dateline)
1468               (org-set-local 'org-agenda-columns-active t)))
1469           (if (bobp) (throw 'exit t))
1470           (beginning-of-line 0))))))
1471
1472 (defun org-agenda-colview-compute (fmt)
1473   "Compute the relevant columns in the contributing source buffers."
1474   (let ((files org-agenda-contributing-files)
1475         (org-columns-begin-marker (make-marker))
1476         (org-columns-top-level-marker (make-marker))
1477         f fm a b)
1478     (while (setq f (pop files))
1479       (setq b (find-buffer-visiting f))
1480       (with-current-buffer (or (buffer-base-buffer b) b)
1481         (save-excursion
1482           (save-restriction
1483             (widen)
1484             (org-with-silent-modifications
1485              (remove-text-properties (point-min) (point-max) '(org-summaries t)))
1486             (goto-char (point-min))
1487             (org-columns-get-format-and-top-level)
1488             (while (setq fm (pop fmt))
1489               (cond ((equal (car fm) "CLOCKSUM")
1490                      (org-clock-sum))
1491                     ((equal (car fm) "CLOCKSUM_T")
1492                      (org-clock-sum-today))
1493                     ((and (nth 4 fm)
1494                           (setq a (assoc (car fm)
1495                                          org-columns-current-fmt-compiled))
1496                           (equal (nth 4 a) (nth 4 fm)))
1497                      (org-columns-compute (car fm)))))))))))
1498
1499 (defun org-format-time-period (interval)
1500   "Convert time in fractional days to days/hours/minutes/seconds."
1501   (if (numberp interval)
1502       (let* ((days (floor interval))
1503              (frac-hours (* 24 (- interval days)))
1504              (hours (floor frac-hours))
1505              (minutes (floor (* 60 (- frac-hours hours))))
1506              (seconds (floor (* 60 (- (* 60 (- frac-hours hours)) minutes)))))
1507         (format "%dd %02dh %02dm %02ds" days hours minutes seconds))
1508     ""))
1509
1510 (defun org-estimate-mean-and-var (v)
1511   "Return the mean and variance of an estimate."
1512   (let* ((low (float (car v)))
1513          (high (float (cadr v)))
1514          (mean (/ (+ low high) 2.0))
1515          (var (/ (+ (expt (- mean low) 2.0) (expt (- high mean) 2.0)) 2.0)))
1516     (list  mean var)))
1517
1518 (defun org-estimate-combine (&rest el)
1519   "Combine a list of estimates, using mean and variance.
1520 The mean and variance of the result will be the sum of the means
1521 and variances (respectively) of the individual estimates."
1522   (let ((mean 0)
1523         (var 0))
1524     (mapc (lambda (e)
1525             (let ((stats (org-estimate-mean-and-var e)))
1526               (setq mean (+ mean (car stats)))
1527               (setq var (+ var (cadr stats)))))
1528           el)
1529     (let ((stdev (sqrt var)))
1530       (list (- mean stdev) (+ mean stdev)))))
1531
1532 (defun org-estimate-print (e &optional fmt)
1533   "Prepare a string representation of an estimate.
1534 This formats these numbers as two numbers with a \"-\" between them."
1535   (if (null fmt) (set 'fmt "%.0f"))
1536   (format "%s" (mapconcat (lambda (n) (format fmt n))  e "-")))
1537
1538 (defun org-string-to-estimate (s)
1539   "Convert a string to an estimate.
1540 The string should be two numbers joined with a \"-\"."
1541   (if (string-match "\\(.*\\)-\\(.*\\)" s)
1542       (list (string-to-number (match-string 1 s))
1543             (string-to-number(match-string 2 s)))
1544     (list (string-to-number s) (string-to-number s))))
1545
1546 (provide 'org-colview)
1547
1548 ;;; org-colview.el ends here