lisp/ob-gnuplot.el

   1 ;;; ob-gnuplot.el --- org-babel functions for gnuplot evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating gnuplot source code.
  27 ;;
  28 ;; This differs from most standard languages in that
  29 ;;
  30 ;; 1) we are generally only going to return results of type "file"
  31 ;;
  32 ;; 2) we are adding the "file" and "cmdline" header arguments
  33
  34 ;;; Requirements:
  35
  36 ;; - gnuplot :: http://www.gnuplot.info/
  37 ;;
  38 ;; - gnuplot-mode :: http://cars9.uchicago.edu/~ravel/software/gnuplot-mode.html
  39
  40 ;;; Code:
  41 (require 'ob)
  42 (eval-when-compile (require 'cl))
  43
  44 (declare-function org-time-string-to-time "org" (s))
  45 (declare-function org-combine-plists "org" (&rest plists))
  46 (declare-function orgtbl-to-generic "org-table" (table params))
  47 (declare-function gnuplot-mode "ext:gnuplot-mode" ())
  48 (declare-function gnuplot-send-string-to-gnuplot "ext:gnuplot-mode" (str txt))
  49 (declare-function gnuplot-send-buffer-to-gnuplot "ext:gnuplot-mode" ())
  50
  51 (defvar org-babel-default-header-args:gnuplot
  52   '((:results . "file") (:exports . "results") (:session . nil))
  53   "Default arguments to use when evaluating a gnuplot source block.")
  54
  55 (defvar org-babel-header-args:gnuplot
  56   '((title      . :any)
  57     (lines      . :any)
  58     (sets       . :any)
  59     (x-labels   . :any)
  60     (y-labels   . :any)
  61     (timefmt    . :any)
  62     (time-ind   . :any)
  63     (missing    . :any)
  64     (term       . :any))
  65   "Gnuplot specific header args.")
  66
  67 (defvar org-babel-gnuplot-timestamp-fmt nil)
  68
  69 (defvar *org-babel-gnuplot-missing* nil)
  70
  71 (defcustom *org-babel-gnuplot-terms*
  72   '((eps . "postscript eps"))
  73   "List of file extensions and the associated gnuplot terminal."
  74   :group 'org-babel
  75   :type '(repeat (cons (symbol :tag "File extension")
  76                        (string :tag "Gnuplot terminal"))))
  77
  78 (defun org-babel-gnuplot-process-vars (params)
  79   "Extract variables from PARAMS and process the variables.
  80 Dumps all vectors into files and returns an association list
  81 of variable names and the related value to be used in the gnuplot
  82 code."
  83   (let ((*org-babel-gnuplot-missing* (cdr (assoc :missing params))))
  84     (mapcar
  85      (lambda (pair)
  86        (cons
  87         (car pair) ;; variable name
  88         (if (listp (cdr pair)) ;; variable value
  89             (org-babel-gnuplot-table-to-data
  90              (cdr pair) (org-babel-temp-file "gnuplot-") params)
  91           (cdr pair))))
  92      (mapcar #'cdr (org-babel-get-header params :var)))))
  93
  94 (defun org-babel-expand-body:gnuplot (body params)
  95   "Expand BODY according to PARAMS, return the expanded body."
  96   (save-window-excursion
  97     (let* ((vars (org-babel-gnuplot-process-vars params))
  98            (out-file (cdr (assoc :file params)))
  99            (prologue (cdr (assoc :prologue params)))
 100            (epilogue (cdr (assoc :epilogue params)))
 101            (term (or (cdr (assoc :term params))
 102                      (when out-file
 103                        (let ((ext (file-name-extension out-file)))
 104                          (or (cdr (assoc (intern (downcase ext))
 105                                          *org-babel-gnuplot-terms*))
 106                              ext)))))
 107            (cmdline (cdr (assoc :cmdline params)))
 108            (title (cdr (assoc :title params)))
 109            (lines (cdr (assoc :line params)))
 110            (sets (cdr (assoc :set params)))
 111            (x-labels (cdr (assoc :xlabels params)))
 112            (y-labels (cdr (assoc :ylabels params)))
 113            (timefmt (cdr (assoc :timefmt params)))
 114            (time-ind (or (cdr (assoc :timeind params))
 115                          (when timefmt 1)))
 116            (missing (cdr (assoc :missing params)))
 117            (add-to-body (lambda (text) (setq body (concat text "\n" body))))
 118            output)
 119       ;; append header argument settings to body
 120       (when title (funcall add-to-body (format "set title '%s'" title)))
 121       (when lines (mapc (lambda (el) (funcall add-to-body el)) lines))
 122       (when missing
 123         (funcall add-to-body (format "set datafile missing '%s'" missing)))
 124       (when sets
 125         (mapc (lambda (el) (funcall add-to-body (format "set %s" el))) sets))
 126       (when x-labels
 127         (funcall add-to-body
 128                  (format "set xtics (%s)"
 129                          (mapconcat (lambda (pair)
 130                                       (format "\"%s\" %d"
 131                                               (cdr pair) (car pair)))
 132                                     x-labels ", "))))
 133       (when y-labels
 134         (funcall add-to-body
 135                  (format "set ytics (%s)"
 136                          (mapconcat (lambda (pair)
 137                                       (format "\"%s\" %d"
 138                                               (cdr pair) (car pair)))
 139                                     y-labels ", "))))
 140       (when time-ind
 141         (funcall add-to-body "set xdata time")
 142         (funcall add-to-body (concat "set timefmt \""
 143                                      (or timefmt
 144                                          "%Y-%m-%d-%H:%M:%S") "\"")))
 145       (when out-file
 146         ;; set the terminal at the top of the block
 147         (funcall add-to-body (format "set output \"%s\"" out-file))
 148         ;; and close the terminal at the bottom of the block
 149         (setq body (concat body "\nset output\n")))
 150       (when term (funcall add-to-body (format "set term %s" term)))
 151       ;; insert variables into code body: this should happen last
 152       ;; placing the variables at the *top* of the code in case their
 153       ;; values are used later
 154       (funcall add-to-body
 155                (mapconcat #'identity
 156                           (org-babel-variable-assignments:gnuplot params)
 157                           "\n"))
 158       ;; replace any variable names preceded by '$' with the actual
 159       ;; value of the variable
 160       (mapc (lambda (pair)
 161               (setq body (replace-regexp-in-string
 162                           (format "\\$%s" (car pair)) (cdr pair) body)))
 163             vars)
 164       (when prologue (funcall add-to-body prologue))
 165       (when epilogue (setq body (concat body "\n" epilogue))))
 166     body))
 167
 168 (defun org-babel-execute:gnuplot (body params)
 169   "Execute a block of Gnuplot code.
 170 This function is called by `org-babel-execute-src-block'."
 171   (require 'gnuplot)
 172   (let ((session (cdr (assoc :session params)))
 173         (result-type (cdr (assoc :results params)))
 174         (out-file (cdr (assoc :file params)))
 175         (body (org-babel-expand-body:gnuplot body params))
 176         output)
 177     (save-window-excursion
 178       ;; evaluate the code body with gnuplot
 179       (if (string= session "none")
 180           (let ((script-file (org-babel-temp-file "gnuplot-script-")))
 181             (with-temp-file script-file
 182               (insert (concat body "\n")))
 183             (message "gnuplot \"%s\"" script-file)
 184             (setq output
 185                   (shell-command-to-string
 186                    (format
 187                     "gnuplot \"%s\""
 188                     (org-babel-process-file-name
 189                      script-file
 190                      (if (member system-type '(cygwin windows-nt ms-dos))
 191                          t nil)))))
 192             (message output))
 193         (with-temp-buffer
 194           (insert (concat body "\n"))
 195           (gnuplot-mode)
 196           (gnuplot-send-buffer-to-gnuplot)))
 197       (if (member "output" (split-string result-type))
 198           output
 199         nil)))) ;; signal that output has already been written to file
 200
 201 (defun org-babel-prep-session:gnuplot (session params)
 202   "Prepare SESSION according to the header arguments in PARAMS."
 203   (let* ((session (org-babel-gnuplot-initiate-session session))
 204          (var-lines (org-babel-variable-assignments:gnuplot params)))
 205     (message "%S" session)
 206     (org-babel-comint-in-buffer session
 207       (mapc (lambda (var-line)
 208               (insert var-line) (comint-send-input nil t)
 209               (org-babel-comint-wait-for-output session)
 210               (sit-for .1) (goto-char (point-max))) var-lines))
 211     session))
 212
 213 (defun org-babel-load-session:gnuplot (session body params)
 214   "Load BODY into SESSION."
 215   (save-window-excursion
 216     (let ((buffer (org-babel-prep-session:gnuplot session params)))
 217       (with-current-buffer buffer
 218         (goto-char (process-mark (get-buffer-process (current-buffer))))
 219         (insert (org-babel-chomp body)))
 220       buffer)))
 221
 222 (defun org-babel-variable-assignments:gnuplot (params)
 223   "Return list of gnuplot statements assigning the block's variables."
 224   (mapcar
 225    (lambda (pair) (format "%s = \"%s\"" (car pair) (cdr pair)))
 226    (org-babel-gnuplot-process-vars params)))
 227
 228 (defvar gnuplot-buffer)
 229 (defun org-babel-gnuplot-initiate-session (&optional session params)
 230   "Initiate a gnuplot session.
 231 If there is not a current inferior-process-buffer in SESSION
 232 then create one.  Return the initialized session.  The current
 233 `gnuplot-mode' doesn't provide support for multiple sessions."
 234   (require 'gnuplot)
 235   (unless (string= session "none")
 236     (save-window-excursion
 237       (gnuplot-send-string-to-gnuplot "" "line")
 238       gnuplot-buffer)))
 239
 240 (defun org-babel-gnuplot-quote-timestamp-field (s)
 241   "Convert S from timestamp to Unix time and export to gnuplot."
 242   (format-time-string org-babel-gnuplot-timestamp-fmt
 243                       (org-time-string-to-time s)))
 244
 245 (defvar org-table-number-regexp)
 246 (defvar org-ts-regexp3)
 247 (defun org-babel-gnuplot-quote-tsv-field (s)
 248   "Quote S for export to gnuplot."
 249   (unless (stringp s)
 250     (setq s (format "%s" s)))
 251   (if (string-match org-table-number-regexp s) s
 252     (if (string-match org-ts-regexp3 s)
 253         (org-babel-gnuplot-quote-timestamp-field s)
 254       (if (zerop (length s))
 255           (or *org-babel-gnuplot-missing* s)
 256         (if (string-match "[ \"]" s)
 257             (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"")
 258                     "\"")
 259           s)))))
 260
 261 (defun org-babel-gnuplot-table-to-data (table data-file params)
 262   "Export TABLE to DATA-FILE in a format readable by gnuplot.
 263 Pass PARAMS through to `orgtbl-to-generic' when exporting TABLE."
 264   (with-temp-file data-file
 265     (make-local-variable 'org-babel-gnuplot-timestamp-fmt)
 266     (setq org-babel-gnuplot-timestamp-fmt (or
 267                                            (plist-get params :timefmt)
 268                                            "%Y-%m-%d-%H:%M:%S"))
 269     (insert (orgtbl-to-generic
 270              table
 271              (org-combine-plists
 272               '(:sep "\t" :fmt org-babel-gnuplot-quote-tsv-field)
 273               params))))
 274   data-file)
 275
 276 (provide 'ob-gnuplot)
 277
 278
 279
 280 ;;; ob-gnuplot.el ends here