lisp/ob-latex.el

   1 ;;; ob-latex.el --- org-babel functions for latex "evaluation"
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating LaTeX source code.
  27 ;;
  28 ;; Currently on evaluation this returns raw LaTeX code, unless a :file
  29 ;; header argument is given in which case small png or pdf files will
  30 ;; be created directly form the latex source code.
  31
  32 ;;; Code:
  33 (require 'ob)
  34
  35 (declare-function org-create-formula-image "org" (string tofile options buffer))
  36 (declare-function org-splice-latex-header "org"
  37                   (tpl def-pkg pkg snippets-p &optional extra))
  38 (declare-function org-latex-guess-inputenc "ox-latex" (header))
  39 (declare-function org-latex-compile "ox-latex" (file))
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("latex" . "tex"))
  43
  44 (defvar org-format-latex-header)          ; From org.el
  45 (defvar org-format-latex-options)         ; From org.el
  46 (defvar org-latex-default-packages-alist) ; From org.el
  47 (defvar org-latex-packages-alist)         ; From org.el
  48
  49 (defvar org-babel-default-header-args:latex
  50   '((:results . "latex") (:exports . "results"))
  51   "Default arguments to use when evaluating a LaTeX source block.")
  52
  53 (defcustom org-babel-latex-htlatex "htlatex"
  54   "The htlatex command to enable conversion of latex to SVG or HTML."
  55   :group 'org-babel
  56   :type 'string)
  57
  58 (defcustom org-babel-latex-htlatex-packages
  59   '("[usenames]{color}" "{tikz}" "{color}" "{listings}" "{amsmath}")
  60   "Packages to use for htlatex export."
  61   :group 'org-babel
  62   :type '(repeat (string)))
  63
  64 (defun org-babel-expand-body:latex (body params)
  65   "Expand BODY according to PARAMS, return the expanded body."
  66   (mapc (lambda (pair) ;; replace variables
  67           (setq body
  68                 (replace-regexp-in-string
  69                  (regexp-quote (format "%S" (car pair)))
  70                  (if (stringp (cdr pair))
  71                      (cdr pair) (format "%S" (cdr pair)))
  72                  body))) (mapcar #'cdr (org-babel-get-header params :var)))
  73   (org-babel-trim body))
  74
  75 (defun org-babel-execute:latex (body params)
  76   "Execute a block of Latex code with Babel.
  77 This function is called by `org-babel-execute-src-block'."
  78   (setq body (org-babel-expand-body:latex body params))
  79   (if (cdr (assoc :file params))
  80       (let* ((out-file (cdr (assoc :file params)))
  81              (tex-file (org-babel-temp-file "latex-" ".tex"))
  82              (border (cdr (assoc :border params)))
  83              (imagemagick (cdr (assoc :imagemagick params)))
  84              (im-in-options (cdr (assoc :iminoptions params)))
  85              (im-out-options (cdr (assoc :imoutoptions params)))
  86              (pdfpng (cdr (assoc :pdfpng params)))
  87              (fit (or (cdr (assoc :fit params)) border))
  88              (height (and fit (cdr (assoc :pdfheight params))))
  89              (width (and fit (cdr (assoc :pdfwidth params))))
  90              (headers (cdr (assoc :headers params)))
  91              (in-buffer (not (string= "no" (cdr (assoc :buffer params)))))
  92              (org-latex-packages-alist
  93               (append (cdr (assoc :packages params)) org-latex-packages-alist)))
  94         (cond
  95          ((and (string-match "\\.png$" out-file) (not imagemagick))
  96           (org-create-formula-image
  97            body out-file org-format-latex-options in-buffer))
  98          ((string-match "\\.tikz$" out-file)
  99           (when (file-exists-p out-file) (delete-file out-file))
 100           (with-temp-file out-file
 101             (insert body)))
 102          ((or (string-match "\\.pdf$" out-file) imagemagick)
 103           (with-temp-file tex-file
 104             (require 'ox-latex)
 105             (insert
 106              (org-latex-guess-inputenc
 107               (org-splice-latex-header
 108                org-format-latex-header
 109                (delq
 110                 nil
 111                 (mapcar
 112                  (lambda (el)
 113                    (unless (and (listp el) (string= "hyperref" (cadr el)))
 114                      el))
 115                  org-latex-default-packages-alist))
 116                org-latex-packages-alist
 117                nil))
 118              (if fit "\n\\usepackage[active, tightpage]{preview}\n" "")
 119              (if border (format "\\setlength{\\PreviewBorder}{%s}" border) "")
 120              (if height (concat "\n" (format "\\pdfpageheight %s" height)) "")
 121              (if width  (concat "\n" (format "\\pdfpagewidth %s" width))   "")
 122              (if headers
 123                  (concat "\n"
 124                          (if (listp headers)
 125                              (mapconcat #'identity headers "\n")
 126                            headers) "\n")
 127                "")
 128              (if fit
 129                  (concat "\n\\begin{document}\n\\begin{preview}\n" body
 130                          "\n\\end{preview}\n\\end{document}\n")
 131                (concat "\n\\begin{document}\n" body "\n\\end{document}\n"))))
 132           (when (file-exists-p out-file) (delete-file out-file))
 133           (let ((transient-pdf-file (org-babel-latex-tex-to-pdf tex-file)))
 134             (cond
 135              ((string-match "\\.pdf$" out-file)
 136               (rename-file transient-pdf-file out-file))
 137              (imagemagick
 138               (org-babel-latex-convert-pdf
 139                transient-pdf-file out-file im-in-options im-out-options)
 140               (when (file-exists-p transient-pdf-file)
 141                 (delete-file transient-pdf-file))))))
 142          ((and (or (string-match "\\.svg$" out-file)
 143                    (string-match "\\.html$" out-file))
 144                (executable-find org-babel-latex-htlatex))
 145           ;; TODO: this is a very different way of generating the
 146           ;; frame latex document than in the pdf case.  Ideally, both
 147           ;; would be unified.  This would prevent bugs creeping in
 148           ;; such as the one fixed on Aug 16 2014 whereby :headers was
 149           ;; not included in the SVG/HTML case.
 150           (with-temp-file tex-file
 151             (insert (concat
 152                      "\\documentclass[preview]{standalone}
 153 \\def\\pgfsysdriver{pgfsys-tex4ht.def}
 154 "
 155                      (mapconcat (lambda (pkg)
 156                                   (concat "\\usepackage" pkg))
 157                                 org-babel-latex-htlatex-packages
 158                                 "\n")
 159                      (if headers
 160                          (concat "\n"
 161                                  (if (listp headers)
 162                                      (mapconcat #'identity headers "\n")
 163                                    headers) "\n")
 164                        "")
 165                      "\\begin{document}"
 166                      body
 167                      "\\end{document}")))
 168           (when (file-exists-p out-file) (delete-file out-file))
 169           (let ((default-directory (file-name-directory tex-file)))
 170             (shell-command (format "%s %s" org-babel-latex-htlatex tex-file)))
 171           (cond
 172            ((file-exists-p (concat (file-name-sans-extension tex-file) "-1.svg"))
 173             (if (string-match "\\.svg$" out-file)
 174                 (progn
 175                   (shell-command "pwd")
 176                   (shell-command (format "mv %s %s"
 177                                          (concat (file-name-sans-extension tex-file) "-1.svg")
 178                                          out-file)))
 179               (error "SVG file produced but HTML file requested")))
 180            ((file-exists-p (concat (file-name-sans-extension tex-file) ".html"))
 181             (if (string-match "\\.html$" out-file)
 182                 (shell-command "mv %s %s"
 183                                (concat (file-name-sans-extension tex-file)
 184                                        ".html")
 185                                out-file)
 186               (error "HTML file produced but SVG file requested")))))
 187          ((string-match "\\.\\([^\\.]+\\)$" out-file)
 188           (error "Can not create %s files, please specify a .png or .pdf file or try the :imagemagick header argument"
 189                  (match-string 1 out-file))))
 190         nil) ;; signal that output has already been written to file
 191     body))
 192
 193 (defun org-babel-latex-convert-pdf (pdffile out-file im-in-options im-out-options)
 194   "Generate a file from a pdf file using imagemagick."
 195   (let ((cmd (concat "convert " im-in-options " " pdffile " "
 196                      im-out-options " " out-file)))
 197     (message (concat "Converting pdffile file " cmd  "..."))
 198     (shell-command cmd)))
 199
 200 (defun org-babel-latex-tex-to-pdf (file)
 201   "Generate a pdf file according to the contents FILE."
 202   (require 'ox-latex)
 203   (org-latex-compile file))
 204
 205 (defun org-babel-prep-session:latex (session params)
 206   "Return an error because LaTeX doesn't support sessions."
 207   (error "LaTeX does not support sessions"))
 208
 209
 210 (provide 'ob-latex)
 211 ;;; ob-latex.el ends here