lisp/org-remember.el

   1 ;;; org-remember.el --- Fast note taking in Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.36trans
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the system to take fast notes with Org-mode.
  30 ;; This system is used together with John Wiegley's `remember.el'.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile
  35   (require 'cl))
  36 (require 'org)
  37 (require 'org-datetree)
  38
  39 (declare-function remember-mode "remember" ())
  40 (declare-function remember "remember" (&optional initial))
  41 (declare-function remember-buffer-desc "remember" ())
  42 (declare-function remember-finalize "remember" ())
  43 (defvar remember-save-after-remembering)
  44 (defvar remember-register)
  45 (defvar remember-buffer)
  46 (defvar remember-handler-functions)
  47 (defvar remember-annotation-functions)
  48 (defvar org-clock-heading)
  49 (defvar org-clock-heading-for-remember)
  50
  51 (defgroup org-remember nil
  52   "Options concerning interaction with remember.el."
  53   :tag "Org Remember"
  54   :group 'org)
  55
  56 (defcustom org-remember-store-without-prompt t
  57   "Non-nil means `C-c C-c' stores remember note without further prompts.
  58 It then uses the file and headline specified by the template or (if the
  59 template does not specify them) by the variables `org-default-notes-file'
  60 and `org-remember-default-headline'.  To force prompting anyway, use
  61 `C-u C-c C-c' to file the note.
  62
  63 When this variable is nil, `C-c C-c' gives you the prompts, and
  64 `C-u C-c C-c' triggers the fasttrack."
  65   :group 'org-remember
  66   :type 'boolean)
  67
  68 (defcustom org-remember-interactive-interface 'refile
  69   "The interface to be used for interactive filing of remember notes.
  70 This is only used when the interactive mode for selecting a filing
  71 location is used (see the variable `org-remember-store-without-prompt').
  72 Allowed values are:
  73 outline                  The interface shows an outline of the relevant file
  74                          and the correct heading is found by moving through
  75                          the outline or by searching with incremental search.
  76 outline-path-completion  Headlines in the current buffer are offered via
  77                          completion.
  78 refile                   Use the refile interface, and offer headlines,
  79                          possibly from different buffers."
  80   :group 'org-remember
  81   :type '(choice
  82           (const :tag "Refile" refile)
  83           (const :tag "Outline" outline)
  84           (const :tag "Outline-path-completion" outline-path-completion)))
  85
  86 (defcustom org-remember-default-headline ""
  87   "The headline that should be the default location in the notes file.
  88 When filing remember notes, the cursor will start at that position.
  89 You can set this on a per-template basis with the variable
  90 `org-remember-templates'."
  91   :group 'org-remember
  92   :type 'string)
  93
  94 (defcustom org-remember-templates nil
  95   "Templates for the creation of remember buffers.
  96 When nil, just let remember make the buffer.
  97 When non-nil, this is a list of (up to) 6-element lists.  In each entry,
  98 the first element is the name of the template, which should be a single
  99 short word.  The second element is a character, a unique key to select
 100 this template.  The third element is the template.
 101
 102 The fourth element is optional and can specify a destination file for
 103 remember items created with this template.  The default file is given
 104 by `org-default-notes-file'.  If the file name is not an absolute path,
 105 it will be interpreted relative to `org-directory'.
 106
 107 An optional fifth element can specify the headline in that file that should
 108 be offered first when the user is asked to file the entry.  The default
 109 headline is given in the variable `org-remember-default-headline'.  When
 110 this element is `top' or `bottom', the note will be placed as a level-1
 111 entry at the beginning or end of the file, respectively.
 112
 113 An optional sixth element specifies the contexts in which the template
 114 will be offered to the user.  This element can be a list of major modes
 115 or a function, and the template will only be offered if `org-remember'
 116 is called from a mode in the list, or if the function returns t.
 117 Templates that specify t or nil for the context will always be added
 118 to the list of selectable templates.
 119
 120 The template specifies the structure of the remember buffer.  It should have
 121 a first line starting with a star, to act as the org-mode headline.
 122 Furthermore, the following %-escapes will be replaced with content:
 123
 124   %^{PROMPT}  Prompt the user for a string and replace this sequence with it.
 125               A default value and a completion table can be specified like this:
 126               %^{prompt|default|completion2|completion3|...}
 127               The arrow keys access a prompt-specific history.
 128   %a          annotation, normally the link created with `org-store-link'
 129   %A          like %a, but prompt for the description part
 130   %i          Initial content, copied from the active region.  If %i is
 131               indented, the entire inserted text will be indented as well.
 132
 133   %t          time stamp, date only
 134   %T          time stamp with date and time
 135   %u, %U      like the above, but inactive time stamps
 136   %^t         like %t, but prompt for date.  Similarly %^T, %^u, %^U.
 137               You may define a prompt like %^{Please specify birthday}t
 138   %n          user name (taken from `user-full-name')
 139   %c          current kill ring head
 140   %x          content of the X clipboard
 141   %:keyword   specific information for certain link types, see below
 142   %^C         interactive selection of which kill or clip to use
 143   %^L         like %^C, but insert as link
 144   %k          title of the currently clocked task
 145   %K          link to the currently clocked task
 146   %^g         prompt for tags, completing tags in the target file
 147   %^G         prompt for tags, completing all tags in all agenda files
 148   %^{PROP}p   Prompt the user for a value for property PROP
 149   %[PATHNAME] insert the contents of the file given by PATHNAME
 150   %(SEXP)     evaluate elisp `(SEXP)' and replace with the result
 151   %!          store this note immediately after completing the template
 152               (skipping the `C-c C-c' that normally triggers storing)
 153   %&          jump to target location immediately after storing note
 154
 155   %?          After completing the template, position cursor here.
 156
 157 Apart from these general escapes, you can access information specific to the
 158 link type that is created.  For example, calling `remember' in emails or gnus
 159 will record the author and the subject of the message, which you can access
 160 with %:author and %:subject, respectively.  Here is a complete list of what
 161 is recorded for each link type.
 162
 163 Link type          |  Available information
 164 -------------------+------------------------------------------------------
 165 bbdb               |  %:type %:name %:company
 166 vm, wl, mh, rmail  |  %:type %:subject %:message-id
 167                    |  %:from %:fromname %:fromaddress
 168                    |  %:to   %:toname   %:toaddress
 169                    |  %:fromto (either \"to NAME\" or \"from NAME\")
 170 gnus               |  %:group, for messages also all email fields
 171 w3, w3m            |  %:type %:url
 172 info               |  %:type %:file %:node
 173 calendar           |  %:type %:date"
 174   :group 'org-remember
 175   :get (lambda (var) ; Make sure all entries have at least 5 elements
 176          (mapcar (lambda (x)
 177                    (if (not (stringp (car x))) (setq x (cons "" x)))
 178                    (cond ((= (length x) 4) (append x '(nil)))
 179                          ((= (length x) 3) (append x '(nil nil)))
 180                          (t x)))
 181                  (default-value var)))
 182   :type '(repeat
 183           :tag "enabled"
 184           (list :value ("" ?a "\n" nil nil nil)
 185                 (string :tag "Name")
 186                 (character :tag "Selection Key")
 187                 (string :tag "Template")
 188                 (choice :tag "Destination file"
 189                  (file :tag "Specify")
 190                  (function :tag "Function")
 191                  (const :tag "Use `org-default-notes-file'" nil))
 192                 (choice :tag "Destin. headline"
 193                  (string :tag "Specify")
 194                  (function :tag "Function")
 195                  (const :tag "Use `org-remember-default-headline'" nil)
 196                  (const :tag "At beginning of file" top)
 197                  (const :tag "At end of file" bottom)
 198                  (const :tag "In a date tree" date-tree))
 199                 (choice :tag "Context"
 200                  (const :tag "Use in all contexts" nil)
 201                  (const :tag "Use in all contexts" t)
 202                  (repeat :tag "Use only if in major mode"
 203                          (symbol :tag "Major mode"))
 204                  (function :tag "Perform a check against function")))))
 205
 206 (defcustom org-remember-delete-empty-lines-at-end t
 207   "Non-nil means clean up final empty lines in remember buffer."
 208   :group 'org-remember
 209   :type 'boolean)
 210
 211 (defcustom org-remember-before-finalize-hook nil
 212   "Hook that is run right before a remember process is finalized.
 213 The remember buffer is still current when this hook runs."
 214   :group 'org-remember
 215   :type 'hook)
 216
 217 (defvar org-remember-mode-map (make-sparse-keymap)
 218   "Keymap for org-remember-mode, a minor mode.
 219 Use this map to set additional keybindings for when Org-mode is used
 220 for a Remember buffer.")
 221 (defvar org-remember-mode-hook nil
 222   "Hook for the minor `org-remember-mode'.")
 223
 224 (define-minor-mode org-remember-mode
 225   "Minor mode for special key bindings in a remember buffer."
 226   nil " Rem" org-remember-mode-map
 227   (run-hooks 'org-remember-mode-hook))
 228 (define-key org-remember-mode-map "\C-c\C-c" 'org-remember-finalize)
 229 (define-key org-remember-mode-map "\C-c\C-k" 'org-remember-kill)
 230
 231 (defcustom org-remember-clock-out-on-exit 'query
 232   "Non-nil means stop the clock when exiting a clocking remember buffer.
 233 This only applies if the clock is running in the remember buffer.  If the
 234 clock is not stopped, it continues to run in the storage location.
 235 Instead of nil or t, this may also be the symbol `query' to prompt the
 236 user each time a remember buffer with a running clock is filed away.  "
 237   :group 'org-remember
 238   :type '(choice
 239           (const :tag "Never" nil)
 240           (const :tag "Always" t)
 241           (const :tag "Query user" query)))
 242
 243 (defcustom org-remember-backup-directory nil
 244   "Directory where to store all remember buffers, for backup purposes.
 245 After a remember buffer has been stored successfully, the backup file
 246 will be removed.  However, if you forget to finish the remember process,
 247 the file will remain there.
 248 See also `org-remember-auto-remove-backup-files'."
 249   :group 'org-remember
 250   :type '(choice
 251           (const :tag "No backups" nil)
 252           (directory :tag "Directory")))
 253
 254 (defcustom org-remember-auto-remove-backup-files t
 255   "Non-nil means remove remember backup files after successfully storage.
 256 When remember is finished successfully, with storing the note at the
 257 desired target, remove the backup files related to this remember process
 258 and show a message about remaining backup files, from previous, unfinished
 259 remember sessions.
 260 Backup files will only be made at all, when `org-remember-backup-directory'
 261 is set."
 262   :group 'org-remember
 263   :type 'boolean)
 264
 265 (defcustom org-remember-warn-about-backups t
 266   "Non-nil means warn about backup files in `org-remember-backup-directory'.
 267
 268 Set this to nil if you find that you don't need the warning.
 269
 270 If you cancel remember calls frequently and know when they
 271 contain useful information (because you know that you made an
 272 error or emacs crashed, for example) nil is more useful.  In the
 273 opposite case, the default, t, is more useful."
 274   :group 'org-remember
 275   :type 'boolean)
 276
 277 (defvar annotation) ; from remember.el, dynamically scoped in `remember-mode'
 278 (defvar initial)    ; from remember.el, dynamically scoped in `remember-mode'
 279
 280 ;;;###autoload
 281 (defun org-remember-insinuate ()
 282   "Setup remember.el for use with Org-mode."
 283   (org-require-remember)
 284   (setq remember-annotation-functions '(org-remember-annotation))
 285   (setq remember-handler-functions '(org-remember-handler))
 286   (add-hook 'remember-mode-hook 'org-remember-apply-template))
 287
 288 ;;;###autoload
 289 (defun org-remember-annotation ()
 290   "Return a link to the current location as an annotation for remember.el.
 291 If you are using Org-mode files as target for data storage with
 292 remember.el, then the annotations should include a link compatible with the
 293 conventions in Org-mode.  This function returns such a link."
 294   (org-store-link nil))
 295
 296 (defconst org-remember-help
 297 "Select a destination location for the note.
 298 UP/DOWN=headline   TAB=cycle visibility  [Q]uit   RET/<left>/<right>=Store
 299 RET on headline   -> Store as sublevel entry to current headline
 300 RET at beg-of-buf -> Append to file as level 2 headline
 301 <left>/<right>    -> before/after current headline, same headings level")
 302
 303 (defvar org-jump-to-target-location nil)
 304 (defvar org-remember-previous-location nil)
 305 (defvar org-remember-reference-date nil)
 306 (defvar org-force-remember-template-char) ;; dynamically scoped
 307
 308 ;; Save the major mode of the buffer we called remember from
 309 (defvar org-select-template-temp-major-mode nil)
 310
 311 ;; Temporary store the buffer where remember was called from
 312 (defvar org-select-template-original-buffer nil)
 313
 314 (defun org-select-remember-template (&optional use-char)
 315   (when org-remember-templates
 316     (let* ((pre-selected-templates
 317             (mapcar
 318              (lambda (tpl)
 319                (let ((ctxt (nth 5 tpl))
 320                      (mode org-select-template-temp-major-mode)
 321                      (buf org-select-template-original-buffer))
 322                  (and (or (not ctxt) (eq ctxt t)
 323                           (and (listp ctxt) (memq mode ctxt))
 324                           (and (functionp ctxt)
 325                                (with-current-buffer buf
 326                                  ;; Protect the user-defined function from error
 327                                  (condition-case nil (funcall ctxt) (error nil)))))
 328                       tpl)))
 329              org-remember-templates))
 330            ;; If no template at this point, add the default templates:
 331            (pre-selected-templates1
 332             (if (not (delq nil pre-selected-templates))
 333                 (mapcar (lambda(x) (if (not (nth 5 x)) x))
 334                         org-remember-templates)
 335               pre-selected-templates))
 336            ;; Then unconditionally add template for any contexts
 337            (pre-selected-templates2
 338             (append (mapcar (lambda(x) (if (eq (nth 5 x) t) x))
 339                             org-remember-templates)
 340                     (delq nil pre-selected-templates1)))
 341            (templates (mapcar (lambda (x)
 342                                 (if (stringp (car x))
 343                                     (append (list (nth 1 x) (car x)) (cddr x))
 344                                   (append (list (car x) "") (cdr x))))
 345                               (delq nil pre-selected-templates2)))
 346            msg
 347            (char (or use-char
 348                      (cond
 349                       ((= (length templates) 1)
 350                        (caar templates))
 351                       ((and (boundp 'org-force-remember-template-char)
 352                             org-force-remember-template-char)
 353                        (if (stringp org-force-remember-template-char)
 354                            (string-to-char org-force-remember-template-char)
 355                          org-force-remember-template-char))
 356                       (t
 357                        (setq msg (format
 358                                   "Select template: %s%s"
 359                                   (mapconcat
 360                                    (lambda (x)
 361                                      (cond
 362                                       ((not (string-match "\\S-" (nth 1 x)))
 363                                        (format "[%c]" (car x)))
 364                                       ((equal (downcase (car x))
 365                                               (downcase (aref (nth 1 x) 0)))
 366                                        (format "[%c]%s" (car x)
 367                                                (substring (nth 1 x) 1)))
 368                                       (t (format "[%c]%s" (car x) (nth 1 x)))))
 369                                    templates " ")
 370                                   (if (assoc ?C templates)
 371                                       ""
 372                                     " [C]customize templates")))
 373                        (let ((inhibit-quit t) char0)
 374                          (while (not char0)
 375                            (message msg)
 376                            (setq char0 (read-char-exclusive))
 377                            (when (and (not (assoc char0 templates))
 378                                       (not (equal char0 ?\C-g))
 379                                       (not (equal char0 ?C)))
 380                              (message "No such template \"%c\"" char0)
 381                              (ding) (sit-for 1)
 382                              (setq char0 nil)))
 383                          (when (equal char0 ?\C-g)
 384                            (jump-to-register remember-register)
 385                            (kill-buffer remember-buffer)
 386                            (error "Abort"))
 387                          (when (not (assoc char0 templates))
 388                            (jump-to-register remember-register)
 389                            (kill-buffer remember-buffer)
 390                            (customize-variable 'org-remember-templates)
 391                            (error "Customize templates"))
 392                          char0))))))
 393       (cddr (assoc char templates)))))
 394
 395 (defun org-get-x-clipboard (value)
 396   "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
 397   (if (eq window-system 'x)
 398       (let ((x (org-get-x-clipboard-compat value)))
 399         (if x (org-no-properties x)))))
 400
 401 ;;;###autoload
 402 (defun org-remember-apply-template (&optional use-char skip-interactive)
 403   "Initialize *remember* buffer with template, invoke `org-mode'.
 404 This function should be placed into `remember-mode-hook' and in fact requires
 405 to be run from that hook to function properly."
 406   (when (and (boundp 'initial) (stringp initial))
 407     (setq initial (org-no-properties initial))
 408     (remove-text-properties 0 (length initial) '(read-only t) initial))
 409   (if org-remember-templates
 410       (let* ((entry (org-select-remember-template use-char))
 411              (ct (or org-overriding-default-time (org-current-time)))
 412              (dct (decode-time ct))
 413              (ct1
 414               (if (< (nth 2 dct) org-extend-today-until)
 415                   (encode-time 0 59 23 (1- (nth 3 dct)) (nth 4 dct) (nth 5 dct))
 416                 ct))
 417              (tpl (car entry))
 418              (plist-p (if org-store-link-plist t nil))
 419              (file (if (and (nth 1 entry)
 420                             (or (and (stringp (nth 1 entry))
 421                                      (string-match "\\S-" (nth 1 entry)))
 422                                 (functionp (nth 1 entry))))
 423                        (nth 1 entry)
 424                      org-default-notes-file))
 425              (headline (nth 2 entry))
 426              (v-c (and (> (length kill-ring) 0) (current-kill 0)))
 427              (v-x (or (org-get-x-clipboard 'PRIMARY)
 428                       (org-get-x-clipboard 'CLIPBOARD)
 429                       (org-get-x-clipboard 'SECONDARY)))
 430              (v-t (format-time-string (car org-time-stamp-formats) ct))
 431              (v-T (format-time-string (cdr org-time-stamp-formats) ct))
 432              (v-u (concat "[" (substring v-t 1 -1) "]"))
 433              (v-U (concat "[" (substring v-T 1 -1) "]"))
 434              ;; `initial' and `annotation' are bound in `remember'.
 435              ;; But if the property list has them, we prefer those values
 436              (v-i (or (plist-get org-store-link-plist :initial)
 437                       (and (boundp 'initial) initial)
 438                       ""))
 439              (v-a (or (plist-get org-store-link-plist :annotation)
 440                       (and (boundp 'annotation) annotation)
 441                       ""))
 442              ;; Is the link empty?  Then we do not want it...
 443              (v-a (if (equal v-a "[[]]") "" v-a))
 444              (clipboards (remove nil (list v-i
 445                                            (org-get-x-clipboard 'PRIMARY)
 446                                            (org-get-x-clipboard 'CLIPBOARD)
 447                                            (org-get-x-clipboard 'SECONDARY)
 448                                            v-c)))
 449              (v-A (if (and v-a
 450                            (string-match "\\[\\(\\[.*?\\]\\)\\(\\[.*?\\]\\)?\\]" v-a))
 451                       (replace-match "[\\1[%^{Link description}]]" nil nil v-a)
 452                     v-a))
 453              (v-n user-full-name)
 454              (v-k (if (marker-buffer org-clock-marker)
 455                       (org-substring-no-properties org-clock-heading)))
 456              (v-K (if (marker-buffer org-clock-marker)
 457                       (org-make-link-string
 458                        (buffer-file-name (marker-buffer org-clock-marker))
 459                        org-clock-heading)))
 460              v-I
 461              (org-startup-folded nil)
 462              (org-inhibit-startup t)
 463              org-time-was-given org-end-time-was-given x
 464              prompt completions char time pos default histvar)
 465
 466         (when (functionp file)
 467           (setq file (funcall file)))
 468         (when (functionp headline)
 469           (setq headline (funcall headline)))
 470         (when (and file (not (file-name-absolute-p file)))
 471           (setq file (expand-file-name file org-directory)))
 472
 473         (setq org-store-link-plist
 474               (plist-put org-store-link-plist :annotation v-a)
 475               org-store-link-plist
 476               (plist-put org-store-link-plist :initial v-i))
 477
 478         (unless tpl (setq tpl "") (message "No template") (ding) (sit-for 1))
 479         (erase-buffer)
 480         (insert (substitute-command-keys
 481                  (format
 482 "## %s  \"%s\" -> \"* %s\"
 483 ## C-u C-c C-c  like C-c C-c, and immediately visit note at target location
 484 ## C-0 C-c C-c  \"%s\" -> \"* %s\"
 485 ## %s  to select file and header location interactively.
 486 ## C-2 C-c C-c  as child (C-3: as sibling) of the currently clocked item
 487 ## To switch templates, use `\\[org-remember]'.  To abort use `C-c C-k'.\n\n"
 488                   (if org-remember-store-without-prompt "    C-c C-c" "    C-1 C-c C-c")
 489                   (abbreviate-file-name (or file org-default-notes-file))
 490                   (or headline "")
 491                   (or (car org-remember-previous-location) "???")
 492                   (or (cdr org-remember-previous-location) "???")
 493                   (if org-remember-store-without-prompt "C-1 C-c C-c" "        C-c C-c"))))
 494         (insert tpl)
 495
 496         ;; %[] Insert contents of a file.
 497         (goto-char (point-min))
 498         (while (re-search-forward "%\\[\\(.+\\)\\]" nil t)
 499           (unless (org-remember-escaped-%)
 500             (let ((start (match-beginning 0))
 501                   (end (match-end 0))
 502                   (filename (expand-file-name (match-string 1))))
 503               (goto-char start)
 504               (delete-region start end)
 505               (condition-case error
 506                   (insert-file-contents filename)
 507                 (error (insert (format "%%![Couldn't insert %s: %s]"
 508                                        filename error)))))))
 509         ;; Simple %-escapes
 510         (goto-char (point-min))
 511         (while (re-search-forward "%\\([tTuUaiAcxkKI]\\)" nil t)
 512           (unless (org-remember-escaped-%)
 513             (when (and initial (equal (match-string 0) "%i"))
 514               (save-match-data
 515                 (let* ((lead (buffer-substring
 516                               (point-at-bol) (match-beginning 0))))
 517                   (setq v-i (mapconcat 'identity
 518                                        (org-split-string initial "\n")
 519                                        (concat "\n" lead))))))
 520             (replace-match
 521              (or (eval (intern (concat "v-" (match-string 1)))) "")
 522              t t)))
 523
 524         ;; %() embedded elisp
 525         (goto-char (point-min))
 526         (while (re-search-forward "%\\((.+)\\)" nil t)
 527           (unless (org-remember-escaped-%)
 528             (goto-char (match-beginning 0))
 529             (let ((template-start (point)))
 530               (forward-char 1)
 531               (let ((result
 532                      (condition-case error
 533                          (eval (read (current-buffer)))
 534                        (error (format "%%![Error: %s]" error)))))
 535                 (delete-region template-start (point))
 536                 (insert result)))))
 537
 538         ;; From the property list
 539         (when plist-p
 540           (goto-char (point-min))
 541           (while (re-search-forward "%\\(:[-a-zA-Z]+\\)" nil t)
 542           (unless (org-remember-escaped-%)
 543             (and (setq x (or (plist-get org-store-link-plist
 544                                         (intern (match-string 1))) ""))
 545                  (replace-match x t t)))))
 546
 547         ;; Turn on org-mode in the remember buffer, set local variables
 548         (let ((org-inhibit-startup t)) (org-mode) (org-remember-mode 1))
 549         (if (and file (string-match "\\S-" file) (not (file-directory-p file)))
 550             (org-set-local 'org-default-notes-file file))
 551         (if headline
 552             (org-set-local 'org-remember-default-headline headline))
 553         (org-set-local 'org-remember-reference-date
 554                        (list (nth 4 dct) (nth 3 dct) (nth 5 dct)))
 555         ;; Interactive template entries
 556         (goto-char (point-min))
 557         (while (re-search-forward "%^\\({\\([^}]*\\)}\\)?\\([gGtTuUCLp]\\)?" nil t)
 558           (unless (org-remember-escaped-%)
 559             (setq char (if (match-end 3) (match-string 3))
 560                   prompt (if (match-end 2) (match-string 2)))
 561             (goto-char (match-beginning 0))
 562             (replace-match "")
 563             (setq completions nil default nil)
 564             (when prompt
 565               (setq completions (org-split-string prompt "|")
 566                     prompt (pop completions)
 567                     default (car completions)
 568                     histvar (intern (concat
 569                                      "org-remember-template-prompt-history::"
 570                                      (or prompt "")))
 571                     completions (mapcar 'list completions)))
 572             (cond
 573              ((member char '("G" "g"))
 574               (let* ((org-last-tags-completion-table
 575                       (org-global-tags-completion-table
 576                        (if (equal char "G") (org-agenda-files) (and file (list file)))))
 577                      (org-add-colon-after-tag-completion t)
 578                      (ins (org-icompleting-read
 579                            (if prompt (concat prompt ": ") "Tags: ")
 580                            'org-tags-completion-function nil nil nil
 581                            'org-tags-history)))
 582                 (setq ins (mapconcat 'identity
 583                                      (org-split-string ins (org-re "[^[:alnum:]_@]+"))
 584                                      ":"))
 585                 (when (string-match "\\S-" ins)
 586                   (or (equal (char-before) ?:) (insert ":"))
 587                   (insert ins)
 588                   (or (equal (char-after) ?:) (insert ":")))))
 589              ((equal char "C")
 590               (cond ((= (length clipboards) 1) (insert (car clipboards)))
 591                     ((> (length clipboards) 1)
 592                      (insert (read-string "Clipboard/kill value: "
 593                                           (car clipboards) '(clipboards . 1)
 594                                           (car clipboards))))))
 595              ((equal char "L")
 596               (cond ((= (length clipboards) 1)
 597                      (org-insert-link 0 (car clipboards)))
 598                     ((> (length clipboards) 1)
 599                      (org-insert-link 0 (read-string "Clipboard/kill value: "
 600                                                      (car clipboards)
 601                                                      '(clipboards . 1)
 602                                                      (car clipboards))))))
 603              ((equal char "p")
 604               (let*
 605                   ((prop (org-substring-no-properties prompt))
 606                    (pall (concat prop "_ALL"))
 607                    (allowed
 608                     (with-current-buffer
 609                         (or (find-buffer-visiting file)
 610                             (find-file-noselect file))
 611                       (or (cdr (assoc pall org-file-properties))
 612                           (cdr (assoc pall org-global-properties))
 613                           (cdr (assoc pall org-global-properties-fixed)))))
 614                    (existing (with-current-buffer
 615                                  (or (find-buffer-visiting file)
 616                                      (find-file-noselect file))
 617                                (mapcar 'list (org-property-values prop))))
 618                    (propprompt (concat "Value for " prop ": "))
 619                    (val (if allowed
 620                             (org-completing-read
 621                              propprompt
 622                              (mapcar 'list (org-split-string allowed "[ \t]+"))
 623                              nil 'req-match)
 624                           (org-completing-read-no-i propprompt existing nil nil
 625                                                     "" nil ""))))
 626                 (org-set-property prop val)))
 627              (char
 628               ;; These are the date/time related ones
 629               (setq org-time-was-given (equal (upcase char) char))
 630               (setq time (org-read-date (equal (upcase char) "U") t nil
 631                                         prompt))
 632               (org-insert-time-stamp time org-time-was-given
 633                                      (member char '("u" "U"))
 634                                      nil nil (list org-end-time-was-given)))
 635              (t
 636               (let (org-completion-use-ido)
 637                 (insert (org-without-partial-completion
 638                          (org-completing-read-no-i
 639                           (concat (if prompt prompt "Enter string")
 640                                   (if default (concat " [" default "]"))
 641                                   ": ")
 642                           completions nil nil nil histvar default))))))))
 643
 644         (goto-char (point-min))
 645         (if (re-search-forward "%\\?" nil t)
 646             (replace-match "")
 647           (and (re-search-forward "^[^#\n]" nil t) (backward-char 1))))
 648     (let ((org-inhibit-startup t)) (org-mode) (org-remember-mode 1)))
 649   (when (save-excursion
 650           (goto-char (point-min))
 651           (re-search-forward "%&" nil t))
 652     (replace-match "")
 653     (org-set-local 'org-jump-to-target-location t))
 654   (when org-remember-backup-directory
 655     (unless (file-directory-p org-remember-backup-directory)
 656       (make-directory org-remember-backup-directory))
 657     (org-set-local 'auto-save-file-name-transforms nil)
 658     (setq buffer-file-name
 659           (expand-file-name
 660            (format-time-string "remember-%Y-%m-%d-%H-%M-%S")
 661            org-remember-backup-directory))
 662     (save-buffer)
 663     (org-set-local 'auto-save-visited-file-name t)
 664     (auto-save-mode 1))
 665   (when (save-excursion
 666           (goto-char (point-min))
 667           (re-search-forward "%!" nil t))
 668     (replace-match "")
 669     (add-hook 'post-command-hook 'org-remember-finish-immediately 'append)))
 670
 671 (defun org-remember-escaped-% ()
 672   (if (equal (char-before (match-beginning 0)) ?\\)
 673       (progn
 674         (delete-region (1- (match-beginning 0)) (match-beginning 0))
 675         t)
 676     nil))
 677
 678
 679 (defun org-remember-finish-immediately ()
 680   "File remember note immediately.
 681 This should be run in `post-command-hook' and will remove itself
 682 from that hook."
 683   (remove-hook 'post-command-hook 'org-remember-finish-immediately)
 684   (org-remember-finalize))
 685
 686 (defun org-remember-visit-immediately ()
 687   "File remember note immediately.
 688 This should be run in `post-command-hook' and will remove itself
 689 from that hook."
 690   (org-remember '(16))
 691   (goto-char (or (text-property-any
 692                   (point) (save-excursion (org-end-of-subtree t t))
 693                   'org-position-cursor t)
 694                  (point)))
 695   (message "%s"
 696            (format
 697             (substitute-command-keys
 698              "Restore window configuration with \\[jump-to-register] %c")
 699             remember-register)))
 700
 701 (defvar org-clock-marker) ; Defined in org.el
 702 (defun org-remember-finalize ()
 703   "Finalize the remember process."
 704   (interactive)
 705   (unless org-remember-mode
 706     (error "This does not seem to be a remember buffer for Org-mode"))
 707   (run-hooks 'org-remember-before-finalize-hook)
 708   (unless (fboundp 'remember-finalize)
 709     (defalias 'remember-finalize 'remember-buffer))
 710   (when (and org-clock-marker
 711              (equal (marker-buffer org-clock-marker) (current-buffer)))
 712     ;; the clock is running in this buffer.
 713     (when (and (equal (marker-buffer org-clock-marker) (current-buffer))
 714                (or (eq org-remember-clock-out-on-exit t)
 715                    (and org-remember-clock-out-on-exit
 716                         (y-or-n-p "The clock is running in this buffer.  Clock out now? "))))
 717       (let (org-log-note-clock-out) (org-clock-out))))
 718   (when buffer-file-name
 719     (do-auto-save))
 720   (remember-finalize))
 721
 722 (defun org-remember-kill ()
 723   "Abort the current remember process."
 724   (interactive)
 725   (let ((org-note-abort t))
 726     (org-remember-finalize)))
 727
 728 ;;;###autoload
 729 (defun org-remember (&optional goto org-force-remember-template-char)
 730   "Call `remember'.  If this is already a remember buffer, re-apply template.
 731 If there is an active region, make sure remember uses it as initial content
 732 of the remember buffer.
 733
 734 When called interactively with a `C-u' prefix argument GOTO, don't remember
 735 anything, just go to the file/headline where the selected template usually
 736 stores its notes.  With a double prefix arg `C-u C-u', go to the last
 737 note stored by remember.
 738
 739 Lisp programs can set ORG-FORCE-REMEMBER-TEMPLATE-CHAR to a character
 740 associated with a template in `org-remember-templates'."
 741   (interactive "P")
 742   (org-require-remember)
 743   (cond
 744    ((equal goto '(4)) (org-go-to-remember-target))
 745    ((equal goto '(16)) (org-remember-goto-last-stored))
 746    (t
 747     ;; set temporary variables that will be needed in
 748     ;; `org-select-remember-template'
 749     (setq org-select-template-temp-major-mode major-mode)
 750     (setq org-select-template-original-buffer (current-buffer))
 751     (if org-remember-mode
 752         (progn
 753           (when (< (length org-remember-templates) 2)
 754             (error "No other template available"))
 755           (erase-buffer)
 756           (let ((annotation (plist-get org-store-link-plist :annotation))
 757                 (initial (plist-get org-store-link-plist :initial)))
 758             (org-remember-apply-template))
 759           (message "Press C-c C-c to remember data"))
 760       (if (org-region-active-p)
 761           (org-do-remember (buffer-substring (point) (mark)))
 762         (org-do-remember))))))
 763
 764 (defvar org-remember-last-stored-marker (make-marker)
 765   "Marker pointing to the entry most recently stored with `org-remember'.")
 766
 767 (defun org-remember-goto-last-stored ()
 768   "Go to the location where the last remember note was stored."
 769   (interactive)
 770   (org-goto-marker-or-bmk org-remember-last-stored-marker
 771                           "org-remember-last-stored")
 772   (message "This is the last note stored by remember"))
 773
 774 (defun org-go-to-remember-target (&optional template-key)
 775   "Go to the target location of a remember template.
 776 The user is queried for the template."
 777   (interactive)
 778   (let* (org-select-template-temp-major-mode
 779          (entry (org-select-remember-template template-key))
 780          (file (nth 1 entry))
 781          (heading (nth 2 entry))
 782          visiting)
 783     (unless (and file (stringp file) (string-match "\\S-" file))
 784       (setq file org-default-notes-file))
 785     (when (and file (not (file-name-absolute-p file)))
 786       (setq file (expand-file-name file org-directory)))
 787     (unless (and heading (stringp heading) (string-match "\\S-" heading))
 788       (setq heading org-remember-default-headline))
 789     (setq visiting (org-find-base-buffer-visiting file))
 790     (if (not visiting) (find-file-noselect file))
 791     (switch-to-buffer (or visiting (get-file-buffer file)))
 792     (widen)
 793     (goto-char (point-min))
 794     (if (re-search-forward
 795          (format org-complex-heading-regexp-format (regexp-quote heading))
 796          nil t)
 797         (goto-char (match-beginning 0))
 798       (error "Target headline not found: %s" heading))))
 799
 800 ;; FIXME (bzg): let's clean up of final empty lines happen only once
 801 ;; (see the org-remember-delete-empty-lines-at-end option below)
 802 ;;;###autoload
 803 (defun org-remember-handler ()
 804   "Store stuff from remember.el into an org file.
 805 When the template has specified a file and a headline, the entry is filed
 806 there, or in the location defined by `org-default-notes-file' and
 807 `org-remember-default-headline'.
 808
 809 If no defaults have been defined, or if the current prefix argument
 810 is 1 (so you must use `C-1 C-c C-c' to exit remember), an interactive
 811 process is used to select the target location.
 812
 813 When the prefix is 0 (i.e. when remember is exited with `C-0 C-c C-c'),
 814 the entry is filed to the same location as the previous note.
 815
 816 When the prefix is 2 (i.e. when remember is exited with `C-2 C-c C-c'),
 817 the entry is filed as a subentry of the entry where the clock is
 818 currently running.
 819
 820 When `C-u' has been used as prefix argument, the note is stored and emacs
 821 moves point to the new location of the note, so that editing can be
 822 continued there (similar to inserting \"%&\" into the template).
 823
 824 Before storing the note, the function ensures that the text has an
 825 org-mode-style headline, i.e. a first line that starts with
 826 a \"*\".  If not, a headline is constructed from the current date and
 827 some additional data.
 828
 829 If the variable `org-adapt-indentation' is non-nil, the entire text is
 830 also indented so that it starts in the same column as the headline
 831 \(i.e. after the stars).
 832
 833 See also the variable `org-reverse-note-order'."
 834   (when (and (equal current-prefix-arg 2)
 835              (not (marker-buffer org-clock-marker)))
 836     (error "No running clock"))
 837   (when (org-bound-and-true-p org-jump-to-target-location)
 838     (let* ((end (min (point-max) (1+ (point))))
 839            (beg (point)))
 840       (if (= end beg) (setq beg (1- beg)))
 841       (put-text-property beg end 'org-position-cursor t)))
 842   (goto-char (point-min))
 843   (while (looking-at "^[ \t]*\n\\|^##.*\n")
 844     (replace-match ""))
 845   (when org-remember-delete-empty-lines-at-end
 846     (goto-char (point-max))
 847     (beginning-of-line 1)
 848     (while (and (looking-at "[ \t]*$\\|##.*") (> (point) 1))
 849       (delete-region (1- (point)) (point-max))
 850       (beginning-of-line 1)))
 851   (catch 'quit
 852     (if org-note-abort (throw 'quit t))
 853     (let* ((visitp (org-bound-and-true-p org-jump-to-target-location))
 854            (backup-file
 855             (and buffer-file-name
 856                  (equal (file-name-directory buffer-file-name)
 857                         (file-name-as-directory
 858                          (expand-file-name org-remember-backup-directory)))
 859                  (string-match "^remember-[0-9]\\{4\\}"
 860                                (file-name-nondirectory buffer-file-name))
 861                  buffer-file-name))
 862
 863            (dummy
 864             (unless (string-match "\\S-" (buffer-string))
 865               (message "Nothing to remember")
 866               (and backup-file
 867                    (ignore-errors
 868                      (delete-file backup-file)
 869                      (delete-file (concat backup-file "~"))))
 870               (set-buffer-modified-p nil)
 871               (throw 'quit t)))
 872            (reference-date org-remember-reference-date)
 873            (previousp (and (member current-prefix-arg '((16) 0))
 874                            org-remember-previous-location))
 875            (clockp (equal current-prefix-arg 2))
 876            (clocksp (equal current-prefix-arg 3))
 877            (fastp (org-xor (equal current-prefix-arg 1)
 878                            org-remember-store-without-prompt))
 879            (file (cond
 880                   (fastp org-default-notes-file)
 881                   ((and (eq org-remember-interactive-interface 'refile)
 882                         org-refile-targets)
 883                    org-default-notes-file)
 884                   ((not previousp)
 885                    (org-get-org-file))))
 886            (heading org-remember-default-headline)
 887            (visiting (and file (org-find-base-buffer-visiting file)))
 888            (org-startup-folded nil)
 889            (org-startup-align-all-tables nil)
 890            (org-goto-start-pos 1)
 891            spos exitcmd level reversed txt text-before-node-creation)
 892       (when (equal current-prefix-arg '(4))
 893         (setq visitp t))
 894       (when previousp
 895         (setq file (car org-remember-previous-location)
 896               visiting (and file (org-find-base-buffer-visiting file))
 897               heading (cdr org-remember-previous-location)
 898               fastp t))
 899       (when (or clockp clocksp)
 900         (setq file (buffer-file-name (marker-buffer org-clock-marker))
 901               visiting (and file (org-find-base-buffer-visiting file))
 902               heading org-clock-heading-for-remember
 903               fastp t))
 904       (setq current-prefix-arg nil)
 905       ;; Modify text so that it becomes a nice subtree which can be inserted
 906       ;; into an org tree.
 907       (when org-remember-delete-empty-lines-at-end
 908         (goto-char (point-min))
 909         (if (re-search-forward "[ \t\n]+\\'" nil t)
 910             ;; remove empty lines at end
 911             (replace-match "")))
 912       (goto-char (point-min))
 913       (setq text-before-node-creation (buffer-string))
 914       (unless (looking-at org-outline-regexp)
 915         ;; add a headline
 916         (insert (concat "* " (current-time-string)
 917                         " (" (remember-buffer-desc) ")\n"))
 918         (backward-char 1)
 919         (when org-adapt-indentation
 920           (while (re-search-forward "^" nil t)
 921             (insert "  "))))
 922       ;; Delete final empty lines
 923       (when org-remember-delete-empty-lines-at-end
 924         (goto-char (point-min))
 925         (if (re-search-forward "\n[ \t]*\n[ \t\n]*\\'" nil t)
 926             (replace-match "\n\n")
 927           (if (re-search-forward "[ \t\n]*\\'")
 928               (replace-match "\n"))))
 929       (goto-char (point-min))
 930       (setq txt (buffer-string))
 931       (org-save-markers-in-region (point-min) (point-max))
 932       (set-buffer-modified-p nil)
 933       (when (and (eq org-remember-interactive-interface 'refile)
 934                  (not fastp))
 935         (org-refile nil (or visiting (find-file-noselect file)))
 936         (and visitp (run-with-idle-timer 0.01 nil 'org-remember-visit-immediately))
 937         (save-excursion
 938           (bookmark-jump "org-refile-last-stored")
 939           (bookmark-set "org-remember-last-stored")
 940           (move-marker org-remember-last-stored-marker (point)))
 941         (throw 'quit t))
 942       ;; Find the file
 943       (with-current-buffer (or visiting (find-file-noselect file))
 944         (unless (or (org-mode-p) (member heading '(top bottom)))
 945           (error "Target files for notes must be in Org-mode if not filing to top/bottom"))
 946         (save-excursion
 947           (save-restriction
 948             (widen)
 949             (setq reversed (org-notes-order-reversed-p))
 950
 951             ;; Find the default location
 952             (when heading
 953               (cond
 954                ((not (org-mode-p))
 955                 (if (eq heading 'top)
 956                     (goto-char (point-min))
 957                   (goto-char (point-max))
 958                   (or (bolp) (newline)))
 959                 (insert text-before-node-creation)
 960                 (when remember-save-after-remembering
 961                   (save-buffer)
 962                   (if (not visiting) (kill-buffer (current-buffer))))
 963                 (throw 'quit t))
 964                ((eq heading 'top)
 965                 (goto-char (point-min))
 966                 (or (looking-at org-outline-regexp)
 967                     (re-search-forward org-outline-regexp nil t))
 968                 (setq org-goto-start-pos (or (match-beginning 0) (point-min))))
 969                ((eq heading 'bottom)
 970                 (goto-char (point-max))
 971                 (or (bolp) (newline))
 972                 (setq org-goto-start-pos (point)))
 973                ((eq heading 'date-tree)
 974                 (org-datetree-find-date-create reference-date)
 975                 (setq reversed nil)
 976                 (setq org-goto-start-pos (point)))
 977                ((and (stringp heading) (string-match "\\S-" heading))
 978                 (goto-char (point-min))
 979                 (if (re-search-forward
 980                      (format org-complex-heading-regexp-format
 981                              (regexp-quote heading))
 982                      nil t)
 983                     (setq org-goto-start-pos (match-beginning 0))
 984                   (when fastp
 985                     (goto-char (point-max))
 986                     (unless (bolp) (newline))
 987                     (insert "* " heading "\n")
 988                     (setq org-goto-start-pos (point-at-bol 0)))))
 989                (t (goto-char (point-min)) (setq org-goto-start-pos (point)
 990                                                 heading 'top))))
 991
 992             ;; Ask the User for a location, using the appropriate interface
 993             (cond
 994              ((and fastp (memq heading '(top bottom)))
 995               (setq spos org-goto-start-pos
 996                           exitcmd (if (eq heading 'top) 'left nil)))
 997              (fastp (setq spos org-goto-start-pos
 998                           exitcmd 'return))
 999              ((eq org-remember-interactive-interface 'outline)
1000               (setq spos (org-get-location (current-buffer)
1001                                            org-remember-help)
1002                     exitcmd (cdr spos)
1003                     spos (car spos)))
1004              ((eq org-remember-interactive-interface 'outline-path-completion)
1005               (let ((org-refile-targets '((nil . (:maxlevel . 10))))
1006                     (org-refile-use-outline-path t))
1007                 (setq spos (org-refile-get-location "Heading: ")
1008                       exitcmd 'return
1009                       spos (nth 3 spos))))
1010              (t (error "This should not happen")))
1011             (if (not spos) (throw 'quit nil)) ; return nil to show we did
1012                                         ; not handle this note
1013             (and visitp (run-with-idle-timer 0.01 nil 'org-remember-visit-immediately))
1014             (goto-char spos)
1015             (cond ((org-on-heading-p t)
1016                    (org-back-to-heading t)
1017                    (setq level (funcall outline-level))
1018                    (cond
1019                     ((eq exitcmd 'return)
1020                      ;; sublevel of current
1021                      (setq org-remember-previous-location
1022                            (cons (abbreviate-file-name file)
1023                                  (org-get-heading 'notags)))
1024                      (if reversed
1025                          (outline-next-heading)
1026                        (org-end-of-subtree t)
1027                        (if (not (bolp))
1028                            (if (looking-at "[ \t]*\n")
1029                                (beginning-of-line 2)
1030                              (end-of-line 1)
1031                              (insert "\n"))))
1032                      (org-paste-subtree (if clocksp
1033                                             level
1034                                           (org-get-valid-level level 1)) txt)
1035                      (and org-auto-align-tags (org-set-tags nil t))
1036                      (bookmark-set "org-remember-last-stored")
1037                      (move-marker org-remember-last-stored-marker (point)))
1038                     ((eq exitcmd 'left)
1039                      ;; before current
1040                      (org-paste-subtree level txt)
1041                      (and org-auto-align-tags (org-set-tags nil t))
1042                      (bookmark-set "org-remember-last-stored")
1043                      (move-marker org-remember-last-stored-marker (point)))
1044                     ((eq exitcmd 'right)
1045                      ;; after current
1046                      (org-end-of-subtree t)
1047                      (org-paste-subtree level txt)
1048                      (and org-auto-align-tags (org-set-tags nil t))
1049                      (bookmark-set "org-remember-last-stored")
1050                      (move-marker org-remember-last-stored-marker (point)))
1051                     (t (error "This should not happen"))))
1052
1053                   ((eq heading 'bottom)
1054                    (org-paste-subtree 1 txt)
1055                    (and org-auto-align-tags (org-set-tags nil t))
1056                    (bookmark-set "org-remember-last-stored")
1057                    (move-marker org-remember-last-stored-marker (point)))
1058
1059                   ((and (bobp) (not reversed))
1060                    ;; Put it at the end, one level below level 1
1061                    (save-restriction
1062                      (widen)
1063                      (goto-char (point-max))
1064                      (if (not (bolp)) (newline))
1065                      (org-paste-subtree (org-get-valid-level 1 1) txt)
1066                      (and org-auto-align-tags (org-set-tags nil t))
1067                      (bookmark-set "org-remember-last-stored")
1068                      (move-marker org-remember-last-stored-marker (point))))
1069
1070                   ((and (bobp) reversed)
1071                    ;; Put it at the start, as level 1
1072                    (save-restriction
1073                      (widen)
1074                      (goto-char (point-min))
1075                      (re-search-forward "^\\*+ " nil t)
1076                      (beginning-of-line 1)
1077                      (org-paste-subtree 1 txt)
1078                      (and org-auto-align-tags (org-set-tags nil t))
1079                      (bookmark-set "org-remember-last-stored")
1080                      (move-marker org-remember-last-stored-marker (point))))
1081                   (t
1082                    ;; Put it right there, with automatic level determined by
1083                    ;; org-paste-subtree or from prefix arg
1084                    (org-paste-subtree
1085                     (if (numberp current-prefix-arg) current-prefix-arg)
1086                     txt)
1087                    (and org-auto-align-tags (org-set-tags nil t))
1088                    (bookmark-set "org-remember-last-stored")
1089                    (move-marker org-remember-last-stored-marker (point))))
1090
1091             (when remember-save-after-remembering
1092               (save-buffer)
1093               (if (and (not visiting)
1094                        (not (equal (marker-buffer org-clock-marker)
1095                                    (current-buffer))))
1096                   (kill-buffer (current-buffer))))
1097             (when org-remember-auto-remove-backup-files
1098               (when backup-file
1099                 (ignore-errors
1100                   (delete-file backup-file)
1101                   (delete-file (concat backup-file "~"))))
1102               (when org-remember-backup-directory
1103                 (let ((n (length
1104                           (directory-files
1105                            org-remember-backup-directory nil
1106                            "^remember-.*[0-9]$"))))
1107                   (when (and org-remember-warn-about-backups
1108                              (> n 0))
1109                     (message
1110                      "%d backup files (unfinished remember calls) in %s"
1111                      n org-remember-backup-directory))))))))))
1112
1113   t)    ;; return t to indicate that we took care of this note.
1114
1115 (defun org-do-remember (&optional initial)
1116   "Call remember."
1117   (remember initial))
1118
1119 (defun org-require-remember ()
1120   "Make sure remember is loaded, or install our own emergency version of it."
1121   (condition-case nil
1122       (require 'remember)
1123     (error
1124      ;; Lets install our own micro version of remember
1125      (defvar remember-register ?R)
1126      (defvar remember-mode-hook nil)
1127      (defvar remember-handler-functions nil)
1128      (defvar remember-buffer "*Remember*")
1129      (defvar remember-save-after-remembering t)
1130      (defvar remember-annotation-functions '(buffer-file-name))
1131      (defun remember-finalize ()
1132        (run-hook-with-args-until-success 'remember-handler-functions)
1133        (when (equal remember-buffer (buffer-name))
1134          (kill-buffer (current-buffer))
1135          (jump-to-register remember-register)))
1136      (defun remember-mode ()
1137        (fundamental-mode)
1138        (setq mode-name "Remember")
1139        (run-hooks 'remember-mode-hook))
1140      (defun remember (&optional initial)
1141        (window-configuration-to-register remember-register)
1142        (let* ((annotation (run-hook-with-args-until-success
1143                            'remember-annotation-functions)))
1144          (switch-to-buffer-other-window (get-buffer-create remember-buffer))
1145          (remember-mode)))
1146      (defun remember-buffer-desc ()
1147        (buffer-substring (point-min) (save-excursion (goto-char (point-min))
1148                                                      (point-at-eol)))))))
1149
1150 (provide 'org-remember)
1151
1152 ;; arch-tag: 497f30d0-4bc3-4097-8622-2d27ac5f2698
1153
1154 ;;; org-remember.el ends here
1155